extra/sequences/extras/extras.factor

   1 USING: accessors arrays assocs fry grouping growable kernel
   2 locals make math math.order math.ranges sequences
   3 sequences.deep sequences.private sorting splitting ;
   4 FROM: sequences => change-nth ;
   5 IN: sequences.extras
   6
   7 : reduce1 ( seq quot -- result ) [ unclip ] dip reduce ; inline
   8
   9 :: reduce-r ( list identity quot: ( obj1 obj2 -- obj ) -- result )
  10     list empty?
  11     [ identity ]
  12     [ list rest identity quot reduce-r list first quot call ] if ;
  13     inline recursive
  14
  15 ! Quot must have static stack effect, unlike "reduce"
  16 :: reduce* ( seq id quot -- result ) seq
  17     [ id ]
  18     [ unclip id swap quot call( prev elt -- next ) quot reduce* ] if-empty ; inline recursive
  19
  20 :: combos ( list1 list2 -- result )
  21     list2 [ [ 2array ] curry list1 swap map ] map concat ;
  22
  23 : find-all ( seq quot -- elts )
  24     [ [ length iota ] keep ] dip
  25     [ dupd call( a -- ? ) [ 2array ] [ 2drop f ] if ] curry
  26     2map [ ] filter ; inline
  27
  28 : insert-sorted ( elt seq -- seq )
  29     2dup [ < ] with find drop over length or swap insert-nth ;
  30
  31 : reduce-from ( ... seq identity quot: ( ... prev elt -- ... next ) i -- ... result )
  32     [ swap ] 2dip each-from ; inline
  33
  34 : all-subseqs ( seq -- seqs )
  35     dup length [1,b] [ clump ] with map concat ;
  36
  37 :: each-subseq ( ... seq quot: ( ... x -- ... ) -- ... )
  38     seq length :> len
  39     len [0,b] [
  40         :> from
  41         from len (a,b] [
  42             :> to
  43             from to seq subseq quot call( x -- )
  44         ] each
  45     ] each ;
  46
  47 : subseq-as ( from to seq exemplar -- subseq )
  48     [ check-slice subseq>copy (copy) ] dip like ;
  49
  50 : map-like ( seq exemplar -- seq' )
  51     '[ _ like ] map ; inline
  52
  53 : filter-all-subseqs-range ( ... seq range quot: ( ... x -- ... ) -- seq )
  54     [
  55         '[ <clumps> _ filter ] with map concat
  56     ] 3keep 2drop map-like ; inline
  57
  58 : filter-all-subseqs ( ... seq quot: ( ... x -- ... ) -- seq )
  59     [ dup length [1,b] ] dip filter-all-subseqs-range ; inline
  60
  61 :: longest-subseq ( seq1 seq2 -- subseq )
  62     seq1 length :> len1
  63     seq2 length :> len2
  64     0 :> n!
  65     0 :> end!
  66     len1 1 + [ len2 1 + 0 <array> ] replicate :> table
  67     len1 [1,b] [| x |
  68         len2 [1,b] [| y |
  69             x 1 - seq1 nth-unsafe
  70             y 1 - seq2 nth-unsafe = [
  71                 y 1 - x 1 - table nth-unsafe nth-unsafe 1 + :> len
  72                 len y x table nth-unsafe set-nth-unsafe
  73                 len n > [ len n! x end! ] when
  74             ] [ 0 y x table nth-unsafe set-nth-unsafe ] if
  75         ] each
  76     ] each end n - end seq1 subseq ;
  77
  78 : pad-longest ( seq1 seq2 elt -- seq1 seq2 )
  79     [ 2dup max-length ] dip [ pad-tail ] 2curry bi@ ;
  80
  81 : change-nths ( ... indices seq quot: ( ... elt -- ... elt' ) -- ... )
  82     [ change-nth ] 2curry each ; inline
  83
  84 : push-if-index ( ..a elt i quot: ( ..a elt i -- ..b ? ) accum -- ..b )
  85     [ 2keep drop ] dip rot [ push ] [ 2drop ] if ; inline
  86
  87 : index-selector-for ( quot exemplar -- selector accum )
  88     [ length ] keep new-resizable [ [ push-if-index ] 2curry ] keep ; inline
  89
  90 : filter-index-as ( ... seq quot: ( ... elt i -- ... ? ) exemplar -- ... seq' )
  91     dup [ index-selector-for [ each-index ] dip ] curry dip like ; inline
  92
  93 : filter-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... seq' )
  94     over filter-index-as ; inline
  95
  96 : even-indices ( seq -- seq' )
  97     [ length 1 + 2/ ] keep [
  98         [ [ 2 * ] dip nth-unsafe ] curry
  99     ] keep map-integers ;
 100
 101 : odd-indices ( seq -- seq' )
 102     [ length 2/ ] keep [
 103         [ [ 2 * 1 + ] dip nth-unsafe ] curry
 104     ] keep map-integers ;
 105
 106 : compact ( seq quot elt -- seq' )
 107     [ split-when harvest ] dip join ; inline
 108
 109 : collapse ( seq quot elt -- seq' )
 110     [ split-when ] dip
 111     [ [ harvest ] dip join ]
 112     [ [ first empty? ] dip [ prepend ] curry when ]
 113     [ [ last empty? ] dip [ append ] curry when ]
 114     2tri ; inline
 115
 116 :: slice-when ( seq quot: ( elt -- ? ) -- seq' )
 117     seq length :> len
 118     0 [ len dupd < ] [
 119         dup seq quot find-from drop
 120         [ 2dup = [ 1 + ] when ] [ len ] if*
 121         [ seq <slice> ] keep len or swap
 122     ] produce nip ; inline
 123
 124 : rotate ( seq n -- seq' )
 125     cut prepend ;
 126
 127 :: rotate! ( seq n -- )
 128     n seq bounds-check length :> end
 129     0 n [ 2dup = ] [
 130         [ seq exchange-unsafe ] [ [ 1 + ] bi@ ] 2bi
 131         dup end = [ drop over ] when
 132         2over = [ -rot nip over ] when
 133     ] until 3drop ;
 134
 135 : all-rotations ( seq -- seq' )
 136     dup length iota [ rotate ] with map ;
 137
 138 : appender-for ( quot exemplar -- quot' vec )
 139     [ length ] keep new-resizable
 140     [ [ push-all ] curry compose ] keep ; inline
 141
 142 : appender ( quot -- quot' vec )
 143     V{ } appender-for ; inline
 144
 145 : map-concat-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 146     dup [ appender-for [ each ] dip ] curry dip like ; inline
 147
 148 : >resizable ( seq -- vec ) ! fixes map-concat "cannot apply call to run-time..."
 149     [ length ] keep [ new-resizable ] [ over push-all ] bi ;
 150
 151 : map-concat ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 152     over [ 2drop { } ] [
 153         first over call dup [
 154             >resizable [ [ push-all ] curry compose ] keep
 155             [ 1 ] 3dip [ (each) (each-integer) ] dip
 156         ] curry dip like
 157     ] if-empty ; inline
 158
 159 : map-filter-as ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) exemplar -- ... subseq )
 160     dup [ selector-for [ compose each ] dip ] curry dip like ; inline
 161
 162 : map-filter ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) -- ... subseq )
 163     pick map-filter-as ; inline
 164
 165 : map-sift ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 166     [ ] map-filter ; inline
 167
 168 : map-harvest ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 169     [ empty? not ] map-filter ; inline
 170
 171 <PRIVATE
 172
 173 : ((each-from)) ( i seq -- n quot )
 174     [ length over [-] swap ] keep '[ _ + _ nth-unsafe ] ; inline
 175
 176 : (each-from) ( i seq quot -- n quot' ) [ ((each-from)) ] dip compose ;
 177     inline
 178
 179 PRIVATE>
 180
 181 : map-from-as ( ... seq quot: ( ... elt -- ... newelt ) i exemplar -- ... newseq )
 182     [ -rot (each-from) ] dip map-integers ; inline
 183
 184 : map-from ( ... seq quot: ( ... elt -- ... newelt ) i -- ... newseq )
 185     pick map-from-as ; inline
 186
 187 <PRIVATE
 188
 189 : push-map-if ( ..a elt filter-quot: ( ..a elt -- ..b ? ) map-quot: ( ..a elt -- ..b newelt ) accum -- ..b )
 190     [ keep over ] 2dip [ when ] dip rot [ push ] [ 2drop ] if ; inline
 191
 192 : filter-mapper-for ( filter-quot map-quot exemplar -- quot' vec )
 193     [ length ] keep new-resizable [ [ push-map-if ] 3curry ] keep ; inline
 194
 195 : filter-mapper ( filter-quot map-quot -- quot' vec )
 196     V{ } filter-mapper-for ; inline
 197
 198 PRIVATE>
 199
 200 : filter-map-as ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 201     dup [ filter-mapper-for [ each ] dip ] curry dip like ; inline
 202
 203 : filter-map ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) -- ... newseq )
 204     pick filter-map-as ; inline
 205
 206 : 2map-sum ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... n ) -- ... n )
 207     [ 0 ] 3dip [ dip + ] curry [ rot ] prepose 2each ; inline
 208
 209 : 2count ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... n )
 210     [ 1 0 ? ] compose 2map-sum ; inline
 211
 212 : round-robin ( seq -- newseq )
 213     [ { } ] [
 214         [ longest length iota ] keep
 215         [ [ ?nth ] with map ] curry map concat sift
 216     ] if-empty ;
 217
 218 : sift-as ( seq exemplar -- newseq )
 219     [ ] swap filter-as ;
 220
 221 : sift! ( seq -- newseq )
 222     [ ] filter! ;
 223
 224 : harvest-as ( seq exemplar -- newseq )
 225     [ empty? not ] swap filter-as ;
 226
 227 : harvest! ( seq -- newseq )
 228     [ empty? not ] filter! ;
 229
 230 : contains? ( seq elts -- ? )
 231     [ member? ] curry any? ; inline
 232
 233 : head-as ( seq n exemplar -- seq' )
 234     [ head-slice ] [ like ] bi* ; inline
 235
 236 : head*-as ( seq n exemplar -- seq' )
 237     [ head-slice* ] [ like ] bi* ; inline
 238
 239 : tail-as ( seq n exemplar -- seq' )
 240     [ tail-slice ] [ like ] bi* ; inline
 241
 242 : tail*-as ( seq n exemplar -- seq' )
 243     [ tail-slice* ] [ like ] bi* ; inline
 244
 245 : trim-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... newseq )
 246     [ trim-slice ] [ like ] bi* ; inline
 247
 248 : ?trim ( seq quot: ( elt -- ? ) -- seq/newseq )
 249     over empty? [ drop ] [
 250         over [ first-unsafe ] [ last-unsafe ] bi pick bi@ or
 251         [ trim ] [ drop ] if
 252     ] if ; inline
 253
 254 : ?trim-head ( seq quot: ( elt -- ? ) -- seq/newseq )
 255     over empty? [ drop ] [
 256         over first-unsafe over call
 257         [ trim-head ] [ drop ] if
 258     ] if ; inline
 259
 260 : ?trim-tail ( seq quot: ( elt -- ? ) -- seq/newseq )
 261     over empty? [ drop ] [
 262         over last-unsafe over call
 263         [ trim-tail ] [ drop ] if
 264     ] if ; inline
 265
 266 : unsurround ( newseq seq2 seq3 -- seq1 )
 267    [ ?head drop ] [ ?tail drop ] bi* ;
 268
 269 : none? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 270     any? not ; inline
 271
 272 : one? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 273     [ find ] 2keep rot [
 274         [ 1 + ] 2dip find-from drop not
 275     ] [ 3drop f ] if ; inline
 276
 277 : map-index! ( ... seq quot: ( ... elt index -- ... newelt ) -- ... seq )
 278     over [ [ (each-index) ] dip collect ] keep ; inline
 279
 280 <PRIVATE
 281
 282 : (2each-index) ( seq1 seq2 quot -- n quot' )
 283     [ ((2each)) [ keep ] curry ] dip compose ; inline
 284
 285 PRIVATE>
 286
 287 : 2each-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... ) -- ... )
 288     (2each-index) each-integer ; inline
 289
 290 : 2map-into ( seq1 seq2 quot into -- )
 291     [ (2each) ] dip collect ; inline
 292
 293 : 2map! ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... seq1 )
 294     pick [ 2map-into ] keep ; inline
 295
 296 : 2map-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... newelt ) -- ... newseq )
 297     pick [ (2each-index) ] dip map-integers ; inline
 298
 299 TUPLE: evens seq length ;
 300
 301 : <evens> ( seq -- evens )
 302     dup length 1 + 2/ evens boa ; inline
 303
 304 M: evens length length>> ; inline
 305
 306 M: evens nth-unsafe [ 2 * ] [ seq>> nth-unsafe ] bi* ; inline
 307
 308 INSTANCE: evens immutable-sequence
 309
 310 TUPLE: odds seq length ;
 311
 312 : <odds> ( seq -- odds )
 313     dup length 2/ odds boa ; inline
 314
 315 M: odds length length>> ; inline
 316
 317 M: odds nth-unsafe [ 2 * 1 + ] [ seq>> nth-unsafe ] bi* ; inline
 318
 319 INSTANCE: odds immutable-sequence
 320
 321 : until-empty ( seq quot -- )
 322     [ dup empty? ] swap until drop ; inline
 323
 324 : arg-max ( seq -- n )
 325     dup length iota zip [ first-unsafe ] supremum-by second ;
 326
 327 : arg-min ( seq -- n )
 328     dup length iota zip [ first-unsafe ] infimum-by second ;
 329
 330 : arg-where ( ... seq quot: ( ... elt -- ... ? ) -- ... indices )
 331     [ dup length iota zip ] dip
 332     [ first-unsafe ] prepose filter values ; inline
 333
 334 : arg-sort ( seq -- indices )
 335     dup length iota zip sort-keys values ;
 336
 337 : first= ( seq elt -- ? ) [ first ] dip = ; inline
 338 : second= ( seq elt -- ? ) [ second ] dip = ; inline
 339 : third= ( seq elt -- ? ) [ third ] dip = ; inline
 340 : fourth= ( seq elt -- ? ) [ fourth ] dip = ; inline
 341 : last= ( seq elt -- ? ) [ last ] dip = ; inline
 342 : nth= ( n seq elt -- ? ) [ nth ] dip = ; inline
 343
 344 : first? ( seq quot -- ? ) [ first ] dip call ; inline
 345 : second? ( seq quot -- ? ) [ second ] dip call ; inline
 346 : third? ( seq quot -- ? ) [ third ] dip call ; inline
 347 : fourth? ( seq quot -- ? ) [ fourth ] dip call ; inline
 348 : last? ( seq quot -- ? ) [ last ] dip call ; inline
 349 : nth? ( n seq quot -- ? ) [ nth ] dip call ; inline
 350
 351 : loop>sequence ( quot exemplar -- seq )
 352    [ '[ [ @ [ [ , ] when* ] keep ] loop ] ] dip make ; inline
 353
 354 : loop>array ( quot -- seq )
 355    { } loop>sequence ; inline
 356
 357 <PRIVATE
 358
 359 : (reverse) ( seq -- newseq )
 360     dup [ length ] keep new-sequence [ 0 swap copy ] keep reverse! ;
 361
 362 PRIVATE>
 363
 364 : reverse-as ( seq exemplar -- newseq )
 365     [ (reverse) ] [ like ] bi* ;
 366
 367 : map-product ( ... seq quot: ( ... elt -- ... n ) -- ... n )
 368     [ 1 ] 2dip [ dip * ] curry [ swap ] prepose each ; inline
 369
 370 : insert-nth! ( elt n seq -- )
 371     [ length ] keep ensure swap pick (a,b]
 372     over '[ [ 1 + ] keep _ move-unsafe ] each
 373     set-nth-unsafe ;
 374
 375 : set-nths ( value indices seq -- )
 376     swapd '[ [ _ ] dip _ set-nth ] each ; inline
 377
 378 : set-nths-unsafe ( value indices seq -- )
 379     swapd '[ [ _ ] dip _ set-nth-unsafe ] each ; inline
 380
 381 : flatten1 ( obj -- seq )
 382     [
 383         [
 384             dup branch? [
 385                 [ dup branch? [ % ] [ , ] if ] each
 386             ] [ , ] if
 387         ]
 388     ] keep dup branch? [ drop f ] unless make ;
 389
 390 : (map-find-index) ( seq quot find-quot -- result elt index )
 391     [ [ f ] 2dip [ [ nip ] 2dip call dup ] curry ] dip call
 392     [ [ [ drop f ] unless ] keep ] dip ; inline
 393
 394 : map-find-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result elt index )
 395     [ find-index ] (map-find-index) ; inline
 396
 397 : filter-length ( seq n -- seq' ) swap [ length = ] with filter ;
 398
 399 : all-shortest ( seqs -- seqs' ) dup shortest length filter-length ;
 400
 401 : all-longest ( seqs -- seqs' ) dup longest length filter-length ;