extra/sequences/extras/extras.factor

   1
   2 USING: accessors arrays assocs combinators generalizations
   3 grouping growable heaps kernel math math.order ranges sequences
   4 sequences.private shuffle sorting splitting vectors ;
   5 IN: sequences.extras
   6
   7 : find-all ( ... seq quot: ( ... elt -- ... ? ) -- ... elts )
   8     [ <enumerated> ] dip '[ nip @ ] assoc-filter ; inline
   9
  10 :: subseq* ( from to seq -- subseq )
  11     seq length :> len
  12     from [ dup 0 < [ len + ] when ] [ 0 ] if*
  13     to [ dup 0 < [ len + ] when ] [ len ] if*
  14     [ 0 len clamp ] bi@ dupd max seq subseq ;
  15
  16 : safe-subseq ( from to seq -- subseq )
  17     [ length '[ 0 _ clamp ] bi@ ] keep subseq ;
  18
  19 : all-subseqs ( seq -- seqs )
  20     dup length [1..b] [ clump ] with map concat ;
  21
  22 : each-subseq ( ... seq quot: ( ... subseq -- ... ) -- ... )
  23     [ dup length [ [0..b] ] [ ] bi ] dip '[
  24         dup _ (a..b] [ rot [ subseq _ call ] keep ] with each
  25     ] each drop ; inline
  26
  27 : map-like ( seq exemplar -- seq' )
  28     '[ _ like ] map ; inline
  29
  30 : filter-all-subseqs-range ( ... seq range quot: ( ... subseq -- ... ? ) -- seq )
  31     [
  32         '[ <clumps> _ filter ] with map concat
  33     ] keepdd map-like ; inline
  34
  35 : filter-all-subseqs ( ... seq quot: ( ... subseq -- ... ? ) -- seq )
  36     [ dup length [1..b] ] dip filter-all-subseqs-range ; inline
  37
  38 :: longest-subseq ( seq1 seq2 -- subseq )
  39     seq1 length :> len1
  40     seq2 length :> len2
  41     0 :> n!
  42     0 :> end!
  43     len1 1 + [ len2 1 + 0 <array> ] replicate :> table
  44     len1 [1..b] [| x |
  45         len2 [1..b] [| y |
  46             x 1 - seq1 nth-unsafe
  47             y 1 - seq2 nth-unsafe = [
  48                 y 1 - x 1 - table nth-unsafe nth-unsafe 1 + :> len
  49                 len y x table nth-unsafe set-nth-unsafe
  50                 len n > [ len n! x end! ] when
  51             ] [ 0 y x table nth-unsafe set-nth-unsafe ] if
  52         ] each
  53     ] each end n - end seq1 subseq ;
  54
  55 : pad-longest ( seq1 seq2 elt -- seq1 seq2 )
  56     [ 2dup max-length ] dip [ pad-tail ] 2curry bi@ ;
  57
  58 : pad-center ( seq n elt -- padded )
  59     swap pick length [-] [ drop ] [
  60         [ 2/ ] [ over - ] bi rot '[ _ <repetition> ] bi@
  61         pick surround-as
  62     ] if-zero ;
  63
  64 : zip-longest-with ( seq1 seq2 fill -- assoc )
  65     pad-longest zip ;
  66
  67 : zip-longest ( seq1 seq2 -- assoc )
  68     f zip-longest-with ;
  69
  70 : change-nths ( ... indices seq quot: ( ... elt -- ... elt' ) -- ... )
  71     [ change-nth ] 2curry each ; inline
  72
  73 : push-if-index ( ..a elt i quot: ( ..a elt i -- ..b ? ) accum -- ..b )
  74     [ keepd ] dip rot [ push ] [ 2drop ] if ; inline
  75
  76 : push-if* ( ..a elt quot: ( ..a elt -- ..b obj/f ) accum -- ..b )
  77     [ call ] dip [ push ] [ drop ] if* ; inline
  78
  79 : maybe-push ( elt/f accum -- )
  80     over [ push ] [ 2drop ] if ; inline
  81
  82 <PRIVATE
  83
  84 : (index-selector-as) ( quot length exampler -- selector accum )
  85     new-resizable [ [ push-if-index ] 2curry ] keep ; inline
  86
  87 : (selector-as*) ( quot length exemplar -- selector accum )
  88     new-resizable [ [ push-if* ] 2curry ] keep ; inline
  89
  90 PRIVATE>
  91
  92 : index-selector-as ( quot exemplar -- selector accum )
  93     [ length ] keep (index-selector-as) ; inline
  94
  95 : index-selector ( quot -- selector accum )
  96     V{ } index-selector-as ; inline
  97
  98 : selector-as* ( quot exemplar -- selector accum )
  99     [ length ] keep (selector-as*) ; inline
 100
 101 : selector* ( quot -- selector accum ) V{ } selector-as* ; inline
 102
 103 : filter-index-as ( ... seq quot: ( ... elt i -- ... ? ) exemplar -- ... seq' )
 104     pick length over [ (index-selector-as) [ each-index ] dip ] 2curry dip like ; inline
 105
 106 : filter-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... seq' )
 107     over filter-index-as ; inline
 108
 109 : even-indices ( seq -- seq' )
 110     [ length 1 + 2/ ] keep [
 111         [ [ 2 * ] dip nth-unsafe ] curry
 112     ] keep map-integers-as ;
 113
 114 : odd-indices ( seq -- seq' )
 115     [ length 2/ ] keep [
 116         [ [ 2 * 1 + ] dip nth-unsafe ] curry
 117     ] keep map-integers-as ;
 118
 119 : compact ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 120     [ split-when harvest ] dip join ; inline
 121
 122 : collapse ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 123     [ split-when ] dip
 124     [ [ harvest ] dip join ]
 125     [ [ first empty? ] dip [ prepend ] curry when ]
 126     [ [ last empty? ] dip [ append ] curry when ]
 127     2tri ; inline
 128
 129 :: slice-when ( seq quot: ( elt -- ? ) -- seq' )
 130     seq length :> len
 131     0 [ len dupd < ] [
 132         dup seq quot find-from drop
 133         [ 2dup = [ 1 + ] when ] [ len ] if*
 134         [ seq <slice> ] keep len or swap
 135     ] produce nip ; inline
 136
 137 : ?<slice> ( from/f to/f sequence -- slice )
 138     [ [ 0 ] unless* ] 2dip
 139     over [ nip [ length ] [ ] bi ] unless
 140     <slice> ; inline
 141
 142 : sequence>slice ( sequence -- slice )
 143     [ drop 0 ] [ length ] [ ] tri <slice> ; inline
 144
 145 : slice-order-by-from ( slice1 slice2 -- slice-lt slice-gt )
 146     2dup [ from>> ] bi@ > [ swap ] when ; inline
 147
 148 : ordered-slices-range ( slice-lt slice-gt -- to from )
 149     [ to>> ] [ from>> ] bi* ;
 150
 151 : unordered-slices-range ( slice1 slice2 -- to from )
 152     slice-order-by-from ordered-slices-range ;
 153
 154 : ordered-slices-overlap? ( slice-lt slice-gt -- ? )
 155     ordered-slices-range > ; inline
 156
 157 : unordered-slices-overlap? ( slice1 slice2 -- ? )
 158     unordered-slices-range > ; inline
 159
 160 : slices-overlap? ( slice1 slice2 -- ? )
 161     unordered-slices-overlap? ;
 162
 163 : ordered-slices-touch? ( slice-lt slice-gt -- ? )
 164     ordered-slices-range >= ; inline
 165
 166 : unordered-slices-touch? ( slice1 slice2 -- ? )
 167     unordered-slices-range >= ; inline
 168
 169 : slices-touch? ( slice1 slice2 -- ? )
 170     unordered-slices-touch? ;
 171
 172 ERROR: slices-don't-touch slice1 slice2 ;
 173
 174 : merge-slices ( slice1 slice2 -- slice/* )
 175     slice-order-by-from
 176     2dup ordered-slices-touch? [
 177         [ from>> ] [ [ to>> ] [ seq>> ] bi ] bi* <slice>
 178     ] [
 179         slices-don't-touch
 180     ] if ;
 181
 182 : rotate ( seq n -- seq' )
 183     over length mod dup 0 >= [ cut ] [ abs cut* ] if prepend ;
 184
 185 ERROR: underlying-mismatch slice1 slice2 ;
 186
 187 : ensure-same-underlying ( slice1 slice2 -- slice1 slice2 )
 188     2dup [ seq>> ] bi@ eq? [ underlying-mismatch ] unless ;
 189
 190 : span-slices ( slice1 slice2 -- slice )
 191     ensure-same-underlying
 192     [ [ from>> ] bi@ min ]
 193     [ [ to>> ] bi@ max ]
 194     [ drop seq>> ] 2tri <slice> ;
 195
 196 : ?span-slices ( slice1/f slice2/f -- slice )
 197     2dup and [ span-slices ] [ or ] if ;
 198
 199 :: rotate! ( seq n -- )
 200     seq length :> len
 201     n len mod dup 0 < [ len + ] when seq bounds-check drop 0 over
 202     [ 2dup = ] [
 203         [ seq exchange-unsafe ] [ [ 1 + ] bi@ ] 2bi
 204         dup len = [ drop over ] when
 205         2over = [ -rot nip over ] when
 206     ] until 3drop ;
 207
 208 : all-rotations ( seq -- seq' )
 209     dup length <iota> [ rotate ] with map ;
 210
 211 <PRIVATE
 212
 213 : (appender-for) ( quot length exemplar -- appender accum )
 214     new-resizable [ [ push-all ] curry compose ] keep ; inline
 215
 216 PRIVATE>
 217
 218 : appender-for ( quot exemplar -- appender accum )
 219     [ length ] keep (appender-for) ; inline
 220
 221 : appender ( quot -- appender accum )
 222     V{ } appender-for ; inline
 223
 224 : map-concat-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 225     [ appender-for [ each ] dip ] keep like ; inline
 226
 227 : >resizable ( seq -- accum ) ! fixes map-concat "cannot apply call to run-time..."
 228     [ length ] keep [ new-resizable ] [ append! ] bi ;
 229
 230 : map-concat ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 231     over empty? [ 2drop { } ] [
 232         [ [ first ] dip call ] 2keep rot [
 233             >resizable [ '[ @ _ push-all ] 1 each-from ] keep
 234         ] keep like
 235     ] if ; inline
 236
 237 : map-filter-as ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) exemplar -- ... subseq )
 238     reach length over
 239     [ (selector-as) [ compose each ] dip ] 2curry dip like ; inline
 240
 241 : map-filter ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) -- ... subseq )
 242     pick map-filter-as ; inline
 243
 244 : map-sift ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 245     [ ] map-filter ; inline
 246
 247 : map-harvest ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 248     [ empty? not ] map-filter ; inline
 249
 250 : (each-integer-with-previous) ( ... prev i n quot: ( ... i -- ... ) -- ... )
 251     2over < [
 252         [ nip call ] 4keep nipdd
 253         [ 1 + ] 2dip (each-integer-with-previous)
 254     ] [
 255         4drop
 256     ] if ; inline recursive
 257
 258 : each-integer-with-previous ( ... n quot: ( ... i -- ... ) -- ... )
 259     [ f 0 ] 2dip (each-integer-with-previous) ; inline
 260
 261 : (collect-with-previous) ( quot into -- quot' )
 262     [ [ keep ] dip [ set-nth-unsafe ] keepdd ] 2curry ; inline
 263
 264 : collect-with-previous ( n quot into --  )
 265     (collect-with-previous) each-integer-with-previous ; inline
 266
 267 : map-integers-with ( ... len quot: ( ... prev i -- ... elt ) exemplar -- ... newseq )
 268     overd [ [ collect-with-previous ] keep ] new-like ; inline
 269
 270 : map-with-previous-as ( ... seq quot: ( ... elt prev/f -- ... newelt ) exemplar -- ... newseq )
 271     [ length-operator ] dip map-integers-with ; inline
 272
 273 : map-with-previous ( ... seq quot: ( ... elt prev/f -- ... newelt ) -- ... newseq )
 274     over map-with-previous-as ; inline
 275
 276 : setup-each-from ( seq quot -- n quot )
 277     [ [ length ] keep [ nth-unsafe ] curry ] dip compose ; inline
 278
 279 : map-from-as ( ... seq quot: ( ... elt -- ... newelt ) from exemplar -- ... newseq )
 280     -rotd [ sequence-operator nipd ] dip map-integers-from-as ; inline
 281
 282 : map-from ( ... seq quot: ( ... elt -- ... newelt ) from -- ... newseq )
 283     pick map-from-as ; inline
 284
 285 : map-if ( ... seq if-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) -- ... newseq )
 286     '[ dup @ _ when ] map ; inline
 287
 288 : reduce-from ( ... seq identity quot: ( ... prev elt -- ... next ) from -- ... result )
 289     [ swap ] 2dip each-from ; inline
 290
 291 : 2reduce-from ( ... seq1 seq2 identity quot: ( ... prev elt1 elt2 -- ... next ) i -- ... result )
 292     [ -rot ] 2dip 2each-from ; inline
 293
 294 : 0accumulate-as ( ... seq quot: ( ... prev elt -- ... next ) exemplar -- ... newseq )
 295     pick empty? [
 296         2nip clone
 297     ] [
 298         [ 0 ] 2dip
 299         [ swapd [ dup ] compose ] dip map-as nip
 300     ] if ; inline
 301
 302 : 0accumulate ( ... seq quot: ( ... prev elt -- ... next ) -- ... final newseq )
 303     over 0accumulate-as ; inline
 304
 305 : nth-index ( n obj seq -- i )
 306     [ = dup [ drop 1 - dup 0 < ] when ] with find drop nip ;
 307
 308 : at+* ( n key assoc -- old new ) [ 0 or [ + ] keep swap dup ] change-at ; inline
 309
 310 : inc-at* ( key assoc -- old new ) [ 1 ] 2dip at+* ; inline
 311
 312 : occurrence-count-by ( seq quot: ( elt -- elt' ) -- hash seq' )
 313     '[ nip @ over inc-at* drop ] [ H{ } clone ] 2dip 0accumulate ; inline
 314
 315 : progressive-index-by-as ( seq1 seq2 quot exemplar -- hash seq' )
 316     [
 317         pick length '[
 318             tuck [ @ over inc-at* drop ] 2dip swap nth-index _ or
 319         ] [ H{ } clone ] 3dip with
 320     ] dip map-as ; inline
 321
 322 : progressive-index-by ( seq1 seq2 quot -- hash seq' )
 323     { } progressive-index-by-as ; inline
 324
 325 : progressive-index ( seq1 seq2 -- hash seq' )
 326     [ ] progressive-index-by ; inline
 327
 328 : 0reduce ( seq quot: ( prev elt -- next ) -- result )
 329     [ 0 ] dip reduce ; inline
 330
 331 : ?unclip ( seq -- rest/f first/f )
 332     [ f f ] [ unclip ] if-empty ;
 333
 334 : 1reduce ( seq quot: ( prev elt -- next ) -- result )
 335     [ ?unclip ] dip reduce ; inline
 336
 337 <PRIVATE
 338
 339 : change-nth-of-unsafe ( seq i quot -- seq )
 340     [ [ nth-of-unsafe ] dip call ] 2keepd rot set-nth-of-unsafe ; inline
 341
 342 PRIVATE>
 343
 344 : nth-of ( seq n -- elt ) swap nth ; inline
 345 : set-nth-of ( seq n elt -- seq ) spin [ set-nth ] keep ; inline
 346 : ?nth-of ( seq n -- elt/f ) swap ?nth ; inline
 347 : ??nth ( n seq -- elt/f ? )
 348     2dup bounds-check? [ nth-unsafe t ] [ 2drop f f ] if ; inline
 349 : ??nth-of ( seq n -- elt/f ? ) swap ??nth ; inline
 350
 351 : reduce-of ( seq quot: ( prev elt -- next ) identity -- result )
 352     swap reduce ; inline
 353
 354 : accumulate-of ( seq quot: ( prev elt -- next ) identity -- result )
 355     swap accumulate ; inline
 356
 357 <PRIVATE
 358
 359 : push-map-when* ( ..a elt quot: ( ..a elt -- ..b obj ? ) accum -- ..b )
 360     [ call ] dip swap [ push ] [ 2drop ] if ; inline
 361
 362 : filter-mapper-for* ( quot length exemplar -- filter-mapper accum )
 363     new-resizable [ [ push-map-when* ] 2curry ] keep ; inline
 364
 365 : 1push-map-when ( ..a filter-quot: ( ..a -- ..b ? ) map-quot: ( ..a -- ..b obj ) accum -- ..b )
 366     [ keep over ] 2dip [ when ] dip rot [ push ] [ 2drop ] if ; inline
 367
 368 : 1filter-mapper-for ( filter-quot map-quot length exemplar -- filter-mapper accum )
 369     new-resizable [ [ 1push-map-when ] 3curry ] keep ; inline
 370
 371 : 2push-map-when ( ..a filter-quot: ( ..a -- ..b ? ) map-quot: ( ..a -- ..b obj ) accum -- ..b )
 372     [ 2keep rot ] 2dip '[ [ @ _ push ] [ 2drop ] if ] call ; inline
 373
 374 : 2filter-mapper-for ( filter-quot map-quot length exemplar -- filter-mapper accum )
 375     new-resizable [ [ 2push-map-when ] 3curry ] keep ; inline
 376
 377 PRIVATE>
 378
 379 : filter-map-as* ( ... seq quot: ( ..a elt -- ..b obj ? ) exemplar -- ... newseq )
 380     pick length over
 381     [ filter-mapper-for* [ each ] dip ] 2curry dip like ; inline
 382
 383 : filter-map* ( ... seq quot: ( ... elt -- ... newelt ? ) -- ... newseq )
 384     over filter-map-as* ; inline
 385
 386 : reject-map-as* ( ... seq quot: ( ... elt -- ... newelt ? ) exemplar -- ... newseq )
 387     [ [ not ] compose ] dip filter-map-as* ; inline
 388
 389 : reject-map* ( ... seq quot: ( ... elt -- ... newelt ? ) -- ... newseq )
 390     over reject-map-as* ; inline
 391
 392 : 2filter-map-as* ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... obj ? ) exemplar -- ... newseq )
 393     reach length over
 394     [ filter-mapper-for* [ 2each ] dip ] 2curry dip like ; inline
 395
 396 : 2filter-map* ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... newseq )
 397     pick 2filter-map-as* ; inline
 398
 399 : 2reject-map-as* ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... obj ? ) exemplar -- ... newseq )
 400     [ [ not ] compose ] dip 2filter-map-as* ; inline
 401
 402 : 2reject-map* ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... obj ? ) -- ... newseq )
 403     pick 2reject-map-as* ; inline
 404
 405
 406 : filter-map-as ( ... seq filter-quot: ( ..a elt -- ..b ? ) map-quot: ( obj -- obj' ) exemplar -- ... newseq )
 407     reach length over
 408     [ 1filter-mapper-for [ each ] dip ] 2curry dip like ; inline
 409
 410 : filter-map ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( obj -- obj' ) -- ... newseq )
 411     pick filter-map-as ; inline
 412
 413 : reject-map-as ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( obj -- obj' ) exemplar -- ... newseq )
 414     [ [ not ] compose ] 2dip filter-map-as ; inline
 415
 416 : reject-map ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( obj -- obj' ) -- ... newseq )
 417     pick reject-map-as ; inline
 418
 419 : 2filter-map-as ( ... seq1 seq2 filter-quot: ( ... elt1 elt2 -- ... ? ) map-quot: ( elt1 elt2 -- obj ) exemplar -- ... newseq )
 420     5 npick length over
 421     [ 2filter-mapper-for [ 2each ] dip ] 2curry dip like ; inline
 422
 423 : 2filter-map ( ... seq1 seq2 filter-quot: ( ... elt1 elt2 -- ... ? ) map-quot: ( elt1 elt2 -- obj ) -- ... newseq )
 424     reach 2filter-map-as ; inline
 425
 426 : 2reject-map-as ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) map-quot: ( elt1 elt2 -- obj ) exemplar -- ... newseq )
 427     [ [ not ] compose ] 2dip 2filter-map-as ; inline
 428
 429 : 2reject-map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) map-quot: ( elt1 elt2 -- obj ) -- ... newseq )
 430     pick 2reject-map-as ; inline
 431
 432 : 2push-when ( ..a elt1 elt2 quot: ( ..a elt1 elt2 -- ..b ? ) accum -- ..b )
 433     [ keepd ] dip rot [ push ] [ 2drop ] if ; inline
 434
 435 : (2selector-as) ( quot length exemplar -- selector accum )
 436     new-resizable [ [ 2push-when ] 2curry ] keep ; inline
 437
 438 : 2filter-as ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) exemplar -- ... newseq )
 439     [
 440         pick [ length ] keep
 441         [ (2selector-as) [ 2each ] dip ] 2curry call
 442     ] dip like ; inline
 443
 444 : 2filter ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
 445     pick 2filter-as ; inline
 446
 447 : 2reject-as ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) exemplar -- ... newseq )
 448     [ [ not ] compose ] dip 2filter-as ; inline
 449
 450 : 2reject ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
 451     pick 2reject-as ; inline
 452
 453 : 2map-sum ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... n ) -- ... n )
 454     [ 0 ] 3dip [ dip + ] curry [ rot ] prepose 2each ; inline
 455
 456 : 2count ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... n )
 457     [ 1 0 ? ] compose 2map-sum ; inline
 458
 459 : 3each-from
 460     ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... ) i -- ... )
 461     [ 3length-operator ] dip -rot each-integer-from ; inline
 462
 463 : 3map-reduce
 464     ( ..a seq1 seq2 seq3 map-quot: ( ..a elt1 elt2 elt3 -- ..b intermediate ) reduce-quot: ( ..b prev intermediate -- ..a next ) -- ..a result )
 465     [ [ [ [ first ] tri@ ] 3keep ] dip [ 3dip ] keep ] dip compose 1 3each-from ; inline
 466
 467 : round-robin ( seq -- newseq )
 468     [ { } ] [
 469         [ longest length <iota> ] keep
 470         [ [ ?nth ] with map ] curry map concat sift
 471     ] if-empty ;
 472
 473 : sift-as ( seq exemplar -- newseq )
 474     [ ] swap filter-as ;
 475
 476 : sift! ( seq -- newseq )
 477     [ ] filter! ;
 478
 479 : harvest-as ( seq exemplar -- newseq )
 480     [ empty? not ] swap filter-as ;
 481
 482 : harvest! ( seq -- newseq )
 483     [ empty? ] reject! ;
 484
 485 : head-as ( seq n exemplar -- seq' )
 486     [ head-slice ] [ like ] bi* ; inline
 487
 488 : head*-as ( seq n exemplar -- seq' )
 489     [ head-slice* ] [ like ] bi* ; inline
 490
 491 : tail-as ( seq n exemplar -- seq' )
 492     [ tail-slice ] [ like ] bi* ; inline
 493
 494 : tail*-as ( seq n exemplar -- seq' )
 495     [ tail-slice* ] [ like ] bi* ; inline
 496
 497 : trim-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... newseq )
 498     [ trim-slice ] [ like ] bi* ; inline
 499
 500 : ?trim ( seq quot: ( elt -- ? ) -- seq/newseq )
 501     over empty? [ drop ] [
 502         over [ first-unsafe ] [ last-unsafe ] bi pick either?
 503         [ trim ] [ drop ] if
 504     ] if ; inline
 505
 506 : ?trim-head ( seq quot: ( elt -- ? ) -- seq/newseq )
 507     over empty? [ drop ] [
 508         over first-unsafe over call
 509         [ trim-head ] [ drop ] if
 510     ] if ; inline
 511
 512 : ?trim-tail ( seq quot: ( elt -- ? ) -- seq/newseq )
 513     over empty? [ drop ] [
 514         over last-unsafe over call
 515         [ trim-tail ] [ drop ] if
 516     ] if ; inline
 517
 518 : unsurround ( newseq seq2 seq3 -- seq1 )
 519     [ ?head drop ] [ ?tail drop ] bi* ;
 520
 521 : >string-list ( seq -- seq' )
 522     [ "\"" 1surround ] map "," join ;
 523
 524 : with-string-lines ( str quot -- str' )
 525     [ string-lines ] dip map "\n" join ; inline
 526
 527 : prepend-lines-with-spaces ( str -- str' )
 528     [ "    " prepend ] with-string-lines ;
 529
 530 : one? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 531     [ find ] 2keep rot [
 532         [ 1 + ] 2dip find-from drop not
 533     ] [ 3drop f ] if ; inline
 534
 535 : map-index! ( ... seq quot: ( ... elt index -- ... newelt ) -- ... seq )
 536     over [ [ sequence-index-operator ] dip collect ] keep ; inline
 537
 538 <PRIVATE
 539
 540 : 2sequence-index-iterator ( seq1 seq2 quot -- n quot' )
 541     [ 2length-iterator [ keep ] curry ] dip compose ; inline
 542
 543 PRIVATE>
 544
 545 : 2each-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... ) -- ... )
 546     2sequence-index-iterator each-integer ; inline
 547
 548 : 2map-into ( seq1 seq2 quot into -- )
 549     [ 2length-operator ] dip collect ; inline
 550
 551 : 2map! ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... seq1 )
 552     pick [ 2map-into ] keep ; inline
 553
 554 : 2map-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... newelt ) -- ... newseq )
 555     pick [ 2sequence-index-iterator ] dip map-integers-as ; inline
 556
 557 TUPLE: evens { seq read-only } ;
 558
 559 C: <evens> evens
 560
 561 M: evens length seq>> length 1 + 2/ ; inline
 562
 563 M: evens virtual@ [ 2 * ] [ seq>> ] bi* ; inline
 564
 565 M: evens virtual-exemplar seq>> ; inline
 566
 567 INSTANCE: evens virtual-sequence
 568
 569 TUPLE: odds { seq read-only } ;
 570
 571 C: <odds> odds
 572
 573 M: odds length seq>> length 2/ ; inline
 574
 575 M: odds virtual@ [ 2 * 1 + ] [ seq>> ] bi* ; inline
 576
 577 M: odds virtual-exemplar seq>> ; inline
 578
 579 INSTANCE: odds virtual-sequence
 580
 581 : until-empty ( seq quot -- )
 582     [ dup empty? ] swap until drop ; inline
 583
 584 <PRIVATE
 585
 586 : push-index-if ( ..a elt i quot: ( ..a elt -- ..b ? ) accum -- ..b )
 587     [ dip ] dip rot [ push ] [ 2drop ] if ; inline
 588
 589 PRIVATE>
 590
 591 : arg-where ( ... seq quot: ( ... elt -- ... ? ) -- ... indices )
 592     over length <vector> [
 593         [ push-index-if ] 2curry each-index
 594     ] keep ; inline
 595
 596 : arg-sort ( seq -- indices )
 597     zip-index sort-keys values ;
 598
 599 : first= ( seq elt -- ? ) [ first ] dip = ; inline
 600 : second= ( seq elt -- ? ) [ second ] dip = ; inline
 601 : third= ( seq elt -- ? ) [ third ] dip = ; inline
 602 : fourth= ( seq elt -- ? ) [ fourth ] dip = ; inline
 603 : last= ( seq elt -- ? ) [ last ] dip = ; inline
 604 : nth= ( n seq elt -- ? ) [ nth ] dip = ; inline
 605
 606 : first? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ first ] dip call ; inline
 607 : second? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ second ] dip call ; inline
 608 : third? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ third ] dip call ; inline
 609 : fourth? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ fourth ] dip call ; inline
 610 : last? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ last ] dip call ; inline
 611 : nth? ( ... n seq quot: ( ... elt -- ... ? ) -- ... ? ) [ nth ] dip call ; inline
 612
 613 : loop>sequence** ( ... quot: ( ... -- ... obj ? ) exemplar -- ... seq )
 614     [ ] swap produce-as nip ; inline
 615
 616 : loop>array** ( ... quot: ( ... -- ... obj ? ) -- ... array )
 617     { } loop>sequence** ; inline
 618
 619 : loop>sequence* ( ... quot: ( ... -- ... obj ? ) exemplar -- ... seq )
 620     [ t ] [ '[ [ _ dip ] [ f f f ] if* ] [ swap ] ] [ produce-as 2nip ] tri* ; inline
 621
 622 : loop>array* ( ... quot: ( ... -- ... obj ? ) -- ... array )
 623     { } loop>sequence* ; inline
 624
 625 : loop>sequence ( ... quot: ( ... -- ... obj/f ) exemplar -- ... seq )
 626     [ [ dup ] compose [ ] ] dip produce-as nip ; inline
 627
 628 : loop>array ( ... quot: ( ... -- ... obj/f ) -- ... array )
 629     { } loop>sequence ; inline
 630
 631 : zero-loop>sequence ( ... quot: ( ... n -- ... obj/f ) exemplar -- ... seq )
 632     [ 0 ] [ '[ _ keep 1 + swap ] ] [ loop>sequence ] tri* nip ; inline
 633
 634 : zero-loop>array ( quot: ( ..a n -- ..a obj ) -- seq )
 635     { } zero-loop>sequence ; inline
 636
 637 : iterate-heap-while ( heap quot1: ( value key -- slurp? ) quot2: ( value key -- obj/f ) -- obj/f loop? )
 638     pick heap-empty?
 639     [ 3drop f f ]
 640     [
 641         [ [ heap-peek ] 2dip drop 2keep ]
 642         [
 643             nip ! ( pop? value key heap quot2 )
 644             5roll [
 645                 swap heap-pop* call( value key -- obj/f ) t
 646             ] [
 647                 4drop f f
 648             ] if
 649         ] 3bi
 650     ] if ; inline
 651
 652 : slurp-heap-while-map ( heap quot1: ( value key -- slurp? ) quot2: ( value key -- obj/f ) -- seq )
 653     '[ _ _ _ iterate-heap-while ] loop>array* ; inline
 654
 655 : heap>pairs ( heap -- pairs )
 656     [ 2drop t ] [ swap 2array ] slurp-heap-while-map ;
 657
 658 : map-zip-swap ( quot: ( x -- y ) -- alist )
 659     '[ _ keep ] map>alist ; inline
 660
 661 : ?heap-pop-value>array ( heap -- array )
 662     dup heap-empty? [ drop { } ] [ heap-pop drop 1array ] if ;
 663
 664 <PRIVATE
 665
 666 : (reverse) ( seq -- newseq )
 667     dup [ length ] keep new-sequence
 668     [ 0 swap copy-unsafe ] keep reverse! ;
 669
 670 PRIVATE>
 671
 672 : reverse-as ( seq exemplar -- newseq )
 673     [ (reverse) ] [ like ] bi* ;
 674
 675 : map-product ( ... seq quot: ( ... elt -- ... n ) -- ... n )
 676     [ 1 ] 2dip [ dip * ] with-assoc each ; inline
 677
 678 : insert-nth! ( elt n seq -- )
 679     [ length ] keep ensure swap pick (a..b]
 680     over '[ [ 1 + ] keep _ move-unsafe ] each
 681     set-nth-unsafe ;
 682
 683 : set-nths ( value indices seq -- )
 684     swapd '[ _ swap _ set-nth ] each ; inline
 685
 686 : set-nths-unsafe ( value indices seq -- )
 687     swapd '[ _ swap _ set-nth-unsafe ] each ; inline
 688
 689 <PRIVATE
 690
 691 : (map-find-index) ( seq quot find-quot -- result i elt )
 692     [ [ f ] 2dip [ [ nip ] 2dip call dup ] curry ] dip call
 693     [ [ [ drop f ] unless ] keep ] dip ; inline
 694
 695 PRIVATE>
 696
 697 : map-find-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 698     [ find-index ] (map-find-index) ; inline
 699
 700 : find-from* ( ... n seq quot: ( ... elt -- ... ? ) -- ... elt i/f )
 701     '[ _ do-find-from element/index ] bounds-check-call ; inline
 702
 703 : find* ( ... seq quot: ( ... elt -- ... ? ) -- ... elt i/f )
 704     [ 0 ] 2dip do-find-from element/index ; inline
 705
 706 : find-last-from* ( ... n seq quot: ( ... elt -- ... ? ) -- ... elt i/f )
 707     '[ _ find-last-from-unsafe element/index ] bounds-check-call ; inline
 708
 709 : find-last* ( ... seq quot: ( ... elt -- ... ? ) -- ... elt i/f )
 710     [ index-of-last ] dip find-last-from* ; inline
 711
 712 : find-index-from* ( ... n seq quot: ( ... elt i -- ... ? ) -- ... elt i/f )
 713     '[
 714         _ [ sequence-index-operator find-integer-from ] keepd
 715         element/index
 716     ] bounds-check-call ; inline
 717
 718 : find-index* ( ... seq quot: ( ... elt i -- ... ? ) -- ... elt i/f )
 719     [ 0 ] 2dip find-index-from* ; inline
 720
 721 : filter-length ( seq n -- seq' ) '[ length _ = ] filter ;
 722
 723 : all-shortest ( seqs -- seqs' ) dup shortest length filter-length ;
 724
 725 : all-longest ( seqs -- seqs' ) dup longest length filter-length ;
 726
 727 <PRIVATE
 728
 729 : nth-unsafe-of ( seq n -- elt ) swap nth-unsafe ; inline
 730 : set-nth-unsafe-of ( seq n elt -- seq ) spin [ set-nth-unsafe ] keep ; inline
 731 : set-length-of ( seq n -- seq ) over set-length ; inline
 732
 733 : move-unsafe-of ( seq to from -- seq )
 734     2dup = [
 735         2drop
 736     ] [
 737         overd nth-unsafe-of set-nth-unsafe-of
 738     ] if ; inline
 739
 740 : move-backward-of ( seq shift from to -- seq )
 741     2dup = [
 742         3drop
 743     ] [
 744         [ [ [ + ] keep move-unsafe-of ] 2keep 1 + ] dip move-backward-of
 745     ] if ;
 746
 747 : open-slice-of ( seq shift from -- seq )
 748     over 0 = [
 749         2drop
 750     ] [
 751         [ ] [ drop [ length ] dip + ] 3bi
 752         [ pick length [ over - ] dip move-backward-of ] dip
 753         set-length-of
 754     ] if ;
 755
 756 PRIVATE>
 757
 758 ERROR: slice-error-of from to seq ;
 759
 760 : check-slice-of ( seq from to -- seq from to )
 761     over 0 < [ slice-error-of ] when
 762     dup reach length > [ slice-error-of ] when
 763     2dup > [ slice-error-of ] when ; inline
 764
 765 : delete-slice-of ( seq from to -- seq )
 766     check-slice-of over [ - ] dip open-slice-of ;
 767
 768 : remove-nth-of ( seq n -- seq' )
 769     [ dup 1 + rot snip-slice ] keepd append-as ;
 770
 771 : remove-nth-of* ( seq n -- nth seq' )
 772     [ nth-of ] [ remove-nth-of ] 2bi ;
 773
 774 : remove-nth-of! ( seq n -- seq )
 775     dup 1 + delete-slice-of ;
 776
 777 : remove-nth-of*! ( seq n -- nth seq )
 778     [ nth-of ] [ dup 1 + delete-slice-of ] 2bi ;
 779
 780 : snip-of ( seq from to -- head tail )
 781     [ head ] [ tail ] bi-curry* bi ; inline
 782
 783 : snip-slice-of ( seq from to -- head tail )
 784     [ head-slice ] [ tail-slice ] bi-curry* bi ; inline
 785
 786 : index* ( seq obj -- n ) [ = ] curry find drop ;
 787
 788 : index-from* ( i seq obj -- n )
 789     [ = ] curry find-from drop ;
 790
 791 : last-index* ( seq obj -- n )
 792     [ = ] curry find-last drop ;
 793
 794 : last-index-from* ( i seq obj -- n )
 795     [ = ] curry find-last-from drop ;
 796
 797 : indices* ( seq obj -- indices )
 798     [ = ] curry [ swap ] prepose V{ } clone [
 799         [ push ] curry [ [ drop ] if ] curry compose each-index
 800     ] keep ;
 801
 802 : remove-first ( obj seq -- seq' )
 803     [ index ] keep over [ remove-nth ] [ nip ] if ;
 804
 805 : remove-first-of ( seq obj -- seq' )
 806     dupd index* [ remove-nth-of ] when* ;
 807
 808 : remove-first! ( obj seq -- seq )
 809     [ index ] keep over [ remove-nth! ] [ nip ] if ;
 810
 811 : remove-last ( obj seq -- seq' )
 812     [ last-index ] keep over [ remove-nth ] [ nip ] if ;
 813
 814 : remove-last! ( obj seq -- seq )
 815     [ last-index ] keep over [ remove-nth! ] [ nip ] if ;
 816
 817 : member-of? ( seq elt -- ? )
 818     [ = ] curry any? ;
 819
 820 : member-eq-of? ( seq elt -- ? )
 821     [ eq? ] curry any? ;
 822
 823 : remove-of ( seq elt -- newseq )
 824     [ = ] curry reject ;
 825
 826 : remove-eq-of ( seq elt -- newseq )
 827     [ eq? ] curry reject ;
 828
 829 : ?first2 ( seq -- first/f second/f )
 830     dup length {
 831         { 0 [ drop f f ] }
 832         { 1 [ first-unsafe f ] }
 833         [ drop first2-unsafe ]
 834     } case ;
 835
 836 : ?first3 ( seq -- first/f second/f third/f )
 837     dup length {
 838         { 0 [ drop f f f ] }
 839         { 1 [ first-unsafe f f ] }
 840         { 2 [ first2-unsafe f ] }
 841         [ drop first3-unsafe ]
 842     } case ;
 843
 844 : ?first4 ( seq -- first/f second/f third/f fourth/f )
 845     dup length {
 846         { 0 [ drop f f f f ] }
 847         { 1 [ first-unsafe f f f ] }
 848         { 2 [ first2-unsafe f f ] }
 849         { 3 [ first3-unsafe f ] }
 850         [ drop first4-unsafe ]
 851     } case ;
 852
 853 : cut-when ( ... seq quot: ( ... elt -- ... ? ) -- ... before after )
 854     [ find drop ] keepd swap
 855     [ cut ] [ f over like ] if* ; inline
 856
 857 : nth* ( n seq -- elt )
 858     [ length 1 - swap - ] [ nth ] bi ; inline
 859
 860 : each-index-from ( ... seq quot: ( ... elt index -- ... ) i -- ... )
 861     -rot sequence-index-operator each-integer-from ; inline
 862
 863 <PRIVATE
 864
 865 : select-by* ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... i elt )
 866     [
 867         [ keep swap ] curry [ dip ] curry
 868         [ [ first 0 ] dip call ] 2keep
 869         [ 2curry 3dip 5 npick pick ] curry
 870     ] [
 871         [ [ 3drop ] [ [ 3drop ] 3dip ] if ] compose
 872     ] bi* compose 1 each-index-from nip swap ; inline
 873
 874 PRIVATE>
 875
 876 : supremum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 877     [ after? ] select-by* ; inline
 878
 879 : infimum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 880     [ before? ] select-by* ; inline
 881
 882 : arg-max ( seq -- n )
 883     [ ] supremum-by* drop ;
 884
 885 : arg-min ( seq -- n )
 886     [ ] infimum-by* drop ;
 887
 888 : ?supremum ( seq/f -- elt/f )
 889     [ f ] [
 890         [ ] [ 2dup and [ max ] [ dupd ? ] if ] map-reduce
 891     ] if-empty ;
 892
 893 : ?infimum ( seq/f -- elt/f )
 894     [ f ] [
 895         [ ] [ 2dup and [ min ] [ dupd ? ] if ] map-reduce
 896     ] if-empty ;
 897
 898 : map-infimum ( seq quot: ( ... elt -- ... elt' ) -- elt' )
 899     [ min ] map-reduce ; inline
 900
 901 : map-supremum ( seq quot: ( ... elt -- ... elt' ) -- elt' )
 902     [ max ] map-reduce ; inline
 903
 904 : change-last ( seq quot -- )
 905     [ index-of-last ] [ change-nth ] bi* ; inline
 906
 907 : change-last-unsafe ( seq quot -- )
 908     [ index-of-last ] [ change-nth-unsafe ] bi* ; inline
 909
 910 : replicate-into ( ... seq quot: ( ... -- ... newelt ) -- ... )
 911     over [ length ] 2dip '[ _ dip _ set-nth-unsafe ] each-integer ; inline
 912
 913 : percent-of ( ... seq quot: ( ... elt -- ... ? ) -- ... % )
 914     over length 0 =
 915     [ 2drop 0 ]
 916     [ over [ count ] [ length ] bi* / ] if ; inline
 917
 918 : sequence-index-operator-last ( n seq quot -- n quot' )
 919     [ [ nth-unsafe ] curry [ keep ] curry ] dip compose ; inline
 920
 921 : find-last-index-from ( ... n seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 922     '[
 923         _ [ sequence-index-operator-last find-last-integer ] keepd
 924         index/element
 925     ] bounds-check-call ; inline
 926
 927 : find-last-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 928     [ index-of-last ] dip find-last-index-from ; inline
 929
 930 : map-find-last-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 931     [ find-last-index ] (map-find-index) ; inline
 932
 933 :: (start-all) ( seq subseq increment -- indices )
 934     0
 935     [ seq subseq subseq-index-from dup ]
 936     [ [ increment + ] keep ] produce nip ;
 937
 938 : start-all ( seq subseq -- indices )
 939     dup length (start-all) ; inline
 940
 941 : start-all* ( seq subseq -- indices )
 942     1 (start-all) ; inline
 943
 944 : count-subseq ( seq subseq -- n )
 945     start-all length ; inline
 946
 947 : count-subseq* ( seq subseq -- n )
 948     start-all* length ; inline
 949
 950 : assoc-zip-with ( quot: ( key value -- calc ) -- alist )
 951     '[ _ 2keep 2array swap ] assoc-map ; inline
 952
 953 : take-while ( ... seq quot: ( ... elt -- ... ? ) -- head-slice )
 954     [ '[ @ not ] find drop ] keepd swap
 955     [ dup length ] unless* head-slice ; inline
 956
 957 : drop-while ( ... seq quot: ( ... elt -- ... ? ) -- tail-slice )
 958     [ '[ @ not ] find drop ] keepd swap
 959     [ dup length ] unless* tail-slice ; inline
 960
 961 : count-head ( seq quot -- n )
 962     [ not ] compose [ find drop ] keepd length or ; inline
 963
 964 : count-tail ( seq quot -- n )
 965     [ not ] compose [ find-last drop ] keepd
 966     length swap [ - 1 - ] when* ; inline
 967
 968 :: shorten* ( vector n -- seq )
 969     vector n tail
 970     n vector shorten ;
 971
 972 :: interleaved-as ( seq glue exemplar -- newseq )
 973     seq length dup 1 - + 0 max exemplar new-sequence :> newseq
 974     seq [ 2 * newseq set-nth-unsafe ] each-index
 975     seq length 1 - [ 2 * 1 + glue swap newseq set-nth-unsafe ] each-integer
 976     newseq ;
 977
 978 : interleaved ( seq glue -- newseq )
 979     over interleaved-as ;
 980
 981 : extract! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 982     [ dup ] compose over [ length ] keep new-resizable
 983     [ [ push-when ] 2curry reject! ] keep swap like ; inline
 984
 985 : find-pred-loop ( ... i n seq quot: ( ... elt -- ... calc ? ) -- ... calc/f i/f elt/f )
 986     2pick < [
 987         [ nipd call ] 4keep
 988         3 7 0 nrotated
 989         [ [ 3drop ] 2dip rot ]
 990         [ 2drop [ 1 + ] 3dip find-pred-loop ] if
 991     ] [
 992         4drop f f f
 993     ] if ; inline recursive
 994
 995 : find-pred ( ... seq quot: ( ... elt -- ... calc ) pred: ( ... calc -- ... ? ) -- ... calc/f i/f elt/f )
 996     [ 0 ] 3dip
 997     [ [ length check-length ] keep ] 2dip
 998     '[ nth-unsafe _ keep swap _ keep swap ] find-pred-loop swapd ; inline
 999
1000 ! https://en.wikipedia.org/wiki/Maximum_subarray_problem
1001 ! Kadane's algorithm O(n) largest sum in subarray
1002 : max-subarray-sum ( seq -- sum )
1003     [ -1/0. 0 ] dip
1004     [ [ + ] keep max [ max ] keep ] each drop ;
1005
1006 TUPLE: step-slice
1007     { from integer read-only initial: 0 }
1008     { to integer read-only initial: 0 }
1009     { seq read-only }
1010     { step integer read-only } ;
1011
1012 :: <step-slice> ( from/f to/f step seq -- step-slice )
1013     step zero? [ "can't be zero" throw ] when
1014     seq length :> len
1015     step 0 > [
1016         from/f [ 0 ] unless*
1017         to/f [ len ] unless*
1018     ] [
1019         from/f [ len ] unless*
1020         to/f [ 0 ] unless*
1021     ] if
1022     [ dup 0 < [ len + ] when 0 len clamp ] bi@
1023     ! FIXME: make this work with steps
1024     seq dup slice? [ collapse-slice ] when
1025     step step-slice boa ;
1026
1027 M: step-slice virtual-exemplar seq>> ; inline
1028
1029 M: step-slice virtual@
1030     [ step>> * ] [ from>> + ] [ seq>> ] tri ; inline
1031
1032 M: step-slice length
1033     [ to>> ] [ from>> - ] [ step>> ] tri
1034     dup 0 < [ [ neg 0 max ] dip neg ] when /mod
1035     zero? [ 1 + ] unless ; inline
1036
1037 INSTANCE: step-slice virtual-sequence
1038
1039 : 2nested-each* ( seq1 seq-quot: ( n -- seq ) quot: ( a b -- ) -- )
1040     '[
1041         _ keep swap _ with each
1042     ] each ; inline
1043
1044 : 2nested-filter-as* ( seq1 seq-quot quot exemplar -- seq )
1045     [ 2over [ length ] bi@ * ] dip
1046     [
1047         new-resizable
1048         [ [ maybe-push ] curry compose 2nested-each* ] keep
1049     ] keep like ; inline
1050
1051 : 2nested-filter* ( seq1 seq-quot quot -- seq )
1052     pick 2nested-filter-as* ; inline
1053
1054 : 2nested-map-as* ( seq1 seq-quot quot exemplar -- seq )
1055     [ 2over [ length ] bi@ * ] dip
1056     [
1057         new-resizable
1058         [ [ push ] curry compose 2nested-each* ] keep
1059     ] keep like ; inline
1060
1061 : 2nested-map* ( seq1 seq-quot quot -- seq )
1062     pick 2nested-map-as* ; inline
1063
1064
1065 : 2nested-each ( seq1 seq2 quot -- )
1066     swapd '[
1067         swap _ with each
1068     ] with each ; inline
1069
1070 : 2nested-filter-as ( seq1 seq2 quot exemplar -- seq )
1071     [ 2over [ length ] bi@ * ] dip
1072     [
1073         new-resizable
1074         [ [ maybe-push ] curry compose 2nested-each ] keep
1075     ] keep like ; inline
1076
1077 : 2nested-filter ( seq1 seq2 quot -- seq )
1078     pick 2nested-filter-as ; inline
1079
1080 : 2nested-map-as ( seq1 seq2 quot exemplar -- seq )
1081     [ 2over [ length ] bi@ * ] dip
1082     [
1083         new-resizable
1084         [ [ push ] curry compose 2nested-each ] keep
1085     ] keep like ; inline
1086
1087 : 2nested-map ( seq1 seq2 quot -- seq )
1088     pick 2nested-map-as ; inline
1089
1090 : 3nested-each ( seq1 seq2 seq3 quot -- )
1091     spind '[
1092         -rot [
1093             swap _ with with each
1094         ] with with each
1095     ] with with each ; inline
1096
1097 : 3nested-filter-as ( seq1 seq2 seq3 quot exemplar -- seq )
1098     [ 3 nover [ length ] tri@ * * ] dip
1099     [
1100         new-resizable
1101         [ [ maybe-push ] curry compose 3nested-each ] keep
1102     ] keep like ; inline
1103
1104 : 3nested-filter ( seq1 seq2 seq3 quot -- seq )
1105     reach 3nested-filter-as ; inline
1106
1107 : 3nested-map-as ( seq1 seq2 seq3 quot exemplar -- seq )
1108     [ 3 nover [ length ] tri@ * * ] dip
1109     [
1110         new-resizable
1111         [ [ push ] curry compose 3nested-each ] keep
1112     ] keep like ; inline
1113
1114 : 3nested-map ( seq1 seq2 seq3 quot -- seq )
1115     reach 3nested-map-as ; inline
1116
1117 : prev ( n seq -- obj ) [ 1 - ] dip nth ; inline
1118 : ?prev ( n seq -- obj/f ) [ 1 - ] dip ?nth ; inline
1119 : ??prev ( n seq -- obj/f ? ) [ 1 - ] dip ??nth ; inline
1120 : prev-of ( seq n -- obj ) 1 - nth-of ; inline
1121 : ?prev-of ( seq n -- obj/f ) 1 - ?nth-of ; inline
1122 : ??prev-of ( seq n -- obj/f ? ) 1 - ??nth-of ; inline
1123
1124 : prev-identity ( i seq -- identity i seq )
1125     2dup ??prev [ drop 0 ] unless -rot ; inline
1126
1127 : each-prior-identity-from ( ... identity i seq quot: ( ... prior elt -- ... ) -- ... )
1128     '[ [ swap @ ] keep ]
1129     length-operator each-integer-from drop ; inline
1130
1131 : each-prior-from ( ... i seq quot: ( ... prior elt -- ... ) -- ... )
1132     [ prev-identity ] dip each-prior-identity-from ; inline
1133
1134 : each-prior ( ... seq quot: ( ... prior elt -- ... ) -- ... )
1135     0 -rot each-prior-from ; inline
1136
1137 : map-prior-identity-from-as ( ... identity i seq quot: ( ... prior elt -- elt' ) exemplar -- seq' )
1138     [
1139         '[ [ swap @ ] keep swap ] length-operator
1140     ] dip map-integers-from-as nip ; inline
1141
1142 : map-prior-identity-as ( ... identity seq quot: ( ... prior elt -- elt' ) exemplar -- seq' )
1143     [ 0 ] 3dip map-prior-identity-from-as ; inline
1144
1145 : map-prior-from-as ( ... i seq quot: ( ... prior elt -- elt' ) exemplar -- seq' )
1146     [ prev-identity ] 2dip map-prior-identity-from-as ; inline
1147
1148 : map-prior-as ( ... seq quot: ( ... prior elt -- elt' ) exemplar -- seq' )
1149     0 -roll map-prior-from-as ; inline
1150
1151 : map-prior-from ( ... i seq quot: ( ... prior elt -- elt' ) -- seq' )
1152     over map-prior-from-as ; inline
1153
1154 : map-prior ( ... seq quot: ( ... prior elt -- elt' ) -- seq' )
1155     over map-prior-as ; inline
1156
1157 TUPLE: virtual-zip-index seq ;
1158
1159 C: <zip-index> virtual-zip-index
1160
1161 M: virtual-zip-index length seq>> length ; inline
1162
1163 M: virtual-zip-index nth-unsafe
1164     over [ seq>> nth-unsafe ] [ 2array ] bi* ; inline
1165
1166 INSTANCE: virtual-zip-index immutable-sequence
1167
1168 : call-push-when ( ..a elt quot: ( ..a elt -- ..b elt' ? ) accum -- ..b )
1169     [ call ] dip swap [ push ] [ 2drop ] if ; inline
1170
1171 : fry-map-as ( seq quot exemplar -- newseq )
1172     [ 2drop length ]
1173     [ overd new-sequence-like dup ]
1174     [ 2nip ] 3tri
1175     '[ [ [ _ nth-unsafe @ ] [ _ set-nth-unsafe ] bi ] each-integer _ _ like ] call ; inline