extra/sequences/extras/extras.factor

   1 USING: accessors arrays assocs combinators fry generalizations
   2 grouping growable kernel locals make math math.order math.ranges
   3 sequences sequences.deep sequences.private sorting splitting
   4 vectors ;
   5 FROM: sequences => change-nth ;
   6 IN: sequences.extras
   7
   8 : reduce1 ( seq quot -- result ) [ unclip ] dip reduce ; inline
   9
  10 :: reduce-r ( seq identity quot: ( obj1 obj2 -- obj ) -- result )
  11     seq [ identity ] [
  12         unclip [ identity quot reduce-r ] [ quot call ] bi*
  13     ] if-empty ; inline recursive
  14
  15 ! Quot must have static stack effect, unlike "reduce"
  16 :: reduce* ( seq identity quot: ( prev elt -- next ) -- result )
  17     seq [ identity ] [
  18         unclip identity swap quot call( prev elt -- next )
  19         quot reduce*
  20     ] if-empty ; inline recursive
  21
  22 :: combos ( list1 list2 -- result )
  23     list2 [ [ 2array ] curry list1 swap map ] map concat ;
  24
  25 : find-all ( seq quot: ( elt -- ? ) -- elts )
  26     [ [ length iota ] keep ] dip
  27     [ dupd call( a -- ? ) [ 2array ] [ 2drop f ] if ] curry
  28     2map sift ; inline
  29
  30 : reduce-from ( ... seq identity quot: ( ... prev elt -- ... next ) i -- ... result )
  31     [ swap ] 2dip each-from ; inline
  32
  33 :: subseq* ( from to seq -- subseq )
  34     seq length :> len
  35     from [ dup 0 < [ len + ] when ] [ 0 ] if*
  36     to [ dup 0 < [ len + ] when ] [ len ] if*
  37     [ 0 len clamp ] bi@ dupd max seq subseq ;
  38
  39 : safe-subseq ( from to seq -- subseq )
  40     [ length '[ 0 _ clamp ] bi@ ] keep subseq ;
  41
  42 : all-subseqs ( seq -- seqs )
  43     dup length [1,b] [ clump ] with map concat ;
  44
  45 :: each-subseq ( ... seq quot: ( ... x -- ... ) -- ... )
  46     seq length :> len
  47     len [0,b] [
  48         :> from
  49         from len (a,b] [
  50             :> to
  51             from to seq subseq quot call
  52         ] each
  53     ] each ; inline
  54
  55 : subseq-as ( from to seq exemplar -- subseq )
  56     [ check-slice subseq>copy (copy) ] dip like ;
  57
  58 : map-like ( seq exemplar -- seq' )
  59     '[ _ like ] map ; inline
  60
  61 : filter-all-subseqs-range ( ... seq range quot: ( ... x -- ... ) -- seq )
  62     [
  63         '[ <clumps> _ filter ] with map concat
  64     ] 3keep 2drop map-like ; inline
  65
  66 : filter-all-subseqs ( ... seq quot: ( ... x -- ... ) -- seq )
  67     [ dup length [1,b] ] dip filter-all-subseqs-range ; inline
  68
  69 :: longest-subseq ( seq1 seq2 -- subseq )
  70     seq1 length :> len1
  71     seq2 length :> len2
  72     0 :> n!
  73     0 :> end!
  74     len1 1 + [ len2 1 + 0 <array> ] replicate :> table
  75     len1 [1,b] [| x |
  76         len2 [1,b] [| y |
  77             x 1 - seq1 nth-unsafe
  78             y 1 - seq2 nth-unsafe = [
  79                 y 1 - x 1 - table nth-unsafe nth-unsafe 1 + :> len
  80                 len y x table nth-unsafe set-nth-unsafe
  81                 len n > [ len n! x end! ] when
  82             ] [ 0 y x table nth-unsafe set-nth-unsafe ] if
  83         ] each
  84     ] each end n - end seq1 subseq ;
  85
  86 : pad-longest ( seq1 seq2 elt -- seq1 seq2 )
  87     [ 2dup max-length ] dip [ pad-tail ] 2curry bi@ ;
  88
  89 : change-nths ( ... indices seq quot: ( ... elt -- ... elt' ) -- ... )
  90     [ change-nth ] 2curry each ; inline
  91
  92 : push-if-index ( ..a elt i quot: ( ..a elt i -- ..b ? ) accum -- ..b )
  93     [ 2keep drop ] dip rot [ push ] [ 2drop ] if ; inline
  94
  95 : push-if* ( ..a elt quot: ( ..a elt -- ..b obj/f ) accum -- ..b )
  96     [ call ] dip [ push ] [ drop ] if* ; inline
  97
  98 <PRIVATE
  99
 100 : (index-selector-for) ( quot length exampler -- selector accum )
 101     new-resizable [ [ push-if-index ] 2curry ] keep ; inline
 102
 103 : (selector-for*) ( quot length exemplar -- selector accum )
 104     new-resizable [ [ push-if* ] 2curry ] keep ; inline
 105
 106 PRIVATE>
 107
 108 : index-selector-for ( quot exemplar -- selector accum )
 109     [ length ] keep (index-selector-for) ; inline
 110
 111 : index-selector ( quot -- selector accum )
 112     V{ } index-selector-for ; inline
 113
 114 : selector-for* ( quot exemplar -- selector accum )
 115     [ length ] keep (selector-for*) ; inline
 116
 117 : selector* ( quot -- selector accum ) V{ } selector-for* ; inline
 118
 119 : filter-index-as ( ... seq quot: ( ... elt i -- ... ? ) exemplar -- ... seq' )
 120     pick length over [ (index-selector-for) [ each-index ] dip ] 2curry dip like ; inline
 121
 122 : filter-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... seq' )
 123     over filter-index-as ; inline
 124
 125 : even-indices ( seq -- seq' )
 126     [ length 1 + 2/ ] keep [
 127         [ [ 2 * ] dip nth-unsafe ] curry
 128     ] keep map-integers ;
 129
 130 : odd-indices ( seq -- seq' )
 131     [ length 2/ ] keep [
 132         [ [ 2 * 1 + ] dip nth-unsafe ] curry
 133     ] keep map-integers ;
 134
 135 : compact ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 136     [ split-when harvest ] dip join ; inline
 137
 138 : collapse ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 139     [ split-when ] dip
 140     [ [ harvest ] dip join ]
 141     [ [ first empty? ] dip [ prepend ] curry when ]
 142     [ [ last empty? ] dip [ append ] curry when ]
 143     2tri ; inline
 144
 145 :: slice-when ( seq quot: ( elt -- ? ) -- seq' )
 146     seq length :> len
 147     0 [ len dupd < ] [
 148         dup seq quot find-from drop
 149         [ 2dup = [ 1 + ] when ] [ len ] if*
 150         [ seq <slice> ] keep len or swap
 151     ] produce nip ; inline
 152
 153 : cut-slice* ( seq n -- before after )
 154     [ head-slice* ] [ tail-slice* ] 2bi ;
 155
 156 : rotate ( seq n -- seq' )
 157     cut prepend ;
 158
 159 :: rotate! ( seq n -- )
 160     n seq bounds-check length :> end
 161     0 n [ 2dup = ] [
 162         [ seq exchange-unsafe ] [ [ 1 + ] bi@ ] 2bi
 163         dup end = [ drop over ] when
 164         2over = [ -rot nip over ] when
 165     ] until 3drop ;
 166
 167 : all-rotations ( seq -- seq' )
 168     dup length iota [ rotate ] with map ;
 169
 170 <PRIVATE
 171
 172 : (appender-for) ( quot length exemplar -- appender accum )
 173     new-resizable [ [ push-all ] curry compose ] keep ; inline
 174
 175 PRIVATE>
 176
 177 : appender-for ( quot exemplar -- appender accum )
 178     [ length ] keep (appender-for) ; inline
 179
 180 : appender ( quot -- appender accum )
 181     V{ } appender-for ; inline
 182
 183 : map-concat-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 184     [ appender-for [ each ] dip ] keep like ; inline
 185
 186 : >resizable ( seq -- accum ) ! fixes map-concat "cannot apply call to run-time..."
 187     [ length ] keep [ new-resizable ] [ append! ] bi ;
 188
 189 : map-concat ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 190     over empty? [ 2drop { } ] [
 191         [ [ first ] dip call ] 2keep rot dup [
 192             >resizable [ [ push-all ] curry compose ] keep
 193             [ 1 ] 3dip [ (each) (each-integer) ] dip
 194         ] curry dip like
 195     ] if ; inline
 196
 197 : map-filter-as ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) exemplar -- ... subseq )
 198     [ pick ] dip swap length over
 199     [ (selector-for) [ compose each ] dip ] 2curry dip like ; inline
 200
 201 : map-filter ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) -- ... subseq )
 202     pick map-filter-as ; inline
 203
 204 : map-sift ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 205     [ ] map-filter ; inline
 206
 207 : map-harvest ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 208     [ empty? not ] map-filter ; inline
 209
 210 <PRIVATE
 211
 212 : ((each-from)) ( i seq -- n quot )
 213     [ length over [-] swap ] keep '[ _ + _ nth-unsafe ] ; inline
 214
 215 : (each-from) ( i seq quot -- n quot' )
 216     [ ((each-from)) ] dip compose ; inline
 217
 218 PRIVATE>
 219
 220 : map-from-as ( ... seq quot: ( ... elt -- ... newelt ) i exemplar -- ... newseq )
 221     [ -rot (each-from) ] dip map-integers ; inline
 222
 223 : map-from ( ... seq quot: ( ... elt -- ... newelt ) i -- ... newseq )
 224     pick map-from-as ; inline
 225
 226 <PRIVATE
 227
 228 : push-map-if ( ..a elt filter-quot: ( ..a elt -- ..b ? ) map-quot: ( ..a elt -- ..b newelt ) accum -- ..b )
 229     [ keep over ] 2dip [ when ] dip rot [ push ] [ 2drop ] if ; inline
 230
 231 : (filter-mapper-for) ( filter-quot map-quot length exempler -- filter-mapper accum )
 232     new-resizable [ [ push-map-if ] 3curry ] keep ; inline
 233
 234 : filter-mapper-for ( filter-quot map-quot exemplar -- filter-mapper accum )
 235     [ length ] keep (filter-mapper-for) ; inline
 236
 237 : filter-mapper ( filter-quot map-quot -- filter-mapper accum )
 238     V{ } filter-mapper-for ; inline
 239
 240 PRIVATE>
 241
 242 : filter-map-as ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 243     [ pick ] dip swap length over
 244     [ (filter-mapper-for) [ each ] dip ] 2curry dip like ; inline
 245
 246 : filter-map ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) -- ... newseq )
 247     pick filter-map-as ; inline
 248
 249 : 2map-sum ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... n ) -- ... n )
 250     [ 0 ] 3dip [ dip + ] curry [ rot ] prepose 2each ; inline
 251
 252 : 2count ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... n )
 253     [ 1 0 ? ] compose 2map-sum ; inline
 254
 255 : round-robin ( seq -- newseq )
 256     [ { } ] [
 257         [ longest length iota ] keep
 258         [ [ ?nth ] with map ] curry map concat sift
 259     ] if-empty ;
 260
 261 : sift-as ( seq exemplar -- newseq )
 262     [ ] swap filter-as ;
 263
 264 : sift! ( seq -- newseq )
 265     [ ] filter! ;
 266
 267 : harvest-as ( seq exemplar -- newseq )
 268     [ empty? not ] swap filter-as ;
 269
 270 : harvest! ( seq -- newseq )
 271     [ empty? ] reject! ;
 272
 273 : head-as ( seq n exemplar -- seq' )
 274     [ head-slice ] [ like ] bi* ; inline
 275
 276 : head*-as ( seq n exemplar -- seq' )
 277     [ head-slice* ] [ like ] bi* ; inline
 278
 279 : tail-as ( seq n exemplar -- seq' )
 280     [ tail-slice ] [ like ] bi* ; inline
 281
 282 : tail*-as ( seq n exemplar -- seq' )
 283     [ tail-slice* ] [ like ] bi* ; inline
 284
 285 : trim-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... newseq )
 286     [ trim-slice ] [ like ] bi* ; inline
 287
 288 : ?trim ( seq quot: ( elt -- ? ) -- seq/newseq )
 289     over empty? [ drop ] [
 290         over [ first-unsafe ] [ last-unsafe ] bi pick either?
 291         [ trim ] [ drop ] if
 292     ] if ; inline
 293
 294 : ?trim-head ( seq quot: ( elt -- ? ) -- seq/newseq )
 295     over empty? [ drop ] [
 296         over first-unsafe over call
 297         [ trim-head ] [ drop ] if
 298     ] if ; inline
 299
 300 : ?trim-tail ( seq quot: ( elt -- ? ) -- seq/newseq )
 301     over empty? [ drop ] [
 302         over last-unsafe over call
 303         [ trim-tail ] [ drop ] if
 304     ] if ; inline
 305
 306 : unsurround ( newseq seq2 seq3 -- seq1 )
 307    [ ?head drop ] [ ?tail drop ] bi* ;
 308
 309 : none? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 310     any? not ; inline
 311
 312 : one? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 313     [ find ] 2keep rot [
 314         [ 1 + ] 2dip find-from drop not
 315     ] [ 3drop f ] if ; inline
 316
 317 : map-index! ( ... seq quot: ( ... elt index -- ... newelt ) -- ... seq )
 318     over [ [ (each-index) ] dip collect ] keep ; inline
 319
 320 <PRIVATE
 321
 322 : (2each-index) ( seq1 seq2 quot -- n quot' )
 323     [ ((2each)) [ keep ] curry ] dip compose ; inline
 324
 325 PRIVATE>
 326
 327 : 2each-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... ) -- ... )
 328     (2each-index) each-integer ; inline
 329
 330 : 2map-into ( seq1 seq2 quot into -- )
 331     [ (2each) ] dip collect ; inline
 332
 333 : 2map! ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... seq1 )
 334     pick [ 2map-into ] keep ; inline
 335
 336 : 2map-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... newelt ) -- ... newseq )
 337     pick [ (2each-index) ] dip map-integers ; inline
 338
 339 TUPLE: evens seq length ;
 340
 341 : <evens> ( seq -- evens )
 342     dup length 1 + 2/ evens boa ; inline
 343
 344 M: evens length length>> ; inline
 345
 346 M: evens nth-unsafe [ 2 * ] [ seq>> nth-unsafe ] bi* ; inline
 347
 348 INSTANCE: evens immutable-sequence
 349
 350 TUPLE: odds seq length ;
 351
 352 : <odds> ( seq -- odds )
 353     dup length 2/ odds boa ; inline
 354
 355 M: odds length length>> ; inline
 356
 357 M: odds nth-unsafe [ 2 * 1 + ] [ seq>> nth-unsafe ] bi* ; inline
 358
 359 INSTANCE: odds immutable-sequence
 360
 361 : until-empty ( seq quot -- )
 362     [ dup empty? ] swap until drop ; inline
 363
 364 : arg-max ( seq -- n )
 365     <enum> [ second-unsafe ] supremum-by first ;
 366
 367 : arg-min ( seq -- n )
 368     <enum> [ second-unsafe ] infimum-by first ;
 369
 370 <PRIVATE
 371
 372 : push-index-if ( ..a elt i quot: ( ..a elt -- ..b ? ) accum -- ..b )
 373     [ dip ] dip rot [ push ] [ 2drop ] if ; inline
 374
 375 PRIVATE>
 376
 377 : arg-where ( ... seq quot: ( ... elt -- ... ? ) -- ... indices )
 378     over length <vector> [
 379         [ push-index-if ] 2curry each-index
 380     ] keep ; inline
 381
 382 : arg-sort ( seq -- indices )
 383     zip-index sort-keys values ;
 384
 385 : first= ( seq elt -- ? ) [ first ] dip = ; inline
 386 : second= ( seq elt -- ? ) [ second ] dip = ; inline
 387 : third= ( seq elt -- ? ) [ third ] dip = ; inline
 388 : fourth= ( seq elt -- ? ) [ fourth ] dip = ; inline
 389 : last= ( seq elt -- ? ) [ last ] dip = ; inline
 390 : nth= ( n seq elt -- ? ) [ nth ] dip = ; inline
 391
 392 : first? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ first ] dip call ; inline
 393 : second? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ second ] dip call ; inline
 394 : third? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ third ] dip call ; inline
 395 : fourth? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ fourth ] dip call ; inline
 396 : last? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ last ] dip call ; inline
 397 : nth? ( ... n seq quot: ( ... elt -- ... ? ) -- ... ? ) [ nth ] dip call ; inline
 398
 399 : loop>sequence ( quot exemplar -- seq )
 400    [ '[ [ @ [ [ , ] when* ] keep ] loop ] ] dip make ; inline
 401
 402 : loop>array ( quot -- seq )
 403    { } loop>sequence ; inline
 404
 405 <PRIVATE
 406
 407 : (reverse) ( seq -- newseq )
 408     dup [ length ] keep new-sequence
 409     [ 0 swap copy-unsafe ] keep reverse! ;
 410
 411 PRIVATE>
 412
 413 : reverse-as ( seq exemplar -- newseq )
 414     [ (reverse) ] [ like ] bi* ;
 415
 416 : map-product ( ... seq quot: ( ... elt -- ... n ) -- ... n )
 417     [ 1 ] 2dip [ dip * ] curry [ swap ] prepose each ; inline
 418
 419 : insert-nth! ( elt n seq -- )
 420     [ length ] keep ensure swap pick (a,b]
 421     over '[ [ 1 + ] keep _ move-unsafe ] each
 422     set-nth-unsafe ;
 423
 424 : set-nths ( value indices seq -- )
 425     swapd '[ _ swap _ set-nth ] each ; inline
 426
 427 : set-nths-unsafe ( value indices seq -- )
 428     swapd '[ _ swap _ set-nth-unsafe ] each ; inline
 429
 430 : flatten1 ( obj -- seq )
 431     [
 432         [
 433             dup branch? [
 434                 [ dup branch? [ % ] [ , ] if ] each
 435             ] [ , ] if
 436         ]
 437     ] keep dup branch? [ drop f ] unless make ;
 438
 439 <PRIVATE
 440
 441 : (map-find-index) ( seq quot find-quot -- result i elt )
 442     [ [ f ] 2dip [ [ nip ] 2dip call dup ] curry ] dip call
 443     [ [ [ drop f ] unless ] keep ] dip ; inline
 444
 445 PRIVATE>
 446
 447 : map-find-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 448     [ find-index ] (map-find-index) ; inline
 449
 450 : filter-length ( seq n -- seq' ) '[ length _ = ] filter ;
 451
 452 : all-shortest ( seqs -- seqs' ) dup shortest length filter-length ;
 453
 454 : all-longest ( seqs -- seqs' ) dup longest length filter-length ;
 455
 456 : remove-first ( obj seq -- seq' )
 457     [ index ] keep over [ remove-nth ] [ nip ] if ;
 458
 459 : remove-first! ( obj seq -- seq )
 460     [ index ] keep over [ remove-nth! ] [ nip ] if ;
 461
 462 : remove-last ( obj seq -- seq' )
 463     [ last-index ] keep over [ remove-nth ] [ nip ] if ;
 464
 465 : remove-last! ( obj seq -- seq )
 466     [ last-index ] keep over [ remove-nth! ] [ nip ] if ;
 467
 468 : ?first2 ( seq -- first/f second/f )
 469     dup length {
 470         { 0 [ drop f f ] }
 471         { 1 [ first-unsafe f ] }
 472         [ drop first2-unsafe ]
 473     } case ;
 474
 475 : ?first3 ( seq -- first/f second/f third/f )
 476     dup length {
 477         { 0 [ drop f f f ] }
 478         { 1 [ first-unsafe f f ] }
 479         { 2 [ first2-unsafe f ] }
 480         [ drop first3-unsafe ]
 481     } case ;
 482
 483 : ?first4 ( seq -- first/f second/f third/f fourth/f )
 484     dup length {
 485         { 0 [ drop f f f f ] }
 486         { 1 [ first-unsafe f f f ] }
 487         { 2 [ first2-unsafe f f ] }
 488         { 3 [ first3-unsafe f ] }
 489         [ drop first4-unsafe ]
 490     } case ;
 491
 492 : cut-when ( ... seq quot: ( ... elt -- ... ? ) -- ... before after )
 493     [ find drop ] 2keep drop swap
 494     [ cut ] [ f over like ] if* ; inline
 495
 496 : nth* ( n seq -- elt )
 497     [ length 1 - swap - ] [ nth ] bi ; inline
 498
 499 : each-index-from ( ... seq quot: ( ... elt index -- ... ) i -- ... )
 500     -rot (each-index) (each-integer) ; inline
 501
 502 <PRIVATE
 503
 504 : select-by* ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... i elt )
 505     [
 506         [ keep swap ] curry [ dip ] curry
 507         [ [ first 0 ] dip call ] 2keep
 508         [ 2curry 3dip 5 npick pick ] curry
 509     ] [
 510         [ [ 3drop ] [ [ 3drop ] 3dip ] if ] compose
 511     ] bi* compose 1 each-index-from nip swap ; inline
 512
 513 PRIVATE>
 514
 515 : supremum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 516     [ after? ] select-by* ; inline
 517
 518 : infimum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 519     [ before? ] select-by* ; inline
 520
 521 : change-last ( seq quot -- )
 522     [ drop length 1 - ] [ change-nth ] 2bi ; inline
 523
 524 : change-last-unsafe ( seq quot -- )
 525     [ drop length 1 - ] [ change-nth-unsafe ] 2bi ; inline
 526
 527 : replicate-into ( ... seq quot: ( ... -- ... newelt ) -- ... )
 528     over [ length ] 2dip '[ _ dip _ set-nth-unsafe ] each-integer ; inline
 529
 530 : count* ( ... seq quot: ( ... elt -- ... ? ) -- ... % )
 531     over [ count ] [ length ] bi* / ; inline
 532
 533 : find-last-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 534     [ [ 1 - ] dip find-last-integer ] (find-index) ; inline
 535
 536 : map-find-last-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 537     [ find-last-index ] (map-find-index) ; inline
 538
 539 :: (start-all) ( subseq seq increment -- indices )
 540     0
 541     [ [ subseq seq ] dip start* dup ]
 542     [ [ increment + ] keep ] produce nip ;
 543
 544 : start-all ( subseq seq -- indices )
 545     over length (start-all) ; inline
 546
 547 : start-all* ( subseq seq -- indices )
 548     1 (start-all) ; inline
 549
 550 : count-subseq ( subseq seq -- n )
 551     start-all length ; inline
 552
 553 : count-subseq* ( subseq seq -- n )
 554     start-all* length ; inline