extra/sequences/extras/extras.factor

   1 USING: accessors arrays assocs combinators generalizations
   2 grouping growable heaps kernel math math.order ranges sequences
   3 sequences.private shuffle sorting splitting vectors ;
   4 IN: sequences.extras
   5
   6 : find-all ( ... seq quot: ( ... elt -- ... ? ) -- ... elts )
   7     [ <enumerated> ] dip '[ nip @ ] assoc-filter ; inline
   8
   9 :: subseq* ( from to seq -- subseq )
  10     seq length :> len
  11     from [ dup 0 < [ len + ] when ] [ 0 ] if*
  12     to [ dup 0 < [ len + ] when ] [ len ] if*
  13     [ 0 len clamp ] bi@ dupd max seq subseq ;
  14
  15 : safe-subseq ( from to seq -- subseq )
  16     [ length '[ 0 _ clamp ] bi@ ] keep subseq ;
  17
  18 : all-subseqs ( seq -- seqs )
  19     dup length [1..b] [ clump ] with map concat ;
  20
  21 : each-subseq ( ... seq quot: ( ... subseq -- ... ) -- ... )
  22     [ dup length [ [0..b] ] [ ] bi ] dip '[
  23         dup _ (a..b] [ rot [ subseq _ call ] keep ] with each
  24     ] each drop ; inline
  25
  26 : map-like ( seq exemplar -- seq' )
  27     '[ _ like ] map ; inline
  28
  29 : filter-all-subseqs-range ( ... seq range quot: ( ... subseq -- ... ? ) -- seq )
  30     [
  31         '[ <clumps> _ filter ] with map concat
  32     ] keepdd map-like ; inline
  33
  34 : filter-all-subseqs ( ... seq quot: ( ... subseq -- ... ? ) -- seq )
  35     [ dup length [1..b] ] dip filter-all-subseqs-range ; inline
  36
  37 :: longest-subseq ( seq1 seq2 -- subseq )
  38     seq1 length :> len1
  39     seq2 length :> len2
  40     0 :> n!
  41     0 :> end!
  42     len1 1 + [ len2 1 + 0 <array> ] replicate :> table
  43     len1 [1..b] [| x |
  44         len2 [1..b] [| y |
  45             x 1 - seq1 nth-unsafe
  46             y 1 - seq2 nth-unsafe = [
  47                 y 1 - x 1 - table nth-unsafe nth-unsafe 1 + :> len
  48                 len y x table nth-unsafe set-nth-unsafe
  49                 len n > [ len n! x end! ] when
  50             ] [ 0 y x table nth-unsafe set-nth-unsafe ] if
  51         ] each
  52     ] each end n - end seq1 subseq ;
  53
  54 : pad-longest ( seq1 seq2 elt -- seq1 seq2 )
  55     [ 2dup max-length ] dip [ pad-tail ] 2curry bi@ ;
  56
  57 : pad-center ( seq n elt -- padded )
  58     swap pick length [-] [ drop ] [
  59         [ 2/ ] [ over - ] bi rot '[ _ <repetition> ] bi@
  60         pick surround-as
  61     ] if-zero ;
  62
  63 : change-nths ( ... indices seq quot: ( ... elt -- ... elt' ) -- ... )
  64     [ change-nth ] 2curry each ; inline
  65
  66 : push-if-index ( ..a elt i quot: ( ..a elt i -- ..b ? ) accum -- ..b )
  67     [ keepd ] dip rot [ push ] [ 2drop ] if ; inline
  68
  69 : push-if* ( ..a elt quot: ( ..a elt -- ..b obj/f ) accum -- ..b )
  70     [ call ] dip [ push ] [ drop ] if* ; inline
  71
  72 : push? ( elt/f accum -- )
  73     over [ push ] [ 2drop ] if ; inline
  74
  75 <PRIVATE
  76
  77 : (index-selector-as) ( quot length exampler -- selector accum )
  78     new-resizable [ [ push-if-index ] 2curry ] keep ; inline
  79
  80 : (selector-as*) ( quot length exemplar -- selector accum )
  81     new-resizable [ [ push-if* ] 2curry ] keep ; inline
  82
  83 PRIVATE>
  84
  85 : index-selector-as ( quot exemplar -- selector accum )
  86     [ length ] keep (index-selector-as) ; inline
  87
  88 : index-selector ( quot -- selector accum )
  89     V{ } index-selector-as ; inline
  90
  91 : selector-as* ( quot exemplar -- selector accum )
  92     [ length ] keep (selector-as*) ; inline
  93
  94 : selector* ( quot -- selector accum ) V{ } selector-as* ; inline
  95
  96 : filter-index-as ( ... seq quot: ( ... elt i -- ... ? ) exemplar -- ... seq' )
  97     pick length over [ (index-selector-as) [ each-index ] dip ] 2curry dip like ; inline
  98
  99 : filter-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... seq' )
 100     over filter-index-as ; inline
 101
 102 : even-indices ( seq -- seq' )
 103     [ length 1 + 2/ ] keep [
 104         [ [ 2 * ] dip nth-unsafe ] curry
 105     ] keep map-integers-as ;
 106
 107 : odd-indices ( seq -- seq' )
 108     [ length 2/ ] keep [
 109         [ [ 2 * 1 + ] dip nth-unsafe ] curry
 110     ] keep map-integers-as ;
 111
 112 : compact ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 113     [ split-when harvest ] dip join ; inline
 114
 115 : collapse ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 116     [ split-when ] dip
 117     [ [ harvest ] dip join ]
 118     [ [ first empty? ] dip [ prepend ] curry when ]
 119     [ [ last empty? ] dip [ append ] curry when ]
 120     2tri ; inline
 121
 122 :: slice-when ( seq quot: ( elt -- ? ) -- seq' )
 123     seq length :> len
 124     0 [ len dupd < ] [
 125         dup seq quot find-from drop
 126         [ 2dup = [ 1 + ] when ] [ len ] if*
 127         [ seq <slice> ] keep len or swap
 128     ] produce nip ; inline
 129
 130 : ?<slice> ( from/f to/f sequence -- slice )
 131     [ [ 0 ] unless* ] 2dip
 132     over [ nip [ length ] [ ] bi ] unless
 133     <slice> ; inline
 134
 135 : sequence>slice ( sequence -- slice )
 136     [ drop 0 ] [ length ] [ ] tri <slice> ; inline
 137
 138 : slice-order-by-from ( slice1 slice2 -- slice-lt slice-gt )
 139     2dup [ from>> ] bi@ > [ swap ] when ; inline
 140
 141 : ordered-slices-range ( slice-lt slice-gt -- to from )
 142     [ to>> ] [ from>> ] bi* ;
 143
 144 : unordered-slices-range ( slice1 slice2 -- to from )
 145     slice-order-by-from ordered-slices-range ;
 146
 147 : ordered-slices-overlap? ( slice-lt slice-gt -- ? )
 148     ordered-slices-range > ; inline
 149
 150 : unordered-slices-overlap? ( slice1 slice2 -- ? )
 151     unordered-slices-range > ; inline
 152
 153 : slices-overlap? ( slice1 slice2 -- ? )
 154     unordered-slices-overlap? ;
 155
 156 : ordered-slices-touch? ( slice-lt slice-gt -- ? )
 157     ordered-slices-range >= ; inline
 158
 159 : unordered-slices-touch? ( slice1 slice2 -- ? )
 160     unordered-slices-range >= ; inline
 161
 162 : slices-touch? ( slice1 slice2 -- ? )
 163     unordered-slices-touch? ;
 164
 165 ERROR: slices-don't-touch slice1 slice2 ;
 166
 167 : merge-slices ( slice1 slice2 -- slice/* )
 168     slice-order-by-from
 169     2dup ordered-slices-touch? [
 170         [ from>> ] [ [ to>> ] [ seq>> ] bi ] bi* <slice>
 171     ] [
 172         slices-don't-touch
 173     ] if ;
 174
 175 : rotate ( seq n -- seq' )
 176     over length mod dup 0 >= [ cut ] [ abs cut* ] if prepend ;
 177
 178 ERROR: underlying-mismatch slice1 slice2 ;
 179
 180 : ensure-same-underlying ( slice1 slice2 -- slice1 slice2 )
 181     2dup [ seq>> ] bi@ eq? [ underlying-mismatch ] unless ;
 182
 183 : span-slices ( slice1 slice2 -- slice )
 184     ensure-same-underlying
 185     [ [ from>> ] bi@ min ]
 186     [ [ to>> ] bi@ max ]
 187     [ drop seq>> ] 2tri <slice> ;
 188
 189 : ?span-slices ( slice1/f slice2/f -- slice )
 190     2dup and [ span-slices ] [ or ] if ;
 191
 192 :: rotate! ( seq n -- )
 193     seq length :> len
 194     n len mod dup 0 < [ len + ] when seq bounds-check drop 0 over
 195     [ 2dup = ] [
 196         [ seq exchange-unsafe ] [ [ 1 + ] bi@ ] 2bi
 197         dup len = [ drop over ] when
 198         2over = [ -rot nip over ] when
 199     ] until 3drop ;
 200
 201 : all-rotations ( seq -- seq' )
 202     dup length <iota> [ rotate ] with map ;
 203
 204 <PRIVATE
 205
 206 : (appender-for) ( quot length exemplar -- appender accum )
 207     new-resizable [ [ push-all ] curry compose ] keep ; inline
 208
 209 PRIVATE>
 210
 211 : appender-for ( quot exemplar -- appender accum )
 212     [ length ] keep (appender-for) ; inline
 213
 214 : appender ( quot -- appender accum )
 215     V{ } appender-for ; inline
 216
 217 : map-concat-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 218     [ appender-for [ each ] dip ] keep like ; inline
 219
 220 : >resizable ( seq -- accum ) ! fixes map-concat "cannot apply call to run-time..."
 221     [ length ] keep [ new-resizable ] [ append! ] bi ;
 222
 223 : map-concat ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 224     over empty? [ 2drop { } ] [
 225         [ [ first ] dip call ] 2keep rot [
 226             >resizable [ '[ @ _ push-all ] 1 each-from ] keep
 227         ] keep like
 228     ] if ; inline
 229
 230 : map-filter-as ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) exemplar -- ... subseq )
 231     reach length over
 232     [ (selector-as) [ compose each ] dip ] 2curry dip like ; inline
 233
 234 : map-filter ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) -- ... subseq )
 235     pick map-filter-as ; inline
 236
 237 : map-sift ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 238     [ ] map-filter ; inline
 239
 240 : map-harvest ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 241     [ empty? not ] map-filter ; inline
 242
 243 : (each-integer-with-previous) ( ... prev i n quot: ( ... i -- ... ) -- ... )
 244     2over < [
 245         [ nip call ] 4keep nipdd
 246         [ 1 + ] 2dip (each-integer-with-previous)
 247     ] [
 248         4drop
 249     ] if ; inline recursive
 250
 251 : each-integer-with-previous ( ... n quot: ( ... i -- ... ) -- ... )
 252     [ f 0 ] 2dip (each-integer-with-previous) ; inline
 253
 254 : (collect-with-previous) ( quot into -- quot' )
 255     [ [ keep ] dip [ set-nth-unsafe ] keepdd ] 2curry ; inline
 256
 257 : collect-with-previous ( n quot into --  )
 258     (collect-with-previous) each-integer-with-previous ; inline
 259
 260 : map-integers-with ( ... len quot: ( ... prev i -- ... elt ) exemplar -- ... newseq )
 261     overd [ [ collect-with-previous ] keep ] new-like ; inline
 262
 263 : map-with-previous-as ( ... seq quot: ( ... elt prev/f -- ... newelt ) exemplar -- ... newseq )
 264     [ length-operator ] dip map-integers-with ; inline
 265
 266 : map-with-previous ( ... seq quot: ( ... elt prev/f -- ... newelt ) -- ... newseq )
 267     over map-with-previous-as ; inline
 268
 269 : setup-each-from ( seq quot -- n quot )
 270     [ [ length ] keep [ nth-unsafe ] curry ] dip compose ; inline
 271
 272 : map-from-as ( ... seq quot: ( ... elt -- ... newelt ) from exemplar -- ... newseq )
 273     -rotd [ sequence-operator nipd ] dip map-integers-from-as ; inline
 274
 275 : map-from ( ... seq quot: ( ... elt -- ... newelt ) from -- ... newseq )
 276     pick map-from-as ; inline
 277
 278 : map-if ( ... seq if-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) -- ... newseq )
 279     '[ dup @ _ when ] map ; inline
 280
 281 : reduce-from ( ... seq identity quot: ( ... prev elt -- ... next ) from -- ... result )
 282     [ swap ] 2dip each-from ; inline
 283
 284 : 2reduce-from ( ... seq1 seq2 identity quot: ( ... prev elt1 elt2 -- ... next ) i -- ... result )
 285     [ -rot ] 2dip 2each-from ; inline
 286
 287 : 0accumulate-as ( ... seq quot: ( ... prev elt -- ... next ) exemplar -- ... newseq )
 288     pick empty? [
 289         2nip clone
 290     ] [
 291         [ 0 ] 2dip
 292         [ swapd [ dup ] compose ] dip map-as nip
 293     ] if ; inline
 294
 295 : 0accumulate ( ... seq quot: ( ... prev elt -- ... next ) -- ... final newseq )
 296     over 0accumulate-as ; inline
 297
 298 : occurrence-count-by ( seq quot: ( elt -- elt' ) -- hash seq' )
 299     '[ nip @ over inc-at* ] [ H{ } clone ] 2dip 0accumulate ; inline
 300
 301 : occurrence-count ( seq -- hash seq' )
 302     [ ] occurrence-count-by ; inline
 303
 304 : nth-index ( n obj seq -- i )
 305     [ = dup [ drop 1 - dup 0 < ] when ] with find drop nip ;
 306
 307 : progressive-index-by-as ( seq1 seq2 quot exemplar -- hash seq' )
 308     [
 309         pick length '[
 310             tuck [ @ over inc-at* ] 2dip swap nth-index _ or
 311         ] [ H{ } clone ] 3dip with
 312     ] dip map-as ; inline
 313
 314 : progressive-index-by ( seq1 seq2 quot -- hash seq' )
 315     { } progressive-index-by-as ; inline
 316
 317 : progressive-index ( seq1 seq2 -- hash seq' )
 318     [ ] progressive-index-by ; inline
 319
 320 : 0reduce ( seq quot: ( prev elt -- next ) -- result )
 321     [ 0 ] dip reduce ; inline
 322
 323 : ?unclip ( seq -- rest/f first/f )
 324     [ f f ] [ unclip ] if-empty ;
 325
 326 : 1reduce ( seq quot: ( prev elt -- next ) -- result )
 327     [ ?unclip ] dip reduce ; inline
 328
 329 : reduce-of ( seq quot: ( prev elt -- next ) identity -- result )
 330     swap reduce ; inline
 331
 332 : accumulate-of ( seq quot: ( prev elt -- next ) identity -- result )
 333     swap accumulate ; inline
 334
 335 <PRIVATE
 336
 337 : push-map-when* ( ..a elt quot: ( ..a elt -- ..b obj ? ) accum -- ..b )
 338     [ call ] dip swap [ push ] [ 2drop ] if ; inline
 339
 340 : filter-mapper-for* ( quot length exemplar -- filter-mapper accum )
 341     new-resizable [ [ push-map-when* ] 2curry ] keep ; inline
 342
 343 : 1push-map-when ( ..a filter-quot: ( ..a -- ..b ? ) map-quot: ( ..a -- ..b obj ) accum -- ..b )
 344     [ keep over ] 2dip [ when ] dip rot [ push ] [ 2drop ] if ; inline
 345
 346 : 1filter-mapper-for ( filter-quot map-quot length exemplar -- filter-mapper accum )
 347     new-resizable [ [ 1push-map-when ] 3curry ] keep ; inline
 348
 349 : 2push-map-when ( ..a filter-quot: ( ..a -- ..b ? ) map-quot: ( ..a -- ..b obj ) accum -- ..b )
 350     [ 2keep rot ] 2dip '[ [ @ _ push ] [ 2drop ] if ] call ; inline
 351
 352 : 2filter-mapper-for ( filter-quot map-quot length exemplar -- filter-mapper accum )
 353     new-resizable [ [ 2push-map-when ] 3curry ] keep ; inline
 354
 355 PRIVATE>
 356
 357 : filter-map-as* ( ... seq quot: ( ..a elt -- ..b obj ? ) exemplar -- ... newseq )
 358     pick length over
 359     [ filter-mapper-for* [ each ] dip ] 2curry dip like ; inline
 360
 361 : filter-map* ( ... seq quot: ( ... elt -- ... newelt ? ) -- ... newseq )
 362     over filter-map-as* ; inline
 363
 364 : reject-map-as* ( ... seq quot: ( ... elt -- ... newelt ? ) exemplar -- ... newseq )
 365     [ [ not ] compose ] dip filter-map-as* ; inline
 366
 367 : reject-map* ( ... seq quot: ( ... elt -- ... newelt ? ) -- ... newseq )
 368     over reject-map-as* ; inline
 369
 370 : 2filter-map-as* ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... obj ? ) exemplar -- ... newseq )
 371     reach length over
 372     [ filter-mapper-for* [ 2each ] dip ] 2curry dip like ; inline
 373
 374 : 2filter-map* ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... newseq )
 375     pick 2filter-map-as* ; inline
 376
 377 : 2reject-map-as* ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... obj ? ) exemplar -- ... newseq )
 378     [ [ not ] compose ] dip 2filter-map-as* ; inline
 379
 380 : 2reject-map* ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... obj ? ) -- ... newseq )
 381     pick 2reject-map-as* ; inline
 382
 383
 384 : filter-map-as ( ... seq filter-quot: ( ..a elt -- ..b ? ) map-quot: ( obj -- obj' ) exemplar -- ... newseq )
 385     reach length over
 386     [ 1filter-mapper-for [ each ] dip ] 2curry dip like ; inline
 387
 388 : filter-map ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( obj -- obj' ) -- ... newseq )
 389     pick filter-map-as ; inline
 390
 391 : reject-map-as ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( obj -- obj' ) exemplar -- ... newseq )
 392     [ [ not ] compose ] 2dip filter-map-as ; inline
 393
 394 : reject-map ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( obj -- obj' ) -- ... newseq )
 395     pick reject-map-as ; inline
 396
 397 : 2filter-map-as ( ... seq1 seq2 filter-quot: ( ... elt1 elt2 -- ... ? ) map-quot: ( elt1 elt2 -- obj ) exemplar -- ... newseq )
 398     5 npick length over
 399     [ 2filter-mapper-for [ 2each ] dip ] 2curry dip like ; inline
 400
 401 : 2filter-map ( ... seq1 seq2 filter-quot: ( ... elt1 elt2 -- ... ? ) map-quot: ( elt1 elt2 -- obj ) -- ... newseq )
 402     reach 2filter-map-as ; inline
 403
 404 : 2reject-map-as ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) map-quot: ( elt1 elt2 -- obj ) exemplar -- ... newseq )
 405     [ [ not ] compose ] 2dip 2filter-map-as ; inline
 406
 407 : 2reject-map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) map-quot: ( elt1 elt2 -- obj ) -- ... newseq )
 408     pick 2reject-map-as ; inline
 409
 410
 411 : 2filter-as ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) exemplar -- ... newseq )
 412     [
 413         pick [ length ] keep
 414         [ (2selector-as) [ 2each ] dip ] 2curry call
 415     ] dip like ; inline
 416
 417 : 2filter ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
 418     pick 2filter-as ; inline
 419
 420 : 2reject-as ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) exemplar -- ... newseq )
 421     [ [ not ] compose ] dip 2filter-as ; inline
 422
 423 : 2reject ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
 424     pick 2reject-as ; inline
 425
 426 : 2map-sum ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... n ) -- ... n )
 427     [ 0 ] 3dip [ dip + ] curry [ rot ] prepose 2each ; inline
 428
 429 : 2count ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... n )
 430     [ 1 0 ? ] compose 2map-sum ; inline
 431
 432 : 3each-from
 433     ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... ) i -- ... )
 434     [ 3length-operator ] dip -rot each-integer-from ; inline
 435
 436 : 3map-reduce
 437     ( ..a seq1 seq2 seq3 map-quot: ( ..a elt1 elt2 elt3 -- ..b intermediate ) reduce-quot: ( ..b prev intermediate -- ..a next ) -- ..a result )
 438     [ [ [ [ first ] tri@ ] 3keep ] dip [ 3dip ] keep ] dip compose 1 3each-from ; inline
 439
 440 : round-robin ( seq -- newseq )
 441     [ { } ] [
 442         [ longest length <iota> ] keep
 443         [ [ ?nth ] with map ] curry map concat sift
 444     ] if-empty ;
 445
 446 : sift-as ( seq exemplar -- newseq )
 447     [ ] swap filter-as ;
 448
 449 : sift! ( seq -- newseq )
 450     [ ] filter! ;
 451
 452 : harvest-as ( seq exemplar -- newseq )
 453     [ empty? not ] swap filter-as ;
 454
 455 : harvest! ( seq -- newseq )
 456     [ empty? ] reject! ;
 457
 458 : head-as ( seq n exemplar -- seq' )
 459     [ head-slice ] [ like ] bi* ; inline
 460
 461 : head*-as ( seq n exemplar -- seq' )
 462     [ head-slice* ] [ like ] bi* ; inline
 463
 464 : tail-as ( seq n exemplar -- seq' )
 465     [ tail-slice ] [ like ] bi* ; inline
 466
 467 : tail*-as ( seq n exemplar -- seq' )
 468     [ tail-slice* ] [ like ] bi* ; inline
 469
 470 : trim-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... newseq )
 471     [ trim-slice ] [ like ] bi* ; inline
 472
 473 : ?trim ( seq quot: ( elt -- ? ) -- seq/newseq )
 474     over empty? [ drop ] [
 475         over [ first-unsafe ] [ last-unsafe ] bi pick either?
 476         [ trim ] [ drop ] if
 477     ] if ; inline
 478
 479 : ?trim-head ( seq quot: ( elt -- ? ) -- seq/newseq )
 480     over empty? [ drop ] [
 481         over first-unsafe over call
 482         [ trim-head ] [ drop ] if
 483     ] if ; inline
 484
 485 : ?trim-tail ( seq quot: ( elt -- ? ) -- seq/newseq )
 486     over empty? [ drop ] [
 487         over last-unsafe over call
 488         [ trim-tail ] [ drop ] if
 489     ] if ; inline
 490
 491 : unsurround ( newseq seq2 seq3 -- seq1 )
 492     [ ?head drop ] [ ?tail drop ] bi* ;
 493
 494 : >string-list ( seq -- seq' )
 495     [ "\"" 1surround ] map "," join ;
 496
 497 : with-string-lines ( str quot -- str' )
 498     [ string-lines ] dip map "\n" join ; inline
 499
 500 : prepend-lines-with-spaces ( str -- str' )
 501     [ "    " prepend ] with-string-lines ;
 502
 503 : one? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 504     [ find ] 2keep rot [
 505         [ 1 + ] 2dip find-from drop not
 506     ] [ 3drop f ] if ; inline
 507
 508 : map-index! ( ... seq quot: ( ... elt index -- ... newelt ) -- ... seq )
 509     over [ [ sequence-index-operator ] dip collect ] keep ; inline
 510
 511 <PRIVATE
 512
 513 : 2sequence-index-iterator ( seq1 seq2 quot -- n quot' )
 514     [ 2length-iterator [ keep ] curry ] dip compose ; inline
 515
 516 PRIVATE>
 517
 518 : 2each-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... ) -- ... )
 519     2sequence-index-iterator each-integer ; inline
 520
 521 : 2map-into ( seq1 seq2 quot into -- )
 522     [ 2length-operator ] dip collect ; inline
 523
 524 : 2map! ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... seq1 )
 525     pick [ 2map-into ] keep ; inline
 526
 527 : 2map-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... newelt ) -- ... newseq )
 528     pick [ 2sequence-index-iterator ] dip map-integers-as ; inline
 529
 530 TUPLE: evens { seq read-only } ;
 531
 532 C: <evens> evens
 533
 534 M: evens length seq>> length 1 + 2/ ; inline
 535
 536 M: evens virtual@ [ 2 * ] [ seq>> ] bi* ; inline
 537
 538 M: evens virtual-exemplar seq>> ; inline
 539
 540 INSTANCE: evens virtual-sequence
 541
 542 TUPLE: odds { seq read-only } ;
 543
 544 C: <odds> odds
 545
 546 M: odds length seq>> length 2/ ; inline
 547
 548 M: odds virtual@ [ 2 * 1 + ] [ seq>> ] bi* ; inline
 549
 550 M: odds virtual-exemplar seq>> ; inline
 551
 552 INSTANCE: odds virtual-sequence
 553
 554 : until-empty ( seq quot -- )
 555     [ dup empty? ] swap until drop ; inline
 556
 557 <PRIVATE
 558
 559 : push-index-if ( ..a elt i quot: ( ..a elt -- ..b ? ) accum -- ..b )
 560     [ dip ] dip rot [ push ] [ 2drop ] if ; inline
 561
 562 PRIVATE>
 563
 564 : arg-where ( ... seq quot: ( ... elt -- ... ? ) -- ... indices )
 565     over length <vector> [
 566         [ push-index-if ] 2curry each-index
 567     ] keep ; inline
 568
 569 : arg-sort ( seq -- indices )
 570     zip-index sort-keys values ;
 571
 572 : first= ( seq elt -- ? ) [ first ] dip = ; inline
 573 : second= ( seq elt -- ? ) [ second ] dip = ; inline
 574 : third= ( seq elt -- ? ) [ third ] dip = ; inline
 575 : fourth= ( seq elt -- ? ) [ fourth ] dip = ; inline
 576 : last= ( seq elt -- ? ) [ last ] dip = ; inline
 577 : nth= ( n seq elt -- ? ) [ nth ] dip = ; inline
 578
 579 : first? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ first ] dip call ; inline
 580 : second? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ second ] dip call ; inline
 581 : third? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ third ] dip call ; inline
 582 : fourth? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ fourth ] dip call ; inline
 583 : last? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ last ] dip call ; inline
 584 : nth? ( ... n seq quot: ( ... elt -- ... ? ) -- ... ? ) [ nth ] dip call ; inline
 585
 586 : loop>sequence** ( ... quot: ( ... -- ... obj ? ) exemplar -- ... seq )
 587     [ ] swap produce-as nip ; inline
 588
 589 : loop>array** ( ... quot: ( ... -- ... obj ? ) -- ... array )
 590     { } loop>sequence** ; inline
 591
 592 : loop>sequence* ( ... quot: ( ... -- ... obj ? ) exemplar -- ... seq )
 593     [ t ] [ '[ [ _ dip ] [ f f f ] if* ] [ swap ] ] [ produce-as 2nip ] tri* ; inline
 594
 595 : loop>array* ( ... quot: ( ... -- ... obj ? ) -- ... array )
 596     { } loop>sequence* ; inline
 597
 598 : loop>sequence ( ... quot: ( ... -- ... obj/f ) exemplar -- ... seq )
 599     [ [ dup ] compose [ ] ] dip produce-as nip ; inline
 600
 601 : loop>array ( ... quot: ( ... -- ... obj/f ) -- ... array )
 602     { } loop>sequence ; inline
 603
 604 : zero-loop>sequence ( ... quot: ( ... n -- ... obj/f ) exemplar -- ... seq )
 605     [ 0 ] [ '[ _ keep 1 + swap ] ] [ loop>sequence ] tri* nip ; inline
 606
 607 : zero-loop>array ( quot: ( ..a n -- ..a obj ) -- seq )
 608     { } zero-loop>sequence ; inline
 609
 610 : iterate-heap-while ( heap quot1: ( value key -- slurp? ) quot2: ( value key -- obj/f ) -- obj/f loop? )
 611     pick heap-empty?
 612     [ 3drop f f ]
 613     [
 614         [ [ heap-peek ] 2dip drop 2keep ]
 615         [
 616             nip ! ( pop? value key heap quot2 )
 617             5roll [
 618                 swap heap-pop* call( value key -- obj/f ) t
 619             ] [
 620                 4drop f f
 621             ] if
 622         ] 3bi
 623     ] if ; inline
 624
 625 : slurp-heap-while-map ( heap quot1: ( value key -- slurp? ) quot2: ( value key -- obj/f ) -- seq )
 626     '[ _ _ _ iterate-heap-while ] loop>array* ; inline
 627
 628 : heap>pairs ( heap -- pairs )
 629     [ 2drop t ] [ swap 2array ] slurp-heap-while-map ;
 630
 631 : map-zip-swap ( quot: ( x -- y ) -- alist )
 632     '[ _ keep ] map>alist ; inline
 633
 634 : ?heap-pop-value>array ( heap -- array )
 635     dup heap-empty? [ drop { } ] [ heap-pop drop 1array ] if ;
 636
 637 <PRIVATE
 638
 639 : (reverse) ( seq -- newseq )
 640     dup [ length ] keep new-sequence
 641     [ 0 swap copy-unsafe ] keep reverse! ;
 642
 643 PRIVATE>
 644
 645 : reverse-as ( seq exemplar -- newseq )
 646     [ (reverse) ] [ like ] bi* ;
 647
 648 : map-product ( ... seq quot: ( ... elt -- ... n ) -- ... n )
 649     [ 1 ] 2dip [ dip * ] with-assoc each ; inline
 650
 651 : insert-nth! ( elt n seq -- )
 652     [ length ] keep ensure swap pick (a..b]
 653     over '[ [ 1 + ] keep _ move-unsafe ] each
 654     set-nth-unsafe ;
 655
 656 : set-nths ( value indices seq -- )
 657     swapd '[ _ swap _ set-nth ] each ; inline
 658
 659 : set-nths-unsafe ( value indices seq -- )
 660     swapd '[ _ swap _ set-nth-unsafe ] each ; inline
 661
 662 <PRIVATE
 663
 664 : (map-find-index) ( seq quot find-quot -- result i elt )
 665     [ [ f ] 2dip [ [ nip ] 2dip call dup ] curry ] dip call
 666     [ [ [ drop f ] unless ] keep ] dip ; inline
 667
 668 PRIVATE>
 669
 670 : map-find-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 671     [ find-index ] (map-find-index) ; inline
 672
 673 : filter-length ( seq n -- seq' ) '[ length _ = ] filter ;
 674
 675 : all-shortest ( seqs -- seqs' ) dup shortest length filter-length ;
 676
 677 : all-longest ( seqs -- seqs' ) dup longest length filter-length ;
 678
 679 <PRIVATE
 680
 681 : nth-unsafe-of ( seq n -- elt ) swap nth-unsafe ; inline
 682 : set-nth-unsafe-of ( seq n elt -- seq ) spin [ set-nth-unsafe ] keep ; inline
 683 : set-length-of ( seq n -- seq ) over set-length ; inline
 684
 685 : move-unsafe-of ( seq to from -- seq )
 686     2dup = [
 687         2drop
 688     ] [
 689         overd nth-unsafe-of set-nth-unsafe-of
 690     ] if ; inline
 691
 692 : move-backward-of ( seq shift from to -- seq )
 693     2dup = [
 694         3drop
 695     ] [
 696         [ [ [ + ] keep move-unsafe-of ] 2keep 1 + ] dip move-backward-of
 697     ] if ;
 698
 699 : open-slice-of ( seq shift from -- seq )
 700     over 0 = [
 701         2drop
 702     ] [
 703         [ ] [ drop [ length ] dip + ] 3bi
 704         [ pick length [ over - ] dip move-backward-of ] dip
 705         set-length-of
 706     ] if ;
 707
 708 PRIVATE>
 709
 710 : index-of ( seq obj -- n ) '[ _ = ] find drop ;
 711
 712 ERROR: slice-error-of from to seq ;
 713
 714 : check-slice-of ( seq from to -- seq from to )
 715     over 0 < [ slice-error-of ] when
 716     dup reach length > [ slice-error-of ] when
 717     2dup > [ slice-error-of ] when ; inline
 718
 719 : delete-slice-of ( seq from to -- seq )
 720     check-slice-of over [ - ] dip open-slice-of ;
 721
 722 : remove-nth-of ( seq n -- seq' )
 723     [ dup 1 + rot snip-slice ] keepd append-as ;
 724
 725 : remove-nth-of! ( seq n -- seq )
 726     dup 1 + delete-slice-of ;
 727
 728 : snip-of ( seq from to -- head tail )
 729     [ head ] [ tail ] bi-curry* bi ; inline
 730
 731 : snip-slice-of ( seq from to -- head tail )
 732     [ head-slice ] [ tail-slice ] bi-curry* bi ; inline
 733
 734 : remove-first ( obj seq -- seq' )
 735     [ index ] keep over [ remove-nth ] [ nip ] if ;
 736
 737 : remove-first-of ( seq obj -- seq' )
 738     dupd index-of [ remove-nth-of ] when* ;
 739
 740 : remove-first! ( obj seq -- seq )
 741     [ index ] keep over [ remove-nth! ] [ nip ] if ;
 742
 743 : remove-last ( obj seq -- seq' )
 744     [ last-index ] keep over [ remove-nth ] [ nip ] if ;
 745
 746 : remove-last! ( obj seq -- seq )
 747     [ last-index ] keep over [ remove-nth! ] [ nip ] if ;
 748
 749 : member-of? ( seq elt -- ? )
 750     [ = ] curry any? ;
 751
 752 : member-eq-of? ( seq elt -- ? )
 753     [ eq? ] curry any? ;
 754
 755 : remove-of ( seq elt -- newseq )
 756     [ = ] curry reject ;
 757
 758 : remove-eq-of ( seq elt -- newseq )
 759     [ eq? ] curry reject ;
 760
 761 : ?first2 ( seq -- first/f second/f )
 762     dup length {
 763         { 0 [ drop f f ] }
 764         { 1 [ first-unsafe f ] }
 765         [ drop first2-unsafe ]
 766     } case ;
 767
 768 : ?first3 ( seq -- first/f second/f third/f )
 769     dup length {
 770         { 0 [ drop f f f ] }
 771         { 1 [ first-unsafe f f ] }
 772         { 2 [ first2-unsafe f ] }
 773         [ drop first3-unsafe ]
 774     } case ;
 775
 776 : ?first4 ( seq -- first/f second/f third/f fourth/f )
 777     dup length {
 778         { 0 [ drop f f f f ] }
 779         { 1 [ first-unsafe f f f ] }
 780         { 2 [ first2-unsafe f f ] }
 781         { 3 [ first3-unsafe f ] }
 782         [ drop first4-unsafe ]
 783     } case ;
 784
 785 : cut-when ( ... seq quot: ( ... elt -- ... ? ) -- ... before after )
 786     [ find drop ] keepd swap
 787     [ cut ] [ f over like ] if* ; inline
 788
 789 : nth* ( n seq -- elt )
 790     [ length 1 - swap - ] [ nth ] bi ; inline
 791
 792 : each-index-from ( ... seq quot: ( ... elt index -- ... ) i -- ... )
 793     -rot sequence-index-operator each-integer-from ; inline
 794
 795 <PRIVATE
 796
 797 : select-by* ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... i elt )
 798     [
 799         [ keep swap ] curry [ dip ] curry
 800         [ [ first 0 ] dip call ] 2keep
 801         [ 2curry 3dip 5 npick pick ] curry
 802     ] [
 803         [ [ 3drop ] [ [ 3drop ] 3dip ] if ] compose
 804     ] bi* compose 1 each-index-from nip swap ; inline
 805
 806 PRIVATE>
 807
 808 : supremum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 809     [ after? ] select-by* ; inline
 810
 811 : infimum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 812     [ before? ] select-by* ; inline
 813
 814 : arg-max ( seq -- n )
 815     [ ] supremum-by* drop ;
 816
 817 : arg-min ( seq -- n )
 818     [ ] infimum-by* drop ;
 819
 820 : ?supremum ( seq/f -- elt/f )
 821     [ f ] [
 822         [ ] [ 2dup and [ max ] [ dupd ? ] if ] map-reduce
 823     ] if-empty ;
 824
 825 : ?infimum ( seq/f -- elt/f )
 826     [ f ] [
 827         [ ] [ 2dup and [ min ] [ dupd ? ] if ] map-reduce
 828     ] if-empty ;
 829
 830 : map-infimum ( seq quot: ( ... elt -- ... elt' ) -- elt' )
 831     [ min ] map-reduce ; inline
 832
 833 : map-supremum ( seq quot: ( ... elt -- ... elt' ) -- elt' )
 834     [ max ] map-reduce ; inline
 835
 836 : change-last ( seq quot -- )
 837     [ index-of-last ] [ change-nth ] bi* ; inline
 838
 839 : change-last-unsafe ( seq quot -- )
 840     [ index-of-last ] [ change-nth-unsafe ] bi* ; inline
 841
 842 : replicate-into ( ... seq quot: ( ... -- ... newelt ) -- ... )
 843     over [ length ] 2dip '[ _ dip _ set-nth-unsafe ] each-integer ; inline
 844
 845 : count* ( ... seq quot: ( ... elt -- ... ? ) -- ... % )
 846     over [ count ] [ length ] bi* / ; inline
 847
 848 : sequence-index-operator-last ( n seq quot -- n quot' )
 849     [ [ nth-unsafe ] curry [ keep ] curry ] dip compose ; inline
 850
 851 : find-last-index-from ( ... n seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 852     '[
 853         _ [ sequence-index-operator-last find-last-integer ] keepd
 854         index/element
 855     ] bounds-check-call ; inline
 856
 857 : find-last-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 858     [ index-of-last ] dip find-last-index-from ; inline
 859
 860 : map-find-last-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 861     [ find-last-index ] (map-find-index) ; inline
 862
 863 :: (start-all) ( seq subseq increment -- indices )
 864     0
 865     [ seq subseq subseq-index-from dup ]
 866     [ [ increment + ] keep ] produce nip ;
 867
 868 : start-all ( seq subseq -- indices )
 869     dup length (start-all) ; inline
 870
 871 : start-all* ( seq subseq -- indices )
 872     1 (start-all) ; inline
 873
 874 : count-subseq ( seq subseq -- n )
 875     start-all length ; inline
 876
 877 : count-subseq* ( seq subseq -- n )
 878     start-all* length ; inline
 879
 880 : assoc-zip-with ( quot: ( key value -- calc ) -- alist )
 881     '[ _ 2keep 2array swap ] assoc-map ; inline
 882
 883 : take-while ( ... seq quot: ( ... elt -- ... ? ) -- head-slice )
 884     [ '[ @ not ] find drop ] keepd swap
 885     [ dup length ] unless* head-slice ; inline
 886
 887 : drop-while ( ... seq quot: ( ... elt -- ... ? ) -- tail-slice )
 888     [ '[ @ not ] find drop ] keepd swap
 889     [ dup length ] unless* tail-slice ; inline
 890
 891 : count-head ( seq quot -- n )
 892     [ not ] compose [ find drop ] keepd length or ; inline
 893
 894 : count-tail ( seq quot -- n )
 895     [ not ] compose [ find-last drop ] keepd
 896     length swap [ - 1 - ] when* ; inline
 897
 898 :: shorten* ( vector n -- seq )
 899     vector n tail
 900     n vector shorten ;
 901
 902 :: interleaved-as ( seq glue exemplar -- newseq )
 903     seq length dup 1 - + 0 max exemplar new-sequence :> newseq
 904     seq [ 2 * newseq set-nth-unsafe ] each-index
 905     seq length 1 - [ 2 * 1 + glue swap newseq set-nth-unsafe ] each-integer
 906     newseq ;
 907
 908 : interleaved ( seq glue -- newseq )
 909     over interleaved-as ;
 910
 911 : extract! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 912     [ dup ] compose over [ length ] keep new-resizable
 913     [ [ push-when ] 2curry reject! ] keep swap like ; inline
 914
 915 : find-pred-loop ( ... i n seq quot: ( ... elt -- ... calc ? ) -- ... calc/f i/f elt/f )
 916     2pick < [
 917         [ nipd call ] 4keep
 918         3 7 0 nrotated
 919         [ [ 3drop ] 2dip rot ]
 920         [ 2drop [ 1 + ] 3dip find-pred-loop ] if
 921     ] [
 922         4drop f f f
 923     ] if ; inline recursive
 924
 925 : find-pred ( ... seq quot: ( ... elt -- ... calc ) pred: ( ... calc -- ... ? ) -- ... calc/f i/f elt/f )
 926     [ 0 ] 3dip
 927     [ [ length check-length ] keep ] 2dip
 928     '[ nth-unsafe _ keep swap _ keep swap ] find-pred-loop swapd ; inline
 929
 930 ! https://en.wikipedia.org/wiki/Maximum_subarray_problem
 931 ! Kadane's algorithm O(n) largest sum in subarray
 932 : max-subarray-sum ( seq -- sum )
 933     [ -1/0. 0 ] dip
 934     [ [ + ] keep max [ max ] keep ] each drop ;
 935
 936 TUPLE: step-slice
 937     { from integer read-only initial: 0 }
 938     { to integer read-only initial: 0 }
 939     { seq read-only }
 940     { step integer read-only } ;
 941
 942 :: <step-slice> ( from/f to/f step seq -- step-slice )
 943     step zero? [ "can't be zero" throw ] when
 944     seq length :> len
 945     step 0 > [
 946         from/f [ 0 ] unless*
 947         to/f [ len ] unless*
 948     ] [
 949         from/f [ len ] unless*
 950         to/f [ 0 ] unless*
 951     ] if
 952     [ dup 0 < [ len + ] when 0 len clamp ] bi@
 953     ! FIXME: make this work with steps
 954     seq dup slice? [ collapse-slice ] when
 955     step step-slice boa ;
 956
 957 M: step-slice virtual-exemplar seq>> ; inline
 958
 959 M: step-slice virtual@
 960     [ step>> * ] [ from>> + ] [ seq>> ] tri ; inline
 961
 962 M: step-slice length
 963     [ to>> ] [ from>> - ] [ step>> ] tri
 964     dup 0 < [ [ neg 0 max ] dip neg ] when /mod
 965     zero? [ 1 + ] unless ; inline
 966
 967 INSTANCE: step-slice virtual-sequence
 968
 969 : 2nested-each* ( seq1 seq-quot: ( n -- seq ) quot: ( a b -- ) -- )
 970     '[
 971         _ keep swap _ with each
 972     ] each ; inline
 973
 974 : 2nested-filter-as* ( seq1 seq-quot quot exemplar -- seq )
 975     [ 2over [ length ] bi@ * ] dip
 976     [
 977         new-resizable
 978         [ [ push? ] curry compose 2nested-each* ] keep
 979     ] keep like ; inline
 980
 981 : 2nested-filter* ( seq1 seq-quot quot -- seq )
 982     pick 2nested-filter-as* ; inline
 983
 984 : 2nested-map-as* ( seq1 seq-quot quot exemplar -- seq )
 985     [ 2over [ length ] bi@ * ] dip
 986     [
 987         new-resizable
 988         [ [ push ] curry compose 2nested-each* ] keep
 989     ] keep like ; inline
 990
 991 : 2nested-map* ( seq1 seq-quot quot -- seq )
 992     pick 2nested-map-as* ; inline
 993
 994
 995 : 2nested-each ( seq1 seq2 quot -- )
 996     swapd '[
 997         swap _ with each
 998     ] with each ; inline
 999
1000 : 2nested-filter-as ( seq1 seq2 quot exemplar -- seq )
1001     [ 2over [ length ] bi@ * ] dip
1002     [
1003         new-resizable
1004         [ [ push? ] curry compose 2nested-each ] keep
1005     ] keep like ; inline
1006
1007 : 2nested-filter ( seq1 seq2 quot -- seq )
1008     pick 2nested-filter-as ; inline
1009
1010 : 2nested-map-as ( seq1 seq2 quot exemplar -- seq )
1011     [ 2over [ length ] bi@ * ] dip
1012     [
1013         new-resizable
1014         [ [ push ] curry compose 2nested-each ] keep
1015     ] keep like ; inline
1016
1017 : 2nested-map ( seq1 seq2 quot -- seq )
1018     pick 2nested-map-as ; inline
1019
1020 : 3nested-each ( seq1 seq2 seq3 quot -- )
1021     [ spin ] dip '[
1022         -rot [
1023             swap _ with with each
1024         ] with with each
1025     ] with with each ; inline
1026
1027 : 3nested-filter-as ( seq1 seq2 seq3 quot exemplar -- seq )
1028     [ 3 nover [ length ] tri@ * * ] dip
1029     [
1030         new-resizable
1031         [ [ push? ] curry compose 3nested-each ] keep
1032     ] keep like ; inline
1033
1034 : 3nested-filter ( seq1 seq2 seq3 quot -- seq )
1035     reach 3nested-filter-as ; inline
1036
1037 : 3nested-map-as ( seq1 seq2 seq3 quot exemplar -- seq )
1038     [ 3 nover [ length ] tri@ * * ] dip
1039     [
1040         new-resizable
1041         [ [ push ] curry compose 3nested-each ] keep
1042     ] keep like ; inline
1043
1044 : 3nested-map ( seq1 seq2 seq3 quot -- seq )
1045     reach 3nested-map-as ; inline
1046
1047 : prev ( n seq -- obj ) [ 1 - ] dip nth ; inline
1048 : ?prev ( n seq -- obj/f ) [ 1 - ] dip ?nth ; inline
1049 : ??prev ( n seq -- obj/f ? ) [ 1 - ] dip ??nth ; inline
1050 : prev-of ( seq n -- obj ) 1 - nth-of ; inline
1051 : ?prev-of ( seq n -- obj/f ) 1 - ?nth-of ; inline
1052 : ??prev-of ( seq n -- obj/f ? ) 1 - ??nth-of ; inline
1053
1054 : prev-identity ( i seq -- identity i seq )
1055     2dup ??prev [ drop 0 ] unless -rot ; inline
1056
1057 : each-prior-identity-from ( ... identity i seq quot: ( ... prior elt -- ... ) -- ... )
1058     '[ [ swap @ ] keep ]
1059     length-operator each-integer-from drop ; inline
1060
1061 : each-prior-from ( ... i seq quot: ( ... prior elt -- ... ) -- ... )
1062     [ prev-identity ] dip each-prior-identity-from ; inline
1063
1064 : each-prior ( ... seq quot: ( ... prior elt -- ... ) -- ... )
1065     0 -rot each-prior-from ; inline
1066
1067 : map-prior-identity-from-as ( ... identity i seq quot: ( ... prior elt -- elt' ) exemplar -- seq' )
1068     [
1069         '[ [ swap @ ] keep swap ] length-operator
1070     ] dip map-integers-from-as nip ; inline
1071
1072 : map-prior-identity-as ( ... identity seq quot: ( ... prior elt -- elt' ) exemplar -- seq' )
1073     [ 0 ] 3dip map-prior-identity-from-as ; inline
1074
1075 : map-prior-from-as ( ... i seq quot: ( ... prior elt -- elt' ) exemplar -- seq' )
1076     [ prev-identity ] 2dip map-prior-identity-from-as ; inline
1077
1078 : map-prior-as ( ... seq quot: ( ... prior elt -- elt' ) exemplar -- seq' )
1079     0 -roll map-prior-from-as ; inline
1080
1081 : map-prior-from ( ... i seq quot: ( ... prior elt -- elt' ) -- seq' )
1082     over map-prior-from-as ; inline
1083
1084 : map-prior ( ... seq quot: ( ... prior elt -- elt' ) -- seq' )
1085     over map-prior-as ; inline
1086
1087 TUPLE: virtual-zip-index seq ;
1088
1089 C: <zip-index> virtual-zip-index
1090
1091 M: virtual-zip-index length seq>> length ; inline
1092
1093 M: virtual-zip-index nth-unsafe
1094     over [ seq>> nth-unsafe ] [ 2array ] bi* ; inline
1095
1096 INSTANCE: virtual-zip-index immutable-sequence