extra/sequences/extras/extras.factor

   1 USING: accessors arrays assocs combinators generalizations
   2 grouping growable heaps kernel math math.order ranges sequences
   3 sequences.private shuffle sorting splitting vectors ;
   4 IN: sequences.extras
   5
   6 : find-all ( ... seq quot: ( ... elt -- ... ? ) -- ... elts )
   7     [ <enumerated> ] dip '[ nip @ ] assoc-filter ; inline
   8
   9 :: subseq* ( from to seq -- subseq )
  10     seq length :> len
  11     from [ dup 0 < [ len + ] when ] [ 0 ] if*
  12     to [ dup 0 < [ len + ] when ] [ len ] if*
  13     [ 0 len clamp ] bi@ dupd max seq subseq ;
  14
  15 : safe-subseq ( from to seq -- subseq )
  16     [ length '[ 0 _ clamp ] bi@ ] keep subseq ;
  17
  18 : all-subseqs ( seq -- seqs )
  19     dup length [1..b] [ clump ] with map concat ;
  20
  21 : each-subseq ( ... seq quot: ( ... subseq -- ... ) -- ... )
  22     [ dup length [ [0..b] ] [ ] bi ] dip '[
  23         dup _ (a..b] [ rot [ subseq _ call ] keep ] with each
  24     ] each drop ; inline
  25
  26 : map-like ( seq exemplar -- seq' )
  27     '[ _ like ] map ; inline
  28
  29 : filter-all-subseqs-range ( ... seq range quot: ( ... subseq -- ... ? ) -- seq )
  30     [
  31         '[ <clumps> _ filter ] with map concat
  32     ] keepdd map-like ; inline
  33
  34 : filter-all-subseqs ( ... seq quot: ( ... subseq -- ... ? ) -- seq )
  35     [ dup length [1..b] ] dip filter-all-subseqs-range ; inline
  36
  37 :: longest-subseq ( seq1 seq2 -- subseq )
  38     seq1 length :> len1
  39     seq2 length :> len2
  40     0 :> n!
  41     0 :> end!
  42     len1 1 + [ len2 1 + 0 <array> ] replicate :> table
  43     len1 [1..b] [| x |
  44         len2 [1..b] [| y |
  45             x 1 - seq1 nth-unsafe
  46             y 1 - seq2 nth-unsafe = [
  47                 y 1 - x 1 - table nth-unsafe nth-unsafe 1 + :> len
  48                 len y x table nth-unsafe set-nth-unsafe
  49                 len n > [ len n! x end! ] when
  50             ] [ 0 y x table nth-unsafe set-nth-unsafe ] if
  51         ] each
  52     ] each end n - end seq1 subseq ;
  53
  54 : pad-longest ( seq1 seq2 elt -- seq1 seq2 )
  55     [ 2dup max-length ] dip [ pad-tail ] 2curry bi@ ;
  56
  57 : pad-center ( seq n elt -- padded )
  58     swap pick length [-] [ drop ] [
  59         [ 2/ ] [ over - ] bi rot '[ _ <repetition> ] bi@
  60         pick surround-as
  61     ] if-zero ;
  62
  63 : change-nths ( ... indices seq quot: ( ... elt -- ... elt' ) -- ... )
  64     [ change-nth ] 2curry each ; inline
  65
  66 : push-if-index ( ..a elt i quot: ( ..a elt i -- ..b ? ) accum -- ..b )
  67     [ keepd ] dip rot [ push ] [ 2drop ] if ; inline
  68
  69 : push-if* ( ..a elt quot: ( ..a elt -- ..b obj/f ) accum -- ..b )
  70     [ call ] dip [ push ] [ drop ] if* ; inline
  71
  72 : push? ( elt/f accum -- )
  73     over [ push ] [ 2drop ] if ; inline
  74
  75 <PRIVATE
  76
  77 : (index-selector-as) ( quot length exampler -- selector accum )
  78     new-resizable [ [ push-if-index ] 2curry ] keep ; inline
  79
  80 : (selector-as*) ( quot length exemplar -- selector accum )
  81     new-resizable [ [ push-if* ] 2curry ] keep ; inline
  82
  83 PRIVATE>
  84
  85 : index-selector-as ( quot exemplar -- selector accum )
  86     [ length ] keep (index-selector-as) ; inline
  87
  88 : index-selector ( quot -- selector accum )
  89     V{ } index-selector-as ; inline
  90
  91 : selector-as* ( quot exemplar -- selector accum )
  92     [ length ] keep (selector-as*) ; inline
  93
  94 : selector* ( quot -- selector accum ) V{ } selector-as* ; inline
  95
  96 : filter-index-as ( ... seq quot: ( ... elt i -- ... ? ) exemplar -- ... seq' )
  97     pick length over [ (index-selector-as) [ each-index ] dip ] 2curry dip like ; inline
  98
  99 : filter-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... seq' )
 100     over filter-index-as ; inline
 101
 102 : even-indices ( seq -- seq' )
 103     [ length 1 + 2/ ] keep [
 104         [ [ 2 * ] dip nth-unsafe ] curry
 105     ] keep map-integers-as ;
 106
 107 : odd-indices ( seq -- seq' )
 108     [ length 2/ ] keep [
 109         [ [ 2 * 1 + ] dip nth-unsafe ] curry
 110     ] keep map-integers-as ;
 111
 112 : compact ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 113     [ split-when harvest ] dip join ; inline
 114
 115 : collapse ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 116     [ split-when ] dip
 117     [ [ harvest ] dip join ]
 118     [ [ first empty? ] dip [ prepend ] curry when ]
 119     [ [ last empty? ] dip [ append ] curry when ]
 120     2tri ; inline
 121
 122 :: slice-when ( seq quot: ( elt -- ? ) -- seq' )
 123     seq length :> len
 124     0 [ len dupd < ] [
 125         dup seq quot find-from drop
 126         [ 2dup = [ 1 + ] when ] [ len ] if*
 127         [ seq <slice> ] keep len or swap
 128     ] produce nip ; inline
 129
 130 : ?<slice> ( from/f to/f sequence -- slice )
 131     [ [ 0 ] unless* ] 2dip
 132     over [ nip [ length ] [ ] bi ] unless
 133     <slice> ; inline
 134
 135 : sequence>slice ( sequence -- slice )
 136     [ drop 0 ] [ length ] [ ] tri <slice> ; inline
 137
 138 : slice-order-by-from ( slice1 slice2 -- slice-lt slice-gt )
 139     2dup [ from>> ] bi@ > [ swap ] when ; inline
 140
 141 : ordered-slices-range ( slice-lt slice-gt -- to from )
 142     [ to>> ] [ from>> ] bi* ;
 143
 144 : unordered-slices-range ( slice1 slice2 -- to from )
 145     slice-order-by-from ordered-slices-range ;
 146
 147 : ordered-slices-overlap? ( slice-lt slice-gt -- ? )
 148     ordered-slices-range > ; inline
 149
 150 : unordered-slices-overlap? ( slice1 slice2 -- ? )
 151     unordered-slices-range > ; inline
 152
 153 : slices-overlap? ( slice1 slice2 -- ? )
 154     unordered-slices-overlap? ;
 155
 156 : ordered-slices-touch? ( slice-lt slice-gt -- ? )
 157     ordered-slices-range >= ; inline
 158
 159 : unordered-slices-touch? ( slice1 slice2 -- ? )
 160     unordered-slices-range >= ; inline
 161
 162 : slices-touch? ( slice1 slice2 -- ? )
 163     unordered-slices-touch? ;
 164
 165 ERROR: slices-don't-touch slice1 slice2 ;
 166
 167 : merge-slices ( slice1 slice2 -- slice/* )
 168     slice-order-by-from
 169     2dup ordered-slices-touch? [
 170         [ from>> ] [ [ to>> ] [ seq>> ] bi ] bi* <slice>
 171     ] [
 172         slices-don't-touch
 173     ] if ;
 174
 175 : rotate ( seq n -- seq' )
 176     over length mod dup 0 >= [ cut ] [ abs cut* ] if prepend ;
 177
 178 ERROR: underlying-mismatch slice1 slice2 ;
 179
 180 : ensure-same-underlying ( slice1 slice2 -- slice1 slice2 )
 181     2dup [ seq>> ] bi@ eq? [ underlying-mismatch ] unless ;
 182
 183 : span-slices ( slice1 slice2 -- slice )
 184     ensure-same-underlying
 185     [ [ from>> ] bi@ min ]
 186     [ [ to>> ] bi@ max ]
 187     [ drop seq>> ] 2tri <slice> ;
 188
 189 : ?span-slices ( slice1/f slice2/f -- slice )
 190     2dup and [ span-slices ] [ or ] if ;
 191
 192 :: rotate! ( seq n -- )
 193     seq length :> len
 194     n len mod dup 0 < [ len + ] when seq bounds-check drop 0 over
 195     [ 2dup = ] [
 196         [ seq exchange-unsafe ] [ [ 1 + ] bi@ ] 2bi
 197         dup len = [ drop over ] when
 198         2over = [ -rot nip over ] when
 199     ] until 3drop ;
 200
 201 : all-rotations ( seq -- seq' )
 202     dup length <iota> [ rotate ] with map ;
 203
 204 <PRIVATE
 205
 206 : (appender-for) ( quot length exemplar -- appender accum )
 207     new-resizable [ [ push-all ] curry compose ] keep ; inline
 208
 209 PRIVATE>
 210
 211 : appender-for ( quot exemplar -- appender accum )
 212     [ length ] keep (appender-for) ; inline
 213
 214 : appender ( quot -- appender accum )
 215     V{ } appender-for ; inline
 216
 217 : map-concat-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 218     [ appender-for [ each ] dip ] keep like ; inline
 219
 220 : >resizable ( seq -- accum ) ! fixes map-concat "cannot apply call to run-time..."
 221     [ length ] keep [ new-resizable ] [ append! ] bi ;
 222
 223 : map-concat ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 224     over empty? [ 2drop { } ] [
 225         [ [ first ] dip call ] 2keep rot [
 226             >resizable [ '[ @ _ push-all ] 1 each-from ] keep
 227         ] keep like
 228     ] if ; inline
 229
 230 : map-filter-as ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) exemplar -- ... subseq )
 231     reach length over
 232     [ (selector-as) [ compose each ] dip ] 2curry dip like ; inline
 233
 234 : map-filter ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) -- ... subseq )
 235     pick map-filter-as ; inline
 236
 237 : map-sift ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 238     [ ] map-filter ; inline
 239
 240 : map-harvest ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 241     [ empty? not ] map-filter ; inline
 242
 243 : (each-integer-with-previous) ( ... prev i n quot: ( ... i -- ... ) -- ... )
 244     2over < [
 245         [ nip call ] 4keep nipdd
 246         [ 1 + ] 2dip (each-integer-with-previous)
 247     ] [
 248         4drop
 249     ] if ; inline recursive
 250
 251 : each-integer-with-previous ( ... n quot: ( ... i -- ... ) -- ... )
 252     [ f 0 ] 2dip (each-integer-with-previous) ; inline
 253
 254 : (collect-with-previous) ( quot into -- quot' )
 255     [ [ keep ] dip [ set-nth-unsafe ] keepdd ] 2curry ; inline
 256
 257 : collect-with-previous ( n quot into --  )
 258     (collect-with-previous) each-integer-with-previous ; inline
 259
 260 : map-integers-with ( ... len quot: ( ... prev i -- ... elt ) exemplar -- ... newseq )
 261     overd [ [ collect-with-previous ] keep ] new-like ; inline
 262
 263 : map-with-previous-as ( ... seq quot: ( ... elt prev/f -- ... newelt ) exemplar -- ... newseq )
 264     [ length-operator ] dip map-integers-with ; inline
 265
 266 : map-with-previous ( ... seq quot: ( ... elt prev/f -- ... newelt ) -- ... newseq )
 267     over map-with-previous-as ; inline
 268
 269 : setup-each-from ( seq quot -- n quot )
 270     [ [ length ] keep [ nth-unsafe ] curry ] dip compose ; inline
 271
 272 : map-from-as ( ... seq quot: ( ... elt -- ... newelt ) from exemplar -- ... newseq )
 273     -rotd [ sequence-operator nipd ] dip map-integers-from-as ; inline
 274
 275 : map-from ( ... seq quot: ( ... elt -- ... newelt ) from -- ... newseq )
 276     pick map-from-as ; inline
 277
 278 : map-if ( ... seq if-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) -- ... newseq )
 279     '[ dup @ _ when ] map ; inline
 280
 281 : reduce-from ( ... seq identity quot: ( ... prev elt -- ... next ) from -- ... result )
 282     [ swap ] 2dip each-from ; inline
 283
 284 : 2reduce-from ( ... seq1 seq2 identity quot: ( ... prev elt1 elt2 -- ... next ) i -- ... result )
 285     [ -rot ] 2dip 2each-from ; inline
 286
 287 : 0accumulate-as ( ... seq quot: ( ... prev elt -- ... next ) exemplar -- ... newseq )
 288     pick empty? [
 289         2nip clone
 290     ] [
 291         [ 0 ] 2dip
 292         [ swapd [ dup ] compose ] dip map-as nip
 293     ] if ; inline
 294
 295 : 0accumulate ( ... seq quot: ( ... prev elt -- ... next ) -- ... final newseq )
 296     over 0accumulate-as ; inline
 297
 298 : occurrence-count-by ( seq quot: ( elt -- elt' ) -- hash seq' )
 299     '[ nip @ over inc-at* ] [ H{ } clone ] 2dip 0accumulate ; inline
 300
 301 : occurrence-count ( seq -- hash seq' )
 302     [ ] occurrence-count-by ; inline
 303
 304 : nth-index ( n obj seq -- i )
 305     [ = dup [ drop 1 - dup 0 < ] when ] with find drop nip ;
 306
 307 : progressive-index-by-as ( seq1 seq2 quot exemplar -- hash seq' )
 308     [
 309         pick length '[
 310             tuck [ @ over inc-at* ] 2dip swap nth-index _ or
 311         ] [ H{ } clone ] 3dip with
 312     ] dip map-as ; inline
 313
 314 : progressive-index-by ( seq1 seq2 quot -- hash seq' )
 315     { } progressive-index-by-as ; inline
 316
 317 : progressive-index ( seq1 seq2 -- hash seq' )
 318     [ ] progressive-index-by ; inline
 319
 320 : 0reduce ( seq quot: ( prev elt -- next ) -- result )
 321     [ 0 ] dip reduce ; inline
 322
 323 <PRIVATE
 324
 325 : push-map-if ( ..a elt filter-quot: ( ..a elt -- ..b ? ) map-quot: ( ..a elt -- ..b newelt ) accum -- ..b )
 326     [ keep over ] 2dip [ when ] dip rot [ push ] [ 2drop ] if ; inline
 327
 328 : (filter-mapper-for) ( filter-quot map-quot length exempler -- filter-mapper accum )
 329     new-resizable [ [ push-map-if ] 3curry ] keep ; inline
 330
 331 : filter-mapper-for ( filter-quot map-quot exemplar -- filter-mapper accum )
 332     [ length ] keep (filter-mapper-for) ; inline
 333
 334 : filter-mapper ( filter-quot map-quot -- filter-mapper accum )
 335     V{ } filter-mapper-for ; inline
 336
 337 PRIVATE>
 338
 339 : filter-map-as ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 340     reach length over
 341     [ (filter-mapper-for) [ each ] dip ] 2curry dip like ; inline
 342
 343 : filter-map ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) -- ... newseq )
 344     pick filter-map-as ; inline
 345
 346 : 2map-sum ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... n ) -- ... n )
 347     [ 0 ] 3dip [ dip + ] curry [ rot ] prepose 2each ; inline
 348
 349 : 2count ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... n )
 350     [ 1 0 ? ] compose 2map-sum ; inline
 351
 352 : 3each-from
 353     ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... ) i -- ... )
 354     [ 3length-operator ] dip -rot each-integer-from ; inline
 355
 356 : 3map-reduce
 357     ( ..a seq1 seq2 seq3 map-quot: ( ..a elt1 elt2 elt3 -- ..b intermediate ) reduce-quot: ( ..b prev intermediate -- ..a next ) -- ..a result )
 358     [ [ [ [ first ] tri@ ] 3keep ] dip [ 3dip ] keep ] dip compose 1 3each-from ; inline
 359
 360 : round-robin ( seq -- newseq )
 361     [ { } ] [
 362         [ longest length <iota> ] keep
 363         [ [ ?nth ] with map ] curry map concat sift
 364     ] if-empty ;
 365
 366 : sift-as ( seq exemplar -- newseq )
 367     [ ] swap filter-as ;
 368
 369 : sift! ( seq -- newseq )
 370     [ ] filter! ;
 371
 372 : harvest-as ( seq exemplar -- newseq )
 373     [ empty? not ] swap filter-as ;
 374
 375 : harvest! ( seq -- newseq )
 376     [ empty? ] reject! ;
 377
 378 : head-as ( seq n exemplar -- seq' )
 379     [ head-slice ] [ like ] bi* ; inline
 380
 381 : head*-as ( seq n exemplar -- seq' )
 382     [ head-slice* ] [ like ] bi* ; inline
 383
 384 : tail-as ( seq n exemplar -- seq' )
 385     [ tail-slice ] [ like ] bi* ; inline
 386
 387 : tail*-as ( seq n exemplar -- seq' )
 388     [ tail-slice* ] [ like ] bi* ; inline
 389
 390 : trim-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... newseq )
 391     [ trim-slice ] [ like ] bi* ; inline
 392
 393 : ?trim ( seq quot: ( elt -- ? ) -- seq/newseq )
 394     over empty? [ drop ] [
 395         over [ first-unsafe ] [ last-unsafe ] bi pick either?
 396         [ trim ] [ drop ] if
 397     ] if ; inline
 398
 399 : ?trim-head ( seq quot: ( elt -- ? ) -- seq/newseq )
 400     over empty? [ drop ] [
 401         over first-unsafe over call
 402         [ trim-head ] [ drop ] if
 403     ] if ; inline
 404
 405 : ?trim-tail ( seq quot: ( elt -- ? ) -- seq/newseq )
 406     over empty? [ drop ] [
 407         over last-unsafe over call
 408         [ trim-tail ] [ drop ] if
 409     ] if ; inline
 410
 411 : unsurround ( newseq seq2 seq3 -- seq1 )
 412     [ ?head drop ] [ ?tail drop ] bi* ;
 413
 414 : >string-list ( seq -- seq' )
 415     [ "\"" 1surround ] map "," join ;
 416
 417 : with-string-lines ( str quot -- str' )
 418     [ string-lines ] dip map "\n" join ; inline
 419
 420 : prepend-lines-with-spaces ( str -- str' )
 421     [ "    " prepend ] with-string-lines ;
 422
 423 : one? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 424     [ find ] 2keep rot [
 425         [ 1 + ] 2dip find-from drop not
 426     ] [ 3drop f ] if ; inline
 427
 428 : map-index! ( ... seq quot: ( ... elt index -- ... newelt ) -- ... seq )
 429     over [ [ sequence-index-operator ] dip collect ] keep ; inline
 430
 431 <PRIVATE
 432
 433 : 2sequence-index-iterator ( seq1 seq2 quot -- n quot' )
 434     [ 2length-iterator [ keep ] curry ] dip compose ; inline
 435
 436 PRIVATE>
 437
 438 : 2each-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... ) -- ... )
 439     2sequence-index-iterator each-integer ; inline
 440
 441 : 2map-into ( seq1 seq2 quot into -- )
 442     [ 2length-operator ] dip collect ; inline
 443
 444 : 2map! ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... seq1 )
 445     pick [ 2map-into ] keep ; inline
 446
 447 : 2map-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... newelt ) -- ... newseq )
 448     pick [ 2sequence-index-iterator ] dip map-integers-as ; inline
 449
 450 TUPLE: evens { seq read-only } ;
 451
 452 C: <evens> evens
 453
 454 M: evens length seq>> length 1 + 2/ ; inline
 455
 456 M: evens virtual@ [ 2 * ] [ seq>> ] bi* ; inline
 457
 458 M: evens virtual-exemplar seq>> ; inline
 459
 460 INSTANCE: evens virtual-sequence
 461
 462 TUPLE: odds { seq read-only } ;
 463
 464 C: <odds> odds
 465
 466 M: odds length seq>> length 2/ ; inline
 467
 468 M: odds virtual@ [ 2 * 1 + ] [ seq>> ] bi* ; inline
 469
 470 M: odds virtual-exemplar seq>> ; inline
 471
 472 INSTANCE: odds virtual-sequence
 473
 474 : until-empty ( seq quot -- )
 475     [ dup empty? ] swap until drop ; inline
 476
 477 <PRIVATE
 478
 479 : push-index-if ( ..a elt i quot: ( ..a elt -- ..b ? ) accum -- ..b )
 480     [ dip ] dip rot [ push ] [ 2drop ] if ; inline
 481
 482 PRIVATE>
 483
 484 : arg-where ( ... seq quot: ( ... elt -- ... ? ) -- ... indices )
 485     over length <vector> [
 486         [ push-index-if ] 2curry each-index
 487     ] keep ; inline
 488
 489 : arg-sort ( seq -- indices )
 490     zip-index sort-keys values ;
 491
 492 : first= ( seq elt -- ? ) [ first ] dip = ; inline
 493 : second= ( seq elt -- ? ) [ second ] dip = ; inline
 494 : third= ( seq elt -- ? ) [ third ] dip = ; inline
 495 : fourth= ( seq elt -- ? ) [ fourth ] dip = ; inline
 496 : last= ( seq elt -- ? ) [ last ] dip = ; inline
 497 : nth= ( n seq elt -- ? ) [ nth ] dip = ; inline
 498
 499 : first? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ first ] dip call ; inline
 500 : second? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ second ] dip call ; inline
 501 : third? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ third ] dip call ; inline
 502 : fourth? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ fourth ] dip call ; inline
 503 : last? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ last ] dip call ; inline
 504 : nth? ( ... n seq quot: ( ... elt -- ... ? ) -- ... ? ) [ nth ] dip call ; inline
 505
 506 : loop>sequence** ( ... quot: ( ... -- ... obj ? ) exemplar -- ... seq )
 507     [ ] swap produce-as nip ; inline
 508
 509 : loop>array** ( ... quot: ( ... -- ... obj ? ) -- ... array )
 510     { } loop>sequence** ; inline
 511
 512 : loop>sequence* ( ... quot: ( ... -- ... obj ? ) exemplar -- ... seq )
 513     [ t ] [ '[ [ _ dip ] [ f f f ] if* ] [ swap ] ] [ produce-as 2nip ] tri* ; inline
 514
 515 : loop>array* ( ... quot: ( ... -- ... obj ? ) -- ... array )
 516     { } loop>sequence* ; inline
 517
 518 : loop>sequence ( ... quot: ( ... -- ... obj/f ) exemplar -- ... seq )
 519     [ [ dup ] compose [ ] ] dip produce-as nip ; inline
 520
 521 : loop>array ( ... quot: ( ... -- ... obj/f ) -- ... array )
 522     { } loop>sequence ; inline
 523
 524 : zero-loop>sequence ( ... quot: ( ... n -- ... obj/f ) exemplar -- ... seq )
 525     [ 0 ] [ '[ _ keep 1 + swap ] ] [ loop>sequence ] tri* nip ; inline
 526
 527 : zero-loop>array ( quot: ( ..a n -- ..a obj ) -- seq )
 528     { } zero-loop>sequence ; inline
 529
 530 : iterate-heap-while ( heap quot1: ( value key -- slurp? ) quot2: ( value key -- obj/f ) -- obj/f loop? )
 531     pick heap-empty?
 532     [ 3drop f f ]
 533     [
 534         [ [ heap-peek ] 2dip drop 2keep ]
 535         [
 536             nip ! ( pop? value key heap quot2 )
 537             5roll [
 538                 swap heap-pop* call( value key -- obj/f ) t
 539             ] [
 540                 4drop f f
 541             ] if
 542         ] 3bi
 543     ] if ; inline
 544
 545 : slurp-heap-while-map ( heap quot1: ( value key -- slurp? ) quot2: ( value key -- obj/f ) -- seq )
 546     '[ _ _ _ iterate-heap-while ] loop>array* ; inline
 547
 548 : heap>pairs ( heap -- pairs )
 549     [ 2drop t ] [ swap 2array ] slurp-heap-while-map ;
 550
 551 : map-zip-swap ( quot: ( x -- y ) -- alist )
 552     '[ _ keep ] map>alist ; inline
 553
 554 : ?heap-pop-value>array ( heap -- array )
 555     dup heap-empty? [ drop { } ] [ heap-pop drop 1array ] if ;
 556
 557 <PRIVATE
 558
 559 : (reverse) ( seq -- newseq )
 560     dup [ length ] keep new-sequence
 561     [ 0 swap copy-unsafe ] keep reverse! ;
 562
 563 PRIVATE>
 564
 565 : reverse-as ( seq exemplar -- newseq )
 566     [ (reverse) ] [ like ] bi* ;
 567
 568 : map-product ( ... seq quot: ( ... elt -- ... n ) -- ... n )
 569     [ 1 ] 2dip [ dip * ] with-assoc each ; inline
 570
 571 : insert-nth! ( elt n seq -- )
 572     [ length ] keep ensure swap pick (a..b]
 573     over '[ [ 1 + ] keep _ move-unsafe ] each
 574     set-nth-unsafe ;
 575
 576 : set-nths ( value indices seq -- )
 577     swapd '[ _ swap _ set-nth ] each ; inline
 578
 579 : set-nths-unsafe ( value indices seq -- )
 580     swapd '[ _ swap _ set-nth-unsafe ] each ; inline
 581
 582 <PRIVATE
 583
 584 : (map-find-index) ( seq quot find-quot -- result i elt )
 585     [ [ f ] 2dip [ [ nip ] 2dip call dup ] curry ] dip call
 586     [ [ [ drop f ] unless ] keep ] dip ; inline
 587
 588 PRIVATE>
 589
 590 : map-find-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 591     [ find-index ] (map-find-index) ; inline
 592
 593 : filter-length ( seq n -- seq' ) '[ length _ = ] filter ;
 594
 595 : all-shortest ( seqs -- seqs' ) dup shortest length filter-length ;
 596
 597 : all-longest ( seqs -- seqs' ) dup longest length filter-length ;
 598
 599 : remove-first ( obj seq -- seq' )
 600     [ index ] keep over [ remove-nth ] [ nip ] if ;
 601
 602 : remove-first! ( obj seq -- seq )
 603     [ index ] keep over [ remove-nth! ] [ nip ] if ;
 604
 605 : remove-last ( obj seq -- seq' )
 606     [ last-index ] keep over [ remove-nth ] [ nip ] if ;
 607
 608 : remove-last! ( obj seq -- seq )
 609     [ last-index ] keep over [ remove-nth! ] [ nip ] if ;
 610
 611 : ?first2 ( seq -- first/f second/f )
 612     dup length {
 613         { 0 [ drop f f ] }
 614         { 1 [ first-unsafe f ] }
 615         [ drop first2-unsafe ]
 616     } case ;
 617
 618 : ?first3 ( seq -- first/f second/f third/f )
 619     dup length {
 620         { 0 [ drop f f f ] }
 621         { 1 [ first-unsafe f f ] }
 622         { 2 [ first2-unsafe f ] }
 623         [ drop first3-unsafe ]
 624     } case ;
 625
 626 : ?first4 ( seq -- first/f second/f third/f fourth/f )
 627     dup length {
 628         { 0 [ drop f f f f ] }
 629         { 1 [ first-unsafe f f f ] }
 630         { 2 [ first2-unsafe f f ] }
 631         { 3 [ first3-unsafe f ] }
 632         [ drop first4-unsafe ]
 633     } case ;
 634
 635 : cut-when ( ... seq quot: ( ... elt -- ... ? ) -- ... before after )
 636     [ find drop ] keepd swap
 637     [ cut ] [ f over like ] if* ; inline
 638
 639 : nth* ( n seq -- elt )
 640     [ length 1 - swap - ] [ nth ] bi ; inline
 641
 642 : each-index-from ( ... seq quot: ( ... elt index -- ... ) i -- ... )
 643     -rot sequence-index-operator each-integer-from ; inline
 644
 645 <PRIVATE
 646
 647 : select-by* ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... i elt )
 648     [
 649         [ keep swap ] curry [ dip ] curry
 650         [ [ first 0 ] dip call ] 2keep
 651         [ 2curry 3dip 5 npick pick ] curry
 652     ] [
 653         [ [ 3drop ] [ [ 3drop ] 3dip ] if ] compose
 654     ] bi* compose 1 each-index-from nip swap ; inline
 655
 656 PRIVATE>
 657
 658 : supremum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 659     [ after? ] select-by* ; inline
 660
 661 : infimum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 662     [ before? ] select-by* ; inline
 663
 664 : arg-max ( seq -- n )
 665     [ ] supremum-by* drop ;
 666
 667 : arg-min ( seq -- n )
 668     [ ] infimum-by* drop ;
 669
 670 : ?supremum ( seq/f -- elt/f )
 671     [ f ] [
 672         [ ] [ 2dup and [ max ] [ dupd ? ] if ] map-reduce
 673     ] if-empty ;
 674
 675 : ?infimum ( seq/f -- elt/f )
 676     [ f ] [
 677         [ ] [ 2dup and [ min ] [ dupd ? ] if ] map-reduce
 678     ] if-empty ;
 679
 680 : map-infimum ( seq quot: ( ... elt -- ... elt' ) -- elt' )
 681     [ min ] map-reduce ; inline
 682
 683 : map-supremum ( seq quot: ( ... elt -- ... elt' ) -- elt' )
 684     [ max ] map-reduce ; inline
 685
 686 : change-last ( seq quot -- )
 687     [ index-of-last ] [ change-nth ] bi* ; inline
 688
 689 : change-last-unsafe ( seq quot -- )
 690     [ index-of-last ] [ change-nth-unsafe ] bi* ; inline
 691
 692 : replicate-into ( ... seq quot: ( ... -- ... newelt ) -- ... )
 693     over [ length ] 2dip '[ _ dip _ set-nth-unsafe ] each-integer ; inline
 694
 695 : count* ( ... seq quot: ( ... elt -- ... ? ) -- ... % )
 696     over [ count ] [ length ] bi* / ; inline
 697
 698 : sequence-index-operator-last ( n seq quot -- n quot' )
 699     [ [ nth-unsafe ] curry [ keep ] curry ] dip compose ; inline
 700
 701 : find-last-index-from ( ... n seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 702     '[
 703         _ [ sequence-index-operator-last find-last-integer ] keepd
 704         index/element
 705     ] bounds-check-call ; inline
 706
 707 : find-last-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 708     [ index-of-last ] dip find-last-index-from ; inline
 709
 710 : map-find-last-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 711     [ find-last-index ] (map-find-index) ; inline
 712
 713 :: (start-all) ( seq subseq increment -- indices )
 714     0
 715     [ seq subseq subseq-index-from dup ]
 716     [ [ increment + ] keep ] produce nip ;
 717
 718 : start-all ( seq subseq -- indices )
 719     dup length (start-all) ; inline
 720
 721 : start-all* ( seq subseq -- indices )
 722     1 (start-all) ; inline
 723
 724 : count-subseq ( seq subseq -- n )
 725     start-all length ; inline
 726
 727 : count-subseq* ( seq subseq -- n )
 728     start-all* length ; inline
 729
 730 : assoc-zip-with ( quot: ( key value -- calc ) -- alist )
 731     '[ _ 2keep 2array swap ] assoc-map ; inline
 732
 733 : take-while ( ... seq quot: ( ... elt -- ... ? ) -- head-slice )
 734     [ '[ @ not ] find drop ] keepd swap
 735     [ dup length ] unless* head-slice ; inline
 736
 737 : drop-while ( ... seq quot: ( ... elt -- ... ? ) -- tail-slice )
 738     [ '[ @ not ] find drop ] keepd swap
 739     [ dup length ] unless* tail-slice ; inline
 740
 741 : count-head ( seq quot -- n )
 742     [ not ] compose [ find drop ] keepd length or ; inline
 743
 744 : count-tail ( seq quot -- n )
 745     [ not ] compose [ find-last drop ] keepd
 746     length swap [ - 1 - ] when* ; inline
 747
 748 :: shorten* ( vector n -- seq )
 749     vector n tail
 750     n vector shorten ;
 751
 752 :: interleaved-as ( seq glue exemplar -- newseq )
 753     seq length dup 1 - + 0 max exemplar new-sequence :> newseq
 754     seq [ 2 * newseq set-nth-unsafe ] each-index
 755     seq length 1 - [ 2 * 1 + glue swap newseq set-nth-unsafe ] each-integer
 756     newseq ;
 757
 758 : interleaved ( seq glue -- newseq )
 759     over interleaved-as ;
 760
 761 : extract! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 762     [ dup ] compose over [ length ] keep new-resizable
 763     [ [ push-when ] 2curry reject! ] keep swap like ; inline
 764
 765 : find-pred-loop ( ... i n seq quot: ( ... elt -- ... calc ? ) -- ... calc/f i/f elt/f )
 766     2pick < [
 767         [ nipd call ] 4keep
 768         3 7 0 nrotated
 769         [ [ 3drop ] 2dip rot ]
 770         [ 2drop [ 1 + ] 3dip find-pred-loop ] if
 771     ] [
 772         4drop f f f
 773     ] if ; inline recursive
 774
 775 : find-pred ( ... seq quot: ( ... elt -- ... calc ) pred: ( ... calc -- ... ? ) -- ... calc/f i/f elt/f )
 776     [ 0 ] 3dip
 777     [ [ length check-length ] keep ] 2dip
 778     '[ nth-unsafe _ keep swap _ keep swap ] find-pred-loop swapd ; inline
 779
 780 ! https://en.wikipedia.org/wiki/Maximum_subarray_problem
 781 ! Kadane's algorithm O(n) largest sum in subarray
 782 : max-subarray-sum ( seq -- sum )
 783     [ -1/0. 0 ] dip
 784     [ [ + ] keep max [ max ] keep ] each drop ;
 785
 786 TUPLE: step-slice
 787     { from integer read-only initial: 0 }
 788     { to integer read-only initial: 0 }
 789     { seq read-only }
 790     { step integer read-only } ;
 791
 792 :: <step-slice> ( from/f to/f step seq -- step-slice )
 793     step zero? [ "can't be zero" throw ] when
 794     seq length :> len
 795     step 0 > [
 796         from/f [ 0 ] unless*
 797         to/f [ len ] unless*
 798     ] [
 799         from/f [ len ] unless*
 800         to/f [ 0 ] unless*
 801     ] if
 802     [ dup 0 < [ len + ] when 0 len clamp ] bi@
 803     ! FIXME: make this work with steps
 804     seq dup slice? [ collapse-slice ] when
 805     step step-slice boa ;
 806
 807 M: step-slice virtual-exemplar seq>> ; inline
 808
 809 M: step-slice virtual@
 810     [ step>> * ] [ from>> + ] [ seq>> ] tri ; inline
 811
 812 M: step-slice length
 813     [ to>> ] [ from>> - ] [ step>> ] tri
 814     dup 0 < [ [ neg 0 max ] dip neg ] when /mod
 815     zero? [ 1 + ] unless ; inline
 816
 817 INSTANCE: step-slice virtual-sequence
 818
 819 : 2nested-each* ( seq1 seq-quot: ( n -- seq ) quot: ( a b -- ) -- )
 820     '[
 821         _ keep swap _ with each
 822     ] each ; inline
 823
 824 : 2nested-filter-as* ( seq1 seq-quot quot exemplar -- seq )
 825     [ 2over [ length ] bi@ * ] dip
 826     [
 827         new-resizable
 828         [ [ push? ] curry compose 2nested-each* ] keep
 829     ] keep like ; inline
 830
 831 : 2nested-filter* ( seq1 seq-quot quot -- seq )
 832     pick 2nested-filter-as* ; inline
 833
 834 : 2nested-map-as* ( seq1 seq-quot quot exemplar -- seq )
 835     [ 2over [ length ] bi@ * ] dip
 836     [
 837         new-resizable
 838         [ [ push ] curry compose 2nested-each* ] keep
 839     ] keep like ; inline
 840
 841 : 2nested-map* ( seq1 seq-quot quot -- seq )
 842     pick 2nested-map-as* ; inline
 843
 844
 845 : 2nested-each ( seq1 seq2 quot -- )
 846     swapd '[
 847         swap _ with each
 848     ] with each ; inline
 849
 850 : 2nested-filter-as ( seq1 seq2 quot exemplar -- seq )
 851     [ 2over [ length ] bi@ * ] dip
 852     [
 853         new-resizable
 854         [ [ push? ] curry compose 2nested-each ] keep
 855     ] keep like ; inline
 856
 857 : 2nested-filter ( seq1 seq2 quot -- seq )
 858     pick 2nested-filter-as ; inline
 859
 860 : 2nested-map-as ( seq1 seq2 quot exemplar -- seq )
 861     [ 2over [ length ] bi@ * ] dip
 862     [
 863         new-resizable
 864         [ [ push ] curry compose 2nested-each ] keep
 865     ] keep like ; inline
 866
 867 : 2nested-map ( seq1 seq2 quot -- seq )
 868     pick 2nested-map-as ; inline
 869
 870 : 3nested-each ( seq1 seq2 seq3 quot -- )
 871     [ spin ] dip '[
 872         -rot [
 873             swap _ with with each
 874         ] with with each
 875     ] with with each ; inline
 876
 877 : 3nested-filter-as ( seq1 seq2 seq3 quot exemplar -- seq )
 878     [ 3 nover [ length ] tri@ * * ] dip
 879     [
 880         new-resizable
 881         [ [ push? ] curry compose 3nested-each ] keep
 882     ] keep like ; inline
 883
 884 : 3nested-filter ( seq1 seq2 seq3 quot -- seq )
 885     reach 3nested-filter-as ; inline
 886
 887 : 3nested-map-as ( seq1 seq2 seq3 quot exemplar -- seq )
 888     [ 3 nover [ length ] tri@ * * ] dip
 889     [
 890         new-resizable
 891         [ [ push ] curry compose 3nested-each ] keep
 892     ] keep like ; inline
 893
 894 : 3nested-map ( seq1 seq2 seq3 quot -- seq )
 895     reach 3nested-map-as ; inline
 896
 897 : prev ( n seq -- obj ) [ 1 - ] dip nth ; inline
 898 : ?prev ( n seq -- obj/f ) [ 1 - ] dip ?nth ; inline
 899 : ??prev ( n seq -- obj/f ? ) [ 1 - ] dip ??nth ; inline
 900 : prev-of ( seq n -- obj ) 1 - nth-of ; inline
 901 : ?prev-of ( seq n -- obj/f ) 1 - ?nth-of ; inline
 902 : ??prev-of ( seq n -- obj/f ? ) 1 - ??nth-of ; inline
 903
 904 : prev-identity ( i seq -- identity i seq )
 905     2dup ??prev [ drop 0 ] unless -rot ; inline
 906
 907 : each-prior-identity-from ( ... identity i seq quot: ( ... prior elt -- ... ) -- ... )
 908     '[ [ swap @ ] keep ]
 909     length-operator each-integer-from drop ; inline
 910
 911 : each-prior-from ( ... i seq quot: ( ... prior elt -- ... ) -- ... )
 912     [ prev-identity ] dip each-prior-identity-from ; inline
 913
 914 : each-prior ( ... seq quot: ( ... prior elt -- ... ) -- ... )
 915     0 -rot each-prior-from ; inline
 916
 917 : map-prior-identity-from-as ( ... identity i seq quot: ( ... prior elt -- elt' ) exemplar -- seq' )
 918     [
 919         '[ [ swap @ ] keep swap ] length-operator
 920     ] dip map-integers-from-as nip ; inline
 921
 922 : map-prior-identity-as ( ... identity seq quot: ( ... prior elt -- elt' ) exemplar -- seq' )
 923     [ 0 ] 3dip map-prior-identity-from-as ; inline
 924
 925 : map-prior-from-as ( ... i seq quot: ( ... prior elt -- elt' ) exemplar -- seq' )
 926     [ prev-identity ] 2dip map-prior-identity-from-as ; inline
 927
 928 : map-prior-as ( ... seq quot: ( ... prior elt -- elt' ) exemplar -- seq' )
 929     0 -roll map-prior-from-as ; inline
 930
 931 : map-prior-from ( ... i seq quot: ( ... prior elt -- elt' ) -- seq' )
 932     over map-prior-from-as ; inline
 933
 934 : map-prior ( ... seq quot: ( ... prior elt -- elt' ) -- seq' )
 935     over map-prior-as ; inline
 936
 937 TUPLE: virtual-zip-index seq ;
 938
 939 C: <zip-index> virtual-zip-index
 940
 941 M: virtual-zip-index length seq>> length ; inline
 942
 943 M: virtual-zip-index nth-unsafe
 944     over [ seq>> nth-unsafe ] [ 2array ] bi* ; inline
 945
 946 INSTANCE: virtual-zip-index immutable-sequence