extra/sequences/extras/extras.factor

   1 USING: accessors arrays assocs fry grouping growable kernel
   2 locals make math math.order math.ranges sequences
   3 sequences.deep sequences.private sorting splitting ;
   4 FROM: sequences => change-nth ;
   5 IN: sequences.extras
   6
   7 : reduce1 ( seq quot -- result ) [ unclip ] dip reduce ; inline
   8
   9 :: reduce-r ( list identity quot: ( obj1 obj2 -- obj ) -- result )
  10     list empty?
  11     [ identity ]
  12     [ list rest identity quot reduce-r list first quot call ] if ;
  13     inline recursive
  14
  15 ! Quot must have static stack effect, unlike "reduce"
  16 :: reduce* ( seq id quot -- result ) seq
  17     [ id ]
  18     [ unclip id swap quot call( prev elt -- next ) quot reduce* ] if-empty ; inline recursive
  19
  20 :: combos ( list1 list2 -- result )
  21     list2 [ [ 2array ] curry list1 swap map ] map concat ;
  22
  23 : find-all ( seq quot -- elts )
  24     [ [ length iota ] keep ] dip
  25     [ dupd call( a -- ? ) [ 2array ] [ 2drop f ] if ] curry
  26     2map [ ] filter ; inline
  27
  28 : insert-sorted ( elt seq -- seq )
  29     2dup [ < ] with find drop over length or swap insert-nth ;
  30
  31 : reduce-from ( ... seq identity quot: ( ... prev elt -- ... next ) i -- ... result )
  32     [ swap ] 2dip each-from ; inline
  33
  34 : all-subseqs ( seq -- seqs )
  35     dup length [1,b] [ <clumps> ] with map concat ;
  36
  37 :: each-subseq ( ... seq quot: ( ... x -- ... ) -- ... )
  38     seq length :> len
  39     len [0,b] [
  40         :> from
  41         from len (a,b] [
  42             :> to
  43             from to seq subseq quot call( x -- )
  44         ] each
  45     ] each ;
  46
  47 : map-like ( seq exemplar -- seq' )
  48     '[ _ like ] map ; inline
  49
  50 : filter-all-subseqs-range ( ... seq range quot: ( ... x -- ... ) -- seq )
  51     [
  52         '[ <sliced-clumps> _ filter ] with map concat
  53     ] 3keep 2drop map-like ; inline
  54
  55 : filter-all-subseqs ( ... seq quot: ( ... x -- ... ) -- seq )
  56     [ dup length [1,b] ] dip filter-all-subseqs-range ; inline
  57
  58 :: longest-subseq ( seq1 seq2 -- subseq )
  59     seq1 length :> len1
  60     seq2 length :> len2
  61     0 :> n!
  62     0 :> end!
  63     len1 1 + [ len2 1 + 0 <array> ] replicate :> table
  64     len1 [1,b] [| x |
  65         len2 [1,b] [| y |
  66             x 1 - seq1 nth-unsafe
  67             y 1 - seq2 nth-unsafe = [
  68                 y 1 - x 1 - table nth-unsafe nth-unsafe 1 + :> len
  69                 len y x table nth-unsafe set-nth-unsafe
  70                 len n > [ len n! x end! ] when
  71             ] [ 0 y x table nth-unsafe set-nth-unsafe ] if
  72         ] each
  73     ] each end n - end seq1 subseq ;
  74
  75 : pad-longest ( seq1 seq2 elt -- seq1 seq2 )
  76     [ 2dup max-length ] dip [ pad-tail ] 2curry bi@ ;
  77
  78 : change-nths ( ... indices seq quot: ( ... elt -- ... elt' ) -- ... )
  79     [ change-nth ] 2curry each ; inline
  80
  81 : push-if-index ( ..a elt i quot: ( ..a elt i -- ..b ? ) accum -- ..b )
  82     [ 2keep drop ] dip rot [ push ] [ 2drop ] if ; inline
  83
  84 : index-selector-for ( quot exemplar -- selector accum )
  85     [ length ] keep new-resizable [ [ push-if-index ] 2curry ] keep ; inline
  86
  87 : filter-index-as ( ... seq quot: ( ... elt i -- ... ? ) exemplar -- ... seq' )
  88     dup [ index-selector-for [ each-index ] dip ] curry dip like ; inline
  89
  90 : filter-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... seq' )
  91     over filter-index-as ; inline
  92
  93 : even-indices ( seq -- seq' ) [ nip even? ] filter-index ;
  94
  95 : odd-indices ( seq -- seq' ) [ nip odd? ] filter-index ;
  96
  97 : compact ( seq quot elt -- seq' )
  98     [ split-when harvest ] dip join ; inline
  99
 100 : collapse ( seq quot elt -- seq' )
 101     [ split-when ] dip
 102     [ [ harvest ] dip join ]
 103     [ [ first empty? ] dip [ prepend ] curry when ]
 104     [ [ last empty? ] dip [ append ] curry when ]
 105     2tri ; inline
 106
 107 :: slice-when ( seq quot: ( elt -- ? ) -- seq' )
 108     seq length :> len
 109     0 [ len dupd < ] [
 110         dup seq quot find-from drop
 111         [ 2dup = [ 1 + ] when ] [ len ] if*
 112         [ seq <slice> ] keep len or swap
 113     ] produce nip ; inline
 114
 115 : rotate ( seq n -- seq' )
 116     cut prepend ;
 117
 118 :: rotate! ( seq n -- )
 119     n seq bounds-check length :> end
 120     0 n [ 2dup = ] [
 121         [ seq exchange-unsafe ] [ [ 1 + ] bi@ ] 2bi
 122         dup end = [ drop over ] when
 123         2over = [ -rot nip over ] when
 124     ] until 3drop ;
 125
 126 : all-rotations ( seq -- seq' )
 127     dup length iota [ rotate ] with map ;
 128
 129 : appender-for ( quot exemplar -- quot' vec )
 130     [ length ] keep new-resizable
 131     [ [ push-all ] curry compose ] keep ; inline
 132
 133 : appender ( quot -- quot' vec )
 134     V{ } appender-for ; inline
 135
 136 : map-concat-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 137     dup [ appender-for [ each ] dip ] curry dip like ; inline
 138
 139 : >resizable ( seq -- vec ) ! fixes map-concat "cannot apply call to run-time..."
 140     [ length ] keep [ new-resizable ] [ over push-all ] bi ;
 141
 142 : map-concat ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 143     over [ 2drop { } ] [
 144         first over call dup [
 145             >resizable [ [ push-all ] curry compose ] keep
 146             [ 1 ] 3dip [ (each) (each-integer) ] dip
 147         ] curry dip like
 148     ] if-empty ; inline
 149
 150 : map-filter-as ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) exemplar -- ... subseq )
 151     dup [ selector-for [ compose each ] dip ] curry dip like ; inline
 152
 153 : map-filter ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) -- ... subseq )
 154     pick map-filter-as ; inline
 155
 156 : map-sift ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 157     [ ] map-filter ; inline
 158
 159 : map-harvest ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 160     [ empty? not ] map-filter ; inline
 161
 162 <PRIVATE
 163
 164 : ((each-from)) ( i seq -- n quot )
 165     [ length over [-] swap ] keep '[ _ + _ nth-unsafe ] ; inline
 166
 167 : (each-from) ( i seq quot -- n quot' ) [ ((each-from)) ] dip compose ;
 168     inline
 169
 170 PRIVATE>
 171
 172 : map-from-as ( ... seq quot: ( ... elt -- ... newelt ) i exemplar -- ... newseq )
 173     [ -rot (each-from) ] dip map-integers ; inline
 174
 175 : map-from ( ... seq quot: ( ... elt -- ... newelt ) i -- ... newseq )
 176     pick map-from-as ; inline
 177
 178 <PRIVATE
 179
 180 : push-map-if ( ..a elt filter-quot: ( ..a elt -- ..b ? ) map-quot: ( ..a elt -- ..b newelt ) accum -- ..b )
 181     [ keep over ] 2dip [ when ] dip rot [ push ] [ 2drop ] if ; inline
 182
 183 : filter-mapper-for ( filter-quot map-quot exemplar -- quot' vec )
 184     [ length ] keep new-resizable [ [ push-map-if ] 3curry ] keep ; inline
 185
 186 : filter-mapper ( filter-quot map-quot -- quot' vec )
 187     V{ } filter-mapper-for ; inline
 188
 189 PRIVATE>
 190
 191 : filter-map-as ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 192     dup [ filter-mapper-for [ each ] dip ] curry dip like ; inline
 193
 194 : filter-map ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) -- ... newseq )
 195     pick filter-map-as ; inline
 196
 197 : 2map-sum ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... n ) -- ... n )
 198     [ 0 ] 3dip [ dip + ] curry [ rot ] prepose 2each ; inline
 199
 200 : 2count ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... n )
 201     [ 1 0 ? ] compose 2map-sum ; inline
 202
 203 : round-robin ( seq -- newseq )
 204     [ { } ] [
 205         [ longest length iota ] keep
 206         [ [ ?nth ] with map ] curry map concat sift
 207     ] if-empty ;
 208
 209 : sift-as ( seq exemplar -- newseq )
 210     [ ] swap filter-as ;
 211
 212 : sift! ( seq -- newseq )
 213     [ ] filter! ;
 214
 215 : harvest-as ( seq exemplar -- newseq )
 216     [ empty? not ] swap filter-as ;
 217
 218 : harvest! ( seq -- newseq )
 219     [ empty? not ] filter! ;
 220
 221 : contains? ( seq elts -- ? )
 222     [ member? ] curry any? ; inline
 223
 224 : head-as ( seq n exemplar -- seq' )
 225     [ head-slice ] [ like ] bi* ; inline
 226
 227 : head*-as ( seq n exemplar -- seq' )
 228     [ head-slice* ] [ like ] bi* ; inline
 229
 230 : tail-as ( seq n exemplar -- seq' )
 231     [ tail-slice ] [ like ] bi* ; inline
 232
 233 : tail*-as ( seq n exemplar -- seq' )
 234     [ tail-slice* ] [ like ] bi* ; inline
 235
 236 : trim-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... newseq )
 237     [ trim-slice ] [ like ] bi* ; inline
 238
 239 : ?trim ( ... seq quot: ( ... elt -- ... ? ) -- ... seq/newseq )
 240     over empty? [ drop ] [
 241         over [ first-unsafe ] [ last-unsafe ] bi pick bi@ or
 242         [ trim ] [ drop ] if
 243     ] if ; inline
 244
 245 : unsurround ( newseq seq2 seq3 -- seq1 )
 246    [ ?head drop ] [ ?tail drop ] bi* ;
 247
 248 : none? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 249     any? not ; inline
 250
 251 : one? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 252     [ find ] 2keep rot [
 253         [ 1 + ] 2dip find-from drop not
 254     ] [ 3drop f ] if ; inline
 255
 256 : map-index! ( ... seq quot: ( ... elt index -- ... newelt ) -- ... seq )
 257     over [ [ (each-index) ] dip collect ] keep ; inline
 258
 259 <PRIVATE
 260
 261 : (2each-index) ( seq1 seq2 quot -- n quot' )
 262     [ ((2each)) [ keep ] curry ] dip compose ; inline
 263
 264 PRIVATE>
 265
 266 : 2each-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... ) -- ... )
 267     (2each-index) each-integer ; inline
 268
 269 : 2map-into ( seq1 seq2 quot into -- )
 270     [ (2each) ] dip collect ; inline
 271
 272 : 2map! ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... seq1 )
 273     pick [ 2map-into ] keep ; inline
 274
 275 : 2map-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... newelt ) -- ... newseq )
 276     pick [ (2each-index) ] dip map-integers ; inline
 277
 278 TUPLE: evens seq length ;
 279
 280 : <evens> ( seq -- evens )
 281     dup length 1 + 2/ evens boa ; inline
 282
 283 M: evens length length>> ; inline
 284
 285 M: evens nth-unsafe [ 2 * ] [ seq>> nth-unsafe ] bi* ; inline
 286
 287 INSTANCE: evens immutable-sequence
 288
 289 TUPLE: odds seq length ;
 290
 291 : <odds> ( seq -- odds )
 292     dup length 2/ odds boa ; inline
 293
 294 M: odds length length>> ; inline
 295
 296 M: odds nth-unsafe [ 2 * 1 + ] [ seq>> nth-unsafe ] bi* ; inline
 297
 298 INSTANCE: odds immutable-sequence
 299
 300 : until-empty ( seq quot -- )
 301     [ dup empty? ] swap until drop ; inline
 302
 303 : arg-max ( seq -- n )
 304     dup length iota zip [ first-unsafe ] supremum-by second ;
 305
 306 : arg-min ( seq -- n )
 307     dup length iota zip [ first-unsafe ] infimum-by second ;
 308
 309 : arg-where ( ... seq quot: ( ... elt -- ... ? ) -- ... indices )
 310     [ dup length iota zip ] dip
 311     [ first-unsafe ] prepose filter values ; inline
 312
 313 : arg-sort ( seq -- indices )
 314     dup length iota zip sort-keys values ;
 315
 316 : first= ( seq elt -- ? ) [ first ] dip = ; inline
 317 : second= ( seq elt -- ? ) [ second ] dip = ; inline
 318 : third= ( seq elt -- ? ) [ third ] dip = ; inline
 319 : fourth= ( seq elt -- ? ) [ fourth ] dip = ; inline
 320 : last= ( seq elt -- ? ) [ last ] dip = ; inline
 321 : nth= ( n seq elt -- ? ) [ nth ] dip = ; inline
 322
 323 : first? ( seq quot -- ? ) [ first ] dip call ; inline
 324 : second? ( seq quot -- ? ) [ second ] dip call ; inline
 325 : third? ( seq quot -- ? ) [ third ] dip call ; inline
 326 : fourth? ( seq quot -- ? ) [ fourth ] dip call ; inline
 327 : last? ( seq quot -- ? ) [ last ] dip call ; inline
 328 : nth? ( n seq quot -- ? ) [ nth ] dip call ; inline
 329
 330 : loop>sequence ( quot exemplar -- seq )
 331    [ '[ [ @ [ [ , ] when* ] keep ] loop ] ] dip make ; inline
 332
 333 : loop>array ( quot -- seq )
 334    { } loop>sequence ; inline
 335
 336 <PRIVATE
 337
 338 : (reverse) ( seq -- newseq )
 339     dup [ length ] keep new-sequence [ 0 swap copy ] keep reverse! ;
 340
 341 PRIVATE>
 342
 343 : reverse-as ( seq exemplar -- newseq )
 344     [ (reverse) ] [ like ] bi* ;
 345
 346 : map-product ( ... seq quot: ( ... elt -- ... n ) -- ... n )
 347     [ 1 ] 2dip [ dip * ] curry [ swap ] prepose each ; inline
 348
 349 : insert-nth! ( elt n seq -- )
 350     [ length ] keep ensure swap pick (a,b]
 351     over '[ [ 1 + ] keep _ move-unsafe ] each
 352     set-nth-unsafe ;
 353
 354 : set-nths ( value indices seq -- )
 355     swapd '[ [ _ ] dip _ set-nth ] each ; inline
 356
 357 : set-nths-unsafe ( value indices seq -- )
 358     swapd '[ [ _ ] dip _ set-nth-unsafe ] each ; inline
 359
 360 : flatten1 ( obj -- seq )
 361     [
 362         [
 363             dup branch? [
 364                 [ dup branch? [ % ] [ , ] if ] each
 365             ] [ , ] if
 366         ]
 367     ] keep dup branch? [ drop f ] unless make ;