extra/sequences/extras/extras.factor

   1 USING: accessors arrays assocs combinators generalizations
   2 grouping growable heaps kernel math math.order ranges sequences
   3 sequences.private shuffle sorting splitting vectors ;
   4 IN: sequences.extras
   5
   6 : find-all ( ... seq quot: ( ... elt -- ... ? ) -- ... elts )
   7     [ <enumerated> ] dip '[ nip @ ] assoc-filter ; inline
   8
   9 :: subseq* ( from to seq -- subseq )
  10     seq length :> len
  11     from [ dup 0 < [ len + ] when ] [ 0 ] if*
  12     to [ dup 0 < [ len + ] when ] [ len ] if*
  13     [ 0 len clamp ] bi@ dupd max seq subseq ;
  14
  15 : safe-subseq ( from to seq -- subseq )
  16     [ length '[ 0 _ clamp ] bi@ ] keep subseq ;
  17
  18 : all-subseqs ( seq -- seqs )
  19     dup length [1..b] [ clump ] with map concat ;
  20
  21 : each-subseq ( ... seq quot: ( ... subseq -- ... ) -- ... )
  22     [ dup length [ [0..b] ] [ ] bi ] dip '[
  23         dup _ (a..b] [ rot [ subseq _ call ] keep ] with each
  24     ] each drop ; inline
  25
  26 : map-like ( seq exemplar -- seq' )
  27     '[ _ like ] map ; inline
  28
  29 : filter-all-subseqs-range ( ... seq range quot: ( ... subseq -- ... ? ) -- seq )
  30     [
  31         '[ <clumps> _ filter ] with map concat
  32     ] keepdd map-like ; inline
  33
  34 : filter-all-subseqs ( ... seq quot: ( ... subseq -- ... ? ) -- seq )
  35     [ dup length [1..b] ] dip filter-all-subseqs-range ; inline
  36
  37 :: longest-subseq ( seq1 seq2 -- subseq )
  38     seq1 length :> len1
  39     seq2 length :> len2
  40     0 :> n!
  41     0 :> end!
  42     len1 1 + [ len2 1 + 0 <array> ] replicate :> table
  43     len1 [1..b] [| x |
  44         len2 [1..b] [| y |
  45             x 1 - seq1 nth-unsafe
  46             y 1 - seq2 nth-unsafe = [
  47                 y 1 - x 1 - table nth-unsafe nth-unsafe 1 + :> len
  48                 len y x table nth-unsafe set-nth-unsafe
  49                 len n > [ len n! x end! ] when
  50             ] [ 0 y x table nth-unsafe set-nth-unsafe ] if
  51         ] each
  52     ] each end n - end seq1 subseq ;
  53
  54 : pad-longest ( seq1 seq2 elt -- seq1 seq2 )
  55     [ 2dup max-length ] dip [ pad-tail ] 2curry bi@ ;
  56
  57 : pad-center ( seq n elt -- padded )
  58     swap pick length [-] [ drop ] [
  59         [ 2/ ] [ over - ] bi rot '[ _ <repetition> ] bi@
  60         pick surround-as
  61     ] if-zero ;
  62
  63 : change-nths ( ... indices seq quot: ( ... elt -- ... elt' ) -- ... )
  64     [ change-nth ] 2curry each ; inline
  65
  66 : push-if-index ( ..a elt i quot: ( ..a elt i -- ..b ? ) accum -- ..b )
  67     [ keepd ] dip rot [ push ] [ 2drop ] if ; inline
  68
  69 : push-if* ( ..a elt quot: ( ..a elt -- ..b obj/f ) accum -- ..b )
  70     [ call ] dip [ push ] [ drop ] if* ; inline
  71
  72 : push? ( elt/f accum -- )
  73     over [ push ] [ 2drop ] if ; inline
  74
  75 <PRIVATE
  76
  77 : (index-selector-as) ( quot length exampler -- selector accum )
  78     new-resizable [ [ push-if-index ] 2curry ] keep ; inline
  79
  80 : (selector-as*) ( quot length exemplar -- selector accum )
  81     new-resizable [ [ push-if* ] 2curry ] keep ; inline
  82
  83 PRIVATE>
  84
  85 : index-selector-as ( quot exemplar -- selector accum )
  86     [ length ] keep (index-selector-as) ; inline
  87
  88 : index-selector ( quot -- selector accum )
  89     V{ } index-selector-as ; inline
  90
  91 : selector-as* ( quot exemplar -- selector accum )
  92     [ length ] keep (selector-as*) ; inline
  93
  94 : selector* ( quot -- selector accum ) V{ } selector-as* ; inline
  95
  96 : filter-index-as ( ... seq quot: ( ... elt i -- ... ? ) exemplar -- ... seq' )
  97     pick length over [ (index-selector-as) [ each-index ] dip ] 2curry dip like ; inline
  98
  99 : filter-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... seq' )
 100     over filter-index-as ; inline
 101
 102 : even-indices ( seq -- seq' )
 103     [ length 1 + 2/ ] keep [
 104         [ [ 2 * ] dip nth-unsafe ] curry
 105     ] keep map-integers-as ;
 106
 107 : odd-indices ( seq -- seq' )
 108     [ length 2/ ] keep [
 109         [ [ 2 * 1 + ] dip nth-unsafe ] curry
 110     ] keep map-integers-as ;
 111
 112 : compact ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 113     [ split-when harvest ] dip join ; inline
 114
 115 : collapse ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 116     [ split-when ] dip
 117     [ [ harvest ] dip join ]
 118     [ [ first empty? ] dip [ prepend ] curry when ]
 119     [ [ last empty? ] dip [ append ] curry when ]
 120     2tri ; inline
 121
 122 :: slice-when ( seq quot: ( elt -- ? ) -- seq' )
 123     seq length :> len
 124     0 [ len dupd < ] [
 125         dup seq quot find-from drop
 126         [ 2dup = [ 1 + ] when ] [ len ] if*
 127         [ seq <slice> ] keep len or swap
 128     ] produce nip ; inline
 129
 130 : ?<slice> ( from/f to/f sequence -- slice )
 131     [ [ 0 ] unless* ] 2dip
 132     over [ nip [ length ] [ ] bi ] unless
 133     <slice> ; inline
 134
 135 : sequence>slice ( sequence -- slice )
 136     [ drop 0 ] [ length ] [ ] tri <slice> ; inline
 137
 138 : slice-order-by-from ( slice1 slice2 -- slice-lt slice-gt )
 139     2dup [ from>> ] bi@ > [ swap ] when ; inline
 140
 141 : ordered-slices-range ( slice-lt slice-gt -- to from )
 142     [ to>> ] [ from>> ] bi* ;
 143
 144 : unordered-slices-range ( slice1 slice2 -- to from )
 145     slice-order-by-from ordered-slices-range ;
 146
 147 : ordered-slices-overlap? ( slice-lt slice-gt -- ? )
 148     ordered-slices-range > ; inline
 149
 150 : unordered-slices-overlap? ( slice1 slice2 -- ? )
 151     unordered-slices-range > ; inline
 152
 153 : slices-overlap? ( slice1 slice2 -- ? )
 154     unordered-slices-overlap? ;
 155
 156 : ordered-slices-touch? ( slice-lt slice-gt -- ? )
 157     ordered-slices-range >= ; inline
 158
 159 : unordered-slices-touch? ( slice1 slice2 -- ? )
 160     unordered-slices-range >= ; inline
 161
 162 : slices-touch? ( slice1 slice2 -- ? )
 163     unordered-slices-touch? ;
 164
 165 ERROR: slices-don't-touch slice1 slice2 ;
 166
 167 : merge-slices ( slice1 slice2 -- slice/* )
 168     slice-order-by-from
 169     2dup ordered-slices-touch? [
 170         [ from>> ] [ [ to>> ] [ seq>> ] bi ] bi* <slice>
 171     ] [
 172         slices-don't-touch
 173     ] if ;
 174
 175 : rotate ( seq n -- seq' )
 176     over length mod dup 0 >= [ cut ] [ abs cut* ] if prepend ;
 177
 178 ERROR: underlying-mismatch slice1 slice2 ;
 179
 180 : ensure-same-underlying ( slice1 slice2 -- slice1 slice2 )
 181     2dup [ seq>> ] bi@ eq? [ underlying-mismatch ] unless ;
 182
 183 : span-slices ( slice1 slice2 -- slice )
 184     ensure-same-underlying
 185     [ [ from>> ] bi@ min ]
 186     [ [ to>> ] bi@ max ]
 187     [ drop seq>> ] 2tri <slice> ;
 188
 189 : ?span-slices ( slice1/f slice2/f -- slice )
 190     2dup and [ span-slices ] [ or ] if ;
 191
 192 :: rotate! ( seq n -- )
 193     seq length :> len
 194     n len mod dup 0 < [ len + ] when seq bounds-check drop 0 over
 195     [ 2dup = ] [
 196         [ seq exchange-unsafe ] [ [ 1 + ] bi@ ] 2bi
 197         dup len = [ drop over ] when
 198         2over = [ -rot nip over ] when
 199     ] until 3drop ;
 200
 201 : all-rotations ( seq -- seq' )
 202     dup length <iota> [ rotate ] with map ;
 203
 204 <PRIVATE
 205
 206 : (appender-for) ( quot length exemplar -- appender accum )
 207     new-resizable [ [ push-all ] curry compose ] keep ; inline
 208
 209 PRIVATE>
 210
 211 : appender-for ( quot exemplar -- appender accum )
 212     [ length ] keep (appender-for) ; inline
 213
 214 : appender ( quot -- appender accum )
 215     V{ } appender-for ; inline
 216
 217 : map-concat-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 218     [ appender-for [ each ] dip ] keep like ; inline
 219
 220 : >resizable ( seq -- accum ) ! fixes map-concat "cannot apply call to run-time..."
 221     [ length ] keep [ new-resizable ] [ append! ] bi ;
 222
 223 : map-concat ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 224     over empty? [ 2drop { } ] [
 225         [ [ first ] dip call ] 2keep rot [
 226             >resizable [ '[ @ _ push-all ] 1 each-from ] keep
 227         ] keep like
 228     ] if ; inline
 229
 230 : map-filter-as ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) exemplar -- ... subseq )
 231     reach length over
 232     [ (selector-as) [ compose each ] dip ] 2curry dip like ; inline
 233
 234 : map-filter ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) -- ... subseq )
 235     pick map-filter-as ; inline
 236
 237 : map-sift ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 238     [ ] map-filter ; inline
 239
 240 : map-harvest ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 241     [ empty? not ] map-filter ; inline
 242
 243 : (each-integer-with-previous) ( ... prev i n quot: ( ... i -- ... ) -- ... )
 244     2over < [
 245         [ nip call ] 4keep nipdd
 246         [ 1 + ] 2dip (each-integer-with-previous)
 247     ] [
 248         4drop
 249     ] if ; inline recursive
 250
 251 : each-integer-with-previous ( ... n quot: ( ... i -- ... ) -- ... )
 252     [ f 0 ] 2dip (each-integer-with-previous) ; inline
 253
 254 : (collect-with-previous) ( quot into -- quot' )
 255     [ [ keep ] dip [ set-nth-unsafe ] keepdd ] 2curry ; inline
 256
 257 : collect-with-previous ( n quot into --  )
 258     (collect-with-previous) each-integer-with-previous ; inline
 259
 260 : map-integers-with ( ... len quot: ( ... prev i -- ... elt ) exemplar -- ... newseq )
 261     overd [ [ collect-with-previous ] keep ] new-like ; inline
 262
 263 : map-with-previous-as ( ... seq quot: ( ... elt prev/f -- ... newelt ) exemplar -- ... newseq )
 264     [ length-operator ] dip map-integers-with ; inline
 265
 266 : map-with-previous ( ... seq quot: ( ... elt prev/f -- ... newelt ) -- ... newseq )
 267     over map-with-previous-as ; inline
 268
 269 : setup-each-from ( seq quot -- n quot )
 270     [ [ length ] keep [ nth-unsafe ] curry ] dip compose ; inline
 271
 272 : map-from-as ( ... seq quot: ( ... elt -- ... newelt ) from exemplar -- ... newseq )
 273     -rotd [ sequence-operator nipd ] dip map-integers-from-as ; inline
 274
 275 : map-from ( ... seq quot: ( ... elt -- ... newelt ) from -- ... newseq )
 276     pick map-from-as ; inline
 277
 278 : map-if ( ... seq if-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) -- ... newseq )
 279     '[ dup @ _ when ] map ; inline
 280
 281 : reduce-from ( ... seq identity quot: ( ... prev elt -- ... next ) from -- ... result )
 282     [ swap ] 2dip each-from ; inline
 283
 284 : 2reduce-from ( ... seq1 seq2 identity quot: ( ... prev elt1 elt2 -- ... next ) i -- ... result )
 285     [ -rot ] 2dip 2each-from ; inline
 286
 287 : 0accumulate-as ( ... seq quot: ( ... prev elt -- ... next ) exemplar -- ... newseq )
 288     pick empty? [
 289         2nip clone
 290     ] [
 291         [ 0 ] 2dip
 292         [ swapd [ dup ] compose ] dip map-as nip
 293     ] if ; inline
 294
 295 : 0accumulate ( ... seq quot: ( ... prev elt -- ... next ) -- ... final newseq )
 296     over 0accumulate-as ; inline
 297
 298 : occurrence-count-by ( seq quot: ( elt -- elt' ) -- hash seq' )
 299     '[ nip @ over inc-at* ] [ H{ } clone ] 2dip 0accumulate ; inline
 300
 301 : occurrence-count ( seq -- hash seq' )
 302     [ ] occurrence-count-by ; inline
 303
 304 : nth-index ( n obj seq -- i )
 305     [ = dup [ drop 1 - dup 0 < ] when ] with find drop nip ;
 306
 307 : progressive-index-by-as ( seq1 seq2 quot exemplar -- hash seq' )
 308     [
 309         pick length '[
 310             tuck [ @ over inc-at* ] 2dip swap nth-index _ or
 311         ] [ H{ } clone ] 3dip with
 312     ] dip map-as ; inline
 313
 314 : progressive-index-by ( seq1 seq2 quot -- hash seq' )
 315     { } progressive-index-by-as ; inline
 316
 317 : progressive-index ( seq1 seq2 -- hash seq' )
 318     [ ] progressive-index-by ; inline
 319
 320 : 0reduce ( seq quot: ( prev elt -- next ) -- result )
 321     [ 0 ] dip reduce ; inline
 322
 323 <PRIVATE
 324
 325 : push-map-if ( ..a elt filter-quot: ( ..a elt -- ..b ? ) map-quot: ( ..a elt -- ..b newelt ) accum -- ..b )
 326     [ keep over ] 2dip [ when ] dip rot [ push ] [ 2drop ] if ; inline
 327
 328 : (filter-mapper-for) ( filter-quot map-quot length exempler -- filter-mapper accum )
 329     new-resizable [ [ push-map-if ] 3curry ] keep ; inline
 330
 331 : filter-mapper-for ( filter-quot map-quot exemplar -- filter-mapper accum )
 332     [ length ] keep (filter-mapper-for) ; inline
 333
 334 : filter-mapper ( filter-quot map-quot -- filter-mapper accum )
 335     V{ } filter-mapper-for ; inline
 336
 337 PRIVATE>
 338
 339 : filter-map-as ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 340     reach length over
 341     [ (filter-mapper-for) [ each ] dip ] 2curry dip like ; inline
 342
 343 : filter-map ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) -- ... newseq )
 344     pick filter-map-as ; inline
 345
 346 : 2filter-as ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) exemplar -- ... newseq )
 347     [
 348         pick [ length ] keep
 349         [ (2selector-as) [ 2each ] dip ] 2curry call
 350     ] dip like ; inline
 351
 352 : 2filter ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
 353     pick 2filter-as ; inline
 354
 355 : 2reject-as ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) exemplar -- ... newseq )
 356     [ [ not ] compose ] dip 2filter-as ; inline
 357
 358 : 2reject ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
 359     pick 2reject-as ; inline
 360
 361 : 2map-sum ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... n ) -- ... n )
 362     [ 0 ] 3dip [ dip + ] curry [ rot ] prepose 2each ; inline
 363
 364 : 2count ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... n )
 365     [ 1 0 ? ] compose 2map-sum ; inline
 366
 367 : 3each-from
 368     ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... ) i -- ... )
 369     [ 3length-operator ] dip -rot each-integer-from ; inline
 370
 371 : 3map-reduce
 372     ( ..a seq1 seq2 seq3 map-quot: ( ..a elt1 elt2 elt3 -- ..b intermediate ) reduce-quot: ( ..b prev intermediate -- ..a next ) -- ..a result )
 373     [ [ [ [ first ] tri@ ] 3keep ] dip [ 3dip ] keep ] dip compose 1 3each-from ; inline
 374
 375 : round-robin ( seq -- newseq )
 376     [ { } ] [
 377         [ longest length <iota> ] keep
 378         [ [ ?nth ] with map ] curry map concat sift
 379     ] if-empty ;
 380
 381 : sift-as ( seq exemplar -- newseq )
 382     [ ] swap filter-as ;
 383
 384 : sift! ( seq -- newseq )
 385     [ ] filter! ;
 386
 387 : harvest-as ( seq exemplar -- newseq )
 388     [ empty? not ] swap filter-as ;
 389
 390 : harvest! ( seq -- newseq )
 391     [ empty? ] reject! ;
 392
 393 : head-as ( seq n exemplar -- seq' )
 394     [ head-slice ] [ like ] bi* ; inline
 395
 396 : head*-as ( seq n exemplar -- seq' )
 397     [ head-slice* ] [ like ] bi* ; inline
 398
 399 : tail-as ( seq n exemplar -- seq' )
 400     [ tail-slice ] [ like ] bi* ; inline
 401
 402 : tail*-as ( seq n exemplar -- seq' )
 403     [ tail-slice* ] [ like ] bi* ; inline
 404
 405 : trim-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... newseq )
 406     [ trim-slice ] [ like ] bi* ; inline
 407
 408 : ?trim ( seq quot: ( elt -- ? ) -- seq/newseq )
 409     over empty? [ drop ] [
 410         over [ first-unsafe ] [ last-unsafe ] bi pick either?
 411         [ trim ] [ drop ] if
 412     ] if ; inline
 413
 414 : ?trim-head ( seq quot: ( elt -- ? ) -- seq/newseq )
 415     over empty? [ drop ] [
 416         over first-unsafe over call
 417         [ trim-head ] [ drop ] if
 418     ] if ; inline
 419
 420 : ?trim-tail ( seq quot: ( elt -- ? ) -- seq/newseq )
 421     over empty? [ drop ] [
 422         over last-unsafe over call
 423         [ trim-tail ] [ drop ] if
 424     ] if ; inline
 425
 426 : unsurround ( newseq seq2 seq3 -- seq1 )
 427     [ ?head drop ] [ ?tail drop ] bi* ;
 428
 429 : >string-list ( seq -- seq' )
 430     [ "\"" 1surround ] map "," join ;
 431
 432 : with-string-lines ( str quot -- str' )
 433     [ string-lines ] dip map "\n" join ; inline
 434
 435 : prepend-lines-with-spaces ( str -- str' )
 436     [ "    " prepend ] with-string-lines ;
 437
 438 : one? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 439     [ find ] 2keep rot [
 440         [ 1 + ] 2dip find-from drop not
 441     ] [ 3drop f ] if ; inline
 442
 443 : map-index! ( ... seq quot: ( ... elt index -- ... newelt ) -- ... seq )
 444     over [ [ sequence-index-operator ] dip collect ] keep ; inline
 445
 446 <PRIVATE
 447
 448 : 2sequence-index-iterator ( seq1 seq2 quot -- n quot' )
 449     [ 2length-iterator [ keep ] curry ] dip compose ; inline
 450
 451 PRIVATE>
 452
 453 : 2each-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... ) -- ... )
 454     2sequence-index-iterator each-integer ; inline
 455
 456 : 2map-into ( seq1 seq2 quot into -- )
 457     [ 2length-operator ] dip collect ; inline
 458
 459 : 2map! ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... seq1 )
 460     pick [ 2map-into ] keep ; inline
 461
 462 : 2map-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... newelt ) -- ... newseq )
 463     pick [ 2sequence-index-iterator ] dip map-integers-as ; inline
 464
 465 TUPLE: evens { seq read-only } ;
 466
 467 C: <evens> evens
 468
 469 M: evens length seq>> length 1 + 2/ ; inline
 470
 471 M: evens virtual@ [ 2 * ] [ seq>> ] bi* ; inline
 472
 473 M: evens virtual-exemplar seq>> ; inline
 474
 475 INSTANCE: evens virtual-sequence
 476
 477 TUPLE: odds { seq read-only } ;
 478
 479 C: <odds> odds
 480
 481 M: odds length seq>> length 2/ ; inline
 482
 483 M: odds virtual@ [ 2 * 1 + ] [ seq>> ] bi* ; inline
 484
 485 M: odds virtual-exemplar seq>> ; inline
 486
 487 INSTANCE: odds virtual-sequence
 488
 489 : until-empty ( seq quot -- )
 490     [ dup empty? ] swap until drop ; inline
 491
 492 <PRIVATE
 493
 494 : push-index-if ( ..a elt i quot: ( ..a elt -- ..b ? ) accum -- ..b )
 495     [ dip ] dip rot [ push ] [ 2drop ] if ; inline
 496
 497 PRIVATE>
 498
 499 : arg-where ( ... seq quot: ( ... elt -- ... ? ) -- ... indices )
 500     over length <vector> [
 501         [ push-index-if ] 2curry each-index
 502     ] keep ; inline
 503
 504 : arg-sort ( seq -- indices )
 505     zip-index sort-keys values ;
 506
 507 : first= ( seq elt -- ? ) [ first ] dip = ; inline
 508 : second= ( seq elt -- ? ) [ second ] dip = ; inline
 509 : third= ( seq elt -- ? ) [ third ] dip = ; inline
 510 : fourth= ( seq elt -- ? ) [ fourth ] dip = ; inline
 511 : last= ( seq elt -- ? ) [ last ] dip = ; inline
 512 : nth= ( n seq elt -- ? ) [ nth ] dip = ; inline
 513
 514 : first? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ first ] dip call ; inline
 515 : second? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ second ] dip call ; inline
 516 : third? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ third ] dip call ; inline
 517 : fourth? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ fourth ] dip call ; inline
 518 : last? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ last ] dip call ; inline
 519 : nth? ( ... n seq quot: ( ... elt -- ... ? ) -- ... ? ) [ nth ] dip call ; inline
 520
 521 : loop>sequence** ( ... quot: ( ... -- ... obj ? ) exemplar -- ... seq )
 522     [ ] swap produce-as nip ; inline
 523
 524 : loop>array** ( ... quot: ( ... -- ... obj ? ) -- ... array )
 525     { } loop>sequence** ; inline
 526
 527 : loop>sequence* ( ... quot: ( ... -- ... obj ? ) exemplar -- ... seq )
 528     [ t ] [ '[ [ _ dip ] [ f f f ] if* ] [ swap ] ] [ produce-as 2nip ] tri* ; inline
 529
 530 : loop>array* ( ... quot: ( ... -- ... obj ? ) -- ... array )
 531     { } loop>sequence* ; inline
 532
 533 : loop>sequence ( ... quot: ( ... -- ... obj/f ) exemplar -- ... seq )
 534     [ [ dup ] compose [ ] ] dip produce-as nip ; inline
 535
 536 : loop>array ( ... quot: ( ... -- ... obj/f ) -- ... array )
 537     { } loop>sequence ; inline
 538
 539 : zero-loop>sequence ( ... quot: ( ... n -- ... obj/f ) exemplar -- ... seq )
 540     [ 0 ] [ '[ _ keep 1 + swap ] ] [ loop>sequence ] tri* nip ; inline
 541
 542 : zero-loop>array ( quot: ( ..a n -- ..a obj ) -- seq )
 543     { } zero-loop>sequence ; inline
 544
 545 : iterate-heap-while ( heap quot1: ( value key -- slurp? ) quot2: ( value key -- obj/f ) -- obj/f loop? )
 546     pick heap-empty?
 547     [ 3drop f f ]
 548     [
 549         [ [ heap-peek ] 2dip drop 2keep ]
 550         [
 551             nip ! ( pop? value key heap quot2 )
 552             5roll [
 553                 swap heap-pop* call( value key -- obj/f ) t
 554             ] [
 555                 4drop f f
 556             ] if
 557         ] 3bi
 558     ] if ; inline
 559
 560 : slurp-heap-while-map ( heap quot1: ( value key -- slurp? ) quot2: ( value key -- obj/f ) -- seq )
 561     '[ _ _ _ iterate-heap-while ] loop>array* ; inline
 562
 563 : heap>pairs ( heap -- pairs )
 564     [ 2drop t ] [ swap 2array ] slurp-heap-while-map ;
 565
 566 : map-zip-swap ( quot: ( x -- y ) -- alist )
 567     '[ _ keep ] map>alist ; inline
 568
 569 : ?heap-pop-value>array ( heap -- array )
 570     dup heap-empty? [ drop { } ] [ heap-pop drop 1array ] if ;
 571
 572 <PRIVATE
 573
 574 : (reverse) ( seq -- newseq )
 575     dup [ length ] keep new-sequence
 576     [ 0 swap copy-unsafe ] keep reverse! ;
 577
 578 PRIVATE>
 579
 580 : reverse-as ( seq exemplar -- newseq )
 581     [ (reverse) ] [ like ] bi* ;
 582
 583 : map-product ( ... seq quot: ( ... elt -- ... n ) -- ... n )
 584     [ 1 ] 2dip [ dip * ] with-assoc each ; inline
 585
 586 : insert-nth! ( elt n seq -- )
 587     [ length ] keep ensure swap pick (a..b]
 588     over '[ [ 1 + ] keep _ move-unsafe ] each
 589     set-nth-unsafe ;
 590
 591 : set-nths ( value indices seq -- )
 592     swapd '[ _ swap _ set-nth ] each ; inline
 593
 594 : set-nths-unsafe ( value indices seq -- )
 595     swapd '[ _ swap _ set-nth-unsafe ] each ; inline
 596
 597 <PRIVATE
 598
 599 : (map-find-index) ( seq quot find-quot -- result i elt )
 600     [ [ f ] 2dip [ [ nip ] 2dip call dup ] curry ] dip call
 601     [ [ [ drop f ] unless ] keep ] dip ; inline
 602
 603 PRIVATE>
 604
 605 : map-find-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 606     [ find-index ] (map-find-index) ; inline
 607
 608 : filter-length ( seq n -- seq' ) '[ length _ = ] filter ;
 609
 610 : all-shortest ( seqs -- seqs' ) dup shortest length filter-length ;
 611
 612 : all-longest ( seqs -- seqs' ) dup longest length filter-length ;
 613
 614 : remove-first ( obj seq -- seq' )
 615     [ index ] keep over [ remove-nth ] [ nip ] if ;
 616
 617 : remove-first! ( obj seq -- seq )
 618     [ index ] keep over [ remove-nth! ] [ nip ] if ;
 619
 620 : remove-last ( obj seq -- seq' )
 621     [ last-index ] keep over [ remove-nth ] [ nip ] if ;
 622
 623 : remove-last! ( obj seq -- seq )
 624     [ last-index ] keep over [ remove-nth! ] [ nip ] if ;
 625
 626 : ?first2 ( seq -- first/f second/f )
 627     dup length {
 628         { 0 [ drop f f ] }
 629         { 1 [ first-unsafe f ] }
 630         [ drop first2-unsafe ]
 631     } case ;
 632
 633 : ?first3 ( seq -- first/f second/f third/f )
 634     dup length {
 635         { 0 [ drop f f f ] }
 636         { 1 [ first-unsafe f f ] }
 637         { 2 [ first2-unsafe f ] }
 638         [ drop first3-unsafe ]
 639     } case ;
 640
 641 : ?first4 ( seq -- first/f second/f third/f fourth/f )
 642     dup length {
 643         { 0 [ drop f f f f ] }
 644         { 1 [ first-unsafe f f f ] }
 645         { 2 [ first2-unsafe f f ] }
 646         { 3 [ first3-unsafe f ] }
 647         [ drop first4-unsafe ]
 648     } case ;
 649
 650 : cut-when ( ... seq quot: ( ... elt -- ... ? ) -- ... before after )
 651     [ find drop ] keepd swap
 652     [ cut ] [ f over like ] if* ; inline
 653
 654 : nth* ( n seq -- elt )
 655     [ length 1 - swap - ] [ nth ] bi ; inline
 656
 657 : each-index-from ( ... seq quot: ( ... elt index -- ... ) i -- ... )
 658     -rot sequence-index-operator each-integer-from ; inline
 659
 660 <PRIVATE
 661
 662 : select-by* ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... i elt )
 663     [
 664         [ keep swap ] curry [ dip ] curry
 665         [ [ first 0 ] dip call ] 2keep
 666         [ 2curry 3dip 5 npick pick ] curry
 667     ] [
 668         [ [ 3drop ] [ [ 3drop ] 3dip ] if ] compose
 669     ] bi* compose 1 each-index-from nip swap ; inline
 670
 671 PRIVATE>
 672
 673 : supremum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 674     [ after? ] select-by* ; inline
 675
 676 : infimum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 677     [ before? ] select-by* ; inline
 678
 679 : arg-max ( seq -- n )
 680     [ ] supremum-by* drop ;
 681
 682 : arg-min ( seq -- n )
 683     [ ] infimum-by* drop ;
 684
 685 : ?supremum ( seq/f -- elt/f )
 686     [ f ] [
 687         [ ] [ 2dup and [ max ] [ dupd ? ] if ] map-reduce
 688     ] if-empty ;
 689
 690 : ?infimum ( seq/f -- elt/f )
 691     [ f ] [
 692         [ ] [ 2dup and [ min ] [ dupd ? ] if ] map-reduce
 693     ] if-empty ;
 694
 695 : map-infimum ( seq quot: ( ... elt -- ... elt' ) -- elt' )
 696     [ min ] map-reduce ; inline
 697
 698 : map-supremum ( seq quot: ( ... elt -- ... elt' ) -- elt' )
 699     [ max ] map-reduce ; inline
 700
 701 : change-last ( seq quot -- )
 702     [ index-of-last ] [ change-nth ] bi* ; inline
 703
 704 : change-last-unsafe ( seq quot -- )
 705     [ index-of-last ] [ change-nth-unsafe ] bi* ; inline
 706
 707 : replicate-into ( ... seq quot: ( ... -- ... newelt ) -- ... )
 708     over [ length ] 2dip '[ _ dip _ set-nth-unsafe ] each-integer ; inline
 709
 710 : count* ( ... seq quot: ( ... elt -- ... ? ) -- ... % )
 711     over [ count ] [ length ] bi* / ; inline
 712
 713 : sequence-index-operator-last ( n seq quot -- n quot' )
 714     [ [ nth-unsafe ] curry [ keep ] curry ] dip compose ; inline
 715
 716 : find-last-index-from ( ... n seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 717     '[
 718         _ [ sequence-index-operator-last find-last-integer ] keepd
 719         index/element
 720     ] bounds-check-call ; inline
 721
 722 : find-last-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 723     [ index-of-last ] dip find-last-index-from ; inline
 724
 725 : map-find-last-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 726     [ find-last-index ] (map-find-index) ; inline
 727
 728 :: (start-all) ( seq subseq increment -- indices )
 729     0
 730     [ seq subseq subseq-index-from dup ]
 731     [ [ increment + ] keep ] produce nip ;
 732
 733 : start-all ( seq subseq -- indices )
 734     dup length (start-all) ; inline
 735
 736 : start-all* ( seq subseq -- indices )
 737     1 (start-all) ; inline
 738
 739 : count-subseq ( seq subseq -- n )
 740     start-all length ; inline
 741
 742 : count-subseq* ( seq subseq -- n )
 743     start-all* length ; inline
 744
 745 : assoc-zip-with ( quot: ( key value -- calc ) -- alist )
 746     '[ _ 2keep 2array swap ] assoc-map ; inline
 747
 748 : take-while ( ... seq quot: ( ... elt -- ... ? ) -- head-slice )
 749     [ '[ @ not ] find drop ] keepd swap
 750     [ dup length ] unless* head-slice ; inline
 751
 752 : drop-while ( ... seq quot: ( ... elt -- ... ? ) -- tail-slice )
 753     [ '[ @ not ] find drop ] keepd swap
 754     [ dup length ] unless* tail-slice ; inline
 755
 756 : count-head ( seq quot -- n )
 757     [ not ] compose [ find drop ] keepd length or ; inline
 758
 759 : count-tail ( seq quot -- n )
 760     [ not ] compose [ find-last drop ] keepd
 761     length swap [ - 1 - ] when* ; inline
 762
 763 :: shorten* ( vector n -- seq )
 764     vector n tail
 765     n vector shorten ;
 766
 767 :: interleaved-as ( seq glue exemplar -- newseq )
 768     seq length dup 1 - + 0 max exemplar new-sequence :> newseq
 769     seq [ 2 * newseq set-nth-unsafe ] each-index
 770     seq length 1 - [ 2 * 1 + glue swap newseq set-nth-unsafe ] each-integer
 771     newseq ;
 772
 773 : interleaved ( seq glue -- newseq )
 774     over interleaved-as ;
 775
 776 : extract! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 777     [ dup ] compose over [ length ] keep new-resizable
 778     [ [ push-when ] 2curry reject! ] keep swap like ; inline
 779
 780 : find-pred-loop ( ... i n seq quot: ( ... elt -- ... calc ? ) -- ... calc/f i/f elt/f )
 781     2pick < [
 782         [ nipd call ] 4keep
 783         3 7 0 nrotated
 784         [ [ 3drop ] 2dip rot ]
 785         [ 2drop [ 1 + ] 3dip find-pred-loop ] if
 786     ] [
 787         4drop f f f
 788     ] if ; inline recursive
 789
 790 : find-pred ( ... seq quot: ( ... elt -- ... calc ) pred: ( ... calc -- ... ? ) -- ... calc/f i/f elt/f )
 791     [ 0 ] 3dip
 792     [ [ length check-length ] keep ] 2dip
 793     '[ nth-unsafe _ keep swap _ keep swap ] find-pred-loop swapd ; inline
 794
 795 ! https://en.wikipedia.org/wiki/Maximum_subarray_problem
 796 ! Kadane's algorithm O(n) largest sum in subarray
 797 : max-subarray-sum ( seq -- sum )
 798     [ -1/0. 0 ] dip
 799     [ [ + ] keep max [ max ] keep ] each drop ;
 800
 801 TUPLE: step-slice
 802     { from integer read-only initial: 0 }
 803     { to integer read-only initial: 0 }
 804     { seq read-only }
 805     { step integer read-only } ;
 806
 807 :: <step-slice> ( from/f to/f step seq -- step-slice )
 808     step zero? [ "can't be zero" throw ] when
 809     seq length :> len
 810     step 0 > [
 811         from/f [ 0 ] unless*
 812         to/f [ len ] unless*
 813     ] [
 814         from/f [ len ] unless*
 815         to/f [ 0 ] unless*
 816     ] if
 817     [ dup 0 < [ len + ] when 0 len clamp ] bi@
 818     ! FIXME: make this work with steps
 819     seq dup slice? [ collapse-slice ] when
 820     step step-slice boa ;
 821
 822 M: step-slice virtual-exemplar seq>> ; inline
 823
 824 M: step-slice virtual@
 825     [ step>> * ] [ from>> + ] [ seq>> ] tri ; inline
 826
 827 M: step-slice length
 828     [ to>> ] [ from>> - ] [ step>> ] tri
 829     dup 0 < [ [ neg 0 max ] dip neg ] when /mod
 830     zero? [ 1 + ] unless ; inline
 831
 832 INSTANCE: step-slice virtual-sequence
 833
 834 : 2nested-each* ( seq1 seq-quot: ( n -- seq ) quot: ( a b -- ) -- )
 835     '[
 836         _ keep swap _ with each
 837     ] each ; inline
 838
 839 : 2nested-filter-as* ( seq1 seq-quot quot exemplar -- seq )
 840     [ 2over [ length ] bi@ * ] dip
 841     [
 842         new-resizable
 843         [ [ push? ] curry compose 2nested-each* ] keep
 844     ] keep like ; inline
 845
 846 : 2nested-filter* ( seq1 seq-quot quot -- seq )
 847     pick 2nested-filter-as* ; inline
 848
 849 : 2nested-map-as* ( seq1 seq-quot quot exemplar -- seq )
 850     [ 2over [ length ] bi@ * ] dip
 851     [
 852         new-resizable
 853         [ [ push ] curry compose 2nested-each* ] keep
 854     ] keep like ; inline
 855
 856 : 2nested-map* ( seq1 seq-quot quot -- seq )
 857     pick 2nested-map-as* ; inline
 858
 859
 860 : 2nested-each ( seq1 seq2 quot -- )
 861     swapd '[
 862         swap _ with each
 863     ] with each ; inline
 864
 865 : 2nested-filter-as ( seq1 seq2 quot exemplar -- seq )
 866     [ 2over [ length ] bi@ * ] dip
 867     [
 868         new-resizable
 869         [ [ push? ] curry compose 2nested-each ] keep
 870     ] keep like ; inline
 871
 872 : 2nested-filter ( seq1 seq2 quot -- seq )
 873     pick 2nested-filter-as ; inline
 874
 875 : 2nested-map-as ( seq1 seq2 quot exemplar -- seq )
 876     [ 2over [ length ] bi@ * ] dip
 877     [
 878         new-resizable
 879         [ [ push ] curry compose 2nested-each ] keep
 880     ] keep like ; inline
 881
 882 : 2nested-map ( seq1 seq2 quot -- seq )
 883     pick 2nested-map-as ; inline
 884
 885 : 3nested-each ( seq1 seq2 seq3 quot -- )
 886     [ spin ] dip '[
 887         -rot [
 888             swap _ with with each
 889         ] with with each
 890     ] with with each ; inline
 891
 892 : 3nested-filter-as ( seq1 seq2 seq3 quot exemplar -- seq )
 893     [ 3 nover [ length ] tri@ * * ] dip
 894     [
 895         new-resizable
 896         [ [ push? ] curry compose 3nested-each ] keep
 897     ] keep like ; inline
 898
 899 : 3nested-filter ( seq1 seq2 seq3 quot -- seq )
 900     reach 3nested-filter-as ; inline
 901
 902 : 3nested-map-as ( seq1 seq2 seq3 quot exemplar -- seq )
 903     [ 3 nover [ length ] tri@ * * ] dip
 904     [
 905         new-resizable
 906         [ [ push ] curry compose 3nested-each ] keep
 907     ] keep like ; inline
 908
 909 : 3nested-map ( seq1 seq2 seq3 quot -- seq )
 910     reach 3nested-map-as ; inline
 911
 912 : prev ( n seq -- obj ) [ 1 - ] dip nth ; inline
 913 : ?prev ( n seq -- obj/f ) [ 1 - ] dip ?nth ; inline
 914 : ??prev ( n seq -- obj/f ? ) [ 1 - ] dip ??nth ; inline
 915 : prev-of ( seq n -- obj ) 1 - nth-of ; inline
 916 : ?prev-of ( seq n -- obj/f ) 1 - ?nth-of ; inline
 917 : ??prev-of ( seq n -- obj/f ? ) 1 - ??nth-of ; inline
 918
 919 : prev-identity ( i seq -- identity i seq )
 920     2dup ??prev [ drop 0 ] unless -rot ; inline
 921
 922 : each-prior-identity-from ( ... identity i seq quot: ( ... prior elt -- ... ) -- ... )
 923     '[ [ swap @ ] keep ]
 924     length-operator each-integer-from drop ; inline
 925
 926 : each-prior-from ( ... i seq quot: ( ... prior elt -- ... ) -- ... )
 927     [ prev-identity ] dip each-prior-identity-from ; inline
 928
 929 : each-prior ( ... seq quot: ( ... prior elt -- ... ) -- ... )
 930     0 -rot each-prior-from ; inline
 931
 932 : map-prior-identity-from-as ( ... identity i seq quot: ( ... prior elt -- elt' ) exemplar -- seq' )
 933     [
 934         '[ [ swap @ ] keep swap ] length-operator
 935     ] dip map-integers-from-as nip ; inline
 936
 937 : map-prior-identity-as ( ... identity seq quot: ( ... prior elt -- elt' ) exemplar -- seq' )
 938     [ 0 ] 3dip map-prior-identity-from-as ; inline
 939
 940 : map-prior-from-as ( ... i seq quot: ( ... prior elt -- elt' ) exemplar -- seq' )
 941     [ prev-identity ] 2dip map-prior-identity-from-as ; inline
 942
 943 : map-prior-as ( ... seq quot: ( ... prior elt -- elt' ) exemplar -- seq' )
 944     0 -roll map-prior-from-as ; inline
 945
 946 : map-prior-from ( ... i seq quot: ( ... prior elt -- elt' ) -- seq' )
 947     over map-prior-from-as ; inline
 948
 949 : map-prior ( ... seq quot: ( ... prior elt -- elt' ) -- seq' )
 950     over map-prior-as ; inline
 951
 952 TUPLE: virtual-zip-index seq ;
 953
 954 C: <zip-index> virtual-zip-index
 955
 956 M: virtual-zip-index length seq>> length ; inline
 957
 958 M: virtual-zip-index nth-unsafe
 959     over [ seq>> nth-unsafe ] [ 2array ] bi* ; inline
 960
 961 INSTANCE: virtual-zip-index immutable-sequence