extra/sequences/extras/extras.factor

   1 USING: accessors arrays assocs fry grouping kernel locals make
   2 math math.order math.ranges sequences sequences.private
   3 splitting ;
   4 FROM: sequences => change-nth ;
   5 IN: sequences.extras
   6
   7 : reduce1 ( seq quot -- result ) [ unclip ] dip reduce ; inline
   8
   9 :: reduce-r ( list identity quot: ( obj1 obj2 -- obj ) -- result )
  10     list empty?
  11     [ identity ]
  12     [ list rest identity quot reduce-r list first quot call ] if ;
  13     inline recursive
  14
  15 ! Quot must have static stack effect, unlike "reduce"
  16 :: reduce* ( seq id quot -- result ) seq
  17     [ id ]
  18     [ unclip id swap quot call( prev elt -- next ) quot reduce* ] if-empty ; inline recursive
  19
  20 :: combos ( list1 list2 -- result )
  21     list2 [ [ 2array ] curry list1 swap map ] map concat ;
  22
  23 : find-all ( seq quot -- elts )
  24     [ [ length iota ] keep ] dip
  25     [ dupd call( a -- ? ) [ 2array ] [ 2drop f ] if ] curry
  26     2map [ ] filter ; inline
  27
  28 : insert-sorted ( elt seq -- seq )
  29     2dup [ < ] with find drop over length or swap insert-nth ;
  30
  31 : each-from ( ... seq quot: ( ... x -- ... ) i -- ... )
  32     -rot (each) (each-integer) ; inline
  33
  34 : reduce-from ( ... seq identity quot: ( ... prev elt -- ... next ) i -- ... result )
  35     [ swap ] 2dip each-from ; inline
  36
  37 : supremum-by ( seq quot: ( ... elt -- ... x ) -- elt )
  38     [ [ first dup ] dip call ] 2keep [
  39         dupd call pick dupd after?
  40         [ [ 2drop ] 2dip ] [ 2drop ] if
  41     ] curry 1 each-from drop ; inline
  42
  43 : infimum-by ( seq quot: ( ... elt -- ... x ) -- elt )
  44     [ [ first dup ] dip call ] 2keep [
  45         dupd call pick dupd before?
  46         [ [ 2drop ] 2dip ] [ 2drop ] if
  47     ] curry 1 each-from drop ; inline
  48
  49 : all-subseqs ( seq -- seqs )
  50     dup length [1,b] [ <clumps> ] with map concat ;
  51
  52 :: each-subseq ( ... seq quot: ( ... x -- ... ) -- ... )
  53     seq length :> len
  54     len [0,b] [
  55         :> from
  56         from len (a,b] [
  57             :> to
  58             from to seq subseq quot call( x -- )
  59         ] each
  60     ] each ;
  61
  62 : map-like ( seq exemplar -- seq' )
  63     '[ _ like ] map ; inline
  64
  65 : filter-all-subseqs-range ( ... seq range quot: ( ... x -- ... ) -- seq )
  66     [
  67         '[ <sliced-clumps> _ filter ] with map concat
  68     ] 3keep 2drop map-like ; inline
  69
  70 : filter-all-subseqs ( ... seq quot: ( ... x -- ... ) -- seq )
  71     [ dup length [1,b] ] dip filter-all-subseqs-range ; inline
  72
  73 :: longest-subseq ( seq1 seq2 -- subseq )
  74     seq1 length :> len1
  75     seq2 length :> len2
  76     0 :> n!
  77     0 :> end!
  78     len1 1 + [ len2 1 + 0 <array> ] replicate :> table
  79     len1 [1,b] [| x |
  80         len2 [1,b] [| y |
  81             x 1 - seq1 nth-unsafe
  82             y 1 - seq2 nth-unsafe = [
  83                 y 1 - x 1 - table nth-unsafe nth-unsafe 1 + :> len
  84                 len y x table nth-unsafe set-nth-unsafe
  85                 len n > [ len n! x end! ] when
  86             ] [ 0 y x table nth-unsafe set-nth-unsafe ] if
  87         ] each
  88     ] each end n - end seq1 subseq ;
  89
  90 : pad-longest ( seq1 seq2 elt -- seq1 seq2 )
  91     [ 2dup max-length ] dip [ pad-tail ] 2curry bi@ ;
  92
  93 : change-nths ( ... indices seq quot: ( ... elt -- ... elt' ) -- ... )
  94     [ change-nth ] 2curry each ; inline
  95
  96 : push-if-index ( ..a elt i quot: ( ..a elt i -- ..b ? ) accum -- ..b )
  97     [ 2keep drop ] dip rot [ push ] [ 2drop ] if ; inline
  98
  99 : index-selector-for ( quot exemplar -- selector accum )
 100     [ length ] keep new-resizable [ [ push-if-index ] 2curry ] keep ; inline
 101
 102 : filter-index-as ( ... seq quot: ( ... elt i -- ... ? ) exemplar -- ... seq' )
 103     dup [ index-selector-for [ each-index ] dip ] curry dip like ; inline
 104
 105 : filter-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... seq' )
 106     over filter-index-as ; inline
 107
 108 : even-indices ( seq -- seq' ) [ nip even? ] filter-index ;
 109
 110 : odd-indices ( seq -- seq' ) [ nip odd? ] filter-index ;
 111
 112 : compact ( seq quot elt -- seq' )
 113     [ split-when harvest ] dip join ; inline
 114
 115 : collapse ( seq quot elt -- seq' )
 116     [ split-when ] dip
 117     [ [ harvest ] dip join ]
 118     [ [ first empty? ] dip [ prepend ] curry when ]
 119     [ [ last empty? ] dip [ append ] curry when ]
 120     2tri ; inline
 121
 122 :: slice-when ( seq quot: ( elt -- ? ) -- seq' )
 123     seq length :> len
 124     0 [ len dupd < ] [
 125         dup seq quot find-from drop
 126         [ 2dup = [ 1 + ] when ] [ len ] if*
 127         [ seq <slice> ] keep len or swap
 128     ] produce nip ; inline
 129
 130 : rotate ( seq n -- seq' )
 131     cut prepend ;
 132
 133 :: rotate! ( seq n -- )
 134     n seq bounds-check length :> end
 135     0 n [ 2dup = ] [
 136         [ seq exchange-unsafe ] [ [ 1 + ] bi@ ] 2bi
 137         dup end = [ drop over ] when
 138         2over = [ -rot nip over ] when
 139     ] until 3drop ;
 140
 141 : all-rotations ( seq -- seq' )
 142     dup length iota [ rotate ] with map ;
 143
 144 : appender-for ( quot exemplar -- quot' vec )
 145     [ length ] keep new-resizable
 146     [ [ push-all ] curry compose ] keep ; inline
 147
 148 : appender ( quot -- quot' vec )
 149     V{ } appender-for ; inline
 150
 151 : map-concat-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 152     dup [ appender-for [ each ] dip ] curry dip like ; inline
 153
 154 : >resizable ( seq -- vec ) ! fixes map-concat "cannot apply call to run-time..."
 155     [ length ] keep [ new-resizable ] [ over push-all ] bi ;
 156
 157 : map-concat ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 158     over [ 2drop { } ] [
 159         first over call dup [
 160             >resizable [ [ push-all ] curry compose ] keep
 161             [ 1 ] 3dip [ (each) (each-integer) ] dip
 162         ] curry dip like
 163     ] if-empty ; inline
 164
 165 : map-filter-as ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) exemplar -- ... subseq )
 166     dup [ selector-for [ compose each ] dip ] curry dip like ; inline
 167
 168 : map-filter ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) -- ... subseq )
 169     pick map-filter-as ; inline
 170
 171 : map-sift ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 172     [ ] map-filter ; inline
 173
 174 : map-harvest ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 175     [ empty? not ] map-filter ; inline
 176
 177 <PRIVATE
 178
 179 : ((each-from)) ( i seq -- n quot )
 180     [ length over - 0 max swap ] keep '[ _ + _ nth-unsafe ] ; inline
 181
 182 : (each-from) ( i seq quot -- n quot' ) [ ((each-from)) ] dip compose ;
 183     inline
 184
 185 PRIVATE>
 186
 187 : map-from-as ( ... seq quot: ( ... elt -- ... newelt ) i exemplar -- ... newseq )
 188     [ -rot (each-from) ] dip map-integers ; inline
 189
 190 : map-from ( ... seq quot: ( ... elt -- ... newelt ) i -- ... newseq )
 191     pick map-from-as ; inline
 192
 193 <PRIVATE
 194
 195 : push-map-if ( ..a elt filter-quot: ( ..a elt -- ..b ? ) map-quot: ( ..a elt -- ..b newelt ) accum -- ..b )
 196     [ keep over ] 2dip [ when ] dip rot [ push ] [ 2drop ] if ; inline
 197
 198 : filter-mapper-for ( filter-quot map-quot exemplar -- quot' vec )
 199     [ length ] keep new-resizable [ [ push-map-if ] 3curry ] keep ; inline
 200
 201 : filter-mapper ( filter-quot map-quot -- quot' vec )
 202     V{ } filter-mapper-for ; inline
 203
 204 PRIVATE>
 205
 206 : filter-map-as ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 207     dup [ filter-mapper-for [ each ] dip ] curry dip like ; inline
 208
 209 : filter-map ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) -- ... newseq )
 210     pick filter-map-as ; inline
 211
 212 : 2map-sum ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... n ) -- ... n )
 213     [ 0 ] 3dip [ dip + ] curry [ rot ] prepose 2each ; inline
 214
 215 : 2count ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... n )
 216     [ 1 0 ? ] compose 2map-sum ; inline
 217
 218 : round-robin ( seq -- newseq )
 219     [ { } ] [
 220         [ [ length ] [ max ] map-reduce iota ] keep
 221         [ [ ?nth ] with map ] curry map concat sift
 222     ] if-empty ;
 223
 224 : sift-as ( seq exemplar -- newseq )
 225     [ ] swap filter-as ;
 226
 227 : harvest-as ( seq exemplar -- newseq )
 228     [ empty? not ] swap filter-as ;
 229
 230 : contains? ( seq elts -- ? )
 231     [ member? ] curry any? ; inline
 232
 233 : trim-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... newseq )
 234     [ trim-slice ] [ like ] bi* ; inline
 235
 236 : ?trim ( ... seq quot: ( ... elt -- ... ? ) -- ... seq/newseq )
 237     over empty? [ drop ] [
 238         over [ first-unsafe ] [ last-unsafe ] bi pick bi@ or
 239         [ trim ] [ drop ] if
 240     ] if ; inline
 241
 242 : unsurround ( newseq seq2 seq3 -- seq1 )
 243    [ ?head drop ] [ ?tail drop ] bi* ;
 244
 245 : none? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 246     any? not ; inline
 247
 248 : one? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 249     [ find ] 2keep rot [
 250         [ 1 + ] 2dip find-from drop not
 251     ] [ 3drop f ] if ; inline
 252
 253 : map-index! ( ... seq quot: ( ... elt index -- ... newelt ) -- ... seq )
 254     over [ [ (each-index) ] dip collect ] keep ; inline
 255
 256 <PRIVATE
 257
 258 : (2each-index) ( seq1 seq2 quot -- n quot' )
 259     [ ((2each)) [ keep ] curry ] dip compose ; inline
 260
 261 PRIVATE>
 262
 263 : 2each-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... ) -- ... )
 264     (2each-index) each-integer ; inline
 265
 266 : 2map-into ( seq1 seq2 quot into -- )
 267     [ (2each) ] dip collect ; inline
 268
 269 : 2map! ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... seq1 )
 270     pick [ 2map-into ] keep ; inline
 271
 272 : 2map-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... newelt ) -- ... newseq )
 273     pick [ (2each-index) ] dip map-integers ; inline
 274
 275 TUPLE: evens seq length ;
 276
 277 : <evens> ( seq -- evens )
 278     dup length 1 + 2/ evens boa ; inline
 279
 280 M: evens length length>> ; inline
 281
 282 M: evens nth-unsafe [ 2 * ] [ seq>> nth-unsafe ] bi* ; inline
 283
 284 INSTANCE: evens immutable-sequence
 285
 286 TUPLE: odds seq length ;
 287
 288 : <odds> ( seq -- odds )
 289     dup length 2/ odds boa ; inline
 290
 291 M: odds length length>> ; inline
 292
 293 M: odds nth-unsafe [ 2 * 1 + ] [ seq>> nth-unsafe ] bi* ; inline
 294
 295 INSTANCE: odds immutable-sequence
 296
 297 : until-empty ( seq quot -- )
 298     [ dup empty? ] swap until drop ; inline
 299
 300 : arg-max ( seq -- n )
 301     dup length iota zip [ first-unsafe ] supremum-by second ;
 302
 303 : arg-min ( seq -- n )
 304     dup length iota zip [ first-unsafe ] infimum-by second ;
 305
 306 : arg-where ( ... seq quot: ( ... elt -- ... ? ) -- ... indices )
 307     [ dup length iota zip ] dip
 308     [ first-unsafe ] prepose filter values ; inline
 309
 310 : first= ( seq elt -- ? ) [ first ] dip = ; inline
 311 : second= ( seq elt -- ? ) [ second ] dip = ; inline
 312 : third= ( seq elt -- ? ) [ third ] dip = ; inline
 313 : fourth= ( seq elt -- ? ) [ fourth ] dip = ; inline
 314 : last= ( seq elt -- ? ) [ last ] dip = ; inline
 315 : nth= ( n seq elt -- ? ) [ nth ] dip = ; inline
 316
 317 : first? ( seq quot -- ? ) [ first ] dip call ; inline
 318 : second? ( seq quot -- ? ) [ second ] dip call ; inline
 319 : third? ( seq quot -- ? ) [ third ] dip call ; inline
 320 : fourth? ( seq quot -- ? ) [ fourth ] dip call ; inline
 321 : last? ( seq quot -- ? ) [ last ] dip call ; inline
 322 : nth? ( n seq quot -- ? ) [ nth ] dip call ; inline
 323
 324 : loop>sequence ( quot exemplar -- seq )
 325    [ '[ [ @ [ [ , ] when* ] keep ] loop ] ] dip make ; inline
 326
 327 : loop>array ( quot -- seq )
 328    { } loop>sequence ; inline
 329
 330 <PRIVATE
 331
 332 : (reverse) ( seq -- newseq )
 333     dup [ length ] keep new-sequence [ 0 swap copy ] keep reverse! ;
 334
 335 PRIVATE>
 336
 337 : reverse-as ( seq exemplar -- newseq )
 338     [ (reverse) ] [ like ] bi* ;
 339
 340 : assoc-reduce ( ... assoc identity quot: ( ... prev key value -- next ) -- ... result )
 341     [ >alist ] 2dip [ first2 ] prepose reduce ; inline
 342
 343 : reduce-keys ( ... assoc identity quot: ( ... prev elt -- ... next ) -- ... result )
 344     [ drop ] prepose assoc-reduce ; inline
 345
 346 : reduce-values ( ... assoc identity quot: ( ... prev elt -- ... next ) -- ... result )
 347     [ nip ] prepose assoc-reduce ; inline
 348
 349 : sum-keys ( assoc -- n ) 0 [ + ] reduce-keys ; inline
 350
 351 : sum-values ( assoc -- n ) 0 [ + ] reduce-values ; inline
 352
 353 : map-product ( ... seq quot: ( ... elt -- ... n ) -- ... n )
 354     [ 1 ] 2dip [ dip * ] curry [ swap ] prepose each ; inline