extra/sequences/extras/extras.factor

   1 USING: accessors arrays assocs assocs.extras combinators
   2 generalizations grouping growable hash-sets heaps kernel math
   3 math.order ranges sequences sequences.private sets shuffle
   4 sorting splitting vectors ;
   5 IN: sequences.extras
   6
   7 : find-all ( ... seq quot: ( ... elt -- ... ? ) -- ... elts )
   8     [ <enumerated> ] dip '[ @ ] filter-values ; inline
   9
  10 :: subseq* ( from to seq -- subseq )
  11     seq length :> len
  12     from [ dup 0 < [ len + ] when ] [ 0 ] if*
  13     to [ dup 0 < [ len + ] when ] [ len ] if*
  14     [ 0 len clamp ] bi@ dupd max seq subseq ;
  15
  16 : safe-subseq ( from to seq -- subseq )
  17     [ length '[ 0 _ clamp ] bi@ ] keep subseq ;
  18
  19 : all-subseqs ( seq -- seqs )
  20     dup length [1..b] [ clump ] with map concat ;
  21
  22 : each-subseq ( ... seq quot: ( ... subseq -- ... ) -- ... )
  23     [ dup length [ [0..b] ] [ ] bi ] dip '[
  24         dup _ (a..b] [ rot [ subseq _ call ] keep ] with each
  25     ] each drop ; inline
  26
  27 : map-like ( seq exemplar -- seq' )
  28     '[ _ like ] map ; inline
  29
  30 : filter-all-subseqs-range ( ... seq range quot: ( ... subseq -- ... ? ) -- seq )
  31     [
  32         '[ <clumps> _ filter ] with map concat
  33     ] keepdd map-like ; inline
  34
  35 : filter-all-subseqs ( ... seq quot: ( ... subseq -- ... ? ) -- seq )
  36     [ dup length [1..b] ] dip filter-all-subseqs-range ; inline
  37
  38 :: longest-subseq ( seq1 seq2 -- subseq )
  39     seq1 length :> len1
  40     seq2 length :> len2
  41     0 :> n!
  42     0 :> end!
  43     len1 1 + [ len2 1 + 0 <array> ] replicate :> table
  44     len1 [1..b] [| x |
  45         len2 [1..b] [| y |
  46             x 1 - seq1 nth-unsafe
  47             y 1 - seq2 nth-unsafe = [
  48                 y 1 - x 1 - table nth-unsafe nth-unsafe 1 + :> len
  49                 len y x table nth-unsafe set-nth-unsafe
  50                 len n > [ len n! x end! ] when
  51             ] [ 0 y x table nth-unsafe set-nth-unsafe ] if
  52         ] each
  53     ] each end n - end seq1 subseq ;
  54
  55 : mismatch-last ( seq1 seq2 -- i-back )
  56     [ <reversed> ] bi@ mismatch ; inline
  57
  58 : pad-longest ( seq1 seq2 elt -- seq1 seq2 )
  59     [ 2dup max-length ] dip [ pad-tail ] 2curry bi@ ;
  60
  61 : pad-center ( seq n elt -- padded )
  62     swap pick length [-] [ drop ] [
  63         [ 2/ ] [ over - ] bi rot '[ _ <repetition> ] bi@
  64         pick surround-as
  65     ] if-zero ;
  66
  67 : zip-longest-with ( seq1 seq2 fill -- assoc )
  68     pad-longest zip ;
  69
  70 : zip-longest ( seq1 seq2 -- assoc )
  71     f zip-longest-with ;
  72
  73 : change-nths ( ... indices seq quot: ( ... elt -- ... elt' ) -- ... )
  74     [ change-nth ] 2curry each ; inline
  75
  76 : push-if-index ( ..a elt i quot: ( ..a elt i -- ..b ? ) accum -- ..b )
  77     [ keepd ] dip rot [ push ] [ 2drop ] if ; inline
  78
  79 : push-if* ( ..a elt quot: ( ..a elt -- ..b obj/f ) accum -- ..b )
  80     [ call ] dip [ push ] [ drop ] if* ; inline
  81
  82 : maybe-push ( elt/f accum -- )
  83     over [ push ] [ 2drop ] if ; inline
  84
  85 <PRIVATE
  86
  87 : (index-selector-as) ( quot length exampler -- selector accum )
  88     new-resizable [ [ push-if-index ] 2curry ] keep ; inline
  89
  90 : (selector-as*) ( quot length exemplar -- selector accum )
  91     new-resizable [ [ push-if* ] 2curry ] keep ; inline
  92
  93 PRIVATE>
  94
  95 : index-selector-as ( quot exemplar -- selector accum )
  96     [ length ] keep (index-selector-as) ; inline
  97
  98 : index-selector ( quot -- selector accum )
  99     V{ } index-selector-as ; inline
 100
 101 : selector-as* ( quot exemplar -- selector accum )
 102     [ length ] keep (selector-as*) ; inline
 103
 104 : selector* ( quot -- selector accum ) V{ } selector-as* ; inline
 105
 106 : filter-index-as ( ... seq quot: ( ... elt i -- ... ? ) exemplar -- ... seq' )
 107     pick length over [ (index-selector-as) [ each-index ] dip ] 2curry dip like ; inline
 108
 109 : filter-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... seq' )
 110     over filter-index-as ; inline
 111
 112 : even-indices ( seq -- seq' )
 113     [ length 1 + 2/ ] keep [
 114         [ [ 2 * ] dip nth-unsafe ] curry
 115     ] keep map-integers-as ;
 116
 117 : odd-indices ( seq -- seq' )
 118     [ length 2/ ] keep [
 119         [ [ 2 * 1 + ] dip nth-unsafe ] curry
 120     ] keep map-integers-as ;
 121
 122 : compact ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 123     [ split-when harvest ] dip join ; inline
 124
 125 : collapse ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 126     [ split-when ] dip
 127     [ [ harvest ] dip join ]
 128     [ [ first empty? ] dip [ prepend ] curry when ]
 129     [ [ last empty? ] dip [ append ] curry when ]
 130     2tri ; inline
 131
 132 :: slice-when ( seq quot: ( elt -- ? ) -- seq' )
 133     seq length :> len
 134     0 [ len dupd < ] [
 135         dup seq quot find-from drop
 136         [ 2dup = [ 1 + ] when ] [ len ] if*
 137         [ seq <slice> ] keep len or swap
 138     ] produce nip ; inline
 139
 140 : ?<slice> ( from/f to/f sequence -- slice )
 141     [ [ 0 ] unless* ] 2dip
 142     over [ nip [ length ] [ ] bi ] unless
 143     <slice> ; inline
 144
 145 : sequence>slice ( sequence -- slice )
 146     [ drop 0 ] [ length ] [ ] tri <slice> ; inline
 147
 148 : slice-order-by-from ( slice1 slice2 -- slice-lt slice-gt )
 149     2dup [ from>> ] bi@ > [ swap ] when ; inline
 150
 151 : ordered-slices-range ( slice-lt slice-gt -- to from )
 152     [ to>> ] [ from>> ] bi* ;
 153
 154 : unordered-slices-range ( slice1 slice2 -- to from )
 155     slice-order-by-from ordered-slices-range ;
 156
 157 : ordered-slices-overlap? ( slice-lt slice-gt -- ? )
 158     ordered-slices-range > ; inline
 159
 160 : unordered-slices-overlap? ( slice1 slice2 -- ? )
 161     unordered-slices-range > ; inline
 162
 163 : slices-overlap? ( slice1 slice2 -- ? )
 164     unordered-slices-overlap? ;
 165
 166 : ordered-slices-touch? ( slice-lt slice-gt -- ? )
 167     ordered-slices-range >= ; inline
 168
 169 : unordered-slices-touch? ( slice1 slice2 -- ? )
 170     unordered-slices-range >= ; inline
 171
 172 : slices-touch? ( slice1 slice2 -- ? )
 173     unordered-slices-touch? ;
 174
 175 ERROR: slices-don't-touch slice1 slice2 ;
 176
 177 : merge-slices ( slice1 slice2 -- slice/* )
 178     slice-order-by-from
 179     2dup ordered-slices-touch? [
 180         [ from>> ] [ [ to>> ] [ seq>> ] bi ] bi* <slice>
 181     ] [
 182         slices-don't-touch
 183     ] if ;
 184
 185 : rotate ( seq n -- seq' )
 186     over length mod dup 0 >= [ cut ] [ abs cut* ] if prepend ;
 187
 188 ERROR: underlying-mismatch slice1 slice2 ;
 189
 190 : ensure-same-underlying ( slice1 slice2 -- slice1 slice2 )
 191     2dup [ seq>> ] bi@ eq? [ underlying-mismatch ] unless ;
 192
 193 : span-slices ( slice1 slice2 -- slice )
 194     ensure-same-underlying
 195     [ [ from>> ] bi@ min ]
 196     [ [ to>> ] bi@ max ]
 197     [ drop seq>> ] 2tri <slice> ;
 198
 199 : ?span-slices ( slice1/f slice2/f -- slice )
 200     2dup and [ span-slices ] [ or ] if ;
 201
 202 :: rotate! ( seq n -- )
 203     seq length :> len
 204     n len mod dup 0 < [ len + ] when seq bounds-check drop 0 over
 205     [ 2dup = ] [
 206         [ seq exchange-unsafe ] [ [ 1 + ] bi@ ] 2bi
 207         dup len = [ drop over ] when
 208         2over = [ -rot nip over ] when
 209     ] until 3drop ;
 210
 211 : all-rotations ( seq -- seq' )
 212     dup length <iota> [ rotate ] with map ;
 213
 214 <PRIVATE
 215
 216 : (appender-for) ( quot length exemplar -- appender accum )
 217     new-resizable [ [ push-all ] curry compose ] keep ; inline
 218
 219 PRIVATE>
 220
 221 : appender-for ( quot exemplar -- appender accum )
 222     [ length ] keep (appender-for) ; inline
 223
 224 : appender ( quot -- appender accum )
 225     V{ } appender-for ; inline
 226
 227 : map-concat-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 228     [ appender-for [ each ] dip ] keep like ; inline
 229
 230 : >resizable ( seq -- accum ) ! fixes map-concat "cannot apply call to run-time..."
 231     [ length ] keep [ new-resizable ] [ append! ] bi ;
 232
 233 : map-concat ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 234     over empty? [ 2drop { } ] [
 235         [ [ first ] dip call ] 2keep rot [
 236             >resizable [ '[ @ _ push-all ] 1 each-from ] keep
 237         ] keep like
 238     ] if ; inline
 239
 240 : map-filter-as ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) exemplar -- ... subseq )
 241     reach length over
 242     [ (selector-as) [ compose each ] dip ] 2curry dip like ; inline
 243
 244 : map-filter ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) -- ... subseq )
 245     pick map-filter-as ; inline
 246
 247 : map-sift ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 248     [ ] map-filter ; inline
 249
 250 : map-harvest ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 251     [ empty? not ] map-filter ; inline
 252
 253 : (each-integer-with-previous) ( ... prev i n quot: ( ... i -- ... ) -- ... )
 254     2over < [
 255         [ nip call ] 4keep nipdd
 256         [ 1 + ] 2dip (each-integer-with-previous)
 257     ] [
 258         4drop
 259     ] if ; inline recursive
 260
 261 : each-integer-with-previous ( ... n quot: ( ... i -- ... ) -- ... )
 262     [ f 0 ] 2dip (each-integer-with-previous) ; inline
 263
 264 : (collect-with-previous) ( quot into -- quot' )
 265     [ [ keep ] dip [ set-nth-unsafe ] keepdd ] 2curry ; inline
 266
 267 : collect-with-previous ( n quot into -- )
 268     (collect-with-previous) each-integer-with-previous ; inline
 269
 270 : map-integers-with ( ... len quot: ( ... prev i -- ... elt ) exemplar -- ... newseq )
 271     overd [ [ collect-with-previous ] keep ] new-like ; inline
 272
 273 : map-with-previous-as ( ... seq quot: ( ... elt prev/f -- ... newelt ) exemplar -- ... newseq )
 274     [ length-operator ] dip map-integers-with ; inline
 275
 276 : map-with-previous ( ... seq quot: ( ... elt prev/f -- ... newelt ) -- ... newseq )
 277     over map-with-previous-as ; inline
 278
 279 : setup-each-from ( seq quot -- n quot )
 280     [ [ length ] keep [ nth-unsafe ] curry ] dip compose ; inline
 281
 282 : map-from-as ( ... seq quot: ( ... elt -- ... newelt ) from exemplar -- ... newseq )
 283     -rotd [ sequence-operator nipd ] dip map-integers-from-as ; inline
 284
 285 : map-from ( ... seq quot: ( ... elt -- ... newelt ) from -- ... newseq )
 286     pick map-from-as ; inline
 287
 288 : map-if ( ... seq if-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) -- ... newseq )
 289     '[ dup @ _ when ] map ; inline
 290
 291 : reduce-from ( ... seq identity quot: ( ... prev elt -- ... next ) from -- ... result )
 292     [ swap ] 2dip each-from ; inline
 293
 294 : 2reduce-from ( ... seq1 seq2 identity quot: ( ... prev elt1 elt2 -- ... next ) i -- ... result )
 295     [ -rot ] 2dip 2each-from ; inline
 296
 297 : 0accumulate-as ( ... seq quot: ( ... prev elt -- ... next ) exemplar -- ... newseq )
 298     pick empty? [
 299         2nip clone
 300     ] [
 301         [ 0 ] 2dip
 302         [ swapd [ dup ] compose ] dip map-as nip
 303     ] if ; inline
 304
 305 : 0accumulate ( ... seq quot: ( ... prev elt -- ... next ) -- ... final newseq )
 306     over 0accumulate-as ; inline
 307
 308 : nth-index ( n obj seq -- i )
 309     [ = dup [ drop 1 - dup 0 < ] when ] with find drop nip ;
 310
 311 : at+* ( n key assoc -- old new ) [ 0 or [ + ] keep swap dup ] change-at ; inline
 312
 313 : inc-at* ( key assoc -- old new ) [ 1 ] 2dip at+* ; inline
 314
 315 : mark-firsts ( seq -- seq' )
 316     dup length <hash-set> '[ _ ?adjoin 1 0 ? ] { } map-as ;
 317
 318 : deduplicate ( seq -- seq' )
 319     dup length <hash-set> '[ _ ?adjoin ] { } filter-as ;
 320
 321 : deduplicate-last ( seq -- seq' )
 322     <reversed> deduplicate reverse ;
 323
 324 : classify-from ( next hash seq -- next' hash seq' )
 325     '[
 326         swap '[
 327             dupd _ ?set-once-at
 328             [ [ 1 + ] dip ] when
 329         ] { } map-as
 330     ] keepd swap ;
 331
 332 : classify* ( seq -- next hash seq' )
 333     [ 0 H{ } clone ] dip classify-from ;
 334
 335 : classify ( seq -- seq' ) classify* 2nip ; inline
 336
 337 : occurrence-count-by ( seq quot: ( elt -- elt' ) -- hash seq' )
 338     '[ nip @ over inc-at* drop ] [ H{ } clone ] 2dip { } 0accumulate-as ; inline
 339
 340 : progressive-index-by-as ( seq1 seq2 quot exemplar -- hash seq' )
 341     [
 342         pick length '[
 343             tuck [ @ over inc-at* drop ] 2dip swap nth-index _ or
 344         ] [ H{ } clone ] 3dip with
 345     ] dip map-as ; inline
 346
 347 : progressive-index-by ( seq1 seq2 quot -- hash seq' )
 348     { } progressive-index-by-as ; inline
 349
 350 : progressive-index ( seq1 seq2 -- hash seq' )
 351     [ ] progressive-index-by ; inline
 352
 353 : 0reduce ( seq quot: ( prev elt -- next ) -- result )
 354     [ 0 ] dip reduce ; inline
 355
 356 : ?unclip ( seq -- rest/f first/f )
 357     [ f f ] [ unclip ] if-empty ;
 358
 359 : 1reduce ( seq quot: ( prev elt -- next ) -- result )
 360     [ ?unclip ] dip reduce ; inline
 361
 362 <PRIVATE
 363
 364 : change-nth-of-unsafe ( seq i quot -- seq )
 365     [ [ nth-of-unsafe ] dip call ] 2keepd rot set-nth-of-unsafe ; inline
 366
 367 PRIVATE>
 368
 369 : nth-of ( seq n -- elt ) swap nth ; inline
 370 : set-nth-of ( seq n elt -- seq ) spin [ set-nth ] keep ; inline
 371 : ?nth-of ( seq n -- elt/f ) swap ?nth ; inline
 372 : ??nth ( n seq -- elt/f ? )
 373     2dup bounds-check? [ nth-unsafe t ] [ 2drop f f ] if ; inline
 374 : ??nth-of ( seq n -- elt/f ? ) swap ??nth ; inline
 375
 376 : reduce-of ( seq quot: ( prev elt -- next ) identity -- result )
 377     swap reduce ; inline
 378
 379 : accumulate-of ( seq quot: ( prev elt -- next ) identity -- result )
 380     swap accumulate ; inline
 381
 382 <PRIVATE
 383
 384 : push-map-when* ( ..a elt quot: ( ..a elt -- ..b obj ? ) accum -- ..b )
 385     [ call ] dip swap [ push ] [ 2drop ] if ; inline
 386
 387 : filter-mapper-for* ( quot length exemplar -- filter-mapper accum )
 388     new-resizable [ [ push-map-when* ] 2curry ] keep ; inline
 389
 390 : 1push-map-when ( ..a filter-quot: ( ..a -- ..b ? ) map-quot: ( ..a -- ..b obj ) accum -- ..b )
 391     [ keep over ] 2dip [ when ] dip rot [ push ] [ 2drop ] if ; inline
 392
 393 : 1filter-mapper-for ( filter-quot map-quot length exemplar -- filter-mapper accum )
 394     new-resizable [ [ 1push-map-when ] 3curry ] keep ; inline
 395
 396 : 2push-map-when ( ..a filter-quot: ( ..a -- ..b ? ) map-quot: ( ..a -- ..b obj ) accum -- ..b )
 397     [ 2keep rot ] 2dip '[ [ @ _ push ] [ 2drop ] if ] call ; inline
 398
 399 : 2filter-mapper-for ( filter-quot map-quot length exemplar -- filter-mapper accum )
 400     new-resizable [ [ 2push-map-when ] 3curry ] keep ; inline
 401
 402 PRIVATE>
 403
 404 : filter-map-as* ( ... seq quot: ( ..a elt -- ..b obj ? ) exemplar -- ... newseq )
 405     pick length over
 406     [ filter-mapper-for* [ each ] dip ] 2curry dip like ; inline
 407
 408 : filter-map* ( ... seq quot: ( ... elt -- ... newelt ? ) -- ... newseq )
 409     over filter-map-as* ; inline
 410
 411 : reject-map-as* ( ... seq quot: ( ... elt -- ... newelt ? ) exemplar -- ... newseq )
 412     [ [ not ] compose ] dip filter-map-as* ; inline
 413
 414 : reject-map* ( ... seq quot: ( ... elt -- ... newelt ? ) -- ... newseq )
 415     over reject-map-as* ; inline
 416
 417 : 2filter-map-as* ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... obj ? ) exemplar -- ... newseq )
 418     reach length over
 419     [ filter-mapper-for* [ 2each ] dip ] 2curry dip like ; inline
 420
 421 : 2filter-map* ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... newseq )
 422     pick 2filter-map-as* ; inline
 423
 424 : 2reject-map-as* ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... obj ? ) exemplar -- ... newseq )
 425     [ [ not ] compose ] dip 2filter-map-as* ; inline
 426
 427 : 2reject-map* ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... obj ? ) -- ... newseq )
 428     pick 2reject-map-as* ; inline
 429
 430
 431 : filter-map-as ( ... seq filter-quot: ( ..a elt -- ..b ? ) map-quot: ( obj -- obj' ) exemplar -- ... newseq )
 432     reach length over
 433     [ 1filter-mapper-for [ each ] dip ] 2curry dip like ; inline
 434
 435 : filter-map ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( obj -- obj' ) -- ... newseq )
 436     pick filter-map-as ; inline
 437
 438 : reject-map-as ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( obj -- obj' ) exemplar -- ... newseq )
 439     [ [ not ] compose ] 2dip filter-map-as ; inline
 440
 441 : reject-map ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( obj -- obj' ) -- ... newseq )
 442     pick reject-map-as ; inline
 443
 444 : 2filter-map-as ( ... seq1 seq2 filter-quot: ( ... elt1 elt2 -- ... ? ) map-quot: ( elt1 elt2 -- obj ) exemplar -- ... newseq )
 445     5 npick length over
 446     [ 2filter-mapper-for [ 2each ] dip ] 2curry dip like ; inline
 447
 448 : 2filter-map ( ... seq1 seq2 filter-quot: ( ... elt1 elt2 -- ... ? ) map-quot: ( elt1 elt2 -- obj ) -- ... newseq )
 449     reach 2filter-map-as ; inline
 450
 451 : 2reject-map-as ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) map-quot: ( elt1 elt2 -- obj ) exemplar -- ... newseq )
 452     [ [ not ] compose ] 2dip 2filter-map-as ; inline
 453
 454 : 2reject-map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) map-quot: ( elt1 elt2 -- obj ) -- ... newseq )
 455     pick 2reject-map-as ; inline
 456
 457 : 2push-when ( ..a elt1 elt2 quot: ( ..a elt1 elt2 -- ..b ? ) accum -- ..b )
 458     [ keepd ] dip rot [ push ] [ 2drop ] if ; inline
 459
 460 : (2selector-as) ( quot length exemplar -- selector accum )
 461     new-resizable [ [ 2push-when ] 2curry ] keep ; inline
 462
 463 : 2filter-as ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) exemplar -- ... newseq )
 464     [
 465         pick [ length ] keep
 466         [ (2selector-as) [ 2each ] dip ] 2curry call
 467     ] dip like ; inline
 468
 469 : 2filter ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
 470     pick 2filter-as ; inline
 471
 472 : 2reject-as ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) exemplar -- ... newseq )
 473     [ [ not ] compose ] dip 2filter-as ; inline
 474
 475 : 2reject ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
 476     pick 2reject-as ; inline
 477
 478 : 2map-sum ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... n ) -- ... n )
 479     [ 0 ] 3dip [ dip + ] curry [ rot ] prepose 2each ; inline
 480
 481 : 2count ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... n )
 482     [ 1 0 ? ] compose 2map-sum ; inline
 483
 484 : 3each-from
 485     ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... ) i -- ... )
 486     [ 3length-operator ] dip -rot each-integer-from ; inline
 487
 488 : 3map-reduce
 489     ( ..a seq1 seq2 seq3 map-quot: ( ..a elt1 elt2 elt3 -- ..b intermediate ) reduce-quot: ( ..b prev intermediate -- ..a next ) -- ..a result )
 490     [ [ [ [ first ] tri@ ] 3keep ] dip [ 3dip ] keep ] dip compose 1 3each-from ; inline
 491
 492 : round-robin ( seq -- newseq )
 493     [ { } ] [
 494         [ longest length <iota> ] keep
 495         [ [ ?nth ] with map ] curry map concat sift
 496     ] if-empty ;
 497
 498 : sift-as ( seq exemplar -- newseq )
 499     [ ] swap filter-as ;
 500
 501 : sift! ( seq -- seq' )
 502     [ ] filter! ;
 503
 504 : harvest-as ( seq exemplar -- newseq )
 505     [ empty? not ] swap filter-as ;
 506
 507 : harvest! ( seq -- newseq )
 508     [ empty? ] reject! ;
 509
 510 : head-as ( seq n exemplar -- seq' )
 511     [ head-slice ] [ like ] bi* ; inline
 512
 513 : head*-as ( seq n exemplar -- seq' )
 514     [ head-slice* ] [ like ] bi* ; inline
 515
 516 : tail-as ( seq n exemplar -- seq' )
 517     [ tail-slice ] [ like ] bi* ; inline
 518
 519 : tail*-as ( seq n exemplar -- seq' )
 520     [ tail-slice* ] [ like ] bi* ; inline
 521
 522 : trim-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... newseq )
 523     [ trim-slice ] [ like ] bi* ; inline
 524
 525 : ?trim ( seq quot: ( elt -- ? ) -- seq/newseq )
 526     over empty? [ drop ] [
 527         over [ first-unsafe ] [ last-unsafe ] bi pick either?
 528         [ trim ] [ drop ] if
 529     ] if ; inline
 530
 531 : ?trim-head ( seq quot: ( elt -- ? ) -- seq/newseq )
 532     over empty? [ drop ] [
 533         over first-unsafe over call
 534         [ trim-head ] [ drop ] if
 535     ] if ; inline
 536
 537 : ?trim-tail ( seq quot: ( elt -- ? ) -- seq/newseq )
 538     over empty? [ drop ] [
 539         over last-unsafe over call
 540         [ trim-tail ] [ drop ] if
 541     ] if ; inline
 542
 543 : unsurround ( newseq seq2 seq3 -- seq1 )
 544     [ ?head drop ] [ ?tail drop ] bi* ;
 545
 546 : >string-list ( seq -- seq' )
 547     [ "\"" 1surround ] map "," join ;
 548
 549 : with-string-lines ( str quot -- str' )
 550     [ string-lines ] dip map "\n" join ; inline
 551
 552 : prepend-lines-with-spaces ( str -- str' )
 553     [ "    " prepend ] with-string-lines ;
 554
 555 : one? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 556     [ find ] 2keep rot [
 557         [ 1 + ] 2dip find-from drop not
 558     ] [ 3drop f ] if ; inline
 559
 560 : map-index! ( ... seq quot: ( ... elt index -- ... newelt ) -- ... seq )
 561     over [ [ sequence-index-operator ] dip collect ] keep ; inline
 562
 563 <PRIVATE
 564
 565 : 2sequence-index-iterator ( seq1 seq2 quot -- n quot' )
 566     [ 2length-iterator [ keep ] curry ] dip compose ; inline
 567
 568 PRIVATE>
 569
 570 : 2each-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... ) -- ... )
 571     2sequence-index-iterator each-integer ; inline
 572
 573 : 2map-into ( seq1 seq2 quot into -- )
 574     [ 2length-operator ] dip collect ; inline
 575
 576 : 2map! ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... seq1 )
 577     pick [ 2map-into ] keep ; inline
 578
 579 : 2map-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... newelt ) -- ... newseq )
 580     pick [ 2sequence-index-iterator ] dip map-integers-as ; inline
 581
 582 TUPLE: evens { seq read-only } ;
 583
 584 C: <evens> evens
 585
 586 M: evens length seq>> length 1 + 2/ ; inline
 587
 588 M: evens virtual@ [ 2 * ] [ seq>> ] bi* ; inline
 589
 590 M: evens virtual-exemplar seq>> ; inline
 591
 592 INSTANCE: evens virtual-sequence
 593
 594 TUPLE: odds { seq read-only } ;
 595
 596 C: <odds> odds
 597
 598 M: odds length seq>> length 2/ ; inline
 599
 600 M: odds virtual@ [ 2 * 1 + ] [ seq>> ] bi* ; inline
 601
 602 M: odds virtual-exemplar seq>> ; inline
 603
 604 INSTANCE: odds virtual-sequence
 605
 606 : until-empty ( seq quot -- )
 607     [ dup empty? ] swap until drop ; inline
 608
 609 <PRIVATE
 610
 611 : push-index-if ( ..a elt i quot: ( ..a elt -- ..b ? ) accum -- ..b )
 612     [ dip ] dip rot [ push ] [ 2drop ] if ; inline
 613
 614 PRIVATE>
 615
 616 : arg-where ( ... seq quot: ( ... elt -- ... ? ) -- ... indices )
 617     over length <vector> [
 618         [ push-index-if ] 2curry each-index
 619     ] keep ; inline
 620
 621 : arg-sort ( seq -- indices )
 622     zip-index sort-keys values ;
 623
 624 : first= ( seq elt -- ? ) [ first ] dip = ; inline
 625 : second= ( seq elt -- ? ) [ second ] dip = ; inline
 626 : third= ( seq elt -- ? ) [ third ] dip = ; inline
 627 : fourth= ( seq elt -- ? ) [ fourth ] dip = ; inline
 628 : last= ( seq elt -- ? ) [ last ] dip = ; inline
 629 : nth= ( n seq elt -- ? ) [ nth ] dip = ; inline
 630
 631 : first? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ first ] dip call ; inline
 632 : second? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ second ] dip call ; inline
 633 : third? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ third ] dip call ; inline
 634 : fourth? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ fourth ] dip call ; inline
 635 : last? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ last ] dip call ; inline
 636 : nth? ( ... n seq quot: ( ... elt -- ... ? ) -- ... ? ) [ nth ] dip call ; inline
 637
 638 : loop>sequence** ( ... quot: ( ... -- ... obj ? ) exemplar -- ... seq )
 639     [ ] swap produce-as nip ; inline
 640
 641 : loop>array** ( ... quot: ( ... -- ... obj ? ) -- ... array )
 642     { } loop>sequence** ; inline
 643
 644 : loop>sequence* ( ... quot: ( ... -- ... obj ? ) exemplar -- ... seq )
 645     [ t ] [ '[ [ _ dip ] [ f f f ] if* ] [ swap ] ] [ produce-as 2nip ] tri* ; inline
 646
 647 : loop>array* ( ... quot: ( ... -- ... obj ? ) -- ... array )
 648     { } loop>sequence* ; inline
 649
 650 : loop>sequence ( ... quot: ( ... -- ... obj/f ) exemplar -- ... seq )
 651     [ [ dup ] compose [ ] ] dip produce-as nip ; inline
 652
 653 : loop>array ( ... quot: ( ... -- ... obj/f ) -- ... array )
 654     { } loop>sequence ; inline
 655
 656 : zero-loop>sequence ( ... quot: ( ... n -- ... obj/f ) exemplar -- ... seq )
 657     [ 0 ] [ '[ _ keep 1 + swap ] ] [ loop>sequence ] tri* nip ; inline
 658
 659 : zero-loop>array ( quot: ( ..a n -- ..a obj ) -- seq )
 660     { } zero-loop>sequence ; inline
 661
 662 : iterate-heap-while ( heap quot1: ( value key -- slurp? ) quot2: ( value key -- obj/f ) -- obj/f loop? )
 663     pick heap-empty?
 664     [ 3drop f f ]
 665     [
 666         [ [ heap-peek ] 2dip drop 2keep ]
 667         [
 668             nip ! ( pop? value key heap quot2 )
 669             5roll [
 670                 swap heap-pop* call( value key -- obj/f ) t
 671             ] [
 672                 4drop f f
 673             ] if
 674         ] 3bi
 675     ] if ; inline
 676
 677 : slurp-heap-while-map ( heap quot1: ( value key -- slurp? ) quot2: ( value key -- obj/f ) -- seq )
 678     '[ _ _ _ iterate-heap-while ] loop>array* ; inline
 679
 680 : heap>pairs ( heap -- pairs )
 681     [ 2drop t ] [ swap 2array ] slurp-heap-while-map ;
 682
 683 : map-zip-swap ( quot: ( x -- y ) -- alist )
 684     '[ _ keep ] map>alist ; inline
 685
 686 : ?heap-pop-value>array ( heap -- array )
 687     dup heap-empty? [ drop { } ] [ heap-pop drop 1array ] if ;
 688
 689 <PRIVATE
 690
 691 : (reverse) ( seq -- newseq )
 692     dup [ length ] keep new-sequence
 693     [ 0 swap copy-unsafe ] keep reverse! ;
 694
 695 PRIVATE>
 696
 697 : reverse-as ( seq exemplar -- newseq )
 698     [ (reverse) ] [ like ] bi* ;
 699
 700 : map-product ( ... seq quot: ( ... elt -- ... n ) -- ... n )
 701     [ 1 ] 2dip [ dip * ] with-assoc each ; inline
 702
 703 : insert-nth! ( elt n seq -- )
 704     [ length ] keep ensure swap pick (a..b]
 705     over '[ [ 1 + ] keep _ move-unsafe ] each
 706     set-nth-unsafe ;
 707
 708 : set-nths ( value indices seq -- )
 709     swapd '[ _ swap _ set-nth ] each ; inline
 710
 711 : set-nths-unsafe ( value indices seq -- )
 712     swapd '[ _ swap _ set-nth-unsafe ] each ; inline
 713
 714 <PRIVATE
 715
 716 : (map-find-index) ( seq quot find-quot -- result i elt )
 717     [ [ f ] 2dip [ [ nip ] 2dip call dup ] curry ] dip call
 718     [ [ [ drop f ] unless ] keep ] dip ; inline
 719
 720 PRIVATE>
 721
 722 : map-find-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 723     [ find-index ] (map-find-index) ; inline
 724
 725 : find-from* ( ... n seq quot: ( ... elt -- ... ? ) -- ... elt i/f )
 726     '[ _ do-find-from element/index ] bounds-check-call ; inline
 727
 728 : find* ( ... seq quot: ( ... elt -- ... ? ) -- ... elt i/f )
 729     [ 0 ] 2dip do-find-from element/index ; inline
 730
 731 : find-last-from* ( ... n seq quot: ( ... elt -- ... ? ) -- ... elt i/f )
 732     '[ _ find-last-from-unsafe element/index ] bounds-check-call ; inline
 733
 734 : find-last* ( ... seq quot: ( ... elt -- ... ? ) -- ... elt i/f )
 735     [ index-of-last ] dip find-last-from* ; inline
 736
 737 : find-index-from* ( ... n seq quot: ( ... elt i -- ... ? ) -- ... elt i/f )
 738     '[
 739         _ [ sequence-index-operator find-integer-from ] keepd
 740         element/index
 741     ] bounds-check-call ; inline
 742
 743 : find-index* ( ... seq quot: ( ... elt i -- ... ? ) -- ... elt i/f )
 744     [ 0 ] 2dip find-index-from* ; inline
 745
 746 : filter-length ( seq n -- seq' ) '[ length _ = ] filter ;
 747
 748 : all-shortest ( seqs -- seqs' ) dup shortest length filter-length ;
 749
 750 : all-longest ( seqs -- seqs' ) dup longest length filter-length ;
 751
 752 <PRIVATE
 753
 754 : nth-unsafe-of ( seq n -- elt ) swap nth-unsafe ; inline
 755 : set-nth-unsafe-of ( seq n elt -- seq ) spin [ set-nth-unsafe ] keep ; inline
 756 : set-length-of ( seq n -- seq ) over set-length ; inline
 757
 758 : move-unsafe-of ( seq to from -- seq )
 759     2dup = [
 760         2drop
 761     ] [
 762         overd nth-unsafe-of set-nth-unsafe-of
 763     ] if ; inline
 764
 765 : move-backward-of ( seq shift from to -- seq )
 766     2dup = [
 767         3drop
 768     ] [
 769         [ [ [ + ] keep move-unsafe-of ] 2keep 1 + ] dip move-backward-of
 770     ] if ;
 771
 772 : open-slice-of ( seq shift from -- seq )
 773     over 0 = [
 774         2drop
 775     ] [
 776         [ ] [ drop [ length ] dip + ] 3bi
 777         [ pick length [ over - ] dip move-backward-of ] dip
 778         set-length-of
 779     ] if ;
 780
 781 PRIVATE>
 782
 783 ERROR: slice-error-of from to seq ;
 784
 785 : check-slice-of ( seq from to -- seq from to )
 786     over 0 < [ slice-error-of ] when
 787     dup reach length > [ slice-error-of ] when
 788     2dup > [ slice-error-of ] when ; inline
 789
 790 : delete-slice-of ( seq from to -- seq )
 791     check-slice-of over [ - ] dip open-slice-of ;
 792
 793 : remove-nth-of ( seq n -- seq' )
 794     [ dup 1 + rot snip-slice ] keepd append-as ;
 795
 796 : remove-nth-of* ( seq n -- nth seq' )
 797     [ nth-of ] [ remove-nth-of ] 2bi ;
 798
 799 : remove-nth-of! ( seq n -- seq )
 800     dup 1 + delete-slice-of ;
 801
 802 : remove-nth-of*! ( seq n -- nth seq )
 803     [ nth-of ] [ dup 1 + delete-slice-of ] 2bi ;
 804
 805 : snip-of ( seq from to -- head tail )
 806     [ head ] [ tail ] bi-curry* bi ; inline
 807
 808 : snip-slice-of ( seq from to -- head tail )
 809     [ head-slice ] [ tail-slice ] bi-curry* bi ; inline
 810
 811 : index* ( seq obj -- n ) [ = ] curry find drop ;
 812
 813 : index-from* ( i seq obj -- n )
 814     [ = ] curry find-from drop ;
 815
 816 : last-index* ( seq obj -- n )
 817     [ = ] curry find-last drop ;
 818
 819 : last-index-from* ( i seq obj -- n )
 820     [ = ] curry find-last-from drop ;
 821
 822 : indices* ( seq obj -- indices )
 823     [ = ] curry [ swap ] prepose V{ } clone [
 824         [ push ] curry [ [ drop ] if ] curry compose each-index
 825     ] keep ;
 826
 827 : remove-first ( obj seq -- seq' )
 828     [ index ] keep over [ remove-nth ] [ nip ] if ;
 829
 830 : remove-first-of ( seq obj -- seq' )
 831     dupd index* [ remove-nth-of ] when* ;
 832
 833 : remove-first! ( obj seq -- seq )
 834     [ index ] keep over [ remove-nth! ] [ nip ] if ;
 835
 836 : remove-last ( obj seq -- seq' )
 837     [ last-index ] keep over [ remove-nth ] [ nip ] if ;
 838
 839 : remove-last! ( obj seq -- seq )
 840     [ last-index ] keep over [ remove-nth! ] [ nip ] if ;
 841
 842 : member-of? ( seq elt -- ? )
 843     [ = ] curry any? ;
 844
 845 : member-eq-of? ( seq elt -- ? )
 846     [ eq? ] curry any? ;
 847
 848 : remove-of ( seq elt -- newseq )
 849     [ = ] curry reject ;
 850
 851 : remove-eq-of ( seq elt -- newseq )
 852     [ eq? ] curry reject ;
 853
 854 : ?first2 ( seq -- first/f second/f )
 855     dup length {
 856         { 0 [ drop f f ] }
 857         { 1 [ first-unsafe f ] }
 858         [ drop first2-unsafe ]
 859     } case ;
 860
 861 : ?first3 ( seq -- first/f second/f third/f )
 862     dup length {
 863         { 0 [ drop f f f ] }
 864         { 1 [ first-unsafe f f ] }
 865         { 2 [ first2-unsafe f ] }
 866         [ drop first3-unsafe ]
 867     } case ;
 868
 869 : ?first4 ( seq -- first/f second/f third/f fourth/f )
 870     dup length {
 871         { 0 [ drop f f f f ] }
 872         { 1 [ first-unsafe f f f ] }
 873         { 2 [ first2-unsafe f f ] }
 874         { 3 [ first3-unsafe f ] }
 875         [ drop first4-unsafe ]
 876     } case ;
 877
 878 : cut-when ( ... seq quot: ( ... elt -- ... ? ) -- ... before after )
 879     [ find drop ] keepd swap
 880     [ cut ] [ f over like ] if* ; inline
 881
 882 : nth* ( n seq -- elt )
 883     [ length 1 - swap - ] [ nth ] bi ; inline
 884
 885 : each-index-from ( ... seq quot: ( ... elt index -- ... ) i -- ... )
 886     -rot sequence-index-operator each-integer-from ; inline
 887
 888 <PRIVATE
 889
 890 : select-by* ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... i elt )
 891     [
 892         [ keep swap ] curry [ dip ] curry
 893         [ [ first 0 ] dip call ] 2keep
 894         [ 2curry 3dip 5 npick pick ] curry
 895     ] [
 896         [ [ 3drop ] [ [ 3drop ] 3dip ] if ] compose
 897     ] bi* compose 1 each-index-from nip swap ; inline
 898
 899 PRIVATE>
 900
 901 : supremum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 902     [ after? ] select-by* ; inline
 903
 904 : infimum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 905     [ before? ] select-by* ; inline
 906
 907 : arg-max ( seq -- n )
 908     [ ] supremum-by* drop ;
 909
 910 : arg-min ( seq -- n )
 911     [ ] infimum-by* drop ;
 912
 913 : ?supremum ( seq/f -- elt/f )
 914     [ f ] [
 915         [ ] [ 2dup and [ max ] [ dupd ? ] if ] map-reduce
 916     ] if-empty ;
 917
 918 : ?infimum ( seq/f -- elt/f )
 919     [ f ] [
 920         [ ] [ 2dup and [ min ] [ dupd ? ] if ] map-reduce
 921     ] if-empty ;
 922
 923 : map-infimum ( seq quot: ( ... elt -- ... elt' ) -- elt' )
 924     [ min ] map-reduce ; inline
 925
 926 : map-supremum ( seq quot: ( ... elt -- ... elt' ) -- elt' )
 927     [ max ] map-reduce ; inline
 928
 929 : change-last ( seq quot -- )
 930     [ index-of-last ] [ change-nth ] bi* ; inline
 931
 932 : change-last-unsafe ( seq quot -- )
 933     [ index-of-last ] [ change-nth-unsafe ] bi* ; inline
 934
 935 : replicate-into ( ... seq quot: ( ... -- ... newelt ) -- ... )
 936     over [ length ] 2dip '[ _ dip _ set-nth-unsafe ] each-integer ; inline
 937
 938 : percent-of ( ... seq quot: ( ... elt -- ... ? ) -- ... % )
 939     over length 0 =
 940     [ 2drop 0 ]
 941     [ over [ count ] [ length ] bi* / ] if ; inline
 942
 943 : sequence-index-operator-last ( n seq quot -- n quot' )
 944     [ [ nth-unsafe ] curry [ keep ] curry ] dip compose ; inline
 945
 946 : find-last-index-from ( ... n seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 947     '[
 948         _ [ sequence-index-operator-last find-last-integer ] keepd
 949         index/element
 950     ] bounds-check-call ; inline
 951
 952 : find-last-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 953     [ index-of-last ] dip find-last-index-from ; inline
 954
 955 : map-find-last-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 956     [ find-last-index ] (map-find-index) ; inline
 957
 958 :: (start-all) ( seq subseq increment -- indices )
 959     0
 960     [ seq subseq subseq-index-from dup ]
 961     [ [ increment + ] keep ] produce nip ;
 962
 963 : start-all ( seq subseq -- indices )
 964     dup length (start-all) ; inline
 965
 966 : start-all* ( seq subseq -- indices )
 967     1 (start-all) ; inline
 968
 969 : count-subseq ( seq subseq -- n )
 970     start-all length ; inline
 971
 972 : count-subseq* ( seq subseq -- n )
 973     start-all* length ; inline
 974
 975 : assoc-zip-with ( quot: ( key value -- calc ) -- alist )
 976     '[ _ 2keep 2array swap ] assoc-map ; inline
 977
 978 : take-while ( ... seq quot: ( ... elt -- ... ? ) -- head-slice )
 979     [ '[ @ not ] find drop ] keepd swap
 980     [ dup length ] unless* head-slice ; inline
 981
 982 : drop-while ( ... seq quot: ( ... elt -- ... ? ) -- tail-slice )
 983     [ '[ @ not ] find drop ] keepd swap
 984     [ dup length ] unless* tail-slice ; inline
 985
 986 : count-head ( seq quot -- n )
 987     [ not ] compose [ find drop ] keepd length or ; inline
 988
 989 : count-tail ( seq quot -- n )
 990     [ not ] compose [ find-last drop ] keepd
 991     length swap [ - 1 - ] when* ; inline
 992
 993 : count= ( ... seq quot: ( ... elt -- ... ? ) n -- ... ? )
 994     [ 0 ] 3dip [
 995         '[ swap _ dip swap [ 1 + ] when dup _ > ] find 2drop
 996     ] keep = ; inline
 997
 998 :: shorten* ( vector n -- seq )
 999     vector n tail
1000     n vector shorten ;
1001
1002 :: interleaved-as ( seq glue exemplar -- newseq )
1003     seq length dup 1 - + 0 max exemplar new-sequence :> newseq
1004     seq [ 2 * newseq set-nth-unsafe ] each-index
1005     seq length 1 - [ 2 * 1 + glue swap newseq set-nth-unsafe ] each-integer
1006     newseq ;
1007
1008 : interleaved ( seq glue -- newseq )
1009     over interleaved-as ;
1010
1011 : extract! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
1012     [ dup ] compose over [ length ] keep new-resizable
1013     [ [ push-when ] 2curry reject! ] keep swap like ; inline
1014
1015 : find-pred-loop ( ... i n seq quot: ( ... elt -- ... calc ? ) -- ... calc/f i/f elt/f )
1016     2pick < [
1017         [ nipd call ] 4keep
1018         3 7 0 nrotated
1019         [ [ 3drop ] 2dip rot ]
1020         [ 2drop [ 1 + ] 3dip find-pred-loop ] if
1021     ] [
1022         4drop f f f
1023     ] if ; inline recursive
1024
1025 : find-pred ( ... seq quot: ( ... elt -- ... calc ) pred: ( ... calc -- ... ? ) -- ... calc/f i/f elt/f )
1026     [ 0 ] 3dip
1027     [ [ length check-length ] keep ] 2dip
1028     '[ nth-unsafe _ keep swap _ keep swap ] find-pred-loop swapd ; inline
1029
1030 ! https://en.wikipedia.org/wiki/Maximum_subarray_problem
1031 ! Kadane's algorithm O(n) largest sum in subarray
1032 : max-subarray-sum ( seq -- sum )
1033     [ -1/0. 0 ] dip
1034     [ [ + ] keep max [ max ] keep ] each drop ;
1035
1036 TUPLE: step-slice
1037     { from integer read-only initial: 0 }
1038     { to integer read-only initial: 0 }
1039     { seq read-only }
1040     { step integer read-only } ;
1041
1042 :: <step-slice> ( from/f to/f step seq -- step-slice )
1043     step zero? [ "can't be zero" throw ] when
1044     seq length :> len
1045     step 0 > [
1046         from/f [ 0 ] unless*
1047         to/f [ len ] unless*
1048     ] [
1049         from/f [ len ] unless*
1050         to/f [ 0 ] unless*
1051     ] if
1052     [ dup 0 < [ len + ] when 0 len clamp ] bi@
1053     ! FIXME: make this work with steps
1054     seq dup slice? [ collapse-slice ] when
1055     step step-slice boa ;
1056
1057 M: step-slice virtual-exemplar seq>> ; inline
1058
1059 M: step-slice virtual@
1060     [ step>> * ] [ from>> + ] [ seq>> ] tri ; inline
1061
1062 M: step-slice length
1063     [ to>> ] [ from>> - ] [ step>> ] tri
1064     dup 0 < [ [ neg 0 max ] dip neg ] when /mod
1065     zero? [ 1 + ] unless ; inline
1066
1067 INSTANCE: step-slice virtual-sequence
1068
1069 : 2nested-each* ( seq1 seq-quot: ( n -- seq ) quot: ( a b -- ) -- )
1070     '[
1071         _ keep swap _ with each
1072     ] each ; inline
1073
1074 : 2nested-filter-as* ( seq1 seq-quot quot exemplar -- seq )
1075     [ 2over [ length ] bi@ * ] dip
1076     [
1077         new-resizable
1078         [ [ maybe-push ] curry compose 2nested-each* ] keep
1079     ] keep like ; inline
1080
1081 : 2nested-filter* ( seq1 seq-quot quot -- seq )
1082     pick 2nested-filter-as* ; inline
1083
1084 : 2nested-map-as* ( seq1 seq-quot quot exemplar -- seq )
1085     [ 2over [ length ] bi@ * ] dip
1086     [
1087         new-resizable
1088         [ [ push ] curry compose 2nested-each* ] keep
1089     ] keep like ; inline
1090
1091 : 2nested-map* ( seq1 seq-quot quot -- seq )
1092     pick 2nested-map-as* ; inline
1093
1094
1095 : 2nested-each ( seq1 seq2 quot -- )
1096     swapd '[
1097         swap _ with each
1098     ] with each ; inline
1099
1100 : 2nested-filter-as ( seq1 seq2 quot exemplar -- seq )
1101     [ 2over [ length ] bi@ * ] dip
1102     [
1103         new-resizable
1104         [ [ maybe-push ] curry compose 2nested-each ] keep
1105     ] keep like ; inline
1106
1107 : 2nested-filter ( seq1 seq2 quot -- seq )
1108     pick 2nested-filter-as ; inline
1109
1110 : 2nested-map-as ( seq1 seq2 quot exemplar -- seq )
1111     [ 2over [ length ] bi@ * ] dip
1112     [
1113         new-resizable
1114         [ [ push ] curry compose 2nested-each ] keep
1115     ] keep like ; inline
1116
1117 : 2nested-map ( seq1 seq2 quot -- seq )
1118     pick 2nested-map-as ; inline
1119
1120 : 3nested-each ( seq1 seq2 seq3 quot -- )
1121     spind '[
1122         -rot [
1123             swap _ with with each
1124         ] with with each
1125     ] with with each ; inline
1126
1127 : 3nested-filter-as ( seq1 seq2 seq3 quot exemplar -- seq )
1128     [ 3 nover [ length ] tri@ * * ] dip
1129     [
1130         new-resizable
1131         [ [ maybe-push ] curry compose 3nested-each ] keep
1132     ] keep like ; inline
1133
1134 : 3nested-filter ( seq1 seq2 seq3 quot -- seq )
1135     reach 3nested-filter-as ; inline
1136
1137 : 3nested-map-as ( seq1 seq2 seq3 quot exemplar -- seq )
1138     [ 3 nover [ length ] tri@ * * ] dip
1139     [
1140         new-resizable
1141         [ [ push ] curry compose 3nested-each ] keep
1142     ] keep like ; inline
1143
1144 : 3nested-map ( seq1 seq2 seq3 quot -- seq )
1145     reach 3nested-map-as ; inline
1146
1147 : prev ( n seq -- obj ) [ 1 - ] dip nth ; inline
1148 : ?prev ( n seq -- obj/f ) [ 1 - ] dip ?nth ; inline
1149 : ??prev ( n seq -- obj/f ? ) [ 1 - ] dip ??nth ; inline
1150 : prev-of ( seq n -- obj ) 1 - nth-of ; inline
1151 : ?prev-of ( seq n -- obj/f ) 1 - ?nth-of ; inline
1152 : ??prev-of ( seq n -- obj/f ? ) 1 - ??nth-of ; inline
1153
1154 : prev-identity ( i seq -- identity i seq )
1155     2dup ??prev [ drop 0 ] unless -rot ; inline
1156
1157 : each-prior-identity-from ( ... identity i seq quot: ( ... prior elt -- ... ) -- ... )
1158     '[ [ swap @ ] keep ]
1159     length-operator each-integer-from drop ; inline
1160
1161 : each-prior-from ( ... i seq quot: ( ... prior elt -- ... ) -- ... )
1162     [ prev-identity ] dip each-prior-identity-from ; inline
1163
1164 : each-prior ( ... seq quot: ( ... prior elt -- ... ) -- ... )
1165     0 -rot each-prior-from ; inline
1166
1167 : map-prior-identity-from-as ( ... identity i seq quot: ( ... prior elt -- elt' ) exemplar -- seq' )
1168     [
1169         '[ [ swap @ ] keep swap ] length-operator
1170     ] dip map-integers-from-as nip ; inline
1171
1172 : map-prior-identity-as ( ... identity seq quot: ( ... prior elt -- elt' ) exemplar -- seq' )
1173     [ 0 ] 3dip map-prior-identity-from-as ; inline
1174
1175 : map-prior-from-as ( ... i seq quot: ( ... prior elt -- elt' ) exemplar -- seq' )
1176     [ prev-identity ] 2dip map-prior-identity-from-as ; inline
1177
1178 : map-prior-as ( ... seq quot: ( ... prior elt -- elt' ) exemplar -- seq' )
1179     0 -roll map-prior-from-as ; inline
1180
1181 : map-prior-from ( ... i seq quot: ( ... prior elt -- elt' ) -- seq' )
1182     over map-prior-from-as ; inline
1183
1184 : map-prior ( ... seq quot: ( ... prior elt -- elt' ) -- seq' )
1185     over map-prior-as ; inline
1186
1187 TUPLE: virtual-zip-index seq ;
1188
1189 C: <zip-index> virtual-zip-index
1190
1191 M: virtual-zip-index length seq>> length ; inline
1192
1193 M: virtual-zip-index nth-unsafe
1194     over [ seq>> nth-unsafe ] [ 2array ] bi* ; inline
1195
1196 INSTANCE: virtual-zip-index immutable-sequence
1197
1198 : call-push-when ( ..a elt quot: ( ..a elt -- ..b elt' ? ) accum -- ..b )
1199     [ call ] dip swap [ push ] [ 2drop ] if ; inline
1200
1201 : fry-map-as ( seq quot exemplar -- newseq )
1202     [ 2drop length ]
1203     [ overd new-sequence-like dup ] 3bi
1204     '[ [ [ _ nth-unsafe @ ] [ _ set-nth-unsafe ] bi ] each-integer _ ] call ; inline
1205
1206 : exchange-subseq ( len pos1 pos2 seq -- )
1207     [ [ assert-non-negative ] tri@ 3dup max + 1 - ] dip bounds-check nip '[
1208         2dup _ exchange-unsafe
1209         [ 1 - ] [ 1 + ] [ 1 + ] tri*
1210     ] [ pick 0 > ] swap while 3drop ;