extra/sequences/extras/extras.factor

   1 USING: accessors arrays assocs fry grouping kernel locals math
   2 math.order math.ranges sequences sequences.private splitting ;
   3 FROM: sequences => change-nth ;
   4 IN: sequences.extras
   5
   6 : reduce1 ( seq quot -- result ) [ unclip ] dip reduce ; inline
   7
   8 :: reduce-r ( list identity quot: ( obj1 obj2 -- obj ) -- result )
   9     list empty?
  10     [ identity ]
  11     [ list rest identity quot reduce-r list first quot call ] if ;
  12     inline recursive
  13
  14 ! Quot must have static stack effect, unlike "reduce"
  15 :: reduce* ( seq id quot -- result ) seq
  16     [ id ]
  17     [ unclip id swap quot call( prev elt -- next ) quot reduce* ] if-empty ; inline recursive
  18
  19 :: combos ( list1 list2 -- result )
  20     list2 [ [ 2array ] curry list1 swap map ] map concat ;
  21
  22 : find-all ( seq quot -- elts )
  23     [ [ length iota ] keep ] dip
  24     [ dupd call( a -- ? ) [ 2array ] [ 2drop f ] if ] curry
  25     2map [ ] filter ; inline
  26
  27 : insert-sorted ( elt seq -- seq )
  28     2dup [ < ] with find drop over length or swap insert-nth ;
  29
  30 : each-from ( ... seq quot: ( ... x -- ... ) i -- ... )
  31     -rot (each) (each-integer) ; inline
  32
  33 : reduce-from ( ... seq identity quot: ( ... prev elt -- ... next ) i -- ... result )
  34     [ swap ] 2dip each-from ; inline
  35
  36 : supremum-by ( seq quot: ( ... elt -- ... x ) -- elt )
  37     [ [ first dup ] dip call ] 2keep [
  38         dupd call pick dupd after?
  39         [ [ 2drop ] 2dip ] [ 2drop ] if
  40     ] curry 1 each-from drop ; inline
  41
  42 : infimum-by ( seq quot: ( ... elt -- ... x ) -- elt )
  43     [ [ first dup ] dip call ] 2keep [
  44         dupd call pick dupd before?
  45         [ [ 2drop ] 2dip ] [ 2drop ] if
  46     ] curry 1 each-from drop ; inline
  47
  48 : all-subseqs ( seq -- seqs )
  49     dup length [1,b] [ <clumps> ] with map concat ;
  50
  51 :: each-subseq ( ... seq quot: ( ... x -- ... ) -- ... )
  52     seq length :> len
  53     len [0,b] [
  54         :> from
  55         from len (a,b] [
  56             :> to
  57             from to seq subseq quot call( x -- )
  58         ] each
  59     ] each ;
  60
  61 :: longest-subseq ( seq1 seq2 -- subseq )
  62     seq1 length :> len1
  63     seq2 length :> len2
  64     0 :> n!
  65     0 :> end!
  66     len1 1 + [ len2 1 + 0 <array> ] replicate :> table
  67     len1 [1,b] [| x |
  68         len2 [1,b] [| y |
  69             x 1 - seq1 nth-unsafe
  70             y 1 - seq2 nth-unsafe = [
  71                 y 1 - x 1 - table nth-unsafe nth-unsafe 1 + :> len
  72                 len y x table nth-unsafe set-nth-unsafe
  73                 len n > [ len n! x end! ] when
  74             ] [ 0 y x table nth-unsafe set-nth-unsafe ] if
  75         ] each
  76     ] each end n - end seq1 subseq ;
  77
  78 : pad-longest ( seq1 seq2 elt -- seq1 seq2 )
  79     [ 2dup max-length ] dip [ pad-tail ] 2curry bi@ ;
  80
  81 : change-nths ( ... indices seq quot: ( ... elt -- ... elt' ) -- ... )
  82     [ change-nth ] 2curry each ; inline
  83
  84 : push-if-index ( ..a elt i quot: ( ..a elt i -- ..b ? ) accum -- ..b )
  85     [ 2keep drop ] dip rot [ push ] [ 2drop ] if ; inline
  86
  87 : index-selector-for ( quot exemplar -- selector accum )
  88     [ length ] keep new-resizable [ [ push-if-index ] 2curry ] keep ; inline
  89
  90 : filter-index-as ( ... seq quot: ( ... elt i -- ... ? ) exemplar -- ... seq' )
  91     dup [ index-selector-for [ each-index ] dip ] curry dip like ; inline
  92
  93 : filter-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... seq' )
  94     over filter-index-as ; inline
  95
  96 : even-indices ( seq -- seq' ) [ nip even? ] filter-index ;
  97
  98 : odd-indices ( seq -- seq' ) [ nip odd? ] filter-index ;
  99
 100 : compact ( seq quot elt -- seq' )
 101     [ split-when harvest ] dip join ; inline
 102
 103 : collapse ( seq quot elt -- seq' )
 104     [ split-when ] dip
 105     [ [ harvest ] dip join ]
 106     [ [ first empty? ] dip [ prepend ] curry when ]
 107     [ [ last empty? ] dip [ append ] curry when ]
 108     2tri ; inline
 109
 110 :: slice-when ( seq quot: ( elt -- ? ) -- seq' )
 111     seq length :> len
 112     0 [ len dupd < ] [
 113         dup seq quot find-from drop
 114         [ 2dup = [ 1 + ] when ] [ len ] if*
 115         [ seq <slice> ] keep len or swap
 116     ] produce nip ; inline
 117
 118 : rotate ( seq n -- seq' )
 119     cut prepend ;
 120
 121 :: rotate! ( seq n -- )
 122     n seq bounds-check length :> end
 123     0 n [ 2dup = ] [
 124         [ seq exchange-unsafe ] [ [ 1 + ] bi@ ] 2bi
 125         dup end = [ drop over ] when
 126         2over = [ -rot nip over ] when
 127     ] until 3drop ;
 128
 129 : all-rotations ( seq -- seq' )
 130     dup length iota [ rotate ] with map ;
 131
 132 : appender-for ( quot exemplar -- quot' vec )
 133     [ length ] keep new-resizable
 134     [ [ push-all ] curry compose ] keep ; inline
 135
 136 : appender ( quot -- quot' vec )
 137     V{ } appender-for ; inline
 138
 139 : map-concat-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 140     dup [ appender-for [ each ] dip ] curry dip like ; inline
 141
 142 : >resizable ( seq -- vec ) ! fixes map-concat "cannot apply call to run-time..."
 143     [ length ] keep [ new-resizable ] [ over push-all ] bi ;
 144
 145 : map-concat ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 146     over [ 2drop { } ] [
 147         first over call dup [
 148             >resizable [ [ push-all ] curry compose ] keep
 149             [ 1 ] 3dip [ (each) (each-integer) ] dip
 150         ] curry dip like
 151     ] if-empty ; inline
 152
 153 : map-filter-as ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) exemplar -- ... subseq )
 154     dup [ selector-for [ compose each ] dip ] curry dip like ; inline
 155
 156 : map-filter ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) -- ... subseq )
 157     pick map-filter-as ; inline
 158
 159 : map-sift ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 160     [ ] map-filter ; inline
 161
 162 : map-harvest ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 163     [ empty? not ] map-filter ; inline
 164
 165 <PRIVATE
 166
 167 : ((each-from)) ( i seq -- n quot )
 168     [ length over - 0 max swap ] keep '[ _ + _ nth-unsafe ] ; inline
 169
 170 : (each-from) ( i seq quot -- n quot' ) [ ((each-from)) ] dip compose ;
 171     inline
 172
 173 PRIVATE>
 174
 175 : map-from-as ( ... seq quot: ( ... elt -- ... newelt ) i exemplar -- ... newseq )
 176     [ -rot (each-from) ] dip map-integers ; inline
 177
 178 : map-from ( ... seq quot: ( ... elt -- ... newelt ) i -- ... newseq )
 179     pick map-from-as ; inline
 180
 181 <PRIVATE
 182
 183 : push-map-if ( ..a elt filter-quot: ( ..a elt -- ..b ? ) map-quot: ( ..a elt -- ..b newelt ) accum -- ..b )
 184     [ keep over ] 2dip [ when ] dip rot [ push ] [ 2drop ] if ; inline
 185
 186 : filter-mapper-for ( filter-quot map-quot exemplar -- quot' vec )
 187     [ length ] keep new-resizable [ [ push-map-if ] 3curry ] keep ; inline
 188
 189 : filter-mapper ( filter-quot map-quot -- quot' vec )
 190     V{ } filter-mapper-for ; inline
 191
 192 PRIVATE>
 193
 194 : filter-map-as ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 195     dup [ filter-mapper-for [ each ] dip ] curry dip like ; inline
 196
 197 : filter-map ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) -- ... newseq )
 198     pick filter-map-as ; inline
 199
 200 : 2map-sum ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... n ) -- ... n )
 201     [ 0 ] 3dip [ dip + ] curry [ rot ] prepose 2each ; inline
 202
 203 : 2count ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... n )
 204     [ 1 0 ? ] compose 2map-sum ; inline
 205
 206 : round-robin ( seq -- newseq )
 207     [ { } ] [
 208         [ [ length ] [ max ] map-reduce iota ] keep
 209         [ [ ?nth ] with map ] curry map concat sift
 210     ] if-empty ;
 211
 212 : sift-as ( seq exemplar -- newseq )
 213     [ ] swap filter-as ;
 214
 215 : harvest-as ( seq exemplar -- newseq )
 216     [ empty? not ] swap filter-as ;
 217
 218 : contains? ( seq elts -- ? )
 219     [ member? ] curry any? ; inline
 220
 221 : trim-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... newseq )
 222     [ trim-slice ] [ like ] bi* ; inline
 223
 224 : ?trim ( ... seq quot: ( ... elt -- ... ? ) -- ... seq/newseq )
 225     over empty? [ drop ] [
 226         over [ first-unsafe ] [ last-unsafe ] bi pick bi@ or
 227         [ trim ] [ drop ] if
 228     ] if ; inline
 229
 230 : unsurround ( newseq seq2 seq3 -- seq1 )
 231    [ ?head drop ] [ ?tail drop ] bi* ;
 232
 233 : none? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 234     any? not ; inline
 235
 236 : one? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 237     [ find ] 2keep rot [
 238         [ 1 + ] 2dip find-from drop not
 239     ] [ 3drop f ] if ; inline
 240
 241 : map-index! ( ... seq quot: ( ... elt index -- ... newelt ) -- ... seq )
 242     over [ [ (each-index) ] dip collect ] keep ; inline
 243
 244 <PRIVATE
 245
 246 : (2each-index) ( seq1 seq2 quot -- n quot' )
 247     [ ((2each)) [ keep ] curry ] dip compose ; inline
 248
 249 PRIVATE>
 250
 251 : 2each-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... ) -- ... )
 252     (2each-index) each-integer ; inline
 253
 254 : 2map-into ( seq1 seq2 quot into -- )
 255     [ (2each) ] dip collect ; inline
 256
 257 : 2map! ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... seq1 )
 258     pick [ 2map-into ] keep ; inline
 259
 260 : 2map-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... newelt ) -- ... newseq )
 261     pick [ (2each-index) ] dip map-integers ; inline
 262
 263 TUPLE: evens seq length ;
 264
 265 : <evens> ( seq -- evens )
 266     dup length 1 + 2/ evens boa ; inline
 267
 268 M: evens length length>> ; inline
 269
 270 M: evens nth-unsafe [ 2 * ] [ seq>> nth-unsafe ] bi* ; inline
 271
 272 INSTANCE: evens immutable-sequence
 273
 274 TUPLE: odds seq length ;
 275
 276 : <odds> ( seq -- odds )
 277     dup length 2/ odds boa ; inline
 278
 279 M: odds length length>> ; inline
 280
 281 M: odds nth-unsafe [ 2 * 1 + ] [ seq>> nth-unsafe ] bi* ; inline
 282
 283 INSTANCE: odds immutable-sequence
 284
 285 : until-empty ( seq quot -- )
 286     [ dup empty? ] swap until drop ; inline
 287
 288 : arg-max ( seq -- n )
 289     dup length iota zip [ first-unsafe ] supremum-by second ;
 290
 291 : arg-min ( seq -- n )
 292     dup length iota zip [ first-unsafe ] infimum-by second ;
 293
 294 : arg-where ( ... seq quot: ( ... elt -- ... ? ) -- ... indices )
 295     [ dup length iota zip ] dip
 296     [ first-unsafe ] prepose filter values ; inline
 297
 298 : first= ( seq elt -- ? ) [ first ] dip = ; inline
 299 : second= ( seq elt -- ? ) [ second ] dip = ; inline
 300 : third= ( seq elt -- ? ) [ third ] dip = ; inline
 301 : fourth= ( seq elt -- ? ) [ fourth ] dip = ; inline
 302 : last= ( seq elt -- ? ) [ last ] dip = ; inline
 303 : nth= ( n seq elt -- ? ) [ nth ] dip = ; inline
 304
 305 : first? ( seq quot -- ? ) [ first ] dip call ; inline
 306 : second? ( seq quot -- ? ) [ second ] dip call ; inline
 307 : third? ( seq quot -- ? ) [ third ] dip call ; inline
 308 : fourth? ( seq quot -- ? ) [ fourth ] dip call ; inline
 309 : last? ( seq quot -- ? ) [ last ] dip call ; inline
 310 : nth? ( n seq quot -- ? ) [ nth ] dip call ; inline