extra/sequences/extras/extras.factor

   1 USING: accessors arrays assocs combinators generalizations
   2 grouping growable heaps kernel math math.order ranges sequences
   3 sequences.private shuffle sorting splitting vectors ;
   4 IN: sequences.extras
   5
   6 : find-all ( ... seq quot: ( ... elt -- ... ? ) -- ... elts )
   7     [ <enumerated> ] dip '[ nip @ ] assoc-filter ; inline
   8
   9 :: subseq* ( from to seq -- subseq )
  10     seq length :> len
  11     from [ dup 0 < [ len + ] when ] [ 0 ] if*
  12     to [ dup 0 < [ len + ] when ] [ len ] if*
  13     [ 0 len clamp ] bi@ dupd max seq subseq ;
  14
  15 : safe-subseq ( from to seq -- subseq )
  16     [ length '[ 0 _ clamp ] bi@ ] keep subseq ;
  17
  18 : all-subseqs ( seq -- seqs )
  19     dup length [1..b] [ clump ] with map concat ;
  20
  21 : each-subseq ( ... seq quot: ( ... subseq -- ... ) -- ... )
  22     [ dup length [ [0..b] ] [ ] bi ] dip '[
  23         dup _ (a..b] [ rot [ subseq _ call ] keep ] with each
  24     ] each drop ; inline
  25
  26 : map-like ( seq exemplar -- seq' )
  27     '[ _ like ] map ; inline
  28
  29 : filter-all-subseqs-range ( ... seq range quot: ( ... subseq -- ... ? ) -- seq )
  30     [
  31         '[ <clumps> _ filter ] with map concat
  32     ] keepdd map-like ; inline
  33
  34 : filter-all-subseqs ( ... seq quot: ( ... subseq -- ... ? ) -- seq )
  35     [ dup length [1..b] ] dip filter-all-subseqs-range ; inline
  36
  37 :: longest-subseq ( seq1 seq2 -- subseq )
  38     seq1 length :> len1
  39     seq2 length :> len2
  40     0 :> n!
  41     0 :> end!
  42     len1 1 + [ len2 1 + 0 <array> ] replicate :> table
  43     len1 [1..b] [| x |
  44         len2 [1..b] [| y |
  45             x 1 - seq1 nth-unsafe
  46             y 1 - seq2 nth-unsafe = [
  47                 y 1 - x 1 - table nth-unsafe nth-unsafe 1 + :> len
  48                 len y x table nth-unsafe set-nth-unsafe
  49                 len n > [ len n! x end! ] when
  50             ] [ 0 y x table nth-unsafe set-nth-unsafe ] if
  51         ] each
  52     ] each end n - end seq1 subseq ;
  53
  54 : pad-longest ( seq1 seq2 elt -- seq1 seq2 )
  55     [ 2dup max-length ] dip [ pad-tail ] 2curry bi@ ;
  56
  57 : pad-center ( seq n elt -- padded )
  58     swap pick length [-] [ drop ] [
  59         [ 2/ ] [ over - ] bi rot '[ _ <repetition> ] bi@
  60         pick surround-as
  61     ] if-zero ;
  62
  63 : change-nths ( ... indices seq quot: ( ... elt -- ... elt' ) -- ... )
  64     [ change-nth ] 2curry each ; inline
  65
  66 : push-if-index ( ..a elt i quot: ( ..a elt i -- ..b ? ) accum -- ..b )
  67     [ keepd ] dip rot [ push ] [ 2drop ] if ; inline
  68
  69 : push-if* ( ..a elt quot: ( ..a elt -- ..b obj/f ) accum -- ..b )
  70     [ call ] dip [ push ] [ drop ] if* ; inline
  71
  72 : push? ( elt/f accum -- )
  73     over [ push ] [ 2drop ] if ; inline
  74
  75 <PRIVATE
  76
  77 : (index-selector-as) ( quot length exampler -- selector accum )
  78     new-resizable [ [ push-if-index ] 2curry ] keep ; inline
  79
  80 : (selector-as*) ( quot length exemplar -- selector accum )
  81     new-resizable [ [ push-if* ] 2curry ] keep ; inline
  82
  83 PRIVATE>
  84
  85 : index-selector-as ( quot exemplar -- selector accum )
  86     [ length ] keep (index-selector-as) ; inline
  87
  88 : index-selector ( quot -- selector accum )
  89     V{ } index-selector-as ; inline
  90
  91 : selector-as* ( quot exemplar -- selector accum )
  92     [ length ] keep (selector-as*) ; inline
  93
  94 : selector* ( quot -- selector accum ) V{ } selector-as* ; inline
  95
  96 : filter-index-as ( ... seq quot: ( ... elt i -- ... ? ) exemplar -- ... seq' )
  97     pick length over [ (index-selector-as) [ each-index ] dip ] 2curry dip like ; inline
  98
  99 : filter-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... seq' )
 100     over filter-index-as ; inline
 101
 102 : even-indices ( seq -- seq' )
 103     [ length 1 + 2/ ] keep [
 104         [ [ 2 * ] dip nth-unsafe ] curry
 105     ] keep map-integers-as ;
 106
 107 : odd-indices ( seq -- seq' )
 108     [ length 2/ ] keep [
 109         [ [ 2 * 1 + ] dip nth-unsafe ] curry
 110     ] keep map-integers-as ;
 111
 112 : compact ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 113     [ split-when harvest ] dip join ; inline
 114
 115 : collapse ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 116     [ split-when ] dip
 117     [ [ harvest ] dip join ]
 118     [ [ first empty? ] dip [ prepend ] curry when ]
 119     [ [ last empty? ] dip [ append ] curry when ]
 120     2tri ; inline
 121
 122 :: slice-when ( seq quot: ( elt -- ? ) -- seq' )
 123     seq length :> len
 124     0 [ len dupd < ] [
 125         dup seq quot find-from drop
 126         [ 2dup = [ 1 + ] when ] [ len ] if*
 127         [ seq <slice> ] keep len or swap
 128     ] produce nip ; inline
 129
 130 : ?<slice> ( from/f to/f sequence -- slice )
 131     [ [ 0 ] unless* ] 2dip
 132     over [ nip [ length ] [ ] bi ] unless
 133     <slice> ; inline
 134
 135 : sequence>slice ( sequence -- slice )
 136     [ drop 0 ] [ length ] [ ] tri <slice> ; inline
 137
 138 : slice-order-by-from ( slice1 slice2 -- slice-lt slice-gt )
 139     2dup [ from>> ] bi@ > [ swap ] when ; inline
 140
 141 : ordered-slices-range ( slice-lt slice-gt -- to from )
 142     [ to>> ] [ from>> ] bi* ;
 143
 144 : unordered-slices-range ( slice1 slice2 -- to from )
 145     slice-order-by-from ordered-slices-range ;
 146
 147 : ordered-slices-overlap? ( slice-lt slice-gt -- ? )
 148     ordered-slices-range > ; inline
 149
 150 : unordered-slices-overlap? ( slice1 slice2 -- ? )
 151     unordered-slices-range > ; inline
 152
 153 : slices-overlap? ( slice1 slice2 -- ? )
 154     unordered-slices-overlap? ;
 155
 156 : ordered-slices-touch? ( slice-lt slice-gt -- ? )
 157     ordered-slices-range >= ; inline
 158
 159 : unordered-slices-touch? ( slice1 slice2 -- ? )
 160     unordered-slices-range >= ; inline
 161
 162 : slices-touch? ( slice1 slice2 -- ? )
 163     unordered-slices-touch? ;
 164
 165 ERROR: slices-don't-touch slice1 slice2 ;
 166
 167 : merge-slices ( slice1 slice2 -- slice/* )
 168     slice-order-by-from
 169     2dup ordered-slices-touch? [
 170         [ from>> ] [ [ to>> ] [ seq>> ] bi ] bi* <slice>
 171     ] [
 172         slices-don't-touch
 173     ] if ;
 174
 175 : rotate ( seq n -- seq' )
 176     over length mod dup 0 >= [ cut ] [ abs cut* ] if prepend ;
 177
 178 ERROR: underlying-mismatch slice1 slice2 ;
 179
 180 : ensure-same-underlying ( slice1 slice2 -- slice1 slice2 )
 181     2dup [ seq>> ] bi@ eq? [ underlying-mismatch ] unless ;
 182
 183 : span-slices ( slice1 slice2 -- slice )
 184     ensure-same-underlying
 185     [ [ from>> ] bi@ min ]
 186     [ [ to>> ] bi@ max ]
 187     [ drop seq>> ] 2tri <slice> ;
 188
 189 : ?span-slices ( slice1/f slice2/f -- slice )
 190     2dup and [ span-slices ] [ or ] if ;
 191
 192 :: rotate! ( seq n -- )
 193     seq length :> len
 194     n len mod dup 0 < [ len + ] when seq bounds-check drop 0 over
 195     [ 2dup = ] [
 196         [ seq exchange-unsafe ] [ [ 1 + ] bi@ ] 2bi
 197         dup len = [ drop over ] when
 198         2over = [ -rot nip over ] when
 199     ] until 3drop ;
 200
 201 : all-rotations ( seq -- seq' )
 202     dup length <iota> [ rotate ] with map ;
 203
 204 <PRIVATE
 205
 206 : (appender-for) ( quot length exemplar -- appender accum )
 207     new-resizable [ [ push-all ] curry compose ] keep ; inline
 208
 209 PRIVATE>
 210
 211 : appender-for ( quot exemplar -- appender accum )
 212     [ length ] keep (appender-for) ; inline
 213
 214 : appender ( quot -- appender accum )
 215     V{ } appender-for ; inline
 216
 217 : map-concat-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 218     [ appender-for [ each ] dip ] keep like ; inline
 219
 220 : >resizable ( seq -- accum ) ! fixes map-concat "cannot apply call to run-time..."
 221     [ length ] keep [ new-resizable ] [ append! ] bi ;
 222
 223 : map-concat ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 224     over empty? [ 2drop { } ] [
 225         [ [ first ] dip call ] 2keep rot [
 226             >resizable [ '[ @ _ push-all ] 1 each-from ] keep
 227         ] keep like
 228     ] if ; inline
 229
 230 : map-filter-as ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) exemplar -- ... subseq )
 231     reach length over
 232     [ (selector-as) [ compose each ] dip ] 2curry dip like ; inline
 233
 234 : map-filter ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) -- ... subseq )
 235     pick map-filter-as ; inline
 236
 237 : map-sift ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 238     [ ] map-filter ; inline
 239
 240 : map-harvest ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 241     [ empty? not ] map-filter ; inline
 242
 243 : (each-integer-with-previous) ( ... prev i n quot: ( ... i -- ... ) -- ... )
 244     2over < [
 245         [ nip call ] 4keep nipdd
 246         [ 1 + ] 2dip (each-integer-with-previous)
 247     ] [
 248         4drop
 249     ] if ; inline recursive
 250
 251 : each-integer-with-previous ( ... n quot: ( ... i -- ... ) -- ... )
 252     [ f 0 ] 2dip (each-integer-with-previous) ; inline
 253
 254 : (collect-with-previous) ( quot into -- quot' )
 255     [ [ keep ] dip [ set-nth-unsafe ] keepdd ] 2curry ; inline
 256
 257 : collect-with-previous ( n quot into --  )
 258     (collect-with-previous) each-integer-with-previous ; inline
 259
 260 : map-integers-with ( ... len quot: ( ... prev i -- ... elt ) exemplar -- ... newseq )
 261     overd [ [ collect-with-previous ] keep ] new-like ; inline
 262
 263 : map-with-previous-as ( ... seq quot: ( ... elt prev/f -- ... newelt ) exemplar -- ... newseq )
 264     [ length-operator ] dip map-integers-with ; inline
 265
 266 : map-with-previous ( ... seq quot: ( ... elt prev/f -- ... newelt ) -- ... newseq )
 267     over map-with-previous-as ; inline
 268
 269 : setup-each-from ( seq quot -- n quot )
 270     [ [ length ] keep [ nth-unsafe ] curry ] dip compose ; inline
 271
 272 : map-from-as ( ... seq quot: ( ... elt -- ... newelt ) from exemplar -- ... newseq )
 273     -rotd [ sequence-operator nipd ] dip map-integers-from-as ; inline
 274
 275 : map-from ( ... seq quot: ( ... elt -- ... newelt ) from -- ... newseq )
 276     pick map-from-as ; inline
 277
 278 : map-if ( ... seq if-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) -- ... newseq )
 279     '[ dup @ _ when ] map ; inline
 280
 281 : reduce-from ( ... seq identity quot: ( ... prev elt -- ... next ) from -- ... result )
 282     [ swap ] 2dip each-from ; inline
 283
 284 : 2reduce-from ( ... seq1 seq2 identity quot: ( ... prev elt1 elt2 -- ... next ) i -- ... result )
 285     [ -rot ] 2dip 2each-from ; inline
 286
 287 : 0accumulate-as ( ... seq quot: ( ... prev elt -- ... next ) exemplar -- ... newseq )
 288     pick empty? [
 289         2nip clone
 290     ] [
 291         [ 0 ] 2dip
 292         [ swapd [ dup ] compose ] dip map-as nip
 293     ] if ; inline
 294
 295 : 0accumulate ( ... seq quot: ( ... prev elt -- ... next ) -- ... final newseq )
 296     over 0accumulate-as ; inline
 297
 298 : occurrence-count-by ( seq quot: ( elt -- elt' ) -- hash seq' )
 299     '[ nip @ over inc-at* ] [ H{ } clone ] 2dip 0accumulate ; inline
 300
 301 : occurrence-count ( seq -- hash seq' )
 302     [ ] occurrence-count-by ; inline
 303
 304 : nth-index ( n obj seq -- i )
 305     [ = dup [ drop 1 - dup 0 < ] when ] with find drop nip ;
 306
 307 : progressive-index-by-as ( seq1 seq2 quot exemplar -- hash seq' )
 308     [
 309         pick length '[
 310             tuck [ @ over inc-at* ] 2dip swap nth-index _ or
 311         ] [ H{ } clone ] 3dip with
 312     ] dip map-as ; inline
 313
 314 : progressive-index-by ( seq1 seq2 quot -- hash seq' )
 315     { } progressive-index-by-as ; inline
 316
 317 : progressive-index ( seq1 seq2 -- hash seq' )
 318     [ ] progressive-index-by ; inline
 319
 320 : 0reduce ( seq quot: ( prev elt -- next ) -- result )
 321     [ 0 ] dip reduce ; inline
 322
 323 <PRIVATE
 324
 325 : push-map-when* ( ..a elt quot: ( ..a elt -- ..b obj ? ) accum -- ..b )
 326     [ call ] dip swap [ push ] [ 2drop ] if ; inline
 327
 328 : filter-mapper-for* ( quot length exemplar -- filter-mapper accum )
 329     new-resizable [ [ push-map-when* ] 2curry ] keep ; inline
 330
 331 : 1push-map-when ( ..a filter-quot: ( ..a -- ..b ? ) map-quot: ( ..a -- ..b obj ) accum -- ..b )
 332     [ keep over ] 2dip [ when ] dip rot [ push ] [ 2drop ] if ; inline
 333
 334 : 1filter-mapper-for ( filter-quot map-quot length exemplar -- filter-mapper accum )
 335     new-resizable [ [ 1push-map-when ] 3curry ] keep ; inline
 336
 337 : 2push-map-when ( ..a filter-quot: ( ..a -- ..b ? ) map-quot: ( ..a -- ..b obj ) accum -- ..b )
 338     [ 2keep rot ] 2dip '[ [ @ _ push ] [ 2drop ] if ] call ; inline
 339
 340 : 2filter-mapper-for ( filter-quot map-quot length exemplar -- filter-mapper accum )
 341     new-resizable [ [ 2push-map-when ] 3curry ] keep ; inline
 342
 343 PRIVATE>
 344
 345 : filter-map-as* ( ... seq quot: ( ..a elt -- ..b obj ? ) exemplar -- ... newseq )
 346     pick length over
 347     [ filter-mapper-for* [ each ] dip ] 2curry dip like ; inline
 348
 349 : filter-map* ( ... seq quot: ( ... elt -- ... newelt ? ) -- ... newseq )
 350     over filter-map-as* ; inline
 351
 352 : reject-map-as* ( ... seq quot: ( ... elt -- ... newelt ? ) exemplar -- ... newseq )
 353     [ [ not ] compose ] dip filter-map-as* ; inline
 354
 355 : reject-map* ( ... seq quot: ( ... elt -- ... newelt ? ) -- ... newseq )
 356     over reject-map-as* ; inline
 357
 358 : 2filter-map-as* ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... obj ? ) exemplar -- ... newseq )
 359     reach length over
 360     [ filter-mapper-for* [ 2each ] dip ] 2curry dip like ; inline
 361
 362 : 2filter-map* ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... newseq )
 363     pick 2filter-map-as* ; inline
 364
 365 : 2reject-map-as* ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... obj ? ) exemplar -- ... newseq )
 366     [ [ not ] compose ] dip 2filter-map-as* ; inline
 367
 368 : 2reject-map* ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... obj ? ) -- ... newseq )
 369     pick 2reject-map-as* ; inline
 370
 371
 372 : filter-map-as ( ... seq filter-quot: ( ..a elt -- ..b ? ) map-quot: ( obj -- obj' ) exemplar -- ... newseq )
 373     reach length over
 374     [ 1filter-mapper-for [ each ] dip ] 2curry dip like ; inline
 375
 376 : filter-map ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( obj -- obj' ) -- ... newseq )
 377     pick filter-map-as ; inline
 378
 379 : reject-map-as ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( obj -- obj' ) exemplar -- ... newseq )
 380     [ [ not ] compose ] 2dip filter-map-as ; inline
 381
 382 : reject-map ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( obj -- obj' ) -- ... newseq )
 383     pick reject-map-as ; inline
 384
 385 : 2filter-map-as ( ... seq1 seq2 filter-quot: ( ... elt1 elt2 -- ... ? ) map-quot: ( elt1 elt2 -- obj ) exemplar -- ... newseq )
 386     5 npick length over
 387     [ 2filter-mapper-for [ 2each ] dip ] 2curry dip like ; inline
 388
 389 : 2filter-map ( ... seq1 seq2 filter-quot: ( ... elt1 elt2 -- ... ? ) map-quot: ( elt1 elt2 -- obj ) -- ... newseq )
 390     reach 2filter-map-as ; inline
 391
 392 : 2reject-map-as ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) map-quot: ( elt1 elt2 -- obj ) exemplar -- ... newseq )
 393     [ [ not ] compose ] 2dip 2filter-map-as ; inline
 394
 395 : 2reject-map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) map-quot: ( elt1 elt2 -- obj ) -- ... newseq )
 396     pick 2reject-map-as ; inline
 397
 398
 399 : 2filter-as ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) exemplar -- ... newseq )
 400     [
 401         pick [ length ] keep
 402         [ (2selector-as) [ 2each ] dip ] 2curry call
 403     ] dip like ; inline
 404
 405 : 2filter ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
 406     pick 2filter-as ; inline
 407
 408 : 2reject-as ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) exemplar -- ... newseq )
 409     [ [ not ] compose ] dip 2filter-as ; inline
 410
 411 : 2reject ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
 412     pick 2reject-as ; inline
 413
 414 : 2map-sum ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... n ) -- ... n )
 415     [ 0 ] 3dip [ dip + ] curry [ rot ] prepose 2each ; inline
 416
 417 : 2count ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... n )
 418     [ 1 0 ? ] compose 2map-sum ; inline
 419
 420 : 3each-from
 421     ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... ) i -- ... )
 422     [ 3length-operator ] dip -rot each-integer-from ; inline
 423
 424 : 3map-reduce
 425     ( ..a seq1 seq2 seq3 map-quot: ( ..a elt1 elt2 elt3 -- ..b intermediate ) reduce-quot: ( ..b prev intermediate -- ..a next ) -- ..a result )
 426     [ [ [ [ first ] tri@ ] 3keep ] dip [ 3dip ] keep ] dip compose 1 3each-from ; inline
 427
 428 : round-robin ( seq -- newseq )
 429     [ { } ] [
 430         [ longest length <iota> ] keep
 431         [ [ ?nth ] with map ] curry map concat sift
 432     ] if-empty ;
 433
 434 : sift-as ( seq exemplar -- newseq )
 435     [ ] swap filter-as ;
 436
 437 : sift! ( seq -- newseq )
 438     [ ] filter! ;
 439
 440 : harvest-as ( seq exemplar -- newseq )
 441     [ empty? not ] swap filter-as ;
 442
 443 : harvest! ( seq -- newseq )
 444     [ empty? ] reject! ;
 445
 446 : head-as ( seq n exemplar -- seq' )
 447     [ head-slice ] [ like ] bi* ; inline
 448
 449 : head*-as ( seq n exemplar -- seq' )
 450     [ head-slice* ] [ like ] bi* ; inline
 451
 452 : tail-as ( seq n exemplar -- seq' )
 453     [ tail-slice ] [ like ] bi* ; inline
 454
 455 : tail*-as ( seq n exemplar -- seq' )
 456     [ tail-slice* ] [ like ] bi* ; inline
 457
 458 : trim-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... newseq )
 459     [ trim-slice ] [ like ] bi* ; inline
 460
 461 : ?trim ( seq quot: ( elt -- ? ) -- seq/newseq )
 462     over empty? [ drop ] [
 463         over [ first-unsafe ] [ last-unsafe ] bi pick either?
 464         [ trim ] [ drop ] if
 465     ] if ; inline
 466
 467 : ?trim-head ( seq quot: ( elt -- ? ) -- seq/newseq )
 468     over empty? [ drop ] [
 469         over first-unsafe over call
 470         [ trim-head ] [ drop ] if
 471     ] if ; inline
 472
 473 : ?trim-tail ( seq quot: ( elt -- ? ) -- seq/newseq )
 474     over empty? [ drop ] [
 475         over last-unsafe over call
 476         [ trim-tail ] [ drop ] if
 477     ] if ; inline
 478
 479 : unsurround ( newseq seq2 seq3 -- seq1 )
 480     [ ?head drop ] [ ?tail drop ] bi* ;
 481
 482 : >string-list ( seq -- seq' )
 483     [ "\"" 1surround ] map "," join ;
 484
 485 : with-string-lines ( str quot -- str' )
 486     [ string-lines ] dip map "\n" join ; inline
 487
 488 : prepend-lines-with-spaces ( str -- str' )
 489     [ "    " prepend ] with-string-lines ;
 490
 491 : one? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 492     [ find ] 2keep rot [
 493         [ 1 + ] 2dip find-from drop not
 494     ] [ 3drop f ] if ; inline
 495
 496 : map-index! ( ... seq quot: ( ... elt index -- ... newelt ) -- ... seq )
 497     over [ [ sequence-index-operator ] dip collect ] keep ; inline
 498
 499 <PRIVATE
 500
 501 : 2sequence-index-iterator ( seq1 seq2 quot -- n quot' )
 502     [ 2length-iterator [ keep ] curry ] dip compose ; inline
 503
 504 PRIVATE>
 505
 506 : 2each-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... ) -- ... )
 507     2sequence-index-iterator each-integer ; inline
 508
 509 : 2map-into ( seq1 seq2 quot into -- )
 510     [ 2length-operator ] dip collect ; inline
 511
 512 : 2map! ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... seq1 )
 513     pick [ 2map-into ] keep ; inline
 514
 515 : 2map-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... newelt ) -- ... newseq )
 516     pick [ 2sequence-index-iterator ] dip map-integers-as ; inline
 517
 518 TUPLE: evens { seq read-only } ;
 519
 520 C: <evens> evens
 521
 522 M: evens length seq>> length 1 + 2/ ; inline
 523
 524 M: evens virtual@ [ 2 * ] [ seq>> ] bi* ; inline
 525
 526 M: evens virtual-exemplar seq>> ; inline
 527
 528 INSTANCE: evens virtual-sequence
 529
 530 TUPLE: odds { seq read-only } ;
 531
 532 C: <odds> odds
 533
 534 M: odds length seq>> length 2/ ; inline
 535
 536 M: odds virtual@ [ 2 * 1 + ] [ seq>> ] bi* ; inline
 537
 538 M: odds virtual-exemplar seq>> ; inline
 539
 540 INSTANCE: odds virtual-sequence
 541
 542 : until-empty ( seq quot -- )
 543     [ dup empty? ] swap until drop ; inline
 544
 545 <PRIVATE
 546
 547 : push-index-if ( ..a elt i quot: ( ..a elt -- ..b ? ) accum -- ..b )
 548     [ dip ] dip rot [ push ] [ 2drop ] if ; inline
 549
 550 PRIVATE>
 551
 552 : arg-where ( ... seq quot: ( ... elt -- ... ? ) -- ... indices )
 553     over length <vector> [
 554         [ push-index-if ] 2curry each-index
 555     ] keep ; inline
 556
 557 : arg-sort ( seq -- indices )
 558     zip-index sort-keys values ;
 559
 560 : first= ( seq elt -- ? ) [ first ] dip = ; inline
 561 : second= ( seq elt -- ? ) [ second ] dip = ; inline
 562 : third= ( seq elt -- ? ) [ third ] dip = ; inline
 563 : fourth= ( seq elt -- ? ) [ fourth ] dip = ; inline
 564 : last= ( seq elt -- ? ) [ last ] dip = ; inline
 565 : nth= ( n seq elt -- ? ) [ nth ] dip = ; inline
 566
 567 : first? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ first ] dip call ; inline
 568 : second? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ second ] dip call ; inline
 569 : third? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ third ] dip call ; inline
 570 : fourth? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ fourth ] dip call ; inline
 571 : last? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ last ] dip call ; inline
 572 : nth? ( ... n seq quot: ( ... elt -- ... ? ) -- ... ? ) [ nth ] dip call ; inline
 573
 574 : loop>sequence** ( ... quot: ( ... -- ... obj ? ) exemplar -- ... seq )
 575     [ ] swap produce-as nip ; inline
 576
 577 : loop>array** ( ... quot: ( ... -- ... obj ? ) -- ... array )
 578     { } loop>sequence** ; inline
 579
 580 : loop>sequence* ( ... quot: ( ... -- ... obj ? ) exemplar -- ... seq )
 581     [ t ] [ '[ [ _ dip ] [ f f f ] if* ] [ swap ] ] [ produce-as 2nip ] tri* ; inline
 582
 583 : loop>array* ( ... quot: ( ... -- ... obj ? ) -- ... array )
 584     { } loop>sequence* ; inline
 585
 586 : loop>sequence ( ... quot: ( ... -- ... obj/f ) exemplar -- ... seq )
 587     [ [ dup ] compose [ ] ] dip produce-as nip ; inline
 588
 589 : loop>array ( ... quot: ( ... -- ... obj/f ) -- ... array )
 590     { } loop>sequence ; inline
 591
 592 : zero-loop>sequence ( ... quot: ( ... n -- ... obj/f ) exemplar -- ... seq )
 593     [ 0 ] [ '[ _ keep 1 + swap ] ] [ loop>sequence ] tri* nip ; inline
 594
 595 : zero-loop>array ( quot: ( ..a n -- ..a obj ) -- seq )
 596     { } zero-loop>sequence ; inline
 597
 598 : iterate-heap-while ( heap quot1: ( value key -- slurp? ) quot2: ( value key -- obj/f ) -- obj/f loop? )
 599     pick heap-empty?
 600     [ 3drop f f ]
 601     [
 602         [ [ heap-peek ] 2dip drop 2keep ]
 603         [
 604             nip ! ( pop? value key heap quot2 )
 605             5roll [
 606                 swap heap-pop* call( value key -- obj/f ) t
 607             ] [
 608                 4drop f f
 609             ] if
 610         ] 3bi
 611     ] if ; inline
 612
 613 : slurp-heap-while-map ( heap quot1: ( value key -- slurp? ) quot2: ( value key -- obj/f ) -- seq )
 614     '[ _ _ _ iterate-heap-while ] loop>array* ; inline
 615
 616 : heap>pairs ( heap -- pairs )
 617     [ 2drop t ] [ swap 2array ] slurp-heap-while-map ;
 618
 619 : map-zip-swap ( quot: ( x -- y ) -- alist )
 620     '[ _ keep ] map>alist ; inline
 621
 622 : ?heap-pop-value>array ( heap -- array )
 623     dup heap-empty? [ drop { } ] [ heap-pop drop 1array ] if ;
 624
 625 <PRIVATE
 626
 627 : (reverse) ( seq -- newseq )
 628     dup [ length ] keep new-sequence
 629     [ 0 swap copy-unsafe ] keep reverse! ;
 630
 631 PRIVATE>
 632
 633 : reverse-as ( seq exemplar -- newseq )
 634     [ (reverse) ] [ like ] bi* ;
 635
 636 : map-product ( ... seq quot: ( ... elt -- ... n ) -- ... n )
 637     [ 1 ] 2dip [ dip * ] with-assoc each ; inline
 638
 639 : insert-nth! ( elt n seq -- )
 640     [ length ] keep ensure swap pick (a..b]
 641     over '[ [ 1 + ] keep _ move-unsafe ] each
 642     set-nth-unsafe ;
 643
 644 : set-nths ( value indices seq -- )
 645     swapd '[ _ swap _ set-nth ] each ; inline
 646
 647 : set-nths-unsafe ( value indices seq -- )
 648     swapd '[ _ swap _ set-nth-unsafe ] each ; inline
 649
 650 <PRIVATE
 651
 652 : (map-find-index) ( seq quot find-quot -- result i elt )
 653     [ [ f ] 2dip [ [ nip ] 2dip call dup ] curry ] dip call
 654     [ [ [ drop f ] unless ] keep ] dip ; inline
 655
 656 PRIVATE>
 657
 658 : map-find-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 659     [ find-index ] (map-find-index) ; inline
 660
 661 : filter-length ( seq n -- seq' ) '[ length _ = ] filter ;
 662
 663 : all-shortest ( seqs -- seqs' ) dup shortest length filter-length ;
 664
 665 : all-longest ( seqs -- seqs' ) dup longest length filter-length ;
 666
 667 <PRIVATE
 668
 669 : nth-unsafe-of ( seq n -- elt ) swap nth-unsafe ; inline
 670 : set-nth-unsafe-of ( seq n elt -- seq ) spin [ set-nth-unsafe ] keep ; inline
 671 : set-length-of ( seq n -- seq ) over set-length ; inline
 672
 673 : move-unsafe-of ( seq to from -- seq )
 674     2dup = [
 675         2drop
 676     ] [
 677         overd nth-unsafe-of set-nth-unsafe-of
 678     ] if ; inline
 679
 680 : move-backward-of ( seq shift from to -- seq )
 681     2dup = [
 682         3drop
 683     ] [
 684         [ [ [ + ] keep move-unsafe-of ] 2keep 1 + ] dip move-backward-of
 685     ] if ;
 686
 687 : open-slice-of ( seq shift from -- seq )
 688     over 0 = [
 689         2drop
 690     ] [
 691         [ ] [ drop [ length ] dip + ] 3bi
 692         [ pick length [ over - ] dip move-backward-of ] dip
 693         set-length-of
 694     ] if ;
 695
 696 PRIVATE>
 697
 698 : index-of ( seq obj -- n ) '[ _ = ] find drop ;
 699
 700 ERROR: slice-error-of from to seq ;
 701
 702 : check-slice-of ( seq from to -- seq from to )
 703     over 0 < [ slice-error-of ] when
 704     dup reach length > [ slice-error-of ] when
 705     2dup > [ slice-error-of ] when ; inline
 706
 707 : delete-slice-of ( seq from to -- seq )
 708     check-slice-of over [ - ] dip open-slice-of ;
 709
 710 : remove-nth-of ( seq n -- seq' )
 711     [ dup 1 + rot snip-slice ] keepd append-as ;
 712
 713 : remove-nth-of! ( seq n -- seq )
 714     dup 1 + delete-slice-of ;
 715
 716 : snip-of ( seq from to -- head tail )
 717     [ head ] [ tail ] bi-curry* bi ; inline
 718
 719 : snip-slice-of ( seq from to -- head tail )
 720     [ head-slice ] [ tail-slice ] bi-curry* bi ; inline
 721
 722 : remove-first ( obj seq -- seq' )
 723     [ index ] keep over [ remove-nth ] [ nip ] if ;
 724
 725 : remove-first-of ( seq obj -- seq' )
 726     dupd index-of [ remove-nth-of ] when* ;
 727
 728 : remove-first! ( obj seq -- seq )
 729     [ index ] keep over [ remove-nth! ] [ nip ] if ;
 730
 731 : remove-last ( obj seq -- seq' )
 732     [ last-index ] keep over [ remove-nth ] [ nip ] if ;
 733
 734 : remove-last! ( obj seq -- seq )
 735     [ last-index ] keep over [ remove-nth! ] [ nip ] if ;
 736
 737 : member-of? ( seq elt -- ? )
 738     [ = ] curry any? ;
 739
 740 : member-eq-of? ( seq elt -- ? )
 741     [ eq? ] curry any? ;
 742
 743 : remove-of ( seq elt -- newseq )
 744     [ = ] curry reject ;
 745
 746 : remove-eq-of ( seq elt -- newseq )
 747     [ eq? ] curry reject ;
 748
 749 : ?first2 ( seq -- first/f second/f )
 750     dup length {
 751         { 0 [ drop f f ] }
 752         { 1 [ first-unsafe f ] }
 753         [ drop first2-unsafe ]
 754     } case ;
 755
 756 : ?first3 ( seq -- first/f second/f third/f )
 757     dup length {
 758         { 0 [ drop f f f ] }
 759         { 1 [ first-unsafe f f ] }
 760         { 2 [ first2-unsafe f ] }
 761         [ drop first3-unsafe ]
 762     } case ;
 763
 764 : ?first4 ( seq -- first/f second/f third/f fourth/f )
 765     dup length {
 766         { 0 [ drop f f f f ] }
 767         { 1 [ first-unsafe f f f ] }
 768         { 2 [ first2-unsafe f f ] }
 769         { 3 [ first3-unsafe f ] }
 770         [ drop first4-unsafe ]
 771     } case ;
 772
 773 : cut-when ( ... seq quot: ( ... elt -- ... ? ) -- ... before after )
 774     [ find drop ] keepd swap
 775     [ cut ] [ f over like ] if* ; inline
 776
 777 : nth* ( n seq -- elt )
 778     [ length 1 - swap - ] [ nth ] bi ; inline
 779
 780 : each-index-from ( ... seq quot: ( ... elt index -- ... ) i -- ... )
 781     -rot sequence-index-operator each-integer-from ; inline
 782
 783 <PRIVATE
 784
 785 : select-by* ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... i elt )
 786     [
 787         [ keep swap ] curry [ dip ] curry
 788         [ [ first 0 ] dip call ] 2keep
 789         [ 2curry 3dip 5 npick pick ] curry
 790     ] [
 791         [ [ 3drop ] [ [ 3drop ] 3dip ] if ] compose
 792     ] bi* compose 1 each-index-from nip swap ; inline
 793
 794 PRIVATE>
 795
 796 : supremum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 797     [ after? ] select-by* ; inline
 798
 799 : infimum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 800     [ before? ] select-by* ; inline
 801
 802 : arg-max ( seq -- n )
 803     [ ] supremum-by* drop ;
 804
 805 : arg-min ( seq -- n )
 806     [ ] infimum-by* drop ;
 807
 808 : ?supremum ( seq/f -- elt/f )
 809     [ f ] [
 810         [ ] [ 2dup and [ max ] [ dupd ? ] if ] map-reduce
 811     ] if-empty ;
 812
 813 : ?infimum ( seq/f -- elt/f )
 814     [ f ] [
 815         [ ] [ 2dup and [ min ] [ dupd ? ] if ] map-reduce
 816     ] if-empty ;
 817
 818 : map-infimum ( seq quot: ( ... elt -- ... elt' ) -- elt' )
 819     [ min ] map-reduce ; inline
 820
 821 : map-supremum ( seq quot: ( ... elt -- ... elt' ) -- elt' )
 822     [ max ] map-reduce ; inline
 823
 824 : change-last ( seq quot -- )
 825     [ index-of-last ] [ change-nth ] bi* ; inline
 826
 827 : change-last-unsafe ( seq quot -- )
 828     [ index-of-last ] [ change-nth-unsafe ] bi* ; inline
 829
 830 : replicate-into ( ... seq quot: ( ... -- ... newelt ) -- ... )
 831     over [ length ] 2dip '[ _ dip _ set-nth-unsafe ] each-integer ; inline
 832
 833 : count* ( ... seq quot: ( ... elt -- ... ? ) -- ... % )
 834     over [ count ] [ length ] bi* / ; inline
 835
 836 : sequence-index-operator-last ( n seq quot -- n quot' )
 837     [ [ nth-unsafe ] curry [ keep ] curry ] dip compose ; inline
 838
 839 : find-last-index-from ( ... n seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 840     '[
 841         _ [ sequence-index-operator-last find-last-integer ] keepd
 842         index/element
 843     ] bounds-check-call ; inline
 844
 845 : find-last-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 846     [ index-of-last ] dip find-last-index-from ; inline
 847
 848 : map-find-last-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 849     [ find-last-index ] (map-find-index) ; inline
 850
 851 :: (start-all) ( seq subseq increment -- indices )
 852     0
 853     [ seq subseq subseq-index-from dup ]
 854     [ [ increment + ] keep ] produce nip ;
 855
 856 : start-all ( seq subseq -- indices )
 857     dup length (start-all) ; inline
 858
 859 : start-all* ( seq subseq -- indices )
 860     1 (start-all) ; inline
 861
 862 : count-subseq ( seq subseq -- n )
 863     start-all length ; inline
 864
 865 : count-subseq* ( seq subseq -- n )
 866     start-all* length ; inline
 867
 868 : assoc-zip-with ( quot: ( key value -- calc ) -- alist )
 869     '[ _ 2keep 2array swap ] assoc-map ; inline
 870
 871 : take-while ( ... seq quot: ( ... elt -- ... ? ) -- head-slice )
 872     [ '[ @ not ] find drop ] keepd swap
 873     [ dup length ] unless* head-slice ; inline
 874
 875 : drop-while ( ... seq quot: ( ... elt -- ... ? ) -- tail-slice )
 876     [ '[ @ not ] find drop ] keepd swap
 877     [ dup length ] unless* tail-slice ; inline
 878
 879 : count-head ( seq quot -- n )
 880     [ not ] compose [ find drop ] keepd length or ; inline
 881
 882 : count-tail ( seq quot -- n )
 883     [ not ] compose [ find-last drop ] keepd
 884     length swap [ - 1 - ] when* ; inline
 885
 886 :: shorten* ( vector n -- seq )
 887     vector n tail
 888     n vector shorten ;
 889
 890 :: interleaved-as ( seq glue exemplar -- newseq )
 891     seq length dup 1 - + 0 max exemplar new-sequence :> newseq
 892     seq [ 2 * newseq set-nth-unsafe ] each-index
 893     seq length 1 - [ 2 * 1 + glue swap newseq set-nth-unsafe ] each-integer
 894     newseq ;
 895
 896 : interleaved ( seq glue -- newseq )
 897     over interleaved-as ;
 898
 899 : extract! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 900     [ dup ] compose over [ length ] keep new-resizable
 901     [ [ push-when ] 2curry reject! ] keep swap like ; inline
 902
 903 : find-pred-loop ( ... i n seq quot: ( ... elt -- ... calc ? ) -- ... calc/f i/f elt/f )
 904     2pick < [
 905         [ nipd call ] 4keep
 906         3 7 0 nrotated
 907         [ [ 3drop ] 2dip rot ]
 908         [ 2drop [ 1 + ] 3dip find-pred-loop ] if
 909     ] [
 910         4drop f f f
 911     ] if ; inline recursive
 912
 913 : find-pred ( ... seq quot: ( ... elt -- ... calc ) pred: ( ... calc -- ... ? ) -- ... calc/f i/f elt/f )
 914     [ 0 ] 3dip
 915     [ [ length check-length ] keep ] 2dip
 916     '[ nth-unsafe _ keep swap _ keep swap ] find-pred-loop swapd ; inline
 917
 918 ! https://en.wikipedia.org/wiki/Maximum_subarray_problem
 919 ! Kadane's algorithm O(n) largest sum in subarray
 920 : max-subarray-sum ( seq -- sum )
 921     [ -1/0. 0 ] dip
 922     [ [ + ] keep max [ max ] keep ] each drop ;
 923
 924 TUPLE: step-slice
 925     { from integer read-only initial: 0 }
 926     { to integer read-only initial: 0 }
 927     { seq read-only }
 928     { step integer read-only } ;
 929
 930 :: <step-slice> ( from/f to/f step seq -- step-slice )
 931     step zero? [ "can't be zero" throw ] when
 932     seq length :> len
 933     step 0 > [
 934         from/f [ 0 ] unless*
 935         to/f [ len ] unless*
 936     ] [
 937         from/f [ len ] unless*
 938         to/f [ 0 ] unless*
 939     ] if
 940     [ dup 0 < [ len + ] when 0 len clamp ] bi@
 941     ! FIXME: make this work with steps
 942     seq dup slice? [ collapse-slice ] when
 943     step step-slice boa ;
 944
 945 M: step-slice virtual-exemplar seq>> ; inline
 946
 947 M: step-slice virtual@
 948     [ step>> * ] [ from>> + ] [ seq>> ] tri ; inline
 949
 950 M: step-slice length
 951     [ to>> ] [ from>> - ] [ step>> ] tri
 952     dup 0 < [ [ neg 0 max ] dip neg ] when /mod
 953     zero? [ 1 + ] unless ; inline
 954
 955 INSTANCE: step-slice virtual-sequence
 956
 957 : 2nested-each* ( seq1 seq-quot: ( n -- seq ) quot: ( a b -- ) -- )
 958     '[
 959         _ keep swap _ with each
 960     ] each ; inline
 961
 962 : 2nested-filter-as* ( seq1 seq-quot quot exemplar -- seq )
 963     [ 2over [ length ] bi@ * ] dip
 964     [
 965         new-resizable
 966         [ [ push? ] curry compose 2nested-each* ] keep
 967     ] keep like ; inline
 968
 969 : 2nested-filter* ( seq1 seq-quot quot -- seq )
 970     pick 2nested-filter-as* ; inline
 971
 972 : 2nested-map-as* ( seq1 seq-quot quot exemplar -- seq )
 973     [ 2over [ length ] bi@ * ] dip
 974     [
 975         new-resizable
 976         [ [ push ] curry compose 2nested-each* ] keep
 977     ] keep like ; inline
 978
 979 : 2nested-map* ( seq1 seq-quot quot -- seq )
 980     pick 2nested-map-as* ; inline
 981
 982
 983 : 2nested-each ( seq1 seq2 quot -- )
 984     swapd '[
 985         swap _ with each
 986     ] with each ; inline
 987
 988 : 2nested-filter-as ( seq1 seq2 quot exemplar -- seq )
 989     [ 2over [ length ] bi@ * ] dip
 990     [
 991         new-resizable
 992         [ [ push? ] curry compose 2nested-each ] keep
 993     ] keep like ; inline
 994
 995 : 2nested-filter ( seq1 seq2 quot -- seq )
 996     pick 2nested-filter-as ; inline
 997
 998 : 2nested-map-as ( seq1 seq2 quot exemplar -- seq )
 999     [ 2over [ length ] bi@ * ] dip
1000     [
1001         new-resizable
1002         [ [ push ] curry compose 2nested-each ] keep
1003     ] keep like ; inline
1004
1005 : 2nested-map ( seq1 seq2 quot -- seq )
1006     pick 2nested-map-as ; inline
1007
1008 : 3nested-each ( seq1 seq2 seq3 quot -- )
1009     [ spin ] dip '[
1010         -rot [
1011             swap _ with with each
1012         ] with with each
1013     ] with with each ; inline
1014
1015 : 3nested-filter-as ( seq1 seq2 seq3 quot exemplar -- seq )
1016     [ 3 nover [ length ] tri@ * * ] dip
1017     [
1018         new-resizable
1019         [ [ push? ] curry compose 3nested-each ] keep
1020     ] keep like ; inline
1021
1022 : 3nested-filter ( seq1 seq2 seq3 quot -- seq )
1023     reach 3nested-filter-as ; inline
1024
1025 : 3nested-map-as ( seq1 seq2 seq3 quot exemplar -- seq )
1026     [ 3 nover [ length ] tri@ * * ] dip
1027     [
1028         new-resizable
1029         [ [ push ] curry compose 3nested-each ] keep
1030     ] keep like ; inline
1031
1032 : 3nested-map ( seq1 seq2 seq3 quot -- seq )
1033     reach 3nested-map-as ; inline
1034
1035 : prev ( n seq -- obj ) [ 1 - ] dip nth ; inline
1036 : ?prev ( n seq -- obj/f ) [ 1 - ] dip ?nth ; inline
1037 : ??prev ( n seq -- obj/f ? ) [ 1 - ] dip ??nth ; inline
1038 : prev-of ( seq n -- obj ) 1 - nth-of ; inline
1039 : ?prev-of ( seq n -- obj/f ) 1 - ?nth-of ; inline
1040 : ??prev-of ( seq n -- obj/f ? ) 1 - ??nth-of ; inline
1041
1042 : prev-identity ( i seq -- identity i seq )
1043     2dup ??prev [ drop 0 ] unless -rot ; inline
1044
1045 : each-prior-identity-from ( ... identity i seq quot: ( ... prior elt -- ... ) -- ... )
1046     '[ [ swap @ ] keep ]
1047     length-operator each-integer-from drop ; inline
1048
1049 : each-prior-from ( ... i seq quot: ( ... prior elt -- ... ) -- ... )
1050     [ prev-identity ] dip each-prior-identity-from ; inline
1051
1052 : each-prior ( ... seq quot: ( ... prior elt -- ... ) -- ... )
1053     0 -rot each-prior-from ; inline
1054
1055 : map-prior-identity-from-as ( ... identity i seq quot: ( ... prior elt -- elt' ) exemplar -- seq' )
1056     [
1057         '[ [ swap @ ] keep swap ] length-operator
1058     ] dip map-integers-from-as nip ; inline
1059
1060 : map-prior-identity-as ( ... identity seq quot: ( ... prior elt -- elt' ) exemplar -- seq' )
1061     [ 0 ] 3dip map-prior-identity-from-as ; inline
1062
1063 : map-prior-from-as ( ... i seq quot: ( ... prior elt -- elt' ) exemplar -- seq' )
1064     [ prev-identity ] 2dip map-prior-identity-from-as ; inline
1065
1066 : map-prior-as ( ... seq quot: ( ... prior elt -- elt' ) exemplar -- seq' )
1067     0 -roll map-prior-from-as ; inline
1068
1069 : map-prior-from ( ... i seq quot: ( ... prior elt -- elt' ) -- seq' )
1070     over map-prior-from-as ; inline
1071
1072 : map-prior ( ... seq quot: ( ... prior elt -- elt' ) -- seq' )
1073     over map-prior-as ; inline
1074
1075 TUPLE: virtual-zip-index seq ;
1076
1077 C: <zip-index> virtual-zip-index
1078
1079 M: virtual-zip-index length seq>> length ; inline
1080
1081 M: virtual-zip-index nth-unsafe
1082     over [ seq>> nth-unsafe ] [ 2array ] bi* ; inline
1083
1084 INSTANCE: virtual-zip-index immutable-sequence