extra/sequences/extras/extras.factor

   1 USING: accessors arrays assocs fry grouping growable kernel
   2 locals make math math.order math.ranges sequences
   3 sequences.deep sequences.private sorting splitting vectors ;
   4 FROM: sequences => change-nth ;
   5 IN: sequences.extras
   6
   7 : reduce1 ( seq quot -- result ) [ unclip ] dip reduce ; inline
   8
   9 :: reduce-r ( seq identity quot: ( obj1 obj2 -- obj ) -- result )
  10     seq [ identity ] [
  11         unclip [ identity quot reduce-r ] [ quot call ] bi*
  12     ] if-empty ; inline recursive
  13
  14 ! Quot must have static stack effect, unlike "reduce"
  15 :: reduce* ( seq identity quot: ( prev elt -- next ) -- result )
  16     seq [ identity ] [
  17         unclip identity swap quot call( prev elt -- next )
  18         quot reduce*
  19     ] if-empty ; inline recursive
  20
  21 :: combos ( list1 list2 -- result )
  22     list2 [ [ 2array ] curry list1 swap map ] map concat ;
  23
  24 : find-all ( seq quot: ( elt -- ? ) -- elts )
  25     [ [ length iota ] keep ] dip
  26     [ dupd call( a -- ? ) [ 2array ] [ 2drop f ] if ] curry
  27     2map [ ] filter ; inline
  28
  29 : insert-sorted ( elt seq -- seq )
  30     2dup [ < ] with find drop over length or swap insert-nth ;
  31
  32 : reduce-from ( ... seq identity quot: ( ... prev elt -- ... next ) i -- ... result )
  33     [ swap ] 2dip each-from ; inline
  34
  35 : all-subseqs ( seq -- seqs )
  36     dup length [1,b] [ clump ] with map concat ;
  37
  38 :: each-subseq ( ... seq quot: ( ... x -- ... ) -- ... )
  39     seq length :> len
  40     len [0,b] [
  41         :> from
  42         from len (a,b] [
  43             :> to
  44             from to seq subseq quot call
  45         ] each
  46     ] each ; inline
  47
  48 : subseq-as ( from to seq exemplar -- subseq )
  49     [ check-slice subseq>copy (copy) ] dip like ;
  50
  51 : map-like ( seq exemplar -- seq' )
  52     '[ _ like ] map ; inline
  53
  54 : filter-all-subseqs-range ( ... seq range quot: ( ... x -- ... ) -- seq )
  55     [
  56         '[ <clumps> _ filter ] with map concat
  57     ] 3keep 2drop map-like ; inline
  58
  59 : filter-all-subseqs ( ... seq quot: ( ... x -- ... ) -- seq )
  60     [ dup length [1,b] ] dip filter-all-subseqs-range ; inline
  61
  62 :: longest-subseq ( seq1 seq2 -- subseq )
  63     seq1 length :> len1
  64     seq2 length :> len2
  65     0 :> n!
  66     0 :> end!
  67     len1 1 + [ len2 1 + 0 <array> ] replicate :> table
  68     len1 [1,b] [| x |
  69         len2 [1,b] [| y |
  70             x 1 - seq1 nth-unsafe
  71             y 1 - seq2 nth-unsafe = [
  72                 y 1 - x 1 - table nth-unsafe nth-unsafe 1 + :> len
  73                 len y x table nth-unsafe set-nth-unsafe
  74                 len n > [ len n! x end! ] when
  75             ] [ 0 y x table nth-unsafe set-nth-unsafe ] if
  76         ] each
  77     ] each end n - end seq1 subseq ;
  78
  79 : pad-longest ( seq1 seq2 elt -- seq1 seq2 )
  80     [ 2dup max-length ] dip [ pad-tail ] 2curry bi@ ;
  81
  82 : change-nths ( ... indices seq quot: ( ... elt -- ... elt' ) -- ... )
  83     [ change-nth ] 2curry each ; inline
  84
  85 : push-if-index ( ..a elt i quot: ( ..a elt i -- ..b ? ) accum -- ..b )
  86     [ 2keep drop ] dip rot [ push ] [ 2drop ] if ; inline
  87
  88 <PRIVATE
  89
  90 : (index-selector-for) ( quot length exampler -- selector accum )
  91     new-resizable [ [ push-if-index ] 2curry ] keep ; inline
  92
  93 PRIVATE>
  94
  95 : index-selector-for ( quot exemplar -- selector accum )
  96     [ length ] keep (index-selector-for) ; inline
  97
  98 : index-selector ( quot -- selector accum )
  99     V{ } index-selector-for ; inline
 100
 101 : filter-index-as ( ... seq quot: ( ... elt i -- ... ? ) exemplar -- ... seq' )
 102     pick length over [ (index-selector-for) [ each-index ] dip ] 2curry dip like ; inline
 103
 104 : filter-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... seq' )
 105     over filter-index-as ; inline
 106
 107 : even-indices ( seq -- seq' )
 108     [ length 1 + 2/ ] keep [
 109         [ [ 2 * ] dip nth-unsafe ] curry
 110     ] keep map-integers ;
 111
 112 : odd-indices ( seq -- seq' )
 113     [ length 2/ ] keep [
 114         [ [ 2 * 1 + ] dip nth-unsafe ] curry
 115     ] keep map-integers ;
 116
 117 : compact ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 118     [ split-when harvest ] dip join ; inline
 119
 120 : collapse ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 121     [ split-when ] dip
 122     [ [ harvest ] dip join ]
 123     [ [ first empty? ] dip [ prepend ] curry when ]
 124     [ [ last empty? ] dip [ append ] curry when ]
 125     2tri ; inline
 126
 127 :: slice-when ( seq quot: ( elt -- ? ) -- seq' )
 128     seq length :> len
 129     0 [ len dupd < ] [
 130         dup seq quot find-from drop
 131         [ 2dup = [ 1 + ] when ] [ len ] if*
 132         [ seq <slice> ] keep len or swap
 133     ] produce nip ; inline
 134
 135 : cut-slice* ( seq n -- before after )
 136     [ head-slice* ] [ tail-slice* ] 2bi ;
 137
 138 : rotate ( seq n -- seq' )
 139     cut prepend ;
 140
 141 :: rotate! ( seq n -- )
 142     n seq bounds-check length :> end
 143     0 n [ 2dup = ] [
 144         [ seq exchange-unsafe ] [ [ 1 + ] bi@ ] 2bi
 145         dup end = [ drop over ] when
 146         2over = [ -rot nip over ] when
 147     ] until 3drop ;
 148
 149 : all-rotations ( seq -- seq' )
 150     dup length iota [ rotate ] with map ;
 151
 152 <PRIVATE
 153
 154 : (appender-for) ( quot length exemplar -- appender accum )
 155     new-resizable [ [ push-all ] curry compose ] keep ; inline
 156
 157 PRIVATE>
 158
 159 : appender-for ( quot exemplar -- appender accum )
 160     [ length ] keep (appender-for) ; inline
 161
 162 : appender ( quot -- appender accum )
 163     V{ } appender-for ; inline
 164
 165 : map-concat-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 166     pick length over [ (appender-for) [ each ] dip ] 2curry dip like ; inline
 167
 168 : >resizable ( seq -- accum ) ! fixes map-concat "cannot apply call to run-time..."
 169     [ length ] keep [ new-resizable ] [ over push-all ] bi ;
 170
 171 : map-concat ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 172     over [ 2drop { } ] [
 173         first over call dup [
 174             >resizable [ [ push-all ] curry compose ] keep
 175             [ 1 ] 3dip [ (each) (each-integer) ] dip
 176         ] curry dip like
 177     ] if-empty ; inline
 178
 179 : map-filter-as ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) exemplar -- ... subseq )
 180     [ pick ] dip swap length over
 181     [ (selector-for) [ compose each ] dip ] 2curry dip like ; inline
 182
 183 : map-filter ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) -- ... subseq )
 184     pick map-filter-as ; inline
 185
 186 : map-sift ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 187     [ ] map-filter ; inline
 188
 189 : map-harvest ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 190     [ empty? not ] map-filter ; inline
 191
 192 <PRIVATE
 193
 194 : ((each-from)) ( i seq -- n quot )
 195     [ length over [-] swap ] keep '[ _ + _ nth-unsafe ] ; inline
 196
 197 : (each-from) ( i seq quot -- n quot' ) [ ((each-from)) ] dip compose ;
 198     inline
 199
 200 PRIVATE>
 201
 202 : map-from-as ( ... seq quot: ( ... elt -- ... newelt ) i exemplar -- ... newseq )
 203     [ -rot (each-from) ] dip map-integers ; inline
 204
 205 : map-from ( ... seq quot: ( ... elt -- ... newelt ) i -- ... newseq )
 206     pick map-from-as ; inline
 207
 208 <PRIVATE
 209
 210 : push-map-if ( ..a elt filter-quot: ( ..a elt -- ..b ? ) map-quot: ( ..a elt -- ..b newelt ) accum -- ..b )
 211     [ keep over ] 2dip [ when ] dip rot [ push ] [ 2drop ] if ; inline
 212
 213 : (filter-mapper-for) ( filter-quot map-quot length exempler -- filter-mapper accum )
 214     new-resizable [ [ push-map-if ] 3curry ] keep ; inline
 215
 216 : filter-mapper-for ( filter-quot map-quot exemplar -- filter-mapper accum )
 217     [ length ] keep (filter-mapper-for) ; inline
 218
 219 : filter-mapper ( filter-quot map-quot -- filter-mapper accum )
 220     V{ } filter-mapper-for ; inline
 221
 222 PRIVATE>
 223
 224 : filter-map-as ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 225     [ pick ] dip swap length over
 226     [ (filter-mapper-for) [ each ] dip ] 2curry dip like ; inline
 227
 228 : filter-map ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) -- ... newseq )
 229     pick filter-map-as ; inline
 230
 231 : 2map-sum ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... n ) -- ... n )
 232     [ 0 ] 3dip [ dip + ] curry [ rot ] prepose 2each ; inline
 233
 234 : 2count ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... n )
 235     [ 1 0 ? ] compose 2map-sum ; inline
 236
 237 : round-robin ( seq -- newseq )
 238     [ { } ] [
 239         [ longest length iota ] keep
 240         [ [ ?nth ] with map ] curry map concat sift
 241     ] if-empty ;
 242
 243 : sift-as ( seq exemplar -- newseq )
 244     [ ] swap filter-as ;
 245
 246 : sift! ( seq -- newseq )
 247     [ ] filter! ;
 248
 249 : harvest-as ( seq exemplar -- newseq )
 250     [ empty? not ] swap filter-as ;
 251
 252 : harvest! ( seq -- newseq )
 253     [ empty? not ] filter! ;
 254
 255 : contains? ( seq elts -- ? )
 256     [ member? ] curry any? ; inline
 257
 258 : head-as ( seq n exemplar -- seq' )
 259     [ head-slice ] [ like ] bi* ; inline
 260
 261 : head*-as ( seq n exemplar -- seq' )
 262     [ head-slice* ] [ like ] bi* ; inline
 263
 264 : tail-as ( seq n exemplar -- seq' )
 265     [ tail-slice ] [ like ] bi* ; inline
 266
 267 : tail*-as ( seq n exemplar -- seq' )
 268     [ tail-slice* ] [ like ] bi* ; inline
 269
 270 : trim-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... newseq )
 271     [ trim-slice ] [ like ] bi* ; inline
 272
 273 : ?trim ( seq quot: ( elt -- ? ) -- seq/newseq )
 274     over empty? [ drop ] [
 275         over [ first-unsafe ] [ last-unsafe ] bi pick bi@ or
 276         [ trim ] [ drop ] if
 277     ] if ; inline
 278
 279 : ?trim-head ( seq quot: ( elt -- ? ) -- seq/newseq )
 280     over empty? [ drop ] [
 281         over first-unsafe over call
 282         [ trim-head ] [ drop ] if
 283     ] if ; inline
 284
 285 : ?trim-tail ( seq quot: ( elt -- ? ) -- seq/newseq )
 286     over empty? [ drop ] [
 287         over last-unsafe over call
 288         [ trim-tail ] [ drop ] if
 289     ] if ; inline
 290
 291 : unsurround ( newseq seq2 seq3 -- seq1 )
 292    [ ?head drop ] [ ?tail drop ] bi* ;
 293
 294 : none? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 295     any? not ; inline
 296
 297 : one? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 298     [ find ] 2keep rot [
 299         [ 1 + ] 2dip find-from drop not
 300     ] [ 3drop f ] if ; inline
 301
 302 : map-index! ( ... seq quot: ( ... elt index -- ... newelt ) -- ... seq )
 303     over [ [ (each-index) ] dip collect ] keep ; inline
 304
 305 <PRIVATE
 306
 307 : (2each-index) ( seq1 seq2 quot -- n quot' )
 308     [ ((2each)) [ keep ] curry ] dip compose ; inline
 309
 310 PRIVATE>
 311
 312 : 2each-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... ) -- ... )
 313     (2each-index) each-integer ; inline
 314
 315 : 2map-into ( seq1 seq2 quot into -- )
 316     [ (2each) ] dip collect ; inline
 317
 318 : 2map! ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... seq1 )
 319     pick [ 2map-into ] keep ; inline
 320
 321 : 2map-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... newelt ) -- ... newseq )
 322     pick [ (2each-index) ] dip map-integers ; inline
 323
 324 TUPLE: evens seq length ;
 325
 326 : <evens> ( seq -- evens )
 327     dup length 1 + 2/ evens boa ; inline
 328
 329 M: evens length length>> ; inline
 330
 331 M: evens nth-unsafe [ 2 * ] [ seq>> nth-unsafe ] bi* ; inline
 332
 333 INSTANCE: evens immutable-sequence
 334
 335 TUPLE: odds seq length ;
 336
 337 : <odds> ( seq -- odds )
 338     dup length 2/ odds boa ; inline
 339
 340 M: odds length length>> ; inline
 341
 342 M: odds nth-unsafe [ 2 * 1 + ] [ seq>> nth-unsafe ] bi* ; inline
 343
 344 INSTANCE: odds immutable-sequence
 345
 346 : until-empty ( seq quot -- )
 347     [ dup empty? ] swap until drop ; inline
 348
 349 : arg-max ( seq -- n )
 350     <enum> [ second-unsafe ] supremum-by first ;
 351
 352 : arg-min ( seq -- n )
 353     <enum> [ second-unsafe ] infimum-by first ;
 354
 355 <PRIVATE
 356
 357 : push-index-if ( ..a elt i quot: ( ..a elt -- ..b ? ) accum -- ..b )
 358     [ dip ] dip rot [ push ] [ 2drop ] if ; inline
 359
 360 PRIVATE>
 361
 362 : arg-where ( ... seq quot: ( ... elt -- ... ? ) -- ... indices )
 363     over length <vector> [
 364         [ push-index-if ] 2curry each-index
 365     ] keep ; inline
 366
 367 : arg-sort ( seq -- indices )
 368     dup length iota zip sort-keys values ;
 369
 370 : first= ( seq elt -- ? ) [ first ] dip = ; inline
 371 : second= ( seq elt -- ? ) [ second ] dip = ; inline
 372 : third= ( seq elt -- ? ) [ third ] dip = ; inline
 373 : fourth= ( seq elt -- ? ) [ fourth ] dip = ; inline
 374 : last= ( seq elt -- ? ) [ last ] dip = ; inline
 375 : nth= ( n seq elt -- ? ) [ nth ] dip = ; inline
 376
 377 : first? ( seq quot -- ? ) [ first ] dip call ; inline
 378 : second? ( seq quot -- ? ) [ second ] dip call ; inline
 379 : third? ( seq quot -- ? ) [ third ] dip call ; inline
 380 : fourth? ( seq quot -- ? ) [ fourth ] dip call ; inline
 381 : last? ( seq quot -- ? ) [ last ] dip call ; inline
 382 : nth? ( n seq quot -- ? ) [ nth ] dip call ; inline
 383
 384 : loop>sequence ( quot exemplar -- seq )
 385    [ '[ [ @ [ [ , ] when* ] keep ] loop ] ] dip make ; inline
 386
 387 : loop>array ( quot -- seq )
 388    { } loop>sequence ; inline
 389
 390 <PRIVATE
 391
 392 : (reverse) ( seq -- newseq )
 393     dup [ length ] keep new-sequence
 394     [ 0 swap copy-unsafe ] keep reverse! ;
 395
 396 PRIVATE>
 397
 398 : reverse-as ( seq exemplar -- newseq )
 399     [ (reverse) ] [ like ] bi* ;
 400
 401 : map-product ( ... seq quot: ( ... elt -- ... n ) -- ... n )
 402     [ 1 ] 2dip [ dip * ] curry [ swap ] prepose each ; inline
 403
 404 : insert-nth! ( elt n seq -- )
 405     [ length ] keep ensure swap pick (a,b]
 406     over '[ [ 1 + ] keep _ move-unsafe ] each
 407     set-nth-unsafe ;
 408
 409 : set-nths ( value indices seq -- )
 410     swapd '[ [ _ ] dip _ set-nth ] each ; inline
 411
 412 : set-nths-unsafe ( value indices seq -- )
 413     swapd '[ [ _ ] dip _ set-nth-unsafe ] each ; inline
 414
 415 : flatten1 ( obj -- seq )
 416     [
 417         [
 418             dup branch? [
 419                 [ dup branch? [ % ] [ , ] if ] each
 420             ] [ , ] if
 421         ]
 422     ] keep dup branch? [ drop f ] unless make ;
 423
 424 <PRIVATE
 425
 426 : (map-find-index) ( seq quot find-quot -- result elt index )
 427     [ [ f ] 2dip [ [ nip ] 2dip call dup ] curry ] dip call
 428     [ [ [ drop f ] unless ] keep ] dip ; inline
 429
 430 PRIVATE>
 431
 432 : map-find-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result elt index )
 433     [ find-index ] (map-find-index) ; inline
 434
 435 : filter-length ( seq n -- seq' ) '[ length _ = ] filter ;
 436
 437 : all-shortest ( seqs -- seqs' ) dup shortest length filter-length ;
 438
 439 : all-longest ( seqs -- seqs' ) dup longest length filter-length ;
 440
 441 : remove-first ( obj seq -- seq' )
 442     [ index ] keep over [ remove-nth ] [ nip ] if ;
 443
 444 : remove-first! ( obj seq -- seq )
 445     [ index ] keep over [ remove-nth! ] [ nip ] if ;
 446
 447 : remove-last ( obj seq -- seq' )
 448     [ last-index ] keep over [ remove-nth ] [ nip ] if ;
 449
 450 : remove-last! ( obj seq -- seq )
 451     [ last-index ] keep over [ remove-nth! ] [ nip ] if ;