extra/sequences/extras/extras.factor

   1 USING: accessors arrays assocs combinators fry generalizations
   2 grouping growable kernel locals make math math.order math.ranges
   3 sequences sequences.deep sequences.private sorting splitting
   4 vectors ;
   5 IN: sequences.extras
   6
   7 : reduce1 ( seq quot -- result ) [ unclip ] dip reduce ; inline
   8
   9 :: reduce-r ( seq identity quot: ( obj1 obj2 -- obj ) -- result )
  10     seq [ identity ] [
  11         unclip [ identity quot reduce-r ] [ quot call ] bi*
  12     ] if-empty ; inline recursive
  13
  14 ! Quot must have static stack effect, unlike "reduce"
  15 :: reduce* ( seq identity quot: ( prev elt -- next ) -- result )
  16     seq [ identity ] [
  17         unclip identity swap quot call( prev elt -- next )
  18         quot reduce*
  19     ] if-empty ; inline recursive
  20
  21 :: combos ( list1 list2 -- result )
  22     list2 [ [ 2array ] curry list1 swap map ] map concat ;
  23
  24 : find-all ( seq quot: ( elt -- ? ) -- elts )
  25     [ [ length iota ] keep ] dip
  26     [ dupd call( a -- ? ) [ 2array ] [ 2drop f ] if ] curry
  27     2map sift ; inline
  28
  29 : reduce-from ( ... seq identity quot: ( ... prev elt -- ... next ) i -- ... result )
  30     [ swap ] 2dip each-from ; inline
  31
  32 :: subseq* ( from to seq -- subseq )
  33     seq length :> len
  34     from [ dup 0 < [ len + ] when ] [ 0 ] if*
  35     to [ dup 0 < [ len + ] when ] [ len ] if*
  36     [ 0 len clamp ] bi@ dupd max seq subseq ;
  37
  38 : safe-subseq ( from to seq -- subseq )
  39     [ length '[ 0 _ clamp ] bi@ ] keep subseq ;
  40
  41 : all-subseqs ( seq -- seqs )
  42     dup length [1,b] [ clump ] with map concat ;
  43
  44 :: each-subseq ( ... seq quot: ( ... x -- ... ) -- ... )
  45     seq length :> len
  46     len [0,b] [
  47         :> from
  48         from len (a,b] [
  49             :> to
  50             from to seq subseq quot call
  51         ] each
  52     ] each ; inline
  53
  54 : subseq-as ( from to seq exemplar -- subseq )
  55     [ check-slice subseq>copy (copy) ] dip like ;
  56
  57 : map-like ( seq exemplar -- seq' )
  58     '[ _ like ] map ; inline
  59
  60 : filter-all-subseqs-range ( ... seq range quot: ( ... x -- ... ) -- seq )
  61     [
  62         '[ <clumps> _ filter ] with map concat
  63     ] 3keep 2drop map-like ; inline
  64
  65 : filter-all-subseqs ( ... seq quot: ( ... x -- ... ) -- seq )
  66     [ dup length [1,b] ] dip filter-all-subseqs-range ; inline
  67
  68 :: longest-subseq ( seq1 seq2 -- subseq )
  69     seq1 length :> len1
  70     seq2 length :> len2
  71     0 :> n!
  72     0 :> end!
  73     len1 1 + [ len2 1 + 0 <array> ] replicate :> table
  74     len1 [1,b] [| x |
  75         len2 [1,b] [| y |
  76             x 1 - seq1 nth-unsafe
  77             y 1 - seq2 nth-unsafe = [
  78                 y 1 - x 1 - table nth-unsafe nth-unsafe 1 + :> len
  79                 len y x table nth-unsafe set-nth-unsafe
  80                 len n > [ len n! x end! ] when
  81             ] [ 0 y x table nth-unsafe set-nth-unsafe ] if
  82         ] each
  83     ] each end n - end seq1 subseq ;
  84
  85 : pad-longest ( seq1 seq2 elt -- seq1 seq2 )
  86     [ 2dup max-length ] dip [ pad-tail ] 2curry bi@ ;
  87
  88 : change-nths ( ... indices seq quot: ( ... elt -- ... elt' ) -- ... )
  89     [ change-nth ] 2curry each ; inline
  90
  91 : push-if-index ( ..a elt i quot: ( ..a elt i -- ..b ? ) accum -- ..b )
  92     [ 2keep drop ] dip rot [ push ] [ 2drop ] if ; inline
  93
  94 : push-if* ( ..a elt quot: ( ..a elt -- ..b obj/f ) accum -- ..b )
  95     [ call ] dip [ push ] [ drop ] if* ; inline
  96
  97 <PRIVATE
  98
  99 : (index-selector-for) ( quot length exampler -- selector accum )
 100     new-resizable [ [ push-if-index ] 2curry ] keep ; inline
 101
 102 : (selector-for*) ( quot length exemplar -- selector accum )
 103     new-resizable [ [ push-if* ] 2curry ] keep ; inline
 104
 105 PRIVATE>
 106
 107 : index-selector-for ( quot exemplar -- selector accum )
 108     [ length ] keep (index-selector-for) ; inline
 109
 110 : index-selector ( quot -- selector accum )
 111     V{ } index-selector-for ; inline
 112
 113 : selector-for* ( quot exemplar -- selector accum )
 114     [ length ] keep (selector-for*) ; inline
 115
 116 : selector* ( quot -- selector accum ) V{ } selector-for* ; inline
 117
 118 : filter-index-as ( ... seq quot: ( ... elt i -- ... ? ) exemplar -- ... seq' )
 119     pick length over [ (index-selector-for) [ each-index ] dip ] 2curry dip like ; inline
 120
 121 : filter-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... seq' )
 122     over filter-index-as ; inline
 123
 124 : even-indices ( seq -- seq' )
 125     [ length 1 + 2/ ] keep [
 126         [ [ 2 * ] dip nth-unsafe ] curry
 127     ] keep map-integers ;
 128
 129 : odd-indices ( seq -- seq' )
 130     [ length 2/ ] keep [
 131         [ [ 2 * 1 + ] dip nth-unsafe ] curry
 132     ] keep map-integers ;
 133
 134 : compact ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 135     [ split-when harvest ] dip join ; inline
 136
 137 : collapse ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 138     [ split-when ] dip
 139     [ [ harvest ] dip join ]
 140     [ [ first empty? ] dip [ prepend ] curry when ]
 141     [ [ last empty? ] dip [ append ] curry when ]
 142     2tri ; inline
 143
 144 :: slice-when ( seq quot: ( elt -- ? ) -- seq' )
 145     seq length :> len
 146     0 [ len dupd < ] [
 147         dup seq quot find-from drop
 148         [ 2dup = [ 1 + ] when ] [ len ] if*
 149         [ seq <slice> ] keep len or swap
 150     ] produce nip ; inline
 151
 152 : cut-slice* ( seq n -- before after )
 153     [ head-slice* ] [ tail-slice* ] 2bi ;
 154
 155 : rotate ( seq n -- seq' )
 156     cut prepend ;
 157
 158 :: rotate! ( seq n -- )
 159     n seq bounds-check length :> end
 160     0 n [ 2dup = ] [
 161         [ seq exchange-unsafe ] [ [ 1 + ] bi@ ] 2bi
 162         dup end = [ drop over ] when
 163         2over = [ -rot nip over ] when
 164     ] until 3drop ;
 165
 166 : all-rotations ( seq -- seq' )
 167     dup length iota [ rotate ] with map ;
 168
 169 <PRIVATE
 170
 171 : (appender-for) ( quot length exemplar -- appender accum )
 172     new-resizable [ [ push-all ] curry compose ] keep ; inline
 173
 174 PRIVATE>
 175
 176 : appender-for ( quot exemplar -- appender accum )
 177     [ length ] keep (appender-for) ; inline
 178
 179 : appender ( quot -- appender accum )
 180     V{ } appender-for ; inline
 181
 182 : map-concat-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 183     [ appender-for [ each ] dip ] keep like ; inline
 184
 185 : >resizable ( seq -- accum ) ! fixes map-concat "cannot apply call to run-time..."
 186     [ length ] keep [ new-resizable ] [ append! ] bi ;
 187
 188 : map-concat ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 189     over empty? [ 2drop { } ] [
 190         [ [ first ] dip call ] 2keep rot dup [
 191             >resizable [ [ push-all ] curry compose ] keep
 192             [ 1 ] 3dip [ setup-each (each-integer) ] dip
 193         ] curry dip like
 194     ] if ; inline
 195
 196 : map-filter-as ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) exemplar -- ... subseq )
 197     [ pick ] dip swap length over
 198     [ (selector-for) [ compose each ] dip ] 2curry dip like ; inline
 199
 200 : map-filter ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) -- ... subseq )
 201     pick map-filter-as ; inline
 202
 203 : map-sift ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 204     [ ] map-filter ; inline
 205
 206 : map-harvest ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 207     [ empty? not ] map-filter ; inline
 208
 209 <PRIVATE
 210
 211 : (setup-each-from) ( i seq -- n quot )
 212     [ length over [-] swap ] keep '[ _ + _ nth-unsafe ] ; inline
 213
 214 : setup-each-from ( i seq quot -- n quot' )
 215     [ (setup-each-from) ] dip compose ; inline
 216
 217 PRIVATE>
 218
 219 : map-from-as ( ... seq quot: ( ... elt -- ... newelt ) i exemplar -- ... newseq )
 220     [ -rot setup-each-from ] dip map-integers ; inline
 221
 222 : map-from ( ... seq quot: ( ... elt -- ... newelt ) i -- ... newseq )
 223     pick map-from-as ; inline
 224
 225 <PRIVATE
 226
 227 : push-map-if ( ..a elt filter-quot: ( ..a elt -- ..b ? ) map-quot: ( ..a elt -- ..b newelt ) accum -- ..b )
 228     [ keep over ] 2dip [ when ] dip rot [ push ] [ 2drop ] if ; inline
 229
 230 : (filter-mapper-for) ( filter-quot map-quot length exempler -- filter-mapper accum )
 231     new-resizable [ [ push-map-if ] 3curry ] keep ; inline
 232
 233 : filter-mapper-for ( filter-quot map-quot exemplar -- filter-mapper accum )
 234     [ length ] keep (filter-mapper-for) ; inline
 235
 236 : filter-mapper ( filter-quot map-quot -- filter-mapper accum )
 237     V{ } filter-mapper-for ; inline
 238
 239 PRIVATE>
 240
 241 : filter-map-as ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 242     [ pick ] dip swap length over
 243     [ (filter-mapper-for) [ each ] dip ] 2curry dip like ; inline
 244
 245 : filter-map ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) -- ... newseq )
 246     pick filter-map-as ; inline
 247
 248 : 2map-sum ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... n ) -- ... n )
 249     [ 0 ] 3dip [ dip + ] curry [ rot ] prepose 2each ; inline
 250
 251 : 2count ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... n )
 252     [ 1 0 ? ] compose 2map-sum ; inline
 253
 254 : round-robin ( seq -- newseq )
 255     [ { } ] [
 256         [ longest length iota ] keep
 257         [ [ ?nth ] with map ] curry map concat sift
 258     ] if-empty ;
 259
 260 : sift-as ( seq exemplar -- newseq )
 261     [ ] swap filter-as ;
 262
 263 : sift! ( seq -- newseq )
 264     [ ] filter! ;
 265
 266 : harvest-as ( seq exemplar -- newseq )
 267     [ empty? not ] swap filter-as ;
 268
 269 : harvest! ( seq -- newseq )
 270     [ empty? ] reject! ;
 271
 272 : head-as ( seq n exemplar -- seq' )
 273     [ head-slice ] [ like ] bi* ; inline
 274
 275 : head*-as ( seq n exemplar -- seq' )
 276     [ head-slice* ] [ like ] bi* ; inline
 277
 278 : tail-as ( seq n exemplar -- seq' )
 279     [ tail-slice ] [ like ] bi* ; inline
 280
 281 : tail*-as ( seq n exemplar -- seq' )
 282     [ tail-slice* ] [ like ] bi* ; inline
 283
 284 : trim-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... newseq )
 285     [ trim-slice ] [ like ] bi* ; inline
 286
 287 : ?trim ( seq quot: ( elt -- ? ) -- seq/newseq )
 288     over empty? [ drop ] [
 289         over [ first-unsafe ] [ last-unsafe ] bi pick either?
 290         [ trim ] [ drop ] if
 291     ] if ; inline
 292
 293 : ?trim-head ( seq quot: ( elt -- ? ) -- seq/newseq )
 294     over empty? [ drop ] [
 295         over first-unsafe over call
 296         [ trim-head ] [ drop ] if
 297     ] if ; inline
 298
 299 : ?trim-tail ( seq quot: ( elt -- ? ) -- seq/newseq )
 300     over empty? [ drop ] [
 301         over last-unsafe over call
 302         [ trim-tail ] [ drop ] if
 303     ] if ; inline
 304
 305 : unsurround ( newseq seq2 seq3 -- seq1 )
 306    [ ?head drop ] [ ?tail drop ] bi* ;
 307
 308 : none? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 309     any? not ; inline
 310
 311 : one? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 312     [ find ] 2keep rot [
 313         [ 1 + ] 2dip find-from drop not
 314     ] [ 3drop f ] if ; inline
 315
 316 : map-index! ( ... seq quot: ( ... elt index -- ... newelt ) -- ... seq )
 317     over [ [ (each-index) ] dip collect ] keep ; inline
 318
 319 <PRIVATE
 320
 321 : (2each-index) ( seq1 seq2 quot -- n quot' )
 322     [ setup-2each [ keep ] curry ] dip compose ; inline
 323
 324 PRIVATE>
 325
 326 : 2each-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... ) -- ... )
 327     (2each-index) each-integer ; inline
 328
 329 : 2map-into ( seq1 seq2 quot into -- )
 330     [ (2each) ] dip collect ; inline
 331
 332 : 2map! ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... seq1 )
 333     pick [ 2map-into ] keep ; inline
 334
 335 : 2map-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... newelt ) -- ... newseq )
 336     pick [ (2each-index) ] dip map-integers ; inline
 337
 338 TUPLE: evens seq length ;
 339
 340 : <evens> ( seq -- evens )
 341     dup length 1 + 2/ evens boa ; inline
 342
 343 M: evens length length>> ; inline
 344
 345 M: evens nth-unsafe [ 2 * ] [ seq>> nth-unsafe ] bi* ; inline
 346
 347 INSTANCE: evens immutable-sequence
 348
 349 TUPLE: odds seq length ;
 350
 351 : <odds> ( seq -- odds )
 352     dup length 2/ odds boa ; inline
 353
 354 M: odds length length>> ; inline
 355
 356 M: odds nth-unsafe [ 2 * 1 + ] [ seq>> nth-unsafe ] bi* ; inline
 357
 358 INSTANCE: odds immutable-sequence
 359
 360 : until-empty ( seq quot -- )
 361     [ dup empty? ] swap until drop ; inline
 362
 363 : arg-max ( seq -- n )
 364     <enum> [ second-unsafe ] supremum-by first ;
 365
 366 : arg-min ( seq -- n )
 367     <enum> [ second-unsafe ] infimum-by first ;
 368
 369 <PRIVATE
 370
 371 : push-index-if ( ..a elt i quot: ( ..a elt -- ..b ? ) accum -- ..b )
 372     [ dip ] dip rot [ push ] [ 2drop ] if ; inline
 373
 374 PRIVATE>
 375
 376 : arg-where ( ... seq quot: ( ... elt -- ... ? ) -- ... indices )
 377     over length <vector> [
 378         [ push-index-if ] 2curry each-index
 379     ] keep ; inline
 380
 381 : arg-sort ( seq -- indices )
 382     zip-index sort-keys values ;
 383
 384 : first= ( seq elt -- ? ) [ first ] dip = ; inline
 385 : second= ( seq elt -- ? ) [ second ] dip = ; inline
 386 : third= ( seq elt -- ? ) [ third ] dip = ; inline
 387 : fourth= ( seq elt -- ? ) [ fourth ] dip = ; inline
 388 : last= ( seq elt -- ? ) [ last ] dip = ; inline
 389 : nth= ( n seq elt -- ? ) [ nth ] dip = ; inline
 390
 391 : first? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ first ] dip call ; inline
 392 : second? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ second ] dip call ; inline
 393 : third? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ third ] dip call ; inline
 394 : fourth? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ fourth ] dip call ; inline
 395 : last? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ last ] dip call ; inline
 396 : nth? ( ... n seq quot: ( ... elt -- ... ? ) -- ... ? ) [ nth ] dip call ; inline
 397
 398 : loop>sequence ( quot exemplar -- seq )
 399    [ '[ [ @ [ [ , ] when* ] keep ] loop ] ] dip make ; inline
 400
 401 : loop>array ( quot -- seq )
 402    { } loop>sequence ; inline
 403
 404 <PRIVATE
 405
 406 : (reverse) ( seq -- newseq )
 407     dup [ length ] keep new-sequence
 408     [ 0 swap copy-unsafe ] keep reverse! ;
 409
 410 PRIVATE>
 411
 412 : reverse-as ( seq exemplar -- newseq )
 413     [ (reverse) ] [ like ] bi* ;
 414
 415 : map-product ( ... seq quot: ( ... elt -- ... n ) -- ... n )
 416     [ 1 ] 2dip [ dip * ] curry [ swap ] prepose each ; inline
 417
 418 : insert-nth! ( elt n seq -- )
 419     [ length ] keep ensure swap pick (a,b]
 420     over '[ [ 1 + ] keep _ move-unsafe ] each
 421     set-nth-unsafe ;
 422
 423 : set-nths ( value indices seq -- )
 424     swapd '[ _ swap _ set-nth ] each ; inline
 425
 426 : set-nths-unsafe ( value indices seq -- )
 427     swapd '[ _ swap _ set-nth-unsafe ] each ; inline
 428
 429 : flatten1 ( obj -- seq )
 430     [
 431         [
 432             dup branch? [
 433                 [ dup branch? [ % ] [ , ] if ] each
 434             ] [ , ] if
 435         ]
 436     ] keep dup branch? [ drop f ] unless make ;
 437
 438 <PRIVATE
 439
 440 : (map-find-index) ( seq quot find-quot -- result i elt )
 441     [ [ f ] 2dip [ [ nip ] 2dip call dup ] curry ] dip call
 442     [ [ [ drop f ] unless ] keep ] dip ; inline
 443
 444 PRIVATE>
 445
 446 : map-find-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 447     [ find-index ] (map-find-index) ; inline
 448
 449 : filter-length ( seq n -- seq' ) '[ length _ = ] filter ;
 450
 451 : all-shortest ( seqs -- seqs' ) dup shortest length filter-length ;
 452
 453 : all-longest ( seqs -- seqs' ) dup longest length filter-length ;
 454
 455 : remove-first ( obj seq -- seq' )
 456     [ index ] keep over [ remove-nth ] [ nip ] if ;
 457
 458 : remove-first! ( obj seq -- seq )
 459     [ index ] keep over [ remove-nth! ] [ nip ] if ;
 460
 461 : remove-last ( obj seq -- seq' )
 462     [ last-index ] keep over [ remove-nth ] [ nip ] if ;
 463
 464 : remove-last! ( obj seq -- seq )
 465     [ last-index ] keep over [ remove-nth! ] [ nip ] if ;
 466
 467 : ?first2 ( seq -- first/f second/f )
 468     dup length {
 469         { 0 [ drop f f ] }
 470         { 1 [ first-unsafe f ] }
 471         [ drop first2-unsafe ]
 472     } case ;
 473
 474 : ?first3 ( seq -- first/f second/f third/f )
 475     dup length {
 476         { 0 [ drop f f f ] }
 477         { 1 [ first-unsafe f f ] }
 478         { 2 [ first2-unsafe f ] }
 479         [ drop first3-unsafe ]
 480     } case ;
 481
 482 : ?first4 ( seq -- first/f second/f third/f fourth/f )
 483     dup length {
 484         { 0 [ drop f f f f ] }
 485         { 1 [ first-unsafe f f f ] }
 486         { 2 [ first2-unsafe f f ] }
 487         { 3 [ first3-unsafe f ] }
 488         [ drop first4-unsafe ]
 489     } case ;
 490
 491 : cut-when ( ... seq quot: ( ... elt -- ... ? ) -- ... before after )
 492     [ find drop ] 2keep drop swap
 493     [ cut ] [ f over like ] if* ; inline
 494
 495 : nth* ( n seq -- elt )
 496     [ length 1 - swap - ] [ nth ] bi ; inline
 497
 498 : each-index-from ( ... seq quot: ( ... elt index -- ... ) i -- ... )
 499     -rot (each-index) (each-integer) ; inline
 500
 501 <PRIVATE
 502
 503 : select-by* ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... i elt )
 504     [
 505         [ keep swap ] curry [ dip ] curry
 506         [ [ first 0 ] dip call ] 2keep
 507         [ 2curry 3dip 5 npick pick ] curry
 508     ] [
 509         [ [ 3drop ] [ [ 3drop ] 3dip ] if ] compose
 510     ] bi* compose 1 each-index-from nip swap ; inline
 511
 512 PRIVATE>
 513
 514 : supremum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 515     [ after? ] select-by* ; inline
 516
 517 : infimum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 518     [ before? ] select-by* ; inline
 519
 520 : change-last ( seq quot -- )
 521     [ drop length 1 - ] [ change-nth ] 2bi ; inline
 522
 523 : change-last-unsafe ( seq quot -- )
 524     [ drop length 1 - ] [ change-nth-unsafe ] 2bi ; inline
 525
 526 : replicate-into ( ... seq quot: ( ... -- ... newelt ) -- ... )
 527     over [ length ] 2dip '[ _ dip _ set-nth-unsafe ] each-integer ; inline
 528
 529 : count* ( ... seq quot: ( ... elt -- ... ? ) -- ... % )
 530     over [ count ] [ length ] bi* / ; inline
 531
 532 : find-last-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 533     [ [ 1 - ] dip find-last-integer ] (find-index) ; inline
 534
 535 : map-find-last-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 536     [ find-last-index ] (map-find-index) ; inline
 537
 538 :: (start-all) ( subseq seq increment -- indices )
 539     0
 540     [ [ subseq seq ] dip start* dup ]
 541     [ [ increment + ] keep ] produce nip ;
 542
 543 : start-all ( subseq seq -- indices )
 544     over length (start-all) ; inline
 545
 546 : start-all* ( subseq seq -- indices )
 547     1 (start-all) ; inline
 548
 549 : count-subseq ( subseq seq -- n )
 550     start-all length ; inline
 551
 552 : count-subseq* ( subseq seq -- n )
 553     start-all* length ; inline