extra/sequences/extras/extras.factor

   1 USING: accessors arrays assocs combinators generalizations
   2 grouping growable heaps kernel math math.order ranges sequences
   3 sequences.private shuffle sorting splitting vectors ;
   4 IN: sequences.extras
   5
   6 : find-all ( ... seq quot: ( ... elt -- ... ? ) -- ... elts )
   7     [ <enumerated> ] dip '[ nip @ ] assoc-filter ; inline
   8
   9 :: subseq* ( from to seq -- subseq )
  10     seq length :> len
  11     from [ dup 0 < [ len + ] when ] [ 0 ] if*
  12     to [ dup 0 < [ len + ] when ] [ len ] if*
  13     [ 0 len clamp ] bi@ dupd max seq subseq ;
  14
  15 : safe-subseq ( from to seq -- subseq )
  16     [ length '[ 0 _ clamp ] bi@ ] keep subseq ;
  17
  18 : all-subseqs ( seq -- seqs )
  19     dup length [1..b] [ clump ] with map concat ;
  20
  21 : each-subseq ( ... seq quot: ( ... subseq -- ... ) -- ... )
  22     [ dup length [ [0..b] ] [ ] bi ] dip '[
  23         dup _ (a..b] [ rot [ subseq _ call ] keep ] with each
  24     ] each drop ; inline
  25
  26 : map-like ( seq exemplar -- seq' )
  27     '[ _ like ] map ; inline
  28
  29 : filter-all-subseqs-range ( ... seq range quot: ( ... subseq -- ... ? ) -- seq )
  30     [
  31         '[ <clumps> _ filter ] with map concat
  32     ] keepdd map-like ; inline
  33
  34 : filter-all-subseqs ( ... seq quot: ( ... subseq -- ... ? ) -- seq )
  35     [ dup length [1..b] ] dip filter-all-subseqs-range ; inline
  36
  37 :: longest-subseq ( seq1 seq2 -- subseq )
  38     seq1 length :> len1
  39     seq2 length :> len2
  40     0 :> n!
  41     0 :> end!
  42     len1 1 + [ len2 1 + 0 <array> ] replicate :> table
  43     len1 [1..b] [| x |
  44         len2 [1..b] [| y |
  45             x 1 - seq1 nth-unsafe
  46             y 1 - seq2 nth-unsafe = [
  47                 y 1 - x 1 - table nth-unsafe nth-unsafe 1 + :> len
  48                 len y x table nth-unsafe set-nth-unsafe
  49                 len n > [ len n! x end! ] when
  50             ] [ 0 y x table nth-unsafe set-nth-unsafe ] if
  51         ] each
  52     ] each end n - end seq1 subseq ;
  53
  54 : pad-longest ( seq1 seq2 elt -- seq1 seq2 )
  55     [ 2dup max-length ] dip [ pad-tail ] 2curry bi@ ;
  56
  57 : pad-center ( seq n elt -- padded )
  58     swap pick length [-] [ drop ] [
  59         [ 2/ ] [ over - ] bi rot '[ _ <repetition> ] bi@
  60         pick surround-as
  61     ] if-zero ;
  62
  63 : change-nths ( ... indices seq quot: ( ... elt -- ... elt' ) -- ... )
  64     [ change-nth ] 2curry each ; inline
  65
  66 : push-if-index ( ..a elt i quot: ( ..a elt i -- ..b ? ) accum -- ..b )
  67     [ keepd ] dip rot [ push ] [ 2drop ] if ; inline
  68
  69 : push-if* ( ..a elt quot: ( ..a elt -- ..b obj/f ) accum -- ..b )
  70     [ call ] dip [ push ] [ drop ] if* ; inline
  71
  72 : push? ( elt/f accum -- )
  73     over [ push ] [ 2drop ] if ; inline
  74
  75 <PRIVATE
  76
  77 : (index-selector-as) ( quot length exampler -- selector accum )
  78     new-resizable [ [ push-if-index ] 2curry ] keep ; inline
  79
  80 : (selector-as*) ( quot length exemplar -- selector accum )
  81     new-resizable [ [ push-if* ] 2curry ] keep ; inline
  82
  83 PRIVATE>
  84
  85 : index-selector-as ( quot exemplar -- selector accum )
  86     [ length ] keep (index-selector-as) ; inline
  87
  88 : index-selector ( quot -- selector accum )
  89     V{ } index-selector-as ; inline
  90
  91 : selector-as* ( quot exemplar -- selector accum )
  92     [ length ] keep (selector-as*) ; inline
  93
  94 : selector* ( quot -- selector accum ) V{ } selector-as* ; inline
  95
  96 : filter-index-as ( ... seq quot: ( ... elt i -- ... ? ) exemplar -- ... seq' )
  97     pick length over [ (index-selector-as) [ each-index ] dip ] 2curry dip like ; inline
  98
  99 : filter-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... seq' )
 100     over filter-index-as ; inline
 101
 102 : even-indices ( seq -- seq' )
 103     [ length 1 + 2/ ] keep [
 104         [ [ 2 * ] dip nth-unsafe ] curry
 105     ] keep map-integers-as ;
 106
 107 : odd-indices ( seq -- seq' )
 108     [ length 2/ ] keep [
 109         [ [ 2 * 1 + ] dip nth-unsafe ] curry
 110     ] keep map-integers-as ;
 111
 112 : compact ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 113     [ split-when harvest ] dip join ; inline
 114
 115 : collapse ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 116     [ split-when ] dip
 117     [ [ harvest ] dip join ]
 118     [ [ first empty? ] dip [ prepend ] curry when ]
 119     [ [ last empty? ] dip [ append ] curry when ]
 120     2tri ; inline
 121
 122 :: slice-when ( seq quot: ( elt -- ? ) -- seq' )
 123     seq length :> len
 124     0 [ len dupd < ] [
 125         dup seq quot find-from drop
 126         [ 2dup = [ 1 + ] when ] [ len ] if*
 127         [ seq <slice> ] keep len or swap
 128     ] produce nip ; inline
 129
 130 : ?<slice> ( from/f to/f sequence -- slice )
 131     [ [ 0 ] unless* ] 2dip
 132     over [ nip [ length ] [ ] bi ] unless
 133     <slice> ; inline
 134
 135 : sequence>slice ( sequence -- slice )
 136     [ drop 0 ] [ length ] [ ] tri <slice> ; inline
 137
 138 : slice-order-by-from ( slice1 slice2 -- slice-lt slice-gt )
 139     2dup [ from>> ] bi@ > [ swap ] when ; inline
 140
 141 : ordered-slices-range ( slice-lt slice-gt -- to from )
 142     [ to>> ] [ from>> ] bi* ;
 143
 144 : unordered-slices-range ( slice1 slice2 -- to from )
 145     slice-order-by-from ordered-slices-range ;
 146
 147 : ordered-slices-overlap? ( slice-lt slice-gt -- ? )
 148     ordered-slices-range > ; inline
 149
 150 : unordered-slices-overlap? ( slice1 slice2 -- ? )
 151     unordered-slices-range > ; inline
 152
 153 : slices-overlap? ( slice1 slice2 -- ? )
 154     unordered-slices-overlap? ;
 155
 156 : ordered-slices-touch? ( slice-lt slice-gt -- ? )
 157     ordered-slices-range >= ; inline
 158
 159 : unordered-slices-touch? ( slice1 slice2 -- ? )
 160     unordered-slices-range >= ; inline
 161
 162 : slices-touch? ( slice1 slice2 -- ? )
 163     unordered-slices-touch? ;
 164
 165 ERROR: slices-don't-touch slice1 slice2 ;
 166
 167 : merge-slices ( slice1 slice2 -- slice/* )
 168     slice-order-by-from
 169     2dup ordered-slices-touch? [
 170         [ from>> ] [ [ to>> ] [ seq>> ] bi ] bi* <slice>
 171     ] [
 172         slices-don't-touch
 173     ] if ;
 174
 175 : rotate ( seq n -- seq' )
 176     over length mod dup 0 >= [ cut ] [ abs cut* ] if prepend ;
 177
 178 ERROR: underlying-mismatch slice1 slice2 ;
 179
 180 : ensure-same-underlying ( slice1 slice2 -- slice1 slice2 )
 181     2dup [ seq>> ] bi@ eq? [ underlying-mismatch ] unless ;
 182
 183 : span-slices ( slice1 slice2 -- slice )
 184     ensure-same-underlying
 185     [ [ from>> ] bi@ min ]
 186     [ [ to>> ] bi@ max ]
 187     [ drop seq>> ] 2tri <slice> ;
 188
 189 : ?span-slices ( slice1/f slice2/f -- slice )
 190     2dup and [ span-slices ] [ or ] if ;
 191
 192 :: rotate! ( seq n -- )
 193     seq length :> len
 194     n len mod dup 0 < [ len + ] when seq bounds-check drop 0 over
 195     [ 2dup = ] [
 196         [ seq exchange-unsafe ] [ [ 1 + ] bi@ ] 2bi
 197         dup len = [ drop over ] when
 198         2over = [ -rot nip over ] when
 199     ] until 3drop ;
 200
 201 : all-rotations ( seq -- seq' )
 202     dup length <iota> [ rotate ] with map ;
 203
 204 <PRIVATE
 205
 206 : (appender-for) ( quot length exemplar -- appender accum )
 207     new-resizable [ [ push-all ] curry compose ] keep ; inline
 208
 209 PRIVATE>
 210
 211 : appender-for ( quot exemplar -- appender accum )
 212     [ length ] keep (appender-for) ; inline
 213
 214 : appender ( quot -- appender accum )
 215     V{ } appender-for ; inline
 216
 217 : map-concat-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 218     [ appender-for [ each ] dip ] keep like ; inline
 219
 220 : >resizable ( seq -- accum ) ! fixes map-concat "cannot apply call to run-time..."
 221     [ length ] keep [ new-resizable ] [ append! ] bi ;
 222
 223 : map-concat ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 224     over empty? [ 2drop { } ] [
 225         [ [ first ] dip call ] 2keep rot [
 226             >resizable [ '[ @ _ push-all ] 1 each-from ] keep
 227         ] keep like
 228     ] if ; inline
 229
 230 : map-filter-as ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) exemplar -- ... subseq )
 231     reach length over
 232     [ (selector-as) [ compose each ] dip ] 2curry dip like ; inline
 233
 234 : map-filter ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) -- ... subseq )
 235     pick map-filter-as ; inline
 236
 237 : map-sift ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 238     [ ] map-filter ; inline
 239
 240 : map-harvest ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 241     [ empty? not ] map-filter ; inline
 242
 243 : (each-integer-with-previous) ( ... prev i n quot: ( ... i -- ... ) -- ... )
 244     2over < [
 245         [ nip call ] 4keep nipdd
 246         [ 1 + ] 2dip (each-integer-with-previous)
 247     ] [
 248         4drop
 249     ] if ; inline recursive
 250
 251 : each-integer-with-previous ( ... n quot: ( ... i -- ... ) -- ... )
 252     [ f 0 ] 2dip (each-integer-with-previous) ; inline
 253
 254 : (collect-with-previous) ( quot into -- quot' )
 255     [ [ keep ] dip [ set-nth-unsafe ] keepdd ] 2curry ; inline
 256
 257 : collect-with-previous ( n quot into --  )
 258     (collect-with-previous) each-integer-with-previous ; inline
 259
 260 : map-integers-with ( ... len quot: ( ... prev i -- ... elt ) exemplar -- ... newseq )
 261     overd [ [ collect-with-previous ] keep ] new-like ; inline
 262
 263 : map-with-previous-as ( ... seq quot: ( ... elt prev/f -- ... newelt ) exemplar -- ... newseq )
 264     [ length-operator ] dip map-integers-with ; inline
 265
 266 : map-with-previous ( ... seq quot: ( ... elt prev/f -- ... newelt ) -- ... newseq )
 267     over map-with-previous-as ; inline
 268
 269 : setup-each-from ( seq quot -- n quot )
 270     [ [ length ] keep [ nth-unsafe ] curry ] dip compose ; inline
 271
 272 : map-from-as ( ... seq quot: ( ... elt -- ... newelt ) from exemplar -- ... newseq )
 273     -rotd [ sequence-operator nipd ] dip map-integers-from-as ; inline
 274
 275 : map-from ( ... seq quot: ( ... elt -- ... newelt ) from -- ... newseq )
 276     pick map-from-as ; inline
 277
 278 : map-if ( ... seq if-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) -- ... newseq )
 279     '[ dup @ _ when ] map ; inline
 280
 281 : reduce-from ( ... seq identity quot: ( ... prev elt -- ... next ) from -- ... result )
 282     [ swap ] 2dip each-from ; inline
 283
 284 : 0accumulate-as ( ... seq quot: ( ... prev elt -- ... next ) exemplar -- ... newseq )
 285     pick empty? [
 286         2nip clone
 287     ] [
 288         [ 0 ] 2dip
 289         [ swapd [ dup ] compose ] dip map-as nip
 290     ] if ; inline
 291
 292 : 0accumulate ( ... seq quot: ( ... prev elt -- ... next ) -- ... final newseq )
 293     over 0accumulate-as ; inline
 294
 295 : occurrence-count-by ( seq quot: ( elt -- elt' ) -- hash seq' )
 296     '[ nip @ over inc-at* ] [ H{ } clone ] 2dip 0accumulate ; inline
 297
 298 : occurrence-count ( seq -- hash seq' )
 299     [ ] occurrence-count-by ; inline
 300
 301 : nth-index ( n obj seq -- i )
 302     [ = dup [ drop 1 - dup 0 < ] when ] with find drop nip ;
 303
 304 : progressive-index-by-as ( seq1 seq2 quot exemplar -- hash seq' )
 305     [
 306         pick length '[
 307             tuck [ @ over inc-at* ] 2dip swap nth-index _ or
 308         ] [ H{ } clone ] 3dip with
 309     ] dip map-as ; inline
 310
 311 : progressive-index-by ( seq1 seq2 quot -- hash seq' )
 312     { } progressive-index-by-as ; inline
 313
 314 : progressive-index ( seq1 seq2 -- hash seq' )
 315     [ ] progressive-index-by ; inline
 316
 317 : 0reduce ( seq quot: ( prev elt -- next ) -- result )
 318     [ 0 ] dip reduce ; inline
 319
 320 <PRIVATE
 321
 322 : push-map-if ( ..a elt filter-quot: ( ..a elt -- ..b ? ) map-quot: ( ..a elt -- ..b newelt ) accum -- ..b )
 323     [ keep over ] 2dip [ when ] dip rot [ push ] [ 2drop ] if ; inline
 324
 325 : (filter-mapper-for) ( filter-quot map-quot length exempler -- filter-mapper accum )
 326     new-resizable [ [ push-map-if ] 3curry ] keep ; inline
 327
 328 : filter-mapper-for ( filter-quot map-quot exemplar -- filter-mapper accum )
 329     [ length ] keep (filter-mapper-for) ; inline
 330
 331 : filter-mapper ( filter-quot map-quot -- filter-mapper accum )
 332     V{ } filter-mapper-for ; inline
 333
 334 PRIVATE>
 335
 336 : filter-map-as ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 337     reach length over
 338     [ (filter-mapper-for) [ each ] dip ] 2curry dip like ; inline
 339
 340 : filter-map ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) -- ... newseq )
 341     pick filter-map-as ; inline
 342
 343 : 2map-sum ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... n ) -- ... n )
 344     [ 0 ] 3dip [ dip + ] curry [ rot ] prepose 2each ; inline
 345
 346 : 2count ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... n )
 347     [ 1 0 ? ] compose 2map-sum ; inline
 348
 349 : 3each-from
 350     ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... ) i -- ... )
 351     [ 3length-operator ] dip -rot each-integer-from ; inline
 352
 353 : 3map-reduce
 354     ( ..a seq1 seq2 seq3 map-quot: ( ..a elt1 elt2 elt3 -- ..b intermediate ) reduce-quot: ( ..b prev intermediate -- ..a next ) -- ..a result )
 355     [ [ [ [ first ] tri@ ] 3keep ] dip [ 3dip ] keep ] dip compose 1 3each-from ; inline
 356
 357 : round-robin ( seq -- newseq )
 358     [ { } ] [
 359         [ longest length <iota> ] keep
 360         [ [ ?nth ] with map ] curry map concat sift
 361     ] if-empty ;
 362
 363 : sift-as ( seq exemplar -- newseq )
 364     [ ] swap filter-as ;
 365
 366 : sift! ( seq -- newseq )
 367     [ ] filter! ;
 368
 369 : harvest-as ( seq exemplar -- newseq )
 370     [ empty? not ] swap filter-as ;
 371
 372 : harvest! ( seq -- newseq )
 373     [ empty? ] reject! ;
 374
 375 : head-as ( seq n exemplar -- seq' )
 376     [ head-slice ] [ like ] bi* ; inline
 377
 378 : head*-as ( seq n exemplar -- seq' )
 379     [ head-slice* ] [ like ] bi* ; inline
 380
 381 : tail-as ( seq n exemplar -- seq' )
 382     [ tail-slice ] [ like ] bi* ; inline
 383
 384 : tail*-as ( seq n exemplar -- seq' )
 385     [ tail-slice* ] [ like ] bi* ; inline
 386
 387 : trim-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... newseq )
 388     [ trim-slice ] [ like ] bi* ; inline
 389
 390 : ?trim ( seq quot: ( elt -- ? ) -- seq/newseq )
 391     over empty? [ drop ] [
 392         over [ first-unsafe ] [ last-unsafe ] bi pick either?
 393         [ trim ] [ drop ] if
 394     ] if ; inline
 395
 396 : ?trim-head ( seq quot: ( elt -- ? ) -- seq/newseq )
 397     over empty? [ drop ] [
 398         over first-unsafe over call
 399         [ trim-head ] [ drop ] if
 400     ] if ; inline
 401
 402 : ?trim-tail ( seq quot: ( elt -- ? ) -- seq/newseq )
 403     over empty? [ drop ] [
 404         over last-unsafe over call
 405         [ trim-tail ] [ drop ] if
 406     ] if ; inline
 407
 408 : unsurround ( newseq seq2 seq3 -- seq1 )
 409     [ ?head drop ] [ ?tail drop ] bi* ;
 410
 411 : >string-list ( seq -- seq' )
 412     [ "\"" 1surround ] map "," join ;
 413
 414 : with-string-lines ( str quot -- str' )
 415     [ string-lines ] dip map "\n" join ; inline
 416
 417 : prepend-lines-with-spaces ( str -- str' )
 418     [ "    " prepend ] with-string-lines ;
 419
 420 : one? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 421     [ find ] 2keep rot [
 422         [ 1 + ] 2dip find-from drop not
 423     ] [ 3drop f ] if ; inline
 424
 425 : map-index! ( ... seq quot: ( ... elt index -- ... newelt ) -- ... seq )
 426     over [ [ sequence-index-operator ] dip collect ] keep ; inline
 427
 428 <PRIVATE
 429
 430 : 2sequence-index-iterator ( seq1 seq2 quot -- n quot' )
 431     [ 2length-iterator [ keep ] curry ] dip compose ; inline
 432
 433 PRIVATE>
 434
 435 : 2each-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... ) -- ... )
 436     2sequence-index-iterator each-integer ; inline
 437
 438 : 2map-into ( seq1 seq2 quot into -- )
 439     [ 2length-operator ] dip collect ; inline
 440
 441 : 2map! ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... seq1 )
 442     pick [ 2map-into ] keep ; inline
 443
 444 : 2map-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... newelt ) -- ... newseq )
 445     pick [ 2sequence-index-iterator ] dip map-integers-as ; inline
 446
 447 TUPLE: evens { seq read-only } ;
 448
 449 C: <evens> evens
 450
 451 M: evens length seq>> length 1 + 2/ ; inline
 452
 453 M: evens virtual@ [ 2 * ] [ seq>> ] bi* ; inline
 454
 455 M: evens virtual-exemplar seq>> ; inline
 456
 457 INSTANCE: evens virtual-sequence
 458
 459 TUPLE: odds { seq read-only } ;
 460
 461 C: <odds> odds
 462
 463 M: odds length seq>> length 2/ ; inline
 464
 465 M: odds virtual@ [ 2 * 1 + ] [ seq>> ] bi* ; inline
 466
 467 M: odds virtual-exemplar seq>> ; inline
 468
 469 INSTANCE: odds virtual-sequence
 470
 471 : until-empty ( seq quot -- )
 472     [ dup empty? ] swap until drop ; inline
 473
 474 <PRIVATE
 475
 476 : push-index-if ( ..a elt i quot: ( ..a elt -- ..b ? ) accum -- ..b )
 477     [ dip ] dip rot [ push ] [ 2drop ] if ; inline
 478
 479 PRIVATE>
 480
 481 : arg-where ( ... seq quot: ( ... elt -- ... ? ) -- ... indices )
 482     over length <vector> [
 483         [ push-index-if ] 2curry each-index
 484     ] keep ; inline
 485
 486 : arg-sort ( seq -- indices )
 487     zip-index sort-keys values ;
 488
 489 : first= ( seq elt -- ? ) [ first ] dip = ; inline
 490 : second= ( seq elt -- ? ) [ second ] dip = ; inline
 491 : third= ( seq elt -- ? ) [ third ] dip = ; inline
 492 : fourth= ( seq elt -- ? ) [ fourth ] dip = ; inline
 493 : last= ( seq elt -- ? ) [ last ] dip = ; inline
 494 : nth= ( n seq elt -- ? ) [ nth ] dip = ; inline
 495
 496 : first? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ first ] dip call ; inline
 497 : second? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ second ] dip call ; inline
 498 : third? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ third ] dip call ; inline
 499 : fourth? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ fourth ] dip call ; inline
 500 : last? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ last ] dip call ; inline
 501 : nth? ( ... n seq quot: ( ... elt -- ... ? ) -- ... ? ) [ nth ] dip call ; inline
 502
 503 : loop>sequence** ( ... quot: ( ... -- ... obj ? ) exemplar -- ... seq )
 504     [ ] swap produce-as nip ; inline
 505
 506 : loop>array** ( ... quot: ( ... -- ... obj ? ) -- ... array )
 507     { } loop>sequence** ; inline
 508
 509 : loop>sequence* ( ... quot: ( ... -- ... obj ? ) exemplar -- ... seq )
 510     [ t ] [ '[ [ _ dip ] [ f f f ] if* ] [ swap ] ] [ produce-as 2nip ] tri* ; inline
 511
 512 : loop>array* ( ... quot: ( ... -- ... obj ? ) -- ... array )
 513     { } loop>sequence* ; inline
 514
 515 : loop>sequence ( ... quot: ( ... -- ... obj/f ) exemplar -- ... seq )
 516     [ [ dup ] compose [ ] ] dip produce-as nip ; inline
 517
 518 : loop>array ( ... quot: ( ... -- ... obj/f ) -- ... array )
 519     { } loop>sequence ; inline
 520
 521 : zero-loop>sequence ( ... quot: ( ... n -- ... obj/f ) exemplar -- ... seq )
 522     [ 0 ] [ '[ _ keep 1 + swap ] ] [ loop>sequence ] tri* nip ; inline
 523
 524 : zero-loop>array ( quot: ( ..a n -- ..a obj ) -- seq )
 525     { } zero-loop>sequence ; inline
 526
 527 : iterate-heap-while ( heap quot1: ( value key -- slurp? ) quot2: ( value key -- obj/f ) -- obj/f loop? )
 528     pick heap-empty?
 529     [ 3drop f f ]
 530     [
 531         [ [ heap-peek ] 2dip drop 2keep ]
 532         [
 533             nip ! ( pop? value key heap quot2 )
 534             5roll [
 535                 swap heap-pop* call( value key -- obj/f ) t
 536             ] [
 537                 4drop f f
 538             ] if
 539         ] 3bi
 540     ] if ; inline
 541
 542 : slurp-heap-while-map ( heap quot1: ( value key -- slurp? ) quot2: ( value key -- obj/f ) -- seq )
 543     '[ _ _ _ iterate-heap-while ] loop>array* ; inline
 544
 545 : heap>pairs ( heap -- pairs )
 546     [ 2drop t ] [ swap 2array ] slurp-heap-while-map ;
 547
 548 : map-zip-swap ( quot: ( x -- y ) -- alist )
 549     '[ _ keep ] map>alist ; inline
 550
 551 : ?heap-pop-value>array ( heap -- array )
 552     dup heap-empty? [ drop { } ] [ heap-pop drop 1array ] if ;
 553
 554 <PRIVATE
 555
 556 : (reverse) ( seq -- newseq )
 557     dup [ length ] keep new-sequence
 558     [ 0 swap copy-unsafe ] keep reverse! ;
 559
 560 PRIVATE>
 561
 562 : reverse-as ( seq exemplar -- newseq )
 563     [ (reverse) ] [ like ] bi* ;
 564
 565 : map-product ( ... seq quot: ( ... elt -- ... n ) -- ... n )
 566     [ 1 ] 2dip [ dip * ] with-assoc each ; inline
 567
 568 : insert-nth! ( elt n seq -- )
 569     [ length ] keep ensure swap pick (a..b]
 570     over '[ [ 1 + ] keep _ move-unsafe ] each
 571     set-nth-unsafe ;
 572
 573 : set-nths ( value indices seq -- )
 574     swapd '[ _ swap _ set-nth ] each ; inline
 575
 576 : set-nths-unsafe ( value indices seq -- )
 577     swapd '[ _ swap _ set-nth-unsafe ] each ; inline
 578
 579 <PRIVATE
 580
 581 : (map-find-index) ( seq quot find-quot -- result i elt )
 582     [ [ f ] 2dip [ [ nip ] 2dip call dup ] curry ] dip call
 583     [ [ [ drop f ] unless ] keep ] dip ; inline
 584
 585 PRIVATE>
 586
 587 : map-find-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 588     [ find-index ] (map-find-index) ; inline
 589
 590 : filter-length ( seq n -- seq' ) '[ length _ = ] filter ;
 591
 592 : all-shortest ( seqs -- seqs' ) dup shortest length filter-length ;
 593
 594 : all-longest ( seqs -- seqs' ) dup longest length filter-length ;
 595
 596 : remove-first ( obj seq -- seq' )
 597     [ index ] keep over [ remove-nth ] [ nip ] if ;
 598
 599 : remove-first! ( obj seq -- seq )
 600     [ index ] keep over [ remove-nth! ] [ nip ] if ;
 601
 602 : remove-last ( obj seq -- seq' )
 603     [ last-index ] keep over [ remove-nth ] [ nip ] if ;
 604
 605 : remove-last! ( obj seq -- seq )
 606     [ last-index ] keep over [ remove-nth! ] [ nip ] if ;
 607
 608 : ?first2 ( seq -- first/f second/f )
 609     dup length {
 610         { 0 [ drop f f ] }
 611         { 1 [ first-unsafe f ] }
 612         [ drop first2-unsafe ]
 613     } case ;
 614
 615 : ?first3 ( seq -- first/f second/f third/f )
 616     dup length {
 617         { 0 [ drop f f f ] }
 618         { 1 [ first-unsafe f f ] }
 619         { 2 [ first2-unsafe f ] }
 620         [ drop first3-unsafe ]
 621     } case ;
 622
 623 : ?first4 ( seq -- first/f second/f third/f fourth/f )
 624     dup length {
 625         { 0 [ drop f f f f ] }
 626         { 1 [ first-unsafe f f f ] }
 627         { 2 [ first2-unsafe f f ] }
 628         { 3 [ first3-unsafe f ] }
 629         [ drop first4-unsafe ]
 630     } case ;
 631
 632 : cut-when ( ... seq quot: ( ... elt -- ... ? ) -- ... before after )
 633     [ find drop ] keepd swap
 634     [ cut ] [ f over like ] if* ; inline
 635
 636 : nth* ( n seq -- elt )
 637     [ length 1 - swap - ] [ nth ] bi ; inline
 638
 639 : each-index-from ( ... seq quot: ( ... elt index -- ... ) i -- ... )
 640     -rot sequence-index-operator each-integer-from ; inline
 641
 642 <PRIVATE
 643
 644 : select-by* ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... i elt )
 645     [
 646         [ keep swap ] curry [ dip ] curry
 647         [ [ first 0 ] dip call ] 2keep
 648         [ 2curry 3dip 5 npick pick ] curry
 649     ] [
 650         [ [ 3drop ] [ [ 3drop ] 3dip ] if ] compose
 651     ] bi* compose 1 each-index-from nip swap ; inline
 652
 653 PRIVATE>
 654
 655 : supremum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 656     [ after? ] select-by* ; inline
 657
 658 : infimum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 659     [ before? ] select-by* ; inline
 660
 661 : arg-max ( seq -- n )
 662     [ ] supremum-by* drop ;
 663
 664 : arg-min ( seq -- n )
 665     [ ] infimum-by* drop ;
 666
 667 : ?supremum ( seq/f -- elt/f )
 668     [ f ] [
 669         [ ] [ 2dup and [ max ] [ dupd ? ] if ] map-reduce
 670     ] if-empty ;
 671
 672 : ?infimum ( seq/f -- elt/f )
 673     [ f ] [
 674         [ ] [ 2dup and [ min ] [ dupd ? ] if ] map-reduce
 675     ] if-empty ;
 676
 677 : map-infimum ( seq quot: ( ... elt -- ... elt' ) -- elt' )
 678     [ min ] map-reduce ; inline
 679
 680 : map-supremum ( seq quot: ( ... elt -- ... elt' ) -- elt' )
 681     [ max ] map-reduce ; inline
 682
 683 : change-last ( seq quot -- )
 684     [ index-of-last ] [ change-nth ] bi* ; inline
 685
 686 : change-last-unsafe ( seq quot -- )
 687     [ index-of-last ] [ change-nth-unsafe ] bi* ; inline
 688
 689 : replicate-into ( ... seq quot: ( ... -- ... newelt ) -- ... )
 690     over [ length ] 2dip '[ _ dip _ set-nth-unsafe ] each-integer ; inline
 691
 692 : count* ( ... seq quot: ( ... elt -- ... ? ) -- ... % )
 693     over [ count ] [ length ] bi* / ; inline
 694
 695 : sequence-index-operator-last ( n seq quot -- n quot' )
 696     [ [ nth-unsafe ] curry [ keep ] curry ] dip compose ; inline
 697
 698 : find-last-index-from ( ... n seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 699     '[
 700         _ [ sequence-index-operator-last find-last-integer ] keepd
 701         index/element
 702     ] bounds-check-call ; inline
 703
 704 : find-last-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 705     [ index-of-last ] dip find-last-index-from ; inline
 706
 707 : map-find-last-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 708     [ find-last-index ] (map-find-index) ; inline
 709
 710 :: (start-all) ( seq subseq increment -- indices )
 711     0
 712     [ seq subseq subseq-index-from dup ]
 713     [ [ increment + ] keep ] produce nip ;
 714
 715 : start-all ( seq subseq -- indices )
 716     dup length (start-all) ; inline
 717
 718 : start-all* ( seq subseq -- indices )
 719     1 (start-all) ; inline
 720
 721 : count-subseq ( seq subseq -- n )
 722     start-all length ; inline
 723
 724 : count-subseq* ( seq subseq -- n )
 725     start-all* length ; inline
 726
 727 : assoc-zip-with ( quot: ( key value -- calc ) -- alist )
 728     '[ _ 2keep 2array swap ] assoc-map ; inline
 729
 730 : take-while ( ... seq quot: ( ... elt -- ... ? ) -- head-slice )
 731     [ '[ @ not ] find drop ] keepd swap
 732     [ dup length ] unless* head-slice ; inline
 733
 734 : drop-while ( ... seq quot: ( ... elt -- ... ? ) -- tail-slice )
 735     [ '[ @ not ] find drop ] keepd swap
 736     [ dup length ] unless* tail-slice ; inline
 737
 738 : count-head ( seq quot -- n )
 739     [ not ] compose [ find drop ] keepd length or ; inline
 740
 741 : count-tail ( seq quot -- n )
 742     [ not ] compose [ find-last drop ] keepd
 743     length swap [ - 1 - ] when* ; inline
 744
 745 :: shorten* ( vector n -- seq )
 746     vector n tail
 747     n vector shorten ;
 748
 749 :: interleaved-as ( seq glue exemplar -- newseq )
 750     seq length dup 1 - + 0 max exemplar new-sequence :> newseq
 751     seq [ 2 * newseq set-nth-unsafe ] each-index
 752     seq length 1 - [ 2 * 1 + glue swap newseq set-nth-unsafe ] each-integer
 753     newseq ;
 754
 755 : interleaved ( seq glue -- newseq )
 756     over interleaved-as ;
 757
 758 : extract! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 759     [ dup ] compose over [ length ] keep new-resizable
 760     [ [ push-when ] 2curry reject! ] keep swap like ; inline
 761
 762 : find-pred-loop ( ... i n seq quot: ( ... elt -- ... calc ? ) -- ... calc/f i/f elt/f )
 763     2pick < [
 764         [ nipd call ] 4keep
 765         3 7 0 nrotated
 766         [ [ 3drop ] 2dip rot ]
 767         [ 2drop [ 1 + ] 3dip find-pred-loop ] if
 768     ] [
 769         4drop f f f
 770     ] if ; inline recursive
 771
 772 : find-pred ( ... seq quot: ( ... elt -- ... calc ) pred: ( ... calc -- ... ? ) -- ... calc/f i/f elt/f )
 773     [ 0 ] 3dip
 774     [ [ length check-length ] keep ] 2dip
 775     '[ nth-unsafe _ keep swap _ keep swap ] find-pred-loop swapd ; inline
 776
 777 ! https://en.wikipedia.org/wiki/Maximum_subarray_problem
 778 ! Kadane's algorithm O(n) largest sum in subarray
 779 : max-subarray-sum ( seq -- sum )
 780     [ -1/0. 0 ] dip
 781     [ [ + ] keep max [ max ] keep ] each drop ;
 782
 783 TUPLE: step-slice
 784     { from integer read-only initial: 0 }
 785     { to integer read-only initial: 0 }
 786     { seq read-only }
 787     { step integer read-only } ;
 788
 789 :: <step-slice> ( from/f to/f step seq -- step-slice )
 790     step zero? [ "can't be zero" throw ] when
 791     seq length :> len
 792     step 0 > [
 793         from/f [ 0 ] unless*
 794         to/f [ len ] unless*
 795     ] [
 796         from/f [ len ] unless*
 797         to/f [ 0 ] unless*
 798     ] if
 799     [ dup 0 < [ len + ] when 0 len clamp ] bi@
 800     ! FIXME: make this work with steps
 801     seq dup slice? [ collapse-slice ] when
 802     step step-slice boa ;
 803
 804 M: step-slice virtual-exemplar seq>> ; inline
 805
 806 M: step-slice virtual@
 807     [ step>> * ] [ from>> + ] [ seq>> ] tri ; inline
 808
 809 M: step-slice length
 810     [ to>> ] [ from>> - ] [ step>> ] tri
 811     dup 0 < [ [ neg 0 max ] dip neg ] when /mod
 812     zero? [ 1 + ] unless ; inline
 813
 814 INSTANCE: step-slice virtual-sequence
 815
 816 : 2nested-each* ( seq1 seq-quot: ( n -- seq ) quot: ( a b -- ) -- )
 817     '[
 818         _ keep swap _ with each
 819     ] each ; inline
 820
 821 : 2nested-filter-as* ( seq1 seq-quot quot exemplar -- seq )
 822     [ 2over [ length ] bi@ * ] dip
 823     [
 824         new-resizable
 825         [ [ push? ] curry compose 2nested-each* ] keep
 826     ] keep like ; inline
 827
 828 : 2nested-filter* ( seq1 seq-quot quot -- seq )
 829     pick 2nested-filter-as* ; inline
 830
 831 : 2nested-map-as* ( seq1 seq-quot quot exemplar -- seq )
 832     [ 2over [ length ] bi@ * ] dip
 833     [
 834         new-resizable
 835         [ [ push ] curry compose 2nested-each* ] keep
 836     ] keep like ; inline
 837
 838 : 2nested-map* ( seq1 seq-quot quot -- seq )
 839     pick 2nested-map-as* ; inline
 840
 841
 842 : 2nested-each ( seq1 seq2 quot -- )
 843     swapd '[
 844         swap _ with each
 845     ] with each ; inline
 846
 847 : 2nested-filter-as ( seq1 seq2 quot exemplar -- seq )
 848     [ 2over [ length ] bi@ * ] dip
 849     [
 850         new-resizable
 851         [ [ push? ] curry compose 2nested-each ] keep
 852     ] keep like ; inline
 853
 854 : 2nested-filter ( seq1 seq2 quot -- seq )
 855     pick 2nested-filter-as ; inline
 856
 857 : 2nested-map-as ( seq1 seq2 quot exemplar -- seq )
 858     [ 2over [ length ] bi@ * ] dip
 859     [
 860         new-resizable
 861         [ [ push ] curry compose 2nested-each ] keep
 862     ] keep like ; inline
 863
 864 : 2nested-map ( seq1 seq2 quot -- seq )
 865     pick 2nested-map-as ; inline
 866
 867 : 3nested-each ( seq1 seq2 seq3 quot -- )
 868     [ spin ] dip '[
 869         -rot [
 870             swap _ with with each
 871         ] with with each
 872     ] with with each ; inline
 873
 874 : 3nested-filter-as ( seq1 seq2 seq3 quot exemplar -- seq )
 875     [ 3 nover [ length ] tri@ * * ] dip
 876     [
 877         new-resizable
 878         [ [ push? ] curry compose 3nested-each ] keep
 879     ] keep like ; inline
 880
 881 : 3nested-filter ( seq1 seq2 seq3 quot -- seq )
 882     reach 3nested-filter-as ; inline
 883
 884 : 3nested-map-as ( seq1 seq2 seq3 quot exemplar -- seq )
 885     [ 3 nover [ length ] tri@ * * ] dip
 886     [
 887         new-resizable
 888         [ [ push ] curry compose 3nested-each ] keep
 889     ] keep like ; inline
 890
 891 : 3nested-map ( seq1 seq2 seq3 quot -- seq )
 892     reach 3nested-map-as ; inline
 893
 894 : prev ( n seq -- obj ) [ 1 - ] dip nth ; inline
 895 : ?prev ( n seq -- obj/f ) [ 1 - ] dip ?nth ; inline
 896 : ??prev ( n seq -- obj/f ? ) [ 1 - ] dip ??nth ; inline
 897 : prev-of ( seq n -- obj ) 1 - nth-of ; inline
 898 : ?prev-of ( seq n -- obj/f ) 1 - ?nth-of ; inline
 899 : ??prev-of ( seq n -- obj/f ? ) 1 - ??nth-of ; inline
 900
 901 : prev-identity ( i seq -- identity i seq )
 902     2dup ??prev [ drop 0 ] unless -rot ; inline
 903
 904 : each-prior-identity-from ( ... identity i seq quot: ( ... prior elt -- ... ) -- ... )
 905     '[ [ swap @ ] keep ]
 906     length-operator each-integer-from drop ; inline
 907
 908 : each-prior-from ( ... i seq quot: ( ... prior elt -- ... ) -- ... )
 909     [ prev-identity ] dip each-prior-identity-from ; inline
 910
 911 : each-prior ( ... seq quot: ( ... prior elt -- ... ) -- ... )
 912     0 -rot each-prior-from ; inline
 913
 914 : map-prior-identity-from-as ( ... identity i seq quot: ( ... prior elt -- elt' ) exemplar -- seq' )
 915     [
 916         '[ [ swap @ ] keep swap ] length-operator
 917     ] dip map-integers-from-as nip ; inline
 918
 919 : map-prior-identity-as ( ... identity seq quot: ( ... prior elt -- elt' ) exemplar -- seq' )
 920     [ 0 ] 3dip map-prior-identity-from-as ; inline
 921
 922 : map-prior-from-as ( ... i seq quot: ( ... prior elt -- elt' ) exemplar -- seq' )
 923     [ prev-identity ] 2dip map-prior-identity-from-as ; inline
 924
 925 : map-prior-as ( ... seq quot: ( ... prior elt -- elt' ) exemplar -- seq' )
 926     0 -roll map-prior-from-as ; inline
 927
 928 : map-prior-from ( ... i seq quot: ( ... prior elt -- elt' ) -- seq' )
 929     over map-prior-from-as ; inline
 930
 931 : map-prior ( ... seq quot: ( ... prior elt -- elt' ) -- seq' )
 932     over map-prior-as ; inline
 933
 934 TUPLE: virtual-zip-index seq ;
 935
 936 C: <zip-index> virtual-zip-index
 937
 938 M: virtual-zip-index length seq>> length ; inline
 939
 940 M: virtual-zip-index nth-unsafe
 941     over [ seq>> nth-unsafe ] [ 2array ] bi* ; inline
 942
 943 INSTANCE: virtual-zip-index immutable-sequence