extra/sequences/extras/extras.factor

   1 USING: accessors arrays assocs combinators fry generalizations
   2 grouping growable kernel locals make math math.order math.ranges
   3 sequences sequences.deep sequences.private sorting splitting
   4 vectors ;
   5 FROM: sequences => change-nth ;
   6 IN: sequences.extras
   7
   8 : reduce1 ( seq quot -- result ) [ unclip ] dip reduce ; inline
   9
  10 :: reduce-r ( seq identity quot: ( obj1 obj2 -- obj ) -- result )
  11     seq [ identity ] [
  12         unclip [ identity quot reduce-r ] [ quot call ] bi*
  13     ] if-empty ; inline recursive
  14
  15 ! Quot must have static stack effect, unlike "reduce"
  16 :: reduce* ( seq identity quot: ( prev elt -- next ) -- result )
  17     seq [ identity ] [
  18         unclip identity swap quot call( prev elt -- next )
  19         quot reduce*
  20     ] if-empty ; inline recursive
  21
  22 :: combos ( list1 list2 -- result )
  23     list2 [ [ 2array ] curry list1 swap map ] map concat ;
  24
  25 : find-all ( seq quot: ( elt -- ? ) -- elts )
  26     [ [ length iota ] keep ] dip
  27     [ dupd call( a -- ? ) [ 2array ] [ 2drop f ] if ] curry
  28     2map sift ; inline
  29
  30 : reduce-from ( ... seq identity quot: ( ... prev elt -- ... next ) i -- ... result )
  31     [ swap ] 2dip each-from ; inline
  32
  33 :: subseq* ( from to seq -- subseq )
  34     seq length :> len
  35     from [ dup 0 < [ len + ] when ] [ 0 ] if*
  36     to [ dup 0 < [ len + ] when ] [ len ] if*
  37     [ 0 len clamp ] bi@ dupd max seq subseq ;
  38
  39 : safe-subseq ( from to seq -- subseq )
  40     [ length '[ 0 _ clamp ] bi@ ] keep subseq ;
  41
  42 : all-subseqs ( seq -- seqs )
  43     dup length [1,b] [ clump ] with map concat ;
  44
  45 :: each-subseq ( ... seq quot: ( ... x -- ... ) -- ... )
  46     seq length :> len
  47     len [0,b] [
  48         :> from
  49         from len (a,b] [
  50             :> to
  51             from to seq subseq quot call
  52         ] each
  53     ] each ; inline
  54
  55 : subseq-as ( from to seq exemplar -- subseq )
  56     [ check-slice subseq>copy (copy) ] dip like ;
  57
  58 : map-like ( seq exemplar -- seq' )
  59     '[ _ like ] map ; inline
  60
  61 : filter-all-subseqs-range ( ... seq range quot: ( ... x -- ... ) -- seq )
  62     [
  63         '[ <clumps> _ filter ] with map concat
  64     ] 3keep 2drop map-like ; inline
  65
  66 : filter-all-subseqs ( ... seq quot: ( ... x -- ... ) -- seq )
  67     [ dup length [1,b] ] dip filter-all-subseqs-range ; inline
  68
  69 :: longest-subseq ( seq1 seq2 -- subseq )
  70     seq1 length :> len1
  71     seq2 length :> len2
  72     0 :> n!
  73     0 :> end!
  74     len1 1 + [ len2 1 + 0 <array> ] replicate :> table
  75     len1 [1,b] [| x |
  76         len2 [1,b] [| y |
  77             x 1 - seq1 nth-unsafe
  78             y 1 - seq2 nth-unsafe = [
  79                 y 1 - x 1 - table nth-unsafe nth-unsafe 1 + :> len
  80                 len y x table nth-unsafe set-nth-unsafe
  81                 len n > [ len n! x end! ] when
  82             ] [ 0 y x table nth-unsafe set-nth-unsafe ] if
  83         ] each
  84     ] each end n - end seq1 subseq ;
  85
  86 : pad-longest ( seq1 seq2 elt -- seq1 seq2 )
  87     [ 2dup max-length ] dip [ pad-tail ] 2curry bi@ ;
  88
  89 : change-nths ( ... indices seq quot: ( ... elt -- ... elt' ) -- ... )
  90     [ change-nth ] 2curry each ; inline
  91
  92 : push-if-index ( ..a elt i quot: ( ..a elt i -- ..b ? ) accum -- ..b )
  93     [ 2keep drop ] dip rot [ push ] [ 2drop ] if ; inline
  94
  95 <PRIVATE
  96
  97 : (index-selector-for) ( quot length exampler -- selector accum )
  98     new-resizable [ [ push-if-index ] 2curry ] keep ; inline
  99
 100 PRIVATE>
 101
 102 : index-selector-for ( quot exemplar -- selector accum )
 103     [ length ] keep (index-selector-for) ; inline
 104
 105 : index-selector ( quot -- selector accum )
 106     V{ } index-selector-for ; inline
 107
 108 : filter-index-as ( ... seq quot: ( ... elt i -- ... ? ) exemplar -- ... seq' )
 109     pick length over [ (index-selector-for) [ each-index ] dip ] 2curry dip like ; inline
 110
 111 : filter-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... seq' )
 112     over filter-index-as ; inline
 113
 114 : even-indices ( seq -- seq' )
 115     [ length 1 + 2/ ] keep [
 116         [ [ 2 * ] dip nth-unsafe ] curry
 117     ] keep map-integers ;
 118
 119 : odd-indices ( seq -- seq' )
 120     [ length 2/ ] keep [
 121         [ [ 2 * 1 + ] dip nth-unsafe ] curry
 122     ] keep map-integers ;
 123
 124 : compact ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 125     [ split-when harvest ] dip join ; inline
 126
 127 : collapse ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 128     [ split-when ] dip
 129     [ [ harvest ] dip join ]
 130     [ [ first empty? ] dip [ prepend ] curry when ]
 131     [ [ last empty? ] dip [ append ] curry when ]
 132     2tri ; inline
 133
 134 :: slice-when ( seq quot: ( elt -- ? ) -- seq' )
 135     seq length :> len
 136     0 [ len dupd < ] [
 137         dup seq quot find-from drop
 138         [ 2dup = [ 1 + ] when ] [ len ] if*
 139         [ seq <slice> ] keep len or swap
 140     ] produce nip ; inline
 141
 142 : cut-slice* ( seq n -- before after )
 143     [ head-slice* ] [ tail-slice* ] 2bi ;
 144
 145 : rotate ( seq n -- seq' )
 146     cut prepend ;
 147
 148 :: rotate! ( seq n -- )
 149     n seq bounds-check length :> end
 150     0 n [ 2dup = ] [
 151         [ seq exchange-unsafe ] [ [ 1 + ] bi@ ] 2bi
 152         dup end = [ drop over ] when
 153         2over = [ -rot nip over ] when
 154     ] until 3drop ;
 155
 156 : all-rotations ( seq -- seq' )
 157     dup length iota [ rotate ] with map ;
 158
 159 <PRIVATE
 160
 161 : (appender-for) ( quot length exemplar -- appender accum )
 162     new-resizable [ [ push-all ] curry compose ] keep ; inline
 163
 164 PRIVATE>
 165
 166 : appender-for ( quot exemplar -- appender accum )
 167     [ length ] keep (appender-for) ; inline
 168
 169 : appender ( quot -- appender accum )
 170     V{ } appender-for ; inline
 171
 172 : map-concat-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 173     [ appender-for [ each ] dip ] keep like ; inline
 174
 175 : >resizable ( seq -- accum ) ! fixes map-concat "cannot apply call to run-time..."
 176     [ length ] keep [ new-resizable ] [ append! ] bi ;
 177
 178 : map-concat ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 179     over empty? [ 2drop { } ] [
 180         [ [ first ] dip call ] 2keep rot dup [
 181             >resizable [ [ push-all ] curry compose ] keep
 182             [ 1 ] 3dip [ (each) (each-integer) ] dip
 183         ] curry dip like
 184     ] if ; inline
 185
 186 : map-filter-as ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) exemplar -- ... subseq )
 187     [ pick ] dip swap length over
 188     [ (selector-for) [ compose each ] dip ] 2curry dip like ; inline
 189
 190 : map-filter ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) -- ... subseq )
 191     pick map-filter-as ; inline
 192
 193 : map-sift ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 194     [ ] map-filter ; inline
 195
 196 : map-harvest ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 197     [ empty? not ] map-filter ; inline
 198
 199 <PRIVATE
 200
 201 : ((each-from)) ( i seq -- n quot )
 202     [ length over [-] swap ] keep '[ _ + _ nth-unsafe ] ; inline
 203
 204 : (each-from) ( i seq quot -- n quot' ) [ ((each-from)) ] dip compose ;
 205     inline
 206
 207 PRIVATE>
 208
 209 : map-from-as ( ... seq quot: ( ... elt -- ... newelt ) i exemplar -- ... newseq )
 210     [ -rot (each-from) ] dip map-integers ; inline
 211
 212 : map-from ( ... seq quot: ( ... elt -- ... newelt ) i -- ... newseq )
 213     pick map-from-as ; inline
 214
 215 <PRIVATE
 216
 217 : push-map-if ( ..a elt filter-quot: ( ..a elt -- ..b ? ) map-quot: ( ..a elt -- ..b newelt ) accum -- ..b )
 218     [ keep over ] 2dip [ when ] dip rot [ push ] [ 2drop ] if ; inline
 219
 220 : (filter-mapper-for) ( filter-quot map-quot length exempler -- filter-mapper accum )
 221     new-resizable [ [ push-map-if ] 3curry ] keep ; inline
 222
 223 : filter-mapper-for ( filter-quot map-quot exemplar -- filter-mapper accum )
 224     [ length ] keep (filter-mapper-for) ; inline
 225
 226 : filter-mapper ( filter-quot map-quot -- filter-mapper accum )
 227     V{ } filter-mapper-for ; inline
 228
 229 PRIVATE>
 230
 231 : filter-map-as ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 232     [ pick ] dip swap length over
 233     [ (filter-mapper-for) [ each ] dip ] 2curry dip like ; inline
 234
 235 : filter-map ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) -- ... newseq )
 236     pick filter-map-as ; inline
 237
 238 : 2map-sum ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... n ) -- ... n )
 239     [ 0 ] 3dip [ dip + ] curry [ rot ] prepose 2each ; inline
 240
 241 : 2count ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... n )
 242     [ 1 0 ? ] compose 2map-sum ; inline
 243
 244 : round-robin ( seq -- newseq )
 245     [ { } ] [
 246         [ longest length iota ] keep
 247         [ [ ?nth ] with map ] curry map concat sift
 248     ] if-empty ;
 249
 250 : sift-as ( seq exemplar -- newseq )
 251     [ ] swap filter-as ;
 252
 253 : sift! ( seq -- newseq )
 254     [ ] filter! ;
 255
 256 : harvest-as ( seq exemplar -- newseq )
 257     [ empty? not ] swap filter-as ;
 258
 259 : harvest! ( seq -- newseq )
 260     [ empty? ] reject! ;
 261
 262 : head-as ( seq n exemplar -- seq' )
 263     [ head-slice ] [ like ] bi* ; inline
 264
 265 : head*-as ( seq n exemplar -- seq' )
 266     [ head-slice* ] [ like ] bi* ; inline
 267
 268 : tail-as ( seq n exemplar -- seq' )
 269     [ tail-slice ] [ like ] bi* ; inline
 270
 271 : tail*-as ( seq n exemplar -- seq' )
 272     [ tail-slice* ] [ like ] bi* ; inline
 273
 274 : trim-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... newseq )
 275     [ trim-slice ] [ like ] bi* ; inline
 276
 277 : ?trim ( seq quot: ( elt -- ? ) -- seq/newseq )
 278     over empty? [ drop ] [
 279         over [ first-unsafe ] [ last-unsafe ] bi pick either?
 280         [ trim ] [ drop ] if
 281     ] if ; inline
 282
 283 : ?trim-head ( seq quot: ( elt -- ? ) -- seq/newseq )
 284     over empty? [ drop ] [
 285         over first-unsafe over call
 286         [ trim-head ] [ drop ] if
 287     ] if ; inline
 288
 289 : ?trim-tail ( seq quot: ( elt -- ? ) -- seq/newseq )
 290     over empty? [ drop ] [
 291         over last-unsafe over call
 292         [ trim-tail ] [ drop ] if
 293     ] if ; inline
 294
 295 : unsurround ( newseq seq2 seq3 -- seq1 )
 296    [ ?head drop ] [ ?tail drop ] bi* ;
 297
 298 : none? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 299     any? not ; inline
 300
 301 : one? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 302     [ find ] 2keep rot [
 303         [ 1 + ] 2dip find-from drop not
 304     ] [ 3drop f ] if ; inline
 305
 306 : map-index! ( ... seq quot: ( ... elt index -- ... newelt ) -- ... seq )
 307     over [ [ (each-index) ] dip collect ] keep ; inline
 308
 309 <PRIVATE
 310
 311 : (2each-index) ( seq1 seq2 quot -- n quot' )
 312     [ ((2each)) [ keep ] curry ] dip compose ; inline
 313
 314 PRIVATE>
 315
 316 : 2each-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... ) -- ... )
 317     (2each-index) each-integer ; inline
 318
 319 : 2map-into ( seq1 seq2 quot into -- )
 320     [ (2each) ] dip collect ; inline
 321
 322 : 2map! ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... seq1 )
 323     pick [ 2map-into ] keep ; inline
 324
 325 : 2map-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... newelt ) -- ... newseq )
 326     pick [ (2each-index) ] dip map-integers ; inline
 327
 328 TUPLE: evens seq length ;
 329
 330 : <evens> ( seq -- evens )
 331     dup length 1 + 2/ evens boa ; inline
 332
 333 M: evens length length>> ; inline
 334
 335 M: evens nth-unsafe [ 2 * ] [ seq>> nth-unsafe ] bi* ; inline
 336
 337 INSTANCE: evens immutable-sequence
 338
 339 TUPLE: odds seq length ;
 340
 341 : <odds> ( seq -- odds )
 342     dup length 2/ odds boa ; inline
 343
 344 M: odds length length>> ; inline
 345
 346 M: odds nth-unsafe [ 2 * 1 + ] [ seq>> nth-unsafe ] bi* ; inline
 347
 348 INSTANCE: odds immutable-sequence
 349
 350 : until-empty ( seq quot -- )
 351     [ dup empty? ] swap until drop ; inline
 352
 353 : arg-max ( seq -- n )
 354     <enum> [ second-unsafe ] supremum-by first ;
 355
 356 : arg-min ( seq -- n )
 357     <enum> [ second-unsafe ] infimum-by first ;
 358
 359 <PRIVATE
 360
 361 : push-index-if ( ..a elt i quot: ( ..a elt -- ..b ? ) accum -- ..b )
 362     [ dip ] dip rot [ push ] [ 2drop ] if ; inline
 363
 364 PRIVATE>
 365
 366 : arg-where ( ... seq quot: ( ... elt -- ... ? ) -- ... indices )
 367     over length <vector> [
 368         [ push-index-if ] 2curry each-index
 369     ] keep ; inline
 370
 371 : arg-sort ( seq -- indices )
 372     zip-index sort-keys values ;
 373
 374 : first= ( seq elt -- ? ) [ first ] dip = ; inline
 375 : second= ( seq elt -- ? ) [ second ] dip = ; inline
 376 : third= ( seq elt -- ? ) [ third ] dip = ; inline
 377 : fourth= ( seq elt -- ? ) [ fourth ] dip = ; inline
 378 : last= ( seq elt -- ? ) [ last ] dip = ; inline
 379 : nth= ( n seq elt -- ? ) [ nth ] dip = ; inline
 380
 381 : first? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ first ] dip call ; inline
 382 : second? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ second ] dip call ; inline
 383 : third? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ third ] dip call ; inline
 384 : fourth? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ fourth ] dip call ; inline
 385 : last? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ last ] dip call ; inline
 386 : nth? ( ... n seq quot: ( ... elt -- ... ? ) -- ... ? ) [ nth ] dip call ; inline
 387
 388 : loop>sequence ( quot exemplar -- seq )
 389    [ '[ [ @ [ [ , ] when* ] keep ] loop ] ] dip make ; inline
 390
 391 : loop>array ( quot -- seq )
 392    { } loop>sequence ; inline
 393
 394 <PRIVATE
 395
 396 : (reverse) ( seq -- newseq )
 397     dup [ length ] keep new-sequence
 398     [ 0 swap copy-unsafe ] keep reverse! ;
 399
 400 PRIVATE>
 401
 402 : reverse-as ( seq exemplar -- newseq )
 403     [ (reverse) ] [ like ] bi* ;
 404
 405 : map-product ( ... seq quot: ( ... elt -- ... n ) -- ... n )
 406     [ 1 ] 2dip [ dip * ] curry [ swap ] prepose each ; inline
 407
 408 : insert-nth! ( elt n seq -- )
 409     [ length ] keep ensure swap pick (a,b]
 410     over '[ [ 1 + ] keep _ move-unsafe ] each
 411     set-nth-unsafe ;
 412
 413 : set-nths ( value indices seq -- )
 414     swapd '[ _ swap _ set-nth ] each ; inline
 415
 416 : set-nths-unsafe ( value indices seq -- )
 417     swapd '[ _ swap _ set-nth-unsafe ] each ; inline
 418
 419 : flatten1 ( obj -- seq )
 420     [
 421         [
 422             dup branch? [
 423                 [ dup branch? [ % ] [ , ] if ] each
 424             ] [ , ] if
 425         ]
 426     ] keep dup branch? [ drop f ] unless make ;
 427
 428 <PRIVATE
 429
 430 : (map-find-index) ( seq quot find-quot -- result i elt )
 431     [ [ f ] 2dip [ [ nip ] 2dip call dup ] curry ] dip call
 432     [ [ [ drop f ] unless ] keep ] dip ; inline
 433
 434 PRIVATE>
 435
 436 : map-find-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 437     [ find-index ] (map-find-index) ; inline
 438
 439 : filter-length ( seq n -- seq' ) '[ length _ = ] filter ;
 440
 441 : all-shortest ( seqs -- seqs' ) dup shortest length filter-length ;
 442
 443 : all-longest ( seqs -- seqs' ) dup longest length filter-length ;
 444
 445 : remove-first ( obj seq -- seq' )
 446     [ index ] keep over [ remove-nth ] [ nip ] if ;
 447
 448 : remove-first! ( obj seq -- seq )
 449     [ index ] keep over [ remove-nth! ] [ nip ] if ;
 450
 451 : remove-last ( obj seq -- seq' )
 452     [ last-index ] keep over [ remove-nth ] [ nip ] if ;
 453
 454 : remove-last! ( obj seq -- seq )
 455     [ last-index ] keep over [ remove-nth! ] [ nip ] if ;
 456
 457 : ?first2 ( seq -- first/f second/f )
 458     dup length {
 459         { 0 [ drop f f ] }
 460         { 1 [ first-unsafe f ] }
 461         [ drop first2-unsafe ]
 462     } case ;
 463
 464 : ?first3 ( seq -- first/f second/f third/f )
 465     dup length {
 466         { 0 [ drop f f f ] }
 467         { 1 [ first-unsafe f f ] }
 468         { 2 [ first2-unsafe f ] }
 469         [ drop first3-unsafe ]
 470     } case ;
 471
 472 : ?first4 ( seq -- first/f second/f third/f fourth/f )
 473     dup length {
 474         { 0 [ drop f f f f ] }
 475         { 1 [ first-unsafe f f f ] }
 476         { 2 [ first2-unsafe f f ] }
 477         { 3 [ first3-unsafe f ] }
 478         [ drop first4-unsafe ]
 479     } case ;
 480
 481 : cut-when ( ... seq quot: ( ... elt -- ... ? ) -- ... before after )
 482     [ find drop ] 2keep drop swap
 483     [ cut ] [ f over like ] if* ; inline
 484
 485 : nth* ( n seq -- elt )
 486     [ length 1 - swap - ] [ nth ] bi ; inline
 487
 488 : each-index-from ( ... seq quot: ( ... elt index -- ... ) i -- ... )
 489     -rot (each-index) (each-integer) ; inline
 490
 491 <PRIVATE
 492
 493 : select-by* ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... i elt )
 494     [
 495         [ keep swap ] curry [ dip ] curry
 496         [ [ first 0 ] dip call ] 2keep
 497         [ 2curry 3dip 5 npick pick ] curry
 498     ] [
 499         [ [ 3drop ] [ [ 3drop ] 3dip ] if ] compose
 500     ] bi* compose 1 each-index-from nip swap ; inline
 501
 502 PRIVATE>
 503
 504 : supremum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 505     [ after? ] select-by* ; inline
 506
 507 : infimum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 508     [ before? ] select-by* ; inline
 509
 510 : change-last ( seq quot -- )
 511     [ drop length 1 - ] [ change-nth ] 2bi ; inline
 512
 513 : change-last-unsafe ( seq quot -- )
 514     [ drop length 1 - ] [ change-nth-unsafe ] 2bi ; inline
 515
 516 : replicate-into ( ... seq quot: ( ... -- ... newelt ) -- ... )
 517     over [ length ] 2dip '[ _ dip _ set-nth-unsafe ] each-integer ; inline
 518
 519 : count* ( ... seq quot: ( ... elt -- ... ? ) -- ... % )
 520     over [ count ] [ length ] bi* / ; inline
 521
 522 : find-last-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 523     [ [ 1 - ] dip find-last-integer ] (find-index) ; inline
 524
 525 : map-find-last-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 526     [ find-last-index ] (map-find-index) ; inline
 527
 528 :: (start-all) ( subseq seq increment -- indices )
 529     0
 530     [ [ subseq seq ] dip start* dup ]
 531     [ [ increment + ] keep ] produce nip ;
 532
 533 : start-all ( subseq seq -- indices )
 534     over length (start-all) ; inline
 535
 536 : start-all* ( subseq seq -- indices )
 537     1 (start-all) ; inline
 538
 539 : count-subseq ( subseq seq -- n )
 540     start-all length ; inline
 541
 542 : count-subseq* ( subseq seq -- n )
 543     start-all* length ; inline