extra/sequences/extras/extras.factor

   1 USING: accessors arrays assocs combinators fry generalizations
   2 grouping growable kernel locals make math math.order math.ranges
   3 sequences sequences.deep sequences.private sorting splitting
   4 vectors ;
   5 IN: sequences.extras
   6
   7 : find-all ( ... seq quot: ( ... elt -- ... ? ) -- ... elts )
   8     [ <enumerated> ] dip '[ nip @ ] assoc-filter ; inline
   9
  10 : reduce-from ( ... seq identity quot: ( ... prev elt -- ... next ) i -- ... result )
  11     [ swap ] 2dip each-from ; inline
  12
  13 :: subseq* ( from to seq -- subseq )
  14     seq length :> len
  15     from [ dup 0 < [ len + ] when ] [ 0 ] if*
  16     to [ dup 0 < [ len + ] when ] [ len ] if*
  17     [ 0 len clamp ] bi@ dupd max seq subseq ;
  18
  19 : safe-subseq ( from to seq -- subseq )
  20     [ length '[ 0 _ clamp ] bi@ ] keep subseq ;
  21
  22 : all-subseqs ( seq -- seqs )
  23     dup length [1,b] [ clump ] with map concat ;
  24
  25 :: each-subseq ( ... seq quot: ( ... subseq -- ... ) -- ... )
  26     seq length :> len
  27     len [0,b] [| from |
  28         from len (a,b] [| to |
  29             from to seq subseq quot call
  30         ] each
  31     ] each ; inline
  32
  33 : map-like ( seq exemplar -- seq' )
  34     '[ _ like ] map ; inline
  35
  36 : filter-all-subseqs-range ( ... seq range quot: ( ... subseq -- ... ) -- seq )
  37     [
  38         '[ <clumps> _ filter ] with map concat
  39     ] keepdd map-like ; inline
  40
  41 : filter-all-subseqs ( ... seq quot: ( ... subseq -- ... ) -- seq )
  42     [ dup length [1,b] ] dip filter-all-subseqs-range ; inline
  43
  44 :: longest-subseq ( seq1 seq2 -- subseq )
  45     seq1 length :> len1
  46     seq2 length :> len2
  47     0 :> n!
  48     0 :> end!
  49     len1 1 + [ len2 1 + 0 <array> ] replicate :> table
  50     len1 [1,b] [| x |
  51         len2 [1,b] [| y |
  52             x 1 - seq1 nth-unsafe
  53             y 1 - seq2 nth-unsafe = [
  54                 y 1 - x 1 - table nth-unsafe nth-unsafe 1 + :> len
  55                 len y x table nth-unsafe set-nth-unsafe
  56                 len n > [ len n! x end! ] when
  57             ] [ 0 y x table nth-unsafe set-nth-unsafe ] if
  58         ] each
  59     ] each end n - end seq1 subseq ;
  60
  61 : pad-longest ( seq1 seq2 elt -- seq1 seq2 )
  62     [ 2dup max-length ] dip [ pad-tail ] 2curry bi@ ;
  63
  64 :: pad-center ( seq n elt -- padded )
  65     n seq length [-] :> extra
  66     extra 2/ :> left
  67     extra left - :> right
  68     left elt <repetition> seq right elt <repetition>
  69     seq 3append-as ;
  70
  71 : change-nths ( ... indices seq quot: ( ... elt -- ... elt' ) -- ... )
  72     [ change-nth ] 2curry each ; inline
  73
  74 : push-if-index ( ..a elt i quot: ( ..a elt i -- ..b ? ) accum -- ..b )
  75     [ keepd ] dip rot [ push ] [ 2drop ] if ; inline
  76
  77 : push-if* ( ..a elt quot: ( ..a elt -- ..b obj/f ) accum -- ..b )
  78     [ call ] dip [ push ] [ drop ] if* ; inline
  79
  80 <PRIVATE
  81
  82 : (index-selector-as) ( quot length exampler -- selector accum )
  83     new-resizable [ [ push-if-index ] 2curry ] keep ; inline
  84
  85 : (selector-as*) ( quot length exemplar -- selector accum )
  86     new-resizable [ [ push-if* ] 2curry ] keep ; inline
  87
  88 PRIVATE>
  89
  90 : index-selector-as ( quot exemplar -- selector accum )
  91     [ length ] keep (index-selector-as) ; inline
  92
  93 : index-selector ( quot -- selector accum )
  94     V{ } index-selector-as ; inline
  95
  96 : selector-as* ( quot exemplar -- selector accum )
  97     [ length ] keep (selector-as*) ; inline
  98
  99 : selector* ( quot -- selector accum ) V{ } selector-as* ; inline
 100
 101 : filter-index-as ( ... seq quot: ( ... elt i -- ... ? ) exemplar -- ... seq' )
 102     pick length over [ (index-selector-as) [ each-index ] dip ] 2curry dip like ; inline
 103
 104 : filter-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... seq' )
 105     over filter-index-as ; inline
 106
 107 : even-indices ( seq -- seq' )
 108     [ length 1 + 2/ ] keep [
 109         [ [ 2 * ] dip nth-unsafe ] curry
 110     ] keep map-integers ;
 111
 112 : odd-indices ( seq -- seq' )
 113     [ length 2/ ] keep [
 114         [ [ 2 * 1 + ] dip nth-unsafe ] curry
 115     ] keep map-integers ;
 116
 117 : compact ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 118     [ split-when harvest ] dip join ; inline
 119
 120 : collapse ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 121     [ split-when ] dip
 122     [ [ harvest ] dip join ]
 123     [ [ first empty? ] dip [ prepend ] curry when ]
 124     [ [ last empty? ] dip [ append ] curry when ]
 125     2tri ; inline
 126
 127 :: slice-when ( seq quot: ( elt -- ? ) -- seq' )
 128     seq length :> len
 129     0 [ len dupd < ] [
 130         dup seq quot find-from drop
 131         [ 2dup = [ 1 + ] when ] [ len ] if*
 132         [ seq <slice> ] keep len or swap
 133     ] produce nip ; inline
 134
 135 : cut-slice* ( seq n -- before after )
 136     [ head-slice* ] [ tail-slice* ] 2bi ;
 137
 138 : ?<slice> ( from/f to/f sequence -- slice )
 139     [ [ 0 ] unless* ] 2dip
 140     over [ nip [ length ] [ ] bi ] unless
 141     <slice> ; inline
 142
 143 : sequence>slice ( sequence -- slice )
 144     [ drop 0 ] [ length ] [ ] tri <slice> ; inline
 145
 146 : slice-order-by-from ( slice1 slice2 -- slice-lt slice-gt )
 147     2dup [ from>> ] bi@ > [ swap ] when ; inline
 148
 149 : ordered-slices-range ( slice-lt slice-gt -- to from )
 150     [ to>> ] [ from>> ] bi* ;
 151
 152 : unordered-slices-range ( slice1 slice2 -- to from )
 153     slice-order-by-from ordered-slices-range ;
 154
 155 : ordered-slices-overlap? ( slice-lt slice-gt -- ? )
 156     ordered-slices-range > ; inline
 157
 158 : unordered-slices-overlap? ( slice1 slice2 -- ? )
 159     unordered-slices-range > ; inline
 160
 161 : slices-overlap? ( slice1 slice2 -- ? )
 162     unordered-slices-overlap? ;
 163
 164 : ordered-slices-touch? ( slice-lt slice-gt -- ? )
 165     ordered-slices-range >= ; inline
 166
 167 : unordered-slices-touch? ( slice1 slice2 -- ? )
 168     unordered-slices-range >= ; inline
 169
 170 : slices-touch? ( slice1 slice2 -- ? )
 171     unordered-slices-touch? ;
 172
 173 ERROR: slices-don't-touch slice1 slice2 ;
 174
 175 : merge-slices ( slice1 slice2 -- slice/* )
 176     slice-order-by-from
 177     2dup ordered-slices-touch? [
 178         [ from>> ] [ [ to>> ] [ seq>> ] bi ] bi* <slice>
 179     ] [
 180         slices-don't-touch
 181     ] if ;
 182
 183 : rotate ( seq n -- seq' )
 184     over length mod dup 0 >= [ cut ] [ abs cut* ] if prepend ;
 185
 186 ERROR: underlying-mismatch slice1 slice2 ;
 187
 188 : ensure-same-underlying ( slice1 slice2 -- slice1 slice2 )
 189     2dup [ seq>> ] bi@ eq? [ underlying-mismatch ] unless ;
 190
 191 : span-slices ( slice1 slice2 -- slice )
 192     ensure-same-underlying
 193     [ [ from>> ] bi@ min ]
 194     [ [ to>> ] bi@ max ]
 195     [ drop seq>> ] 2tri <slice> ;
 196
 197 : ?span-slices ( slice1/f slice2/f -- slice )
 198     2dup and [ span-slices ] [ or ] if ;
 199
 200 :: rotate! ( seq n -- )
 201     seq length :> len
 202     n len mod dup 0 < [ len + ] when seq bounds-check drop 0 over
 203     [ 2dup = ] [
 204         [ seq exchange-unsafe ] [ [ 1 + ] bi@ ] 2bi
 205         dup len = [ drop over ] when
 206         2over = [ -rot nip over ] when
 207     ] until 3drop ;
 208
 209 : all-rotations ( seq -- seq' )
 210     dup length <iota> [ rotate ] with map ;
 211
 212 <PRIVATE
 213
 214 : (appender-for) ( quot length exemplar -- appender accum )
 215     new-resizable [ [ push-all ] curry compose ] keep ; inline
 216
 217 PRIVATE>
 218
 219 : appender-for ( quot exemplar -- appender accum )
 220     [ length ] keep (appender-for) ; inline
 221
 222 : appender ( quot -- appender accum )
 223     V{ } appender-for ; inline
 224
 225 : map-concat-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 226     [ appender-for [ each ] dip ] keep like ; inline
 227
 228 : >resizable ( seq -- accum ) ! fixes map-concat "cannot apply call to run-time..."
 229     [ length ] keep [ new-resizable ] [ append! ] bi ;
 230
 231 : map-concat ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 232     over empty? [ 2drop { } ] [
 233         [ [ first ] dip call ] 2keep rot [
 234             >resizable [ '[ @ _ push-all ] 1 each-from ] keep
 235         ] keep like
 236     ] if ; inline
 237
 238 : map-filter-as ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) exemplar -- ... subseq )
 239     reach length over
 240     [ (selector-as) [ compose each ] dip ] 2curry dip like ; inline
 241
 242 : map-filter ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) -- ... subseq )
 243     pick map-filter-as ; inline
 244
 245 : map-sift ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 246     [ ] map-filter ; inline
 247
 248 : map-harvest ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 249     [ empty? not ] map-filter ; inline
 250
 251 <PRIVATE
 252
 253 : (setup-each-from) ( i seq -- n quot )
 254     [ length over [-] swap ] keep '[ _ + _ nth-unsafe ] ; inline
 255
 256 : setup-each-from ( i seq quot -- n quot' )
 257     [ (setup-each-from) ] dip compose ; inline
 258
 259 PRIVATE>
 260
 261 : map-from-as ( ... seq quot: ( ... elt -- ... newelt ) i exemplar -- ... newseq )
 262     [ -rot setup-each-from ] dip map-integers ; inline
 263
 264 : map-from ( ... seq quot: ( ... elt -- ... newelt ) i -- ... newseq )
 265     pick map-from-as ; inline
 266
 267 <PRIVATE
 268
 269 : push-map-if ( ..a elt filter-quot: ( ..a elt -- ..b ? ) map-quot: ( ..a elt -- ..b newelt ) accum -- ..b )
 270     [ keep over ] 2dip [ when ] dip rot [ push ] [ 2drop ] if ; inline
 271
 272 : (filter-mapper-for) ( filter-quot map-quot length exempler -- filter-mapper accum )
 273     new-resizable [ [ push-map-if ] 3curry ] keep ; inline
 274
 275 : filter-mapper-for ( filter-quot map-quot exemplar -- filter-mapper accum )
 276     [ length ] keep (filter-mapper-for) ; inline
 277
 278 : filter-mapper ( filter-quot map-quot -- filter-mapper accum )
 279     V{ } filter-mapper-for ; inline
 280
 281 PRIVATE>
 282
 283 : filter-map-as ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 284     reach length over
 285     [ (filter-mapper-for) [ each ] dip ] 2curry dip like ; inline
 286
 287 : filter-map ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) -- ... newseq )
 288     pick filter-map-as ; inline
 289
 290 : 2map-sum ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... n ) -- ... n )
 291     [ 0 ] 3dip [ dip + ] curry [ rot ] prepose 2each ; inline
 292
 293 : 2count ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... n )
 294     [ 1 0 ? ] compose 2map-sum ; inline
 295
 296 : 3each-from
 297     ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... ) i -- ... )
 298     [ (3each) ] dip -rot (each-integer) ; inline
 299
 300 : 3map-reduce
 301     ( ..a seq1 seq2 seq3 map-quot: ( ..a elt1 elt2 elt3 -- ..b intermediate ) reduce-quot: ( ..b prev intermediate -- ..a next ) -- ..a result )
 302     [ [ [ [ first ] tri@ ] 3keep ] dip [ 3dip ] keep ] dip compose 1 3each-from ; inline
 303
 304 : round-robin ( seq -- newseq )
 305     [ { } ] [
 306         [ longest length <iota> ] keep
 307         [ [ ?nth ] with map ] curry map concat sift
 308     ] if-empty ;
 309
 310 : sift-as ( seq exemplar -- newseq )
 311     [ ] swap filter-as ;
 312
 313 : sift! ( seq -- newseq )
 314     [ ] filter! ;
 315
 316 : harvest-as ( seq exemplar -- newseq )
 317     [ empty? not ] swap filter-as ;
 318
 319 : harvest! ( seq -- newseq )
 320     [ empty? ] reject! ;
 321
 322 : head-as ( seq n exemplar -- seq' )
 323     [ head-slice ] [ like ] bi* ; inline
 324
 325 : head*-as ( seq n exemplar -- seq' )
 326     [ head-slice* ] [ like ] bi* ; inline
 327
 328 : tail-as ( seq n exemplar -- seq' )
 329     [ tail-slice ] [ like ] bi* ; inline
 330
 331 : tail*-as ( seq n exemplar -- seq' )
 332     [ tail-slice* ] [ like ] bi* ; inline
 333
 334 : trim-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... newseq )
 335     [ trim-slice ] [ like ] bi* ; inline
 336
 337 : ?trim ( seq quot: ( elt -- ? ) -- seq/newseq )
 338     over empty? [ drop ] [
 339         over [ first-unsafe ] [ last-unsafe ] bi pick either?
 340         [ trim ] [ drop ] if
 341     ] if ; inline
 342
 343 : ?trim-head ( seq quot: ( elt -- ? ) -- seq/newseq )
 344     over empty? [ drop ] [
 345         over first-unsafe over call
 346         [ trim-head ] [ drop ] if
 347     ] if ; inline
 348
 349 : ?trim-tail ( seq quot: ( elt -- ? ) -- seq/newseq )
 350     over empty? [ drop ] [
 351         over last-unsafe over call
 352         [ trim-tail ] [ drop ] if
 353     ] if ; inline
 354
 355 : unsurround ( newseq seq2 seq3 -- seq1 )
 356    [ ?head drop ] [ ?tail drop ] bi* ;
 357
 358 : one? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 359     [ find ] 2keep rot [
 360         [ 1 + ] 2dip find-from drop not
 361     ] [ 3drop f ] if ; inline
 362
 363 : map-index! ( ... seq quot: ( ... elt index -- ... newelt ) -- ... seq )
 364     over [ [ (each-index) ] dip collect ] keep ; inline
 365
 366 <PRIVATE
 367
 368 : (2each-index) ( seq1 seq2 quot -- n quot' )
 369     [ setup-2each [ keep ] curry ] dip compose ; inline
 370
 371 PRIVATE>
 372
 373 : 2each-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... ) -- ... )
 374     (2each-index) each-integer ; inline
 375
 376 : 2map-into ( seq1 seq2 quot into -- )
 377     [ (2each) ] dip collect ; inline
 378
 379 : 2map! ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... seq1 )
 380     pick [ 2map-into ] keep ; inline
 381
 382 : 2map-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... newelt ) -- ... newseq )
 383     pick [ (2each-index) ] dip map-integers ; inline
 384
 385 TUPLE: evens { seq read-only } ;
 386
 387 C: <evens> evens
 388
 389 M: evens length seq>> length 1 + 2/ ; inline
 390
 391 M: evens virtual@ [ 2 * ] [ seq>> ] bi* ; inline
 392
 393 M: evens virtual-exemplar seq>> ; inline
 394
 395 INSTANCE: evens virtual-sequence
 396
 397 TUPLE: odds { seq read-only } ;
 398
 399 C: <odds> odds
 400
 401 M: odds length seq>> length 2/ ; inline
 402
 403 M: odds virtual@ [ 2 * 1 + ] [ seq>> ] bi* ; inline
 404
 405 M: odds virtual-exemplar seq>> ; inline
 406
 407 INSTANCE: odds virtual-sequence
 408
 409 : until-empty ( seq quot -- )
 410     [ dup empty? ] swap until drop ; inline
 411
 412 : arg-max ( seq -- n )
 413     [ supremum ] keep index ;
 414
 415 : arg-min ( seq -- n )
 416     [ infimum ] keep index ;
 417
 418 <PRIVATE
 419
 420 : push-index-if ( ..a elt i quot: ( ..a elt -- ..b ? ) accum -- ..b )
 421     [ dip ] dip rot [ push ] [ 2drop ] if ; inline
 422
 423 PRIVATE>
 424
 425 : arg-where ( ... seq quot: ( ... elt -- ... ? ) -- ... indices )
 426     over length <vector> [
 427         [ push-index-if ] 2curry each-index
 428     ] keep ; inline
 429
 430 : arg-sort ( seq -- indices )
 431     zip-index sort-keys values ;
 432
 433 : first= ( seq elt -- ? ) [ first ] dip = ; inline
 434 : second= ( seq elt -- ? ) [ second ] dip = ; inline
 435 : third= ( seq elt -- ? ) [ third ] dip = ; inline
 436 : fourth= ( seq elt -- ? ) [ fourth ] dip = ; inline
 437 : last= ( seq elt -- ? ) [ last ] dip = ; inline
 438 : nth= ( n seq elt -- ? ) [ nth ] dip = ; inline
 439
 440 : first? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ first ] dip call ; inline
 441 : second? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ second ] dip call ; inline
 442 : third? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ third ] dip call ; inline
 443 : fourth? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ fourth ] dip call ; inline
 444 : last? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ last ] dip call ; inline
 445 : nth? ( ... n seq quot: ( ... elt -- ... ? ) -- ... ? ) [ nth ] dip call ; inline
 446
 447 : loop>sequence ( quot: ( ..a -- ..a obj/f ) exemplar -- seq )
 448    [ '[ [ @ [ [ , ] when* ] keep ] loop ] ] dip make ; inline
 449
 450 : loop>array ( quot: ( ..a -- ..a obj/f ) -- seq )
 451    { } loop>sequence ; inline
 452
 453 : loop>sequence* ( quot: ( ..a -- ..a obj ? ) exemplar -- seq )
 454     [ '[ [ @ [ [ , ] when* ] [ ] bi* ] loop ] ] dip make ; inline
 455
 456 : loop>array* ( quot: ( ..a -- ..a obj ? ) -- seq )
 457    { } loop>sequence* ; inline
 458
 459 <PRIVATE
 460
 461 : (reverse) ( seq -- newseq )
 462     dup [ length ] keep new-sequence
 463     [ 0 swap copy-unsafe ] keep reverse! ;
 464
 465 PRIVATE>
 466
 467 : reverse-as ( seq exemplar -- newseq )
 468     [ (reverse) ] [ like ] bi* ;
 469
 470 : map-product ( ... seq quot: ( ... elt -- ... n ) -- ... n )
 471     [ 1 ] 2dip [ dip * ] curry [ swap ] prepose each ; inline
 472
 473 : insert-nth! ( elt n seq -- )
 474     [ length ] keep ensure swap pick (a,b]
 475     over '[ [ 1 + ] keep _ move-unsafe ] each
 476     set-nth-unsafe ;
 477
 478 : set-nths ( value indices seq -- )
 479     swapd '[ _ swap _ set-nth ] each ; inline
 480
 481 : set-nths-unsafe ( value indices seq -- )
 482     swapd '[ _ swap _ set-nth-unsafe ] each ; inline
 483
 484 <PRIVATE
 485
 486 : (map-find-index) ( seq quot find-quot -- result i elt )
 487     [ [ f ] 2dip [ [ nip ] 2dip call dup ] curry ] dip call
 488     [ [ [ drop f ] unless ] keep ] dip ; inline
 489
 490 PRIVATE>
 491
 492 : map-find-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 493     [ find-index ] (map-find-index) ; inline
 494
 495 : filter-length ( seq n -- seq' ) '[ length _ = ] filter ;
 496
 497 : all-shortest ( seqs -- seqs' ) dup shortest length filter-length ;
 498
 499 : all-longest ( seqs -- seqs' ) dup longest length filter-length ;
 500
 501 : remove-first ( obj seq -- seq' )
 502     [ index ] keep over [ remove-nth ] [ nip ] if ;
 503
 504 : remove-first! ( obj seq -- seq )
 505     [ index ] keep over [ remove-nth! ] [ nip ] if ;
 506
 507 : remove-last ( obj seq -- seq' )
 508     [ last-index ] keep over [ remove-nth ] [ nip ] if ;
 509
 510 : remove-last! ( obj seq -- seq )
 511     [ last-index ] keep over [ remove-nth! ] [ nip ] if ;
 512
 513 : ?first2 ( seq -- first/f second/f )
 514     dup length {
 515         { 0 [ drop f f ] }
 516         { 1 [ first-unsafe f ] }
 517         [ drop first2-unsafe ]
 518     } case ;
 519
 520 : ?first3 ( seq -- first/f second/f third/f )
 521     dup length {
 522         { 0 [ drop f f f ] }
 523         { 1 [ first-unsafe f f ] }
 524         { 2 [ first2-unsafe f ] }
 525         [ drop first3-unsafe ]
 526     } case ;
 527
 528 : ?first4 ( seq -- first/f second/f third/f fourth/f )
 529     dup length {
 530         { 0 [ drop f f f f ] }
 531         { 1 [ first-unsafe f f f ] }
 532         { 2 [ first2-unsafe f f ] }
 533         { 3 [ first3-unsafe f ] }
 534         [ drop first4-unsafe ]
 535     } case ;
 536
 537 : cut-when ( ... seq quot: ( ... elt -- ... ? ) -- ... before after )
 538     [ find drop ] keepd swap
 539     [ cut ] [ f over like ] if* ; inline
 540
 541 : nth* ( n seq -- elt )
 542     [ length 1 - swap - ] [ nth ] bi ; inline
 543
 544 : each-index-from ( ... seq quot: ( ... elt index -- ... ) i -- ... )
 545     -rot (each-index) (each-integer) ; inline
 546
 547 <PRIVATE
 548
 549 : select-by* ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... i elt )
 550     [
 551         [ keep swap ] curry [ dip ] curry
 552         [ [ first 0 ] dip call ] 2keep
 553         [ 2curry 3dip 5 npick pick ] curry
 554     ] [
 555         [ [ 3drop ] [ [ 3drop ] 3dip ] if ] compose
 556     ] bi* compose 1 each-index-from nip swap ; inline
 557
 558 PRIVATE>
 559
 560 : supremum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 561     [ after? ] select-by* ; inline
 562
 563 : infimum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 564     [ before? ] select-by* ; inline
 565
 566 : ?supremum ( seq/f -- elt/f )
 567     [ f ] [
 568         [ ] [ 2dup and [ max ] [ dupd ? ] if ] map-reduce
 569     ] if-empty ;
 570
 571 : ?infimum ( seq/f -- elt/f )
 572     [ f ] [
 573         [ ] [ 2dup and [ min ] [ dupd ? ] if ] map-reduce
 574     ] if-empty ;
 575
 576 : change-last ( seq quot -- )
 577     [ drop length 1 - ] [ change-nth ] 2bi ; inline
 578
 579 : change-last-unsafe ( seq quot -- )
 580     [ drop length 1 - ] [ change-nth-unsafe ] 2bi ; inline
 581
 582 : replicate-into ( ... seq quot: ( ... -- ... newelt ) -- ... )
 583     over [ length ] 2dip '[ _ dip _ set-nth-unsafe ] each-integer ; inline
 584
 585 : count* ( ... seq quot: ( ... elt -- ... ? ) -- ... % )
 586     over [ count ] [ length ] bi* / ; inline
 587
 588 : find-last-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 589     [ [ 1 - ] dip find-last-integer ] (find-index) ; inline
 590
 591 : map-find-last-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 592     [ find-last-index ] (map-find-index) ; inline
 593
 594 :: (start-all) ( subseq seq increment -- indices )
 595     0
 596     [ [ subseq seq ] dip subseq-start-from dup ]
 597     [ [ increment + ] keep ] produce nip ;
 598
 599 : start-all ( subseq seq -- indices )
 600     over length (start-all) ; inline
 601
 602 : start-all* ( subseq seq -- indices )
 603     1 (start-all) ; inline
 604
 605 : count-subseq ( subseq seq -- n )
 606     start-all length ; inline
 607
 608 : count-subseq* ( subseq seq -- n )
 609     start-all* length ; inline
 610
 611 : map-zip ( quot: ( x -- y ) -- alist )
 612     '[ _ keep swap ] map>alist ; inline
 613
 614 : map-keys ( assoc quot: ( key -- key' ) -- assoc )
 615     '[ _ dip ] assoc-map ; inline
 616
 617 : map-values ( assoc quot: ( value -- value' ) -- assoc )
 618     '[ swap _ dip swap ] assoc-map ; inline
 619
 620 : filter-keys ( assoc quot: ( key -- key' ) -- assoc' )
 621     '[ drop @ ] assoc-filter ; inline
 622
 623 : filter-values ( assoc quot: ( value -- value' ) -- assoc' )
 624     '[ nip @ ] assoc-filter ; inline
 625
 626 : reject-keys ( assoc quot: ( key -- key' ) -- assoc' )
 627     '[ drop @ ] assoc-reject ; inline
 628
 629 : reject-values ( assoc quot: ( value -- value' ) -- assoc' )
 630     '[ nip @ ] assoc-reject ; inline
 631
 632 : take-while ( ... seq quot: ( ... elt -- ... ? ) -- head-slice )
 633     [ '[ @ not ] find drop ] keepd swap
 634     [ dup length ] unless* head-slice ; inline
 635
 636 : drop-while ( ... seq quot: ( ... elt -- ... ? ) -- tail-slice )
 637     [ '[ @ not ] find drop ] keepd swap
 638     [ dup length ] unless* tail-slice ; inline
 639
 640 : count-head ( seq quot -- n )
 641     [ not ] compose [ find drop ] 2keep drop length or ; inline
 642
 643 : count-tail ( seq quot -- n )
 644     [ not ] compose [ find-last drop ] 2keep drop
 645     length swap [ - 1 - ] when* ; inline
 646
 647 :: interleaved-as ( seq glue exemplar -- newseq )
 648     seq length dup 1 - + 0 max exemplar new-sequence :> newseq
 649     seq [ 2 * newseq set-nth-unsafe ] each-index
 650     seq length 1 - [ 2 * 1 + glue swap newseq set-nth-unsafe ] each-integer
 651     newseq ;
 652
 653 : interleaved ( seq glue -- newseq )
 654     over interleaved-as ;
 655
 656 : extract! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 657     [ dup ] compose over [ length ] keep new-resizable
 658     [ [ push-if ] 2curry reject! ] keep swap like ; inline