extra/sequences/extras/extras.factor

   1 USING: accessors arrays assocs fry grouping growable kernel
   2 locals make math math.order math.ranges sequences
   3 sequences.deep sequences.private sorting splitting vectors ;
   4 FROM: sequences => change-nth ;
   5 IN: sequences.extras
   6
   7 : reduce1 ( seq quot -- result ) [ unclip ] dip reduce ; inline
   8
   9 :: reduce-r ( seq identity quot: ( obj1 obj2 -- obj ) -- result )
  10     seq [ identity ] [
  11         unclip [ identity quot reduce-r ] [ quot call ] bi*
  12     ] if-empty ; inline recursive
  13
  14 ! Quot must have static stack effect, unlike "reduce"
  15 :: reduce* ( seq identity quot: ( prev elt -- next ) -- result )
  16     seq [ identity ] [
  17         unclip identity swap quot call( prev elt -- next )
  18         quot reduce*
  19     ] if-empty ; inline recursive
  20
  21 :: combos ( list1 list2 -- result )
  22     list2 [ [ 2array ] curry list1 swap map ] map concat ;
  23
  24 : find-all ( seq quot: ( elt -- ? ) -- elts )
  25     [ [ length iota ] keep ] dip
  26     [ dupd call( a -- ? ) [ 2array ] [ 2drop f ] if ] curry
  27     2map [ ] filter ; inline
  28
  29 : insert-sorted ( elt seq -- seq )
  30     2dup [ < ] with find drop over length or swap insert-nth ;
  31
  32 : reduce-from ( ... seq identity quot: ( ... prev elt -- ... next ) i -- ... result )
  33     [ swap ] 2dip each-from ; inline
  34
  35 : all-subseqs ( seq -- seqs )
  36     dup length [1,b] [ clump ] with map concat ;
  37
  38 :: each-subseq ( ... seq quot: ( ... x -- ... ) -- ... )
  39     seq length :> len
  40     len [0,b] [
  41         :> from
  42         from len (a,b] [
  43             :> to
  44             from to seq subseq quot call
  45         ] each
  46     ] each ; inline
  47
  48 : subseq-as ( from to seq exemplar -- subseq )
  49     [ check-slice subseq>copy (copy) ] dip like ;
  50
  51 : map-like ( seq exemplar -- seq' )
  52     '[ _ like ] map ; inline
  53
  54 : filter-all-subseqs-range ( ... seq range quot: ( ... x -- ... ) -- seq )
  55     [
  56         '[ <clumps> _ filter ] with map concat
  57     ] 3keep 2drop map-like ; inline
  58
  59 : filter-all-subseqs ( ... seq quot: ( ... x -- ... ) -- seq )
  60     [ dup length [1,b] ] dip filter-all-subseqs-range ; inline
  61
  62 :: longest-subseq ( seq1 seq2 -- subseq )
  63     seq1 length :> len1
  64     seq2 length :> len2
  65     0 :> n!
  66     0 :> end!
  67     len1 1 + [ len2 1 + 0 <array> ] replicate :> table
  68     len1 [1,b] [| x |
  69         len2 [1,b] [| y |
  70             x 1 - seq1 nth-unsafe
  71             y 1 - seq2 nth-unsafe = [
  72                 y 1 - x 1 - table nth-unsafe nth-unsafe 1 + :> len
  73                 len y x table nth-unsafe set-nth-unsafe
  74                 len n > [ len n! x end! ] when
  75             ] [ 0 y x table nth-unsafe set-nth-unsafe ] if
  76         ] each
  77     ] each end n - end seq1 subseq ;
  78
  79 : pad-longest ( seq1 seq2 elt -- seq1 seq2 )
  80     [ 2dup max-length ] dip [ pad-tail ] 2curry bi@ ;
  81
  82 : change-nths ( ... indices seq quot: ( ... elt -- ... elt' ) -- ... )
  83     [ change-nth ] 2curry each ; inline
  84
  85 : push-if-index ( ..a elt i quot: ( ..a elt i -- ..b ? ) accum -- ..b )
  86     [ 2keep drop ] dip rot [ push ] [ 2drop ] if ; inline
  87
  88 <PRIVATE
  89
  90 : (index-selector-for) ( quot length exampler -- selector accum )
  91     new-resizable [ [ push-if-index ] 2curry ] keep ; inline
  92
  93 PRIVATE>
  94
  95 : index-selector-for ( quot exemplar -- selector accum )
  96     [ length ] keep (index-selector-for) ; inline
  97
  98 : filter-index-as ( ... seq quot: ( ... elt i -- ... ? ) exemplar -- ... seq' )
  99     pick length over [ (index-selector-for) [ each-index ] dip ] 2curry dip like ; inline
 100
 101 : filter-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... seq' )
 102     over filter-index-as ; inline
 103
 104 : even-indices ( seq -- seq' )
 105     [ length 1 + 2/ ] keep [
 106         [ [ 2 * ] dip nth-unsafe ] curry
 107     ] keep map-integers ;
 108
 109 : odd-indices ( seq -- seq' )
 110     [ length 2/ ] keep [
 111         [ [ 2 * 1 + ] dip nth-unsafe ] curry
 112     ] keep map-integers ;
 113
 114 : compact ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 115     [ split-when harvest ] dip join ; inline
 116
 117 : collapse ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 118     [ split-when ] dip
 119     [ [ harvest ] dip join ]
 120     [ [ first empty? ] dip [ prepend ] curry when ]
 121     [ [ last empty? ] dip [ append ] curry when ]
 122     2tri ; inline
 123
 124 :: slice-when ( seq quot: ( elt -- ? ) -- seq' )
 125     seq length :> len
 126     0 [ len dupd < ] [
 127         dup seq quot find-from drop
 128         [ 2dup = [ 1 + ] when ] [ len ] if*
 129         [ seq <slice> ] keep len or swap
 130     ] produce nip ; inline
 131
 132 : cut-slice* ( seq n -- before after )
 133     [ head-slice* ] [ tail-slice* ] 2bi ;
 134
 135 : rotate ( seq n -- seq' )
 136     cut prepend ;
 137
 138 :: rotate! ( seq n -- )
 139     n seq bounds-check length :> end
 140     0 n [ 2dup = ] [
 141         [ seq exchange-unsafe ] [ [ 1 + ] bi@ ] 2bi
 142         dup end = [ drop over ] when
 143         2over = [ -rot nip over ] when
 144     ] until 3drop ;
 145
 146 : all-rotations ( seq -- seq' )
 147     dup length iota [ rotate ] with map ;
 148
 149 <PRIVATE
 150
 151 : (appender-for) ( quot length exemplar -- appender accum )
 152     new-resizable [ [ push-all ] curry compose ] keep ; inline
 153
 154 PRIVATE>
 155
 156 : appender-for ( quot exemplar -- appender accum )
 157     [ length ] keep (appender-for) ; inline
 158
 159 : appender ( quot -- appender accum )
 160     V{ } appender-for ; inline
 161
 162 : map-concat-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 163     pick length over [ (appender-for) [ each ] dip ] 2curry dip like ; inline
 164
 165 : >resizable ( seq -- accum ) ! fixes map-concat "cannot apply call to run-time..."
 166     [ length ] keep [ new-resizable ] [ over push-all ] bi ;
 167
 168 : map-concat ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 169     over [ 2drop { } ] [
 170         first over call dup [
 171             >resizable [ [ push-all ] curry compose ] keep
 172             [ 1 ] 3dip [ (each) (each-integer) ] dip
 173         ] curry dip like
 174     ] if-empty ; inline
 175
 176 : map-filter-as ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) exemplar -- ... subseq )
 177     [ pick ] dip swap length over
 178     [ (selector-for) [ compose each ] dip ] 2curry dip like ; inline
 179
 180 : map-filter ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) -- ... subseq )
 181     pick map-filter-as ; inline
 182
 183 : map-sift ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 184     [ ] map-filter ; inline
 185
 186 : map-harvest ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 187     [ empty? not ] map-filter ; inline
 188
 189 <PRIVATE
 190
 191 : ((each-from)) ( i seq -- n quot )
 192     [ length over [-] swap ] keep '[ _ + _ nth-unsafe ] ; inline
 193
 194 : (each-from) ( i seq quot -- n quot' ) [ ((each-from)) ] dip compose ;
 195     inline
 196
 197 PRIVATE>
 198
 199 : map-from-as ( ... seq quot: ( ... elt -- ... newelt ) i exemplar -- ... newseq )
 200     [ -rot (each-from) ] dip map-integers ; inline
 201
 202 : map-from ( ... seq quot: ( ... elt -- ... newelt ) i -- ... newseq )
 203     pick map-from-as ; inline
 204
 205 <PRIVATE
 206
 207 : push-map-if ( ..a elt filter-quot: ( ..a elt -- ..b ? ) map-quot: ( ..a elt -- ..b newelt ) accum -- ..b )
 208     [ keep over ] 2dip [ when ] dip rot [ push ] [ 2drop ] if ; inline
 209
 210 : (filter-mapper-for) ( filter-quot map-quot length exempler -- filter-mapper accum )
 211     new-resizable [ [ push-map-if ] 3curry ] keep ; inline
 212
 213 : filter-mapper-for ( filter-quot map-quot exemplar -- filter-mapper accum )
 214     [ length ] keep (filter-mapper-for) ; inline
 215
 216 : filter-mapper ( filter-quot map-quot -- filter-mapper accum )
 217     V{ } filter-mapper-for ; inline
 218
 219 PRIVATE>
 220
 221 : filter-map-as ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 222     [ pick ] dip swap length over
 223     [ (filter-mapper-for) [ each ] dip ] 2curry dip like ; inline
 224
 225 : filter-map ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) -- ... newseq )
 226     pick filter-map-as ; inline
 227
 228 : 2map-sum ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... n ) -- ... n )
 229     [ 0 ] 3dip [ dip + ] curry [ rot ] prepose 2each ; inline
 230
 231 : 2count ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... n )
 232     [ 1 0 ? ] compose 2map-sum ; inline
 233
 234 : round-robin ( seq -- newseq )
 235     [ { } ] [
 236         [ longest length iota ] keep
 237         [ [ ?nth ] with map ] curry map concat sift
 238     ] if-empty ;
 239
 240 : sift-as ( seq exemplar -- newseq )
 241     [ ] swap filter-as ;
 242
 243 : sift! ( seq -- newseq )
 244     [ ] filter! ;
 245
 246 : harvest-as ( seq exemplar -- newseq )
 247     [ empty? not ] swap filter-as ;
 248
 249 : harvest! ( seq -- newseq )
 250     [ empty? not ] filter! ;
 251
 252 : contains? ( seq elts -- ? )
 253     [ member? ] curry any? ; inline
 254
 255 : head-as ( seq n exemplar -- seq' )
 256     [ head-slice ] [ like ] bi* ; inline
 257
 258 : head*-as ( seq n exemplar -- seq' )
 259     [ head-slice* ] [ like ] bi* ; inline
 260
 261 : tail-as ( seq n exemplar -- seq' )
 262     [ tail-slice ] [ like ] bi* ; inline
 263
 264 : tail*-as ( seq n exemplar -- seq' )
 265     [ tail-slice* ] [ like ] bi* ; inline
 266
 267 : trim-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... newseq )
 268     [ trim-slice ] [ like ] bi* ; inline
 269
 270 : ?trim ( seq quot: ( elt -- ? ) -- seq/newseq )
 271     over empty? [ drop ] [
 272         over [ first-unsafe ] [ last-unsafe ] bi pick bi@ or
 273         [ trim ] [ drop ] if
 274     ] if ; inline
 275
 276 : ?trim-head ( seq quot: ( elt -- ? ) -- seq/newseq )
 277     over empty? [ drop ] [
 278         over first-unsafe over call
 279         [ trim-head ] [ drop ] if
 280     ] if ; inline
 281
 282 : ?trim-tail ( seq quot: ( elt -- ? ) -- seq/newseq )
 283     over empty? [ drop ] [
 284         over last-unsafe over call
 285         [ trim-tail ] [ drop ] if
 286     ] if ; inline
 287
 288 : unsurround ( newseq seq2 seq3 -- seq1 )
 289    [ ?head drop ] [ ?tail drop ] bi* ;
 290
 291 : none? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 292     any? not ; inline
 293
 294 : one? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 295     [ find ] 2keep rot [
 296         [ 1 + ] 2dip find-from drop not
 297     ] [ 3drop f ] if ; inline
 298
 299 : map-index! ( ... seq quot: ( ... elt index -- ... newelt ) -- ... seq )
 300     over [ [ (each-index) ] dip collect ] keep ; inline
 301
 302 <PRIVATE
 303
 304 : (2each-index) ( seq1 seq2 quot -- n quot' )
 305     [ ((2each)) [ keep ] curry ] dip compose ; inline
 306
 307 PRIVATE>
 308
 309 : 2each-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... ) -- ... )
 310     (2each-index) each-integer ; inline
 311
 312 : 2map-into ( seq1 seq2 quot into -- )
 313     [ (2each) ] dip collect ; inline
 314
 315 : 2map! ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... seq1 )
 316     pick [ 2map-into ] keep ; inline
 317
 318 : 2map-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... newelt ) -- ... newseq )
 319     pick [ (2each-index) ] dip map-integers ; inline
 320
 321 TUPLE: evens seq length ;
 322
 323 : <evens> ( seq -- evens )
 324     dup length 1 + 2/ evens boa ; inline
 325
 326 M: evens length length>> ; inline
 327
 328 M: evens nth-unsafe [ 2 * ] [ seq>> nth-unsafe ] bi* ; inline
 329
 330 INSTANCE: evens immutable-sequence
 331
 332 TUPLE: odds seq length ;
 333
 334 : <odds> ( seq -- odds )
 335     dup length 2/ odds boa ; inline
 336
 337 M: odds length length>> ; inline
 338
 339 M: odds nth-unsafe [ 2 * 1 + ] [ seq>> nth-unsafe ] bi* ; inline
 340
 341 INSTANCE: odds immutable-sequence
 342
 343 : until-empty ( seq quot -- )
 344     [ dup empty? ] swap until drop ; inline
 345
 346 : arg-max ( seq -- n )
 347     <enum> [ second-unsafe ] supremum-by first ;
 348
 349 : arg-min ( seq -- n )
 350     <enum> [ second-unsafe ] infimum-by first ;
 351
 352 <PRIVATE
 353
 354 : push-index-if ( ..a elt i quot: ( ..a elt -- ..b ? ) accum -- ..b )
 355     [ dip ] dip rot [ push ] [ 2drop ] if ; inline
 356
 357 PRIVATE>
 358
 359 : arg-where ( ... seq quot: ( ... elt -- ... ? ) -- ... indices )
 360     over length <vector> [
 361         [ push-index-if ] 2curry each-index
 362     ] keep ; inline
 363
 364 : arg-sort ( seq -- indices )
 365     dup length iota zip sort-keys values ;
 366
 367 : first= ( seq elt -- ? ) [ first ] dip = ; inline
 368 : second= ( seq elt -- ? ) [ second ] dip = ; inline
 369 : third= ( seq elt -- ? ) [ third ] dip = ; inline
 370 : fourth= ( seq elt -- ? ) [ fourth ] dip = ; inline
 371 : last= ( seq elt -- ? ) [ last ] dip = ; inline
 372 : nth= ( n seq elt -- ? ) [ nth ] dip = ; inline
 373
 374 : first? ( seq quot -- ? ) [ first ] dip call ; inline
 375 : second? ( seq quot -- ? ) [ second ] dip call ; inline
 376 : third? ( seq quot -- ? ) [ third ] dip call ; inline
 377 : fourth? ( seq quot -- ? ) [ fourth ] dip call ; inline
 378 : last? ( seq quot -- ? ) [ last ] dip call ; inline
 379 : nth? ( n seq quot -- ? ) [ nth ] dip call ; inline
 380
 381 : loop>sequence ( quot exemplar -- seq )
 382    [ '[ [ @ [ [ , ] when* ] keep ] loop ] ] dip make ; inline
 383
 384 : loop>array ( quot -- seq )
 385    { } loop>sequence ; inline
 386
 387 <PRIVATE
 388
 389 : (reverse) ( seq -- newseq )
 390     dup [ length ] keep new-sequence
 391     [ 0 swap copy-unsafe ] keep reverse! ;
 392
 393 PRIVATE>
 394
 395 : reverse-as ( seq exemplar -- newseq )
 396     [ (reverse) ] [ like ] bi* ;
 397
 398 : map-product ( ... seq quot: ( ... elt -- ... n ) -- ... n )
 399     [ 1 ] 2dip [ dip * ] curry [ swap ] prepose each ; inline
 400
 401 : insert-nth! ( elt n seq -- )
 402     [ length ] keep ensure swap pick (a,b]
 403     over '[ [ 1 + ] keep _ move-unsafe ] each
 404     set-nth-unsafe ;
 405
 406 : set-nths ( value indices seq -- )
 407     swapd '[ [ _ ] dip _ set-nth ] each ; inline
 408
 409 : set-nths-unsafe ( value indices seq -- )
 410     swapd '[ [ _ ] dip _ set-nth-unsafe ] each ; inline
 411
 412 : flatten1 ( obj -- seq )
 413     [
 414         [
 415             dup branch? [
 416                 [ dup branch? [ % ] [ , ] if ] each
 417             ] [ , ] if
 418         ]
 419     ] keep dup branch? [ drop f ] unless make ;
 420
 421 <PRIVATE
 422
 423 : (map-find-index) ( seq quot find-quot -- result elt index )
 424     [ [ f ] 2dip [ [ nip ] 2dip call dup ] curry ] dip call
 425     [ [ [ drop f ] unless ] keep ] dip ; inline
 426
 427 PRIVATE>
 428
 429 : map-find-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result elt index )
 430     [ find-index ] (map-find-index) ; inline
 431
 432 : filter-length ( seq n -- seq' ) '[ length _ = ] filter ;
 433
 434 : all-shortest ( seqs -- seqs' ) dup shortest length filter-length ;
 435
 436 : all-longest ( seqs -- seqs' ) dup longest length filter-length ;
 437
 438 : remove-first ( obj seq -- seq' )
 439     [ index ] keep over [ remove-nth ] [ nip ] if ;
 440
 441 : remove-first! ( obj seq -- seq )
 442     [ index ] keep over [ remove-nth! ] [ nip ] if ;
 443
 444 : remove-last ( obj seq -- seq' )
 445     [ last-index ] keep over [ remove-nth ] [ nip ] if ;
 446
 447 : remove-last! ( obj seq -- seq )
 448     [ last-index ] keep over [ remove-nth! ] [ nip ] if ;