extra/sequences/extras/extras.factor

   1 USING: accessors arrays assocs combinators generalizations
   2 grouping growable heaps kernel math math.order ranges sequences
   3 sequences.private shuffle sorting splitting vectors ;
   4 IN: sequences.extras
   5
   6 : find-all ( ... seq quot: ( ... elt -- ... ? ) -- ... elts )
   7     [ <enumerated> ] dip '[ nip @ ] assoc-filter ; inline
   8
   9 :: subseq* ( from to seq -- subseq )
  10     seq length :> len
  11     from [ dup 0 < [ len + ] when ] [ 0 ] if*
  12     to [ dup 0 < [ len + ] when ] [ len ] if*
  13     [ 0 len clamp ] bi@ dupd max seq subseq ;
  14
  15 : safe-subseq ( from to seq -- subseq )
  16     [ length '[ 0 _ clamp ] bi@ ] keep subseq ;
  17
  18 : all-subseqs ( seq -- seqs )
  19     dup length [1..b] [ clump ] with map concat ;
  20
  21 : each-subseq ( ... seq quot: ( ... subseq -- ... ) -- ... )
  22     [ dup length [ [0..b] ] [ ] bi ] dip '[
  23         dup _ (a..b] [ rot [ subseq _ call ] keep ] with each
  24     ] each drop ; inline
  25
  26 : map-like ( seq exemplar -- seq' )
  27     '[ _ like ] map ; inline
  28
  29 : filter-all-subseqs-range ( ... seq range quot: ( ... subseq -- ... ? ) -- seq )
  30     [
  31         '[ <clumps> _ filter ] with map concat
  32     ] keepdd map-like ; inline
  33
  34 : filter-all-subseqs ( ... seq quot: ( ... subseq -- ... ? ) -- seq )
  35     [ dup length [1..b] ] dip filter-all-subseqs-range ; inline
  36
  37 :: longest-subseq ( seq1 seq2 -- subseq )
  38     seq1 length :> len1
  39     seq2 length :> len2
  40     0 :> n!
  41     0 :> end!
  42     len1 1 + [ len2 1 + 0 <array> ] replicate :> table
  43     len1 [1..b] [| x |
  44         len2 [1..b] [| y |
  45             x 1 - seq1 nth-unsafe
  46             y 1 - seq2 nth-unsafe = [
  47                 y 1 - x 1 - table nth-unsafe nth-unsafe 1 + :> len
  48                 len y x table nth-unsafe set-nth-unsafe
  49                 len n > [ len n! x end! ] when
  50             ] [ 0 y x table nth-unsafe set-nth-unsafe ] if
  51         ] each
  52     ] each end n - end seq1 subseq ;
  53
  54 : pad-longest ( seq1 seq2 elt -- seq1 seq2 )
  55     [ 2dup max-length ] dip [ pad-tail ] 2curry bi@ ;
  56
  57 : pad-center ( seq n elt -- padded )
  58     swap pick length [-] [ drop ] [
  59         [ 2/ ] [ over - ] bi rot '[ _ <repetition> ] bi@
  60         pick surround-as
  61     ] if-zero ;
  62
  63 : change-nths ( ... indices seq quot: ( ... elt -- ... elt' ) -- ... )
  64     [ change-nth ] 2curry each ; inline
  65
  66 : push-if-index ( ..a elt i quot: ( ..a elt i -- ..b ? ) accum -- ..b )
  67     [ keepd ] dip rot [ push ] [ 2drop ] if ; inline
  68
  69 : push-if* ( ..a elt quot: ( ..a elt -- ..b obj/f ) accum -- ..b )
  70     [ call ] dip [ push ] [ drop ] if* ; inline
  71
  72 : push? ( elt/f accum -- )
  73     over [ push ] [ 2drop ] if ; inline
  74
  75 <PRIVATE
  76
  77 : (index-selector-as) ( quot length exampler -- selector accum )
  78     new-resizable [ [ push-if-index ] 2curry ] keep ; inline
  79
  80 : (selector-as*) ( quot length exemplar -- selector accum )
  81     new-resizable [ [ push-if* ] 2curry ] keep ; inline
  82
  83 PRIVATE>
  84
  85 : index-selector-as ( quot exemplar -- selector accum )
  86     [ length ] keep (index-selector-as) ; inline
  87
  88 : index-selector ( quot -- selector accum )
  89     V{ } index-selector-as ; inline
  90
  91 : selector-as* ( quot exemplar -- selector accum )
  92     [ length ] keep (selector-as*) ; inline
  93
  94 : selector* ( quot -- selector accum ) V{ } selector-as* ; inline
  95
  96 : filter-index-as ( ... seq quot: ( ... elt i -- ... ? ) exemplar -- ... seq' )
  97     pick length over [ (index-selector-as) [ each-index ] dip ] 2curry dip like ; inline
  98
  99 : filter-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... seq' )
 100     over filter-index-as ; inline
 101
 102 : even-indices ( seq -- seq' )
 103     [ length 1 + 2/ ] keep [
 104         [ [ 2 * ] dip nth-unsafe ] curry
 105     ] keep map-integers-as ;
 106
 107 : odd-indices ( seq -- seq' )
 108     [ length 2/ ] keep [
 109         [ [ 2 * 1 + ] dip nth-unsafe ] curry
 110     ] keep map-integers-as ;
 111
 112 : compact ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 113     [ split-when harvest ] dip join ; inline
 114
 115 : collapse ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 116     [ split-when ] dip
 117     [ [ harvest ] dip join ]
 118     [ [ first empty? ] dip [ prepend ] curry when ]
 119     [ [ last empty? ] dip [ append ] curry when ]
 120     2tri ; inline
 121
 122 :: slice-when ( seq quot: ( elt -- ? ) -- seq' )
 123     seq length :> len
 124     0 [ len dupd < ] [
 125         dup seq quot find-from drop
 126         [ 2dup = [ 1 + ] when ] [ len ] if*
 127         [ seq <slice> ] keep len or swap
 128     ] produce nip ; inline
 129
 130 : ?<slice> ( from/f to/f sequence -- slice )
 131     [ [ 0 ] unless* ] 2dip
 132     over [ nip [ length ] [ ] bi ] unless
 133     <slice> ; inline
 134
 135 : sequence>slice ( sequence -- slice )
 136     [ drop 0 ] [ length ] [ ] tri <slice> ; inline
 137
 138 : slice-order-by-from ( slice1 slice2 -- slice-lt slice-gt )
 139     2dup [ from>> ] bi@ > [ swap ] when ; inline
 140
 141 : ordered-slices-range ( slice-lt slice-gt -- to from )
 142     [ to>> ] [ from>> ] bi* ;
 143
 144 : unordered-slices-range ( slice1 slice2 -- to from )
 145     slice-order-by-from ordered-slices-range ;
 146
 147 : ordered-slices-overlap? ( slice-lt slice-gt -- ? )
 148     ordered-slices-range > ; inline
 149
 150 : unordered-slices-overlap? ( slice1 slice2 -- ? )
 151     unordered-slices-range > ; inline
 152
 153 : slices-overlap? ( slice1 slice2 -- ? )
 154     unordered-slices-overlap? ;
 155
 156 : ordered-slices-touch? ( slice-lt slice-gt -- ? )
 157     ordered-slices-range >= ; inline
 158
 159 : unordered-slices-touch? ( slice1 slice2 -- ? )
 160     unordered-slices-range >= ; inline
 161
 162 : slices-touch? ( slice1 slice2 -- ? )
 163     unordered-slices-touch? ;
 164
 165 ERROR: slices-don't-touch slice1 slice2 ;
 166
 167 : merge-slices ( slice1 slice2 -- slice/* )
 168     slice-order-by-from
 169     2dup ordered-slices-touch? [
 170         [ from>> ] [ [ to>> ] [ seq>> ] bi ] bi* <slice>
 171     ] [
 172         slices-don't-touch
 173     ] if ;
 174
 175 : rotate ( seq n -- seq' )
 176     over length mod dup 0 >= [ cut ] [ abs cut* ] if prepend ;
 177
 178 ERROR: underlying-mismatch slice1 slice2 ;
 179
 180 : ensure-same-underlying ( slice1 slice2 -- slice1 slice2 )
 181     2dup [ seq>> ] bi@ eq? [ underlying-mismatch ] unless ;
 182
 183 : span-slices ( slice1 slice2 -- slice )
 184     ensure-same-underlying
 185     [ [ from>> ] bi@ min ]
 186     [ [ to>> ] bi@ max ]
 187     [ drop seq>> ] 2tri <slice> ;
 188
 189 : ?span-slices ( slice1/f slice2/f -- slice )
 190     2dup and [ span-slices ] [ or ] if ;
 191
 192 :: rotate! ( seq n -- )
 193     seq length :> len
 194     n len mod dup 0 < [ len + ] when seq bounds-check drop 0 over
 195     [ 2dup = ] [
 196         [ seq exchange-unsafe ] [ [ 1 + ] bi@ ] 2bi
 197         dup len = [ drop over ] when
 198         2over = [ -rot nip over ] when
 199     ] until 3drop ;
 200
 201 : all-rotations ( seq -- seq' )
 202     dup length <iota> [ rotate ] with map ;
 203
 204 <PRIVATE
 205
 206 : (appender-for) ( quot length exemplar -- appender accum )
 207     new-resizable [ [ push-all ] curry compose ] keep ; inline
 208
 209 PRIVATE>
 210
 211 : appender-for ( quot exemplar -- appender accum )
 212     [ length ] keep (appender-for) ; inline
 213
 214 : appender ( quot -- appender accum )
 215     V{ } appender-for ; inline
 216
 217 : map-concat-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 218     [ appender-for [ each ] dip ] keep like ; inline
 219
 220 : >resizable ( seq -- accum ) ! fixes map-concat "cannot apply call to run-time..."
 221     [ length ] keep [ new-resizable ] [ append! ] bi ;
 222
 223 : map-concat ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 224     over empty? [ 2drop { } ] [
 225         [ [ first ] dip call ] 2keep rot [
 226             >resizable [ '[ @ _ push-all ] 1 each-from ] keep
 227         ] keep like
 228     ] if ; inline
 229
 230 : map-filter-as ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) exemplar -- ... subseq )
 231     reach length over
 232     [ (selector-as) [ compose each ] dip ] 2curry dip like ; inline
 233
 234 : map-filter ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) -- ... subseq )
 235     pick map-filter-as ; inline
 236
 237 : map-sift ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 238     [ ] map-filter ; inline
 239
 240 : map-harvest ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 241     [ empty? not ] map-filter ; inline
 242
 243 : (each-integer-with-previous) ( ... prev i n quot: ( ... i -- ... ) -- ... )
 244     2over < [
 245         [ nip call ] 4keep nipdd
 246         [ 1 + ] 2dip (each-integer-with-previous)
 247     ] [
 248         4drop
 249     ] if ; inline recursive
 250
 251 : each-integer-with-previous ( ... n quot: ( ... i -- ... ) -- ... )
 252     [ f 0 ] 2dip (each-integer-with-previous) ; inline
 253
 254 : (collect-with-previous) ( quot into -- quot' )
 255     [ [ keep ] dip [ set-nth-unsafe ] keepdd ] 2curry ; inline
 256
 257 : collect-with-previous ( n quot into --  )
 258     (collect-with-previous) each-integer-with-previous ; inline
 259
 260 : map-integers-with ( ... len quot: ( ... prev i -- ... elt ) exemplar -- ... newseq )
 261     overd [ [ collect-with-previous ] keep ] new-like ; inline
 262
 263 : map-with-previous-as ( ... seq quot: ( ... elt prev/f -- ... newelt ) exemplar -- ... newseq )
 264     [ length-operator ] dip map-integers-with ; inline
 265
 266 : map-with-previous ( ... seq quot: ( ... elt prev/f -- ... newelt ) -- ... newseq )
 267     over map-with-previous-as ; inline
 268
 269 : setup-each-from ( seq quot -- n quot )
 270     [ [ length ] keep [ nth-unsafe ] curry ] dip compose ; inline
 271
 272 : map-from-as ( ... from seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 273     [ sequence-operator ] dip map-integers-as ; inline
 274
 275 : map-from ( ... from seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 276     pick map-from-as ; inline
 277
 278 : map-if ( ... seq if-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) -- ... newseq )
 279     '[ dup @ _ when ] map ; inline
 280
 281 : reduce-from ( ... seq identity quot: ( ... prev elt -- ... next ) from -- ... result )
 282     [ swap ] 2dip each-from ; inline
 283
 284 : 0accumulate-as ( ... seq quot: ( ... prev elt -- ... next ) exemplar -- ... newseq )
 285     pick empty? [
 286         2nip clone
 287     ] [
 288         [ 0 ] 2dip
 289         [ swapd [ dup ] compose ] dip map-as nip
 290     ] if ; inline
 291
 292 : 0accumulate ( ... seq quot: ( ... prev elt -- ... next ) -- ... final newseq )
 293     over 0accumulate-as ; inline
 294
 295 : 0reduce ( seq quot: ( prev elt -- next ) -- result )
 296     [ 0 ] dip reduce ; inline
 297
 298 <PRIVATE
 299
 300 : push-map-if ( ..a elt filter-quot: ( ..a elt -- ..b ? ) map-quot: ( ..a elt -- ..b newelt ) accum -- ..b )
 301     [ keep over ] 2dip [ when ] dip rot [ push ] [ 2drop ] if ; inline
 302
 303 : (filter-mapper-for) ( filter-quot map-quot length exempler -- filter-mapper accum )
 304     new-resizable [ [ push-map-if ] 3curry ] keep ; inline
 305
 306 : filter-mapper-for ( filter-quot map-quot exemplar -- filter-mapper accum )
 307     [ length ] keep (filter-mapper-for) ; inline
 308
 309 : filter-mapper ( filter-quot map-quot -- filter-mapper accum )
 310     V{ } filter-mapper-for ; inline
 311
 312 PRIVATE>
 313
 314 : filter-map-as ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 315     reach length over
 316     [ (filter-mapper-for) [ each ] dip ] 2curry dip like ; inline
 317
 318 : filter-map ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) -- ... newseq )
 319     pick filter-map-as ; inline
 320
 321 : 2map-sum ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... n ) -- ... n )
 322     [ 0 ] 3dip [ dip + ] curry [ rot ] prepose 2each ; inline
 323
 324 : 2count ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... n )
 325     [ 1 0 ? ] compose 2map-sum ; inline
 326
 327 : 3each-from
 328     ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... ) i -- ... )
 329     [ 3length-operator ] dip -rot each-integer-from ; inline
 330
 331 : 3map-reduce
 332     ( ..a seq1 seq2 seq3 map-quot: ( ..a elt1 elt2 elt3 -- ..b intermediate ) reduce-quot: ( ..b prev intermediate -- ..a next ) -- ..a result )
 333     [ [ [ [ first ] tri@ ] 3keep ] dip [ 3dip ] keep ] dip compose 1 3each-from ; inline
 334
 335 : round-robin ( seq -- newseq )
 336     [ { } ] [
 337         [ longest length <iota> ] keep
 338         [ [ ?nth ] with map ] curry map concat sift
 339     ] if-empty ;
 340
 341 : sift-as ( seq exemplar -- newseq )
 342     [ ] swap filter-as ;
 343
 344 : sift! ( seq -- newseq )
 345     [ ] filter! ;
 346
 347 : harvest-as ( seq exemplar -- newseq )
 348     [ empty? not ] swap filter-as ;
 349
 350 : harvest! ( seq -- newseq )
 351     [ empty? ] reject! ;
 352
 353 : head-as ( seq n exemplar -- seq' )
 354     [ head-slice ] [ like ] bi* ; inline
 355
 356 : head*-as ( seq n exemplar -- seq' )
 357     [ head-slice* ] [ like ] bi* ; inline
 358
 359 : tail-as ( seq n exemplar -- seq' )
 360     [ tail-slice ] [ like ] bi* ; inline
 361
 362 : tail*-as ( seq n exemplar -- seq' )
 363     [ tail-slice* ] [ like ] bi* ; inline
 364
 365 : trim-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... newseq )
 366     [ trim-slice ] [ like ] bi* ; inline
 367
 368 : ?trim ( seq quot: ( elt -- ? ) -- seq/newseq )
 369     over empty? [ drop ] [
 370         over [ first-unsafe ] [ last-unsafe ] bi pick either?
 371         [ trim ] [ drop ] if
 372     ] if ; inline
 373
 374 : ?trim-head ( seq quot: ( elt -- ? ) -- seq/newseq )
 375     over empty? [ drop ] [
 376         over first-unsafe over call
 377         [ trim-head ] [ drop ] if
 378     ] if ; inline
 379
 380 : ?trim-tail ( seq quot: ( elt -- ? ) -- seq/newseq )
 381     over empty? [ drop ] [
 382         over last-unsafe over call
 383         [ trim-tail ] [ drop ] if
 384     ] if ; inline
 385
 386 : unsurround ( newseq seq2 seq3 -- seq1 )
 387     [ ?head drop ] [ ?tail drop ] bi* ;
 388
 389 : >string-list ( seq -- seq' )
 390     [ "\"" 1surround ] map "," join ;
 391
 392 : with-string-lines ( str quot -- str' )
 393     [ string-lines ] dip map "\n" join ; inline
 394
 395 : prepend-lines-with-spaces ( str -- str' )
 396     [ "    " prepend ] with-string-lines ;
 397
 398 : one? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 399     [ find ] 2keep rot [
 400         [ 1 + ] 2dip find-from drop not
 401     ] [ 3drop f ] if ; inline
 402
 403 : map-index! ( ... seq quot: ( ... elt index -- ... newelt ) -- ... seq )
 404     over [ [ sequence-index-operator ] dip collect ] keep ; inline
 405
 406 <PRIVATE
 407
 408 : 2sequence-index-iterator ( seq1 seq2 quot -- n quot' )
 409     [ 2length-iterator [ keep ] curry ] dip compose ; inline
 410
 411 PRIVATE>
 412
 413 : 2each-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... ) -- ... )
 414     2sequence-index-iterator each-integer ; inline
 415
 416 : 2map-into ( seq1 seq2 quot into -- )
 417     [ 2length-operator ] dip collect ; inline
 418
 419 : 2map! ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... seq1 )
 420     pick [ 2map-into ] keep ; inline
 421
 422 : 2map-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... newelt ) -- ... newseq )
 423     pick [ 2sequence-index-iterator ] dip map-integers-as ; inline
 424
 425 TUPLE: evens { seq read-only } ;
 426
 427 C: <evens> evens
 428
 429 M: evens length seq>> length 1 + 2/ ; inline
 430
 431 M: evens virtual@ [ 2 * ] [ seq>> ] bi* ; inline
 432
 433 M: evens virtual-exemplar seq>> ; inline
 434
 435 INSTANCE: evens virtual-sequence
 436
 437 TUPLE: odds { seq read-only } ;
 438
 439 C: <odds> odds
 440
 441 M: odds length seq>> length 2/ ; inline
 442
 443 M: odds virtual@ [ 2 * 1 + ] [ seq>> ] bi* ; inline
 444
 445 M: odds virtual-exemplar seq>> ; inline
 446
 447 INSTANCE: odds virtual-sequence
 448
 449 : until-empty ( seq quot -- )
 450     [ dup empty? ] swap until drop ; inline
 451
 452 <PRIVATE
 453
 454 : push-index-if ( ..a elt i quot: ( ..a elt -- ..b ? ) accum -- ..b )
 455     [ dip ] dip rot [ push ] [ 2drop ] if ; inline
 456
 457 PRIVATE>
 458
 459 : arg-where ( ... seq quot: ( ... elt -- ... ? ) -- ... indices )
 460     over length <vector> [
 461         [ push-index-if ] 2curry each-index
 462     ] keep ; inline
 463
 464 : arg-sort ( seq -- indices )
 465     zip-index sort-keys values ;
 466
 467 : first= ( seq elt -- ? ) [ first ] dip = ; inline
 468 : second= ( seq elt -- ? ) [ second ] dip = ; inline
 469 : third= ( seq elt -- ? ) [ third ] dip = ; inline
 470 : fourth= ( seq elt -- ? ) [ fourth ] dip = ; inline
 471 : last= ( seq elt -- ? ) [ last ] dip = ; inline
 472 : nth= ( n seq elt -- ? ) [ nth ] dip = ; inline
 473
 474 : first? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ first ] dip call ; inline
 475 : second? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ second ] dip call ; inline
 476 : third? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ third ] dip call ; inline
 477 : fourth? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ fourth ] dip call ; inline
 478 : last? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ last ] dip call ; inline
 479 : nth? ( ... n seq quot: ( ... elt -- ... ? ) -- ... ? ) [ nth ] dip call ; inline
 480
 481 : loop>sequence** ( ... quot: ( ... -- ... obj ? ) exemplar -- ... seq )
 482     [ ] swap produce-as nip ; inline
 483
 484 : loop>array** ( ... quot: ( ... -- ... obj ? ) -- ... array )
 485     { } loop>sequence** ; inline
 486
 487 : loop>sequence* ( ... quot: ( ... -- ... obj ? ) exemplar -- ... seq )
 488     [ t ] [ '[ [ _ dip ] [ f f f ] if* ] [ swap ] ] [ produce-as 2nip ] tri* ; inline
 489
 490 : loop>array* ( ... quot: ( ... -- ... obj ? ) -- ... array )
 491     { } loop>sequence* ; inline
 492
 493 : loop>sequence ( ... quot: ( ... -- ... obj/f ) exemplar -- ... seq )
 494     [ [ dup ] compose [ ] ] dip produce-as nip ; inline
 495
 496 : loop>array ( ... quot: ( ... -- ... obj/f ) -- ... array )
 497     { } loop>sequence ; inline
 498
 499 : zero-loop>sequence ( ... quot: ( ... n -- ... obj/f ) exemplar -- ... seq )
 500     [ 0 ] [ '[ _ keep 1 + swap ] ] [ loop>sequence ] tri* nip ; inline
 501
 502 : zero-loop>array ( quot: ( ..a n -- ..a obj ) -- seq )
 503     { } zero-loop>sequence ; inline
 504
 505 : iterate-heap-while ( heap quot1: ( value key -- slurp? ) quot2: ( value key -- obj/f ) -- obj/f loop? )
 506     pick heap-empty?
 507     [ 3drop f f ]
 508     [
 509         [ [ heap-peek ] 2dip drop 2keep ]
 510         [
 511             nip ! ( pop? value key heap quot2 )
 512             5roll [
 513                 swap heap-pop* call( value key -- obj/f ) t
 514             ] [
 515                 4drop f f
 516             ] if
 517         ] 3bi
 518     ] if ; inline
 519
 520 : slurp-heap-while-map ( heap quot1: ( value key -- slurp? ) quot2: ( value key -- obj/f ) -- seq )
 521     '[ _ _ _ iterate-heap-while ] loop>array* ; inline
 522
 523 : heap>pairs ( heap -- pairs )
 524     [ 2drop t ] [ swap 2array ] slurp-heap-while-map ;
 525
 526 : map-zip-swap ( quot: ( x -- y ) -- alist )
 527     '[ _ keep ] map>alist ; inline
 528
 529 : ?heap-pop-value>array ( heap -- array )
 530     dup heap-empty? [ drop { } ] [ heap-pop drop 1array ] if ;
 531
 532 <PRIVATE
 533
 534 : (reverse) ( seq -- newseq )
 535     dup [ length ] keep new-sequence
 536     [ 0 swap copy-unsafe ] keep reverse! ;
 537
 538 PRIVATE>
 539
 540 : reverse-as ( seq exemplar -- newseq )
 541     [ (reverse) ] [ like ] bi* ;
 542
 543 : map-product ( ... seq quot: ( ... elt -- ... n ) -- ... n )
 544     [ 1 ] 2dip [ dip * ] with-assoc each ; inline
 545
 546 : insert-nth! ( elt n seq -- )
 547     [ length ] keep ensure swap pick (a..b]
 548     over '[ [ 1 + ] keep _ move-unsafe ] each
 549     set-nth-unsafe ;
 550
 551 : set-nths ( value indices seq -- )
 552     swapd '[ _ swap _ set-nth ] each ; inline
 553
 554 : set-nths-unsafe ( value indices seq -- )
 555     swapd '[ _ swap _ set-nth-unsafe ] each ; inline
 556
 557 <PRIVATE
 558
 559 : (map-find-index) ( seq quot find-quot -- result i elt )
 560     [ [ f ] 2dip [ [ nip ] 2dip call dup ] curry ] dip call
 561     [ [ [ drop f ] unless ] keep ] dip ; inline
 562
 563 PRIVATE>
 564
 565 : map-find-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 566     [ find-index ] (map-find-index) ; inline
 567
 568 : filter-length ( seq n -- seq' ) '[ length _ = ] filter ;
 569
 570 : all-shortest ( seqs -- seqs' ) dup shortest length filter-length ;
 571
 572 : all-longest ( seqs -- seqs' ) dup longest length filter-length ;
 573
 574 : remove-first ( obj seq -- seq' )
 575     [ index ] keep over [ remove-nth ] [ nip ] if ;
 576
 577 : remove-first! ( obj seq -- seq )
 578     [ index ] keep over [ remove-nth! ] [ nip ] if ;
 579
 580 : remove-last ( obj seq -- seq' )
 581     [ last-index ] keep over [ remove-nth ] [ nip ] if ;
 582
 583 : remove-last! ( obj seq -- seq )
 584     [ last-index ] keep over [ remove-nth! ] [ nip ] if ;
 585
 586 : ?first2 ( seq -- first/f second/f )
 587     dup length {
 588         { 0 [ drop f f ] }
 589         { 1 [ first-unsafe f ] }
 590         [ drop first2-unsafe ]
 591     } case ;
 592
 593 : ?first3 ( seq -- first/f second/f third/f )
 594     dup length {
 595         { 0 [ drop f f f ] }
 596         { 1 [ first-unsafe f f ] }
 597         { 2 [ first2-unsafe f ] }
 598         [ drop first3-unsafe ]
 599     } case ;
 600
 601 : ?first4 ( seq -- first/f second/f third/f fourth/f )
 602     dup length {
 603         { 0 [ drop f f f f ] }
 604         { 1 [ first-unsafe f f f ] }
 605         { 2 [ first2-unsafe f f ] }
 606         { 3 [ first3-unsafe f ] }
 607         [ drop first4-unsafe ]
 608     } case ;
 609
 610 : cut-when ( ... seq quot: ( ... elt -- ... ? ) -- ... before after )
 611     [ find drop ] keepd swap
 612     [ cut ] [ f over like ] if* ; inline
 613
 614 : nth* ( n seq -- elt )
 615     [ length 1 - swap - ] [ nth ] bi ; inline
 616
 617 : each-index-from ( ... seq quot: ( ... elt index -- ... ) i -- ... )
 618     -rot sequence-index-operator each-integer-from ; inline
 619
 620 <PRIVATE
 621
 622 : select-by* ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... i elt )
 623     [
 624         [ keep swap ] curry [ dip ] curry
 625         [ [ first 0 ] dip call ] 2keep
 626         [ 2curry 3dip 5 npick pick ] curry
 627     ] [
 628         [ [ 3drop ] [ [ 3drop ] 3dip ] if ] compose
 629     ] bi* compose 1 each-index-from nip swap ; inline
 630
 631 PRIVATE>
 632
 633 : supremum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 634     [ after? ] select-by* ; inline
 635
 636 : infimum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 637     [ before? ] select-by* ; inline
 638
 639 : arg-max ( seq -- n )
 640     [ ] supremum-by* drop ;
 641
 642 : arg-min ( seq -- n )
 643     [ ] infimum-by* drop ;
 644
 645 : ?supremum ( seq/f -- elt/f )
 646     [ f ] [
 647         [ ] [ 2dup and [ max ] [ dupd ? ] if ] map-reduce
 648     ] if-empty ;
 649
 650 : ?infimum ( seq/f -- elt/f )
 651     [ f ] [
 652         [ ] [ 2dup and [ min ] [ dupd ? ] if ] map-reduce
 653     ] if-empty ;
 654
 655 : map-infimum ( seq quot: ( ... elt -- ... elt' ) -- elt' )
 656     [ min ] map-reduce ; inline
 657
 658 : map-supremum ( seq quot: ( ... elt -- ... elt' ) -- elt' )
 659     [ max ] map-reduce ; inline
 660
 661 : change-last ( seq quot -- )
 662     [ index-of-last ] [ change-nth ] bi* ; inline
 663
 664 : change-last-unsafe ( seq quot -- )
 665     [ index-of-last ] [ change-nth-unsafe ] bi* ; inline
 666
 667 : replicate-into ( ... seq quot: ( ... -- ... newelt ) -- ... )
 668     over [ length ] 2dip '[ _ dip _ set-nth-unsafe ] each-integer ; inline
 669
 670 : count* ( ... seq quot: ( ... elt -- ... ? ) -- ... % )
 671     over [ count ] [ length ] bi* / ; inline
 672
 673 : sequence-index-operator-last ( n seq quot -- n quot' )
 674     [ [ nth-unsafe ] curry [ keep ] curry ] dip compose ; inline
 675
 676 : find-last-index-from ( ... n seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 677     '[
 678         _ [ sequence-index-operator-last find-last-integer ] keepd
 679         index/element
 680     ] bounds-check-call ; inline
 681
 682 : find-last-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 683     [ index-of-last ] dip find-last-index-from ; inline
 684
 685 : map-find-last-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 686     [ find-last-index ] (map-find-index) ; inline
 687
 688 :: (start-all) ( seq subseq increment -- indices )
 689     0
 690     [ seq subseq subseq-index-from dup ]
 691     [ [ increment + ] keep ] produce nip ;
 692
 693 : start-all ( seq subseq -- indices )
 694     dup length (start-all) ; inline
 695
 696 : start-all* ( seq subseq -- indices )
 697     1 (start-all) ; inline
 698
 699 : count-subseq ( seq subseq -- n )
 700     start-all length ; inline
 701
 702 : count-subseq* ( seq subseq -- n )
 703     start-all* length ; inline
 704
 705 : assoc-zip-with ( quot: ( key value -- calc ) -- alist )
 706     '[ _ 2keep 2array swap ] assoc-map ; inline
 707
 708 : take-while ( ... seq quot: ( ... elt -- ... ? ) -- head-slice )
 709     [ '[ @ not ] find drop ] keepd swap
 710     [ dup length ] unless* head-slice ; inline
 711
 712 : drop-while ( ... seq quot: ( ... elt -- ... ? ) -- tail-slice )
 713     [ '[ @ not ] find drop ] keepd swap
 714     [ dup length ] unless* tail-slice ; inline
 715
 716 : count-head ( seq quot -- n )
 717     [ not ] compose [ find drop ] keepd length or ; inline
 718
 719 : count-tail ( seq quot -- n )
 720     [ not ] compose [ find-last drop ] keepd
 721     length swap [ - 1 - ] when* ; inline
 722
 723 :: shorten* ( vector n -- seq )
 724     vector n tail
 725     n vector shorten ;
 726
 727 :: interleaved-as ( seq glue exemplar -- newseq )
 728     seq length dup 1 - + 0 max exemplar new-sequence :> newseq
 729     seq [ 2 * newseq set-nth-unsafe ] each-index
 730     seq length 1 - [ 2 * 1 + glue swap newseq set-nth-unsafe ] each-integer
 731     newseq ;
 732
 733 : interleaved ( seq glue -- newseq )
 734     over interleaved-as ;
 735
 736 : extract! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 737     [ dup ] compose over [ length ] keep new-resizable
 738     [ [ push-when ] 2curry reject! ] keep swap like ; inline
 739
 740 : find-pred-loop ( ... i n seq quot: ( ... elt -- ... calc ? ) -- ... calc/f i/f elt/f )
 741     2pick < [
 742         [ nipd call ] 4keep
 743         3 7 0 nrotated
 744         [ [ 3drop ] 2dip rot ]
 745         [ 2drop [ 1 + ] 3dip find-pred-loop ] if
 746     ] [
 747         4drop f f f
 748     ] if ; inline recursive
 749
 750 : find-pred ( ... seq quot: ( ... elt -- ... calc ) pred: ( ... calc -- ... ? ) -- ... calc/f i/f elt/f )
 751     [ 0 ] 3dip
 752     [ [ length check-length ] keep ] 2dip
 753     '[ nth-unsafe _ keep swap _ keep swap ] find-pred-loop swapd ; inline
 754
 755 ! https://en.wikipedia.org/wiki/Maximum_subarray_problem
 756 ! Kadane's algorithm O(n) largest sum in subarray
 757 : max-subarray-sum ( seq -- sum )
 758     [ -1/0. 0 ] dip
 759     [ [ + ] keep max [ max ] keep ] each drop ;
 760
 761 TUPLE: step-slice
 762     { from integer read-only initial: 0 }
 763     { to integer read-only initial: 0 }
 764     { seq read-only }
 765     { step integer read-only } ;
 766
 767 :: <step-slice> ( from/f to/f step seq -- step-slice )
 768     step zero? [ "can't be zero" throw ] when
 769     seq length :> len
 770     step 0 > [
 771         from/f [ 0 ] unless*
 772         to/f [ len ] unless*
 773     ] [
 774         from/f [ len ] unless*
 775         to/f [ 0 ] unless*
 776     ] if
 777     [ dup 0 < [ len + ] when 0 len clamp ] bi@
 778     ! FIXME: make this work with steps
 779     seq dup slice? [ collapse-slice ] when
 780     step step-slice boa ;
 781
 782 M: step-slice virtual-exemplar seq>> ; inline
 783
 784 M: step-slice virtual@
 785     [ step>> * ] [ from>> + ] [ seq>> ] tri ; inline
 786
 787 M: step-slice length
 788     [ to>> ] [ from>> - ] [ step>> ] tri
 789     dup 0 < [ [ neg 0 max ] dip neg ] when /mod
 790     zero? [ 1 + ] unless ; inline
 791
 792 INSTANCE: step-slice virtual-sequence
 793
 794 : 2nested-each* ( seq1 seq-quot: ( n -- seq ) quot: ( a b -- ) -- )
 795     '[
 796         _ keep swap _ with each
 797     ] each ; inline
 798
 799 : 2nested-filter-as* ( seq1 seq-quot quot exemplar -- seq )
 800     [ 2over [ length ] bi@ * ] dip
 801     [
 802         new-resizable
 803         [ [ push? ] curry compose 2nested-each* ] keep
 804     ] keep like ; inline
 805
 806 : 2nested-filter* ( seq1 seq-quot quot -- seq )
 807     pick 2nested-filter-as* ; inline
 808
 809 : 2nested-map-as* ( seq1 seq-quot quot exemplar -- seq )
 810     [ 2over [ length ] bi@ * ] dip
 811     [
 812         new-resizable
 813         [ [ push ] curry compose 2nested-each* ] keep
 814     ] keep like ; inline
 815
 816 : 2nested-map* ( seq1 seq-quot quot -- seq )
 817     pick 2nested-map-as* ; inline
 818
 819
 820 : 2nested-each ( seq1 seq2 quot -- )
 821     swapd '[
 822         swap _ with each
 823     ] with each ; inline
 824
 825 : 2nested-filter-as ( seq1 seq2 quot exemplar -- seq )
 826     [ 2over [ length ] bi@ * ] dip
 827     [
 828         new-resizable
 829         [ [ push? ] curry compose 2nested-each ] keep
 830     ] keep like ; inline
 831
 832 : 2nested-filter ( seq1 seq2 quot -- seq )
 833     pick 2nested-filter-as ; inline
 834
 835 : 2nested-map-as ( seq1 seq2 quot exemplar -- seq )
 836     [ 2over [ length ] bi@ * ] dip
 837     [
 838         new-resizable
 839         [ [ push ] curry compose 2nested-each ] keep
 840     ] keep like ; inline
 841
 842 : 2nested-map ( seq1 seq2 quot -- seq )
 843     pick 2nested-map-as ; inline
 844
 845 : 3nested-each ( seq1 seq2 seq3 quot -- )
 846     [ spin ] dip '[
 847         -rot [
 848             swap _ with with each
 849         ] with with each
 850     ] with with each ; inline
 851
 852 : 3nested-filter-as ( seq1 seq2 seq3 quot exemplar -- seq )
 853     [ 3 nover [ length ] tri@ * * ] dip
 854     [
 855         new-resizable
 856         [ [ push? ] curry compose 3nested-each ] keep
 857     ] keep like ; inline
 858
 859 : 3nested-filter ( seq1 seq2 seq3 quot -- seq )
 860     reach 3nested-filter-as ; inline
 861
 862 : 3nested-map-as ( seq1 seq2 seq3 quot exemplar -- seq )
 863     [ 3 nover [ length ] tri@ * * ] dip
 864     [
 865         new-resizable
 866         [ [ push ] curry compose 3nested-each ] keep
 867     ] keep like ; inline
 868
 869 : 3nested-map ( seq1 seq2 seq3 quot -- seq )
 870     reach 3nested-map-as ; inline
 871
 872 : prev ( n seq -- obj ) [ 1 - ] dip nth ; inline
 873 : ?prev ( n seq -- obj/f ) [ 1 - ] dip ?nth ; inline
 874 : ??prev ( n seq -- obj/f ? ) [ 1 - ] dip ??nth ; inline
 875 : prev-of ( seq n -- obj ) 1 - nth-of ; inline
 876 : ?prev-of ( seq n -- obj/f ) 1 - ?nth-of ; inline
 877 : ??prev-of ( seq n -- obj/f ? ) 1 - ??nth-of ; inline
 878
 879 : prev-identity ( i seq -- identity i seq )
 880     2dup ??prev [ drop 0 ] unless -rot ; inline
 881
 882 : each-prior-identity-from ( ... identity i seq quot: ( ... prior elt -- ... ) -- ... )
 883     '[ [ swap @ ] keep ]
 884     length-operator each-integer-from drop ; inline
 885
 886 : each-prior-from ( ... i seq quot: ( ... prior elt -- ... ) -- ... )
 887     [ prev-identity ] dip each-prior-identity-from ; inline
 888
 889 : each-prior ( ... seq quot: ( ... prior elt -- ... ) -- ... )
 890     0 -rot each-prior-from ; inline
 891
 892 : map-prior-identity-from-as ( ... identity i seq quot: ( ... prior elt -- elt' ) exemplar -- seq' )
 893     [
 894         '[ [ swap @ ] keep swap ] length-operator
 895     ] dip map-integers-from-as nip ; inline
 896
 897 : map-prior-identity-as ( ... identity seq quot: ( ... prior elt -- elt' ) exemplar -- seq' )
 898     [ 0 ] 3dip map-prior-identity-from-as ; inline
 899
 900 : map-prior-from-as ( ... i seq quot: ( ... prior elt -- elt' ) exemplar -- seq' )
 901     [ prev-identity ] 2dip map-prior-identity-from-as ; inline
 902
 903 : map-prior-as ( ... seq quot: ( ... prior elt -- elt' ) exemplar -- seq' )
 904     0 -roll map-prior-from-as ; inline
 905
 906 : map-prior-from ( ... i seq quot: ( ... prior elt -- elt' ) -- seq' )
 907     over map-prior-from-as ; inline
 908
 909 : map-prior ( ... seq quot: ( ... prior elt -- elt' ) -- seq' )
 910     over map-prior-as ; inline
 911
 912 TUPLE: virtual-zip-index seq ;
 913
 914 C: <zip-index> virtual-zip-index
 915
 916 M: virtual-zip-index length seq>> length ; inline
 917
 918 M: virtual-zip-index nth-unsafe
 919     over [ seq>> nth-unsafe ] [ 2array ] bi* ; inline
 920
 921 INSTANCE: virtual-zip-index immutable-sequence
 922
 923 : nth-index ( n obj seq -- i )
 924     [ = dup [ drop 1 - dup 0 < ] when ] with find drop nip ;