extra/sequences/extras/extras.factor

   1 USING: accessors arrays assocs combinators generalizations
   2 grouping growable heaps kernel math math.order ranges sequences
   3 sequences.private shuffle sorting splitting vectors ;
   4 IN: sequences.extras
   5
   6 : find-all ( ... seq quot: ( ... elt -- ... ? ) -- ... elts )
   7     [ <enumerated> ] dip '[ nip @ ] assoc-filter ; inline
   8
   9 : reduce-from ( ... seq identity quot: ( ... prev elt -- ... next ) i -- ... result )
  10     [ swap ] 2dip each-from ; inline
  11
  12 :: subseq* ( from to seq -- subseq )
  13     seq length :> len
  14     from [ dup 0 < [ len + ] when ] [ 0 ] if*
  15     to [ dup 0 < [ len + ] when ] [ len ] if* [ 0 len clamp ] bi@ dupd max seq subseq ;
  16
  17 : safe-subseq ( from to seq -- subseq )
  18     [ length '[ 0 _ clamp ] bi@ ] keep subseq ;
  19
  20 : all-subseqs ( seq -- seqs )
  21     dup length [1..b] [ clump ] with map concat ;
  22
  23 :: each-subseq ( ... seq quot: ( ... subseq -- ... ) -- ... )
  24     seq length :> len
  25     len [0..b] [| from |
  26         from len (a..b] [| to |
  27             from to seq subseq quot call
  28         ] each
  29     ] each ; inline
  30
  31 : map-like ( seq exemplar -- seq' )
  32     '[ _ like ] map ; inline
  33
  34 : filter-all-subseqs-range ( ... seq range quot: ( ... subseq -- ... ? ) -- seq )
  35     [
  36         '[ <clumps> _ filter ] with map concat
  37     ] keepdd map-like ; inline
  38
  39 : filter-all-subseqs ( ... seq quot: ( ... subseq -- ... ? ) -- seq )
  40     [ dup length [1..b] ] dip filter-all-subseqs-range ; inline
  41
  42 :: longest-subseq ( seq1 seq2 -- subseq )
  43     seq1 length :> len1
  44     seq2 length :> len2
  45     0 :> n!
  46     0 :> end!
  47     len1 1 + [ len2 1 + 0 <array> ] replicate :> table
  48     len1 [1..b] [| x |
  49         len2 [1..b] [| y |
  50             x 1 - seq1 nth-unsafe
  51             y 1 - seq2 nth-unsafe = [
  52                 y 1 - x 1 - table nth-unsafe nth-unsafe 1 + :> len
  53                 len y x table nth-unsafe set-nth-unsafe
  54                 len n > [ len n! x end! ] when
  55             ] [ 0 y x table nth-unsafe set-nth-unsafe ] if
  56         ] each
  57     ] each end n - end seq1 subseq ;
  58
  59 : pad-longest ( seq1 seq2 elt -- seq1 seq2 )
  60     [ 2dup max-length ] dip [ pad-tail ] 2curry bi@ ;
  61
  62 : pad-center ( seq n elt -- padded )
  63     swap pick length [-] [ drop ] [
  64         [ 2/ ] [ over - ] bi rot '[ _ <repetition> ] bi@
  65         pick surround-as
  66     ] if-zero ;
  67
  68 : change-nths ( ... indices seq quot: ( ... elt -- ... elt' ) -- ... )
  69     [ change-nth ] 2curry each ; inline
  70
  71 : push-if-index ( ..a elt i quot: ( ..a elt i -- ..b ? ) accum -- ..b )
  72     [ keepd ] dip rot [ push ] [ 2drop ] if ; inline
  73
  74 : push-if* ( ..a elt quot: ( ..a elt -- ..b obj/f ) accum -- ..b )
  75     [ call ] dip [ push ] [ drop ] if* ; inline
  76
  77 <PRIVATE
  78
  79 : (index-selector-as) ( quot length exampler -- selector accum )
  80     new-resizable [ [ push-if-index ] 2curry ] keep ; inline
  81
  82 : (selector-as*) ( quot length exemplar -- selector accum )
  83     new-resizable [ [ push-if* ] 2curry ] keep ; inline
  84
  85 PRIVATE>
  86
  87 : index-selector-as ( quot exemplar -- selector accum )
  88     [ length ] keep (index-selector-as) ; inline
  89
  90 : index-selector ( quot -- selector accum )
  91     V{ } index-selector-as ; inline
  92
  93 : selector-as* ( quot exemplar -- selector accum )
  94     [ length ] keep (selector-as*) ; inline
  95
  96 : selector* ( quot -- selector accum ) V{ } selector-as* ; inline
  97
  98 : filter-index-as ( ... seq quot: ( ... elt i -- ... ? ) exemplar -- ... seq' )
  99     pick length over [ (index-selector-as) [ each-index ] dip ] 2curry dip like ; inline
 100
 101 : filter-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... seq' )
 102     over filter-index-as ; inline
 103
 104 : even-indices ( seq -- seq' )
 105     [ length 1 + 2/ ] keep [
 106         [ [ 2 * ] dip nth-unsafe ] curry
 107     ] keep map-integers ;
 108
 109 : odd-indices ( seq -- seq' )
 110     [ length 2/ ] keep [
 111         [ [ 2 * 1 + ] dip nth-unsafe ] curry
 112     ] keep map-integers ;
 113
 114 : compact ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 115     [ split-when harvest ] dip join ; inline
 116
 117 : collapse ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 118     [ split-when ] dip
 119     [ [ harvest ] dip join ]
 120     [ [ first empty? ] dip [ prepend ] curry when ]
 121     [ [ last empty? ] dip [ append ] curry when ]
 122     2tri ; inline
 123
 124 :: slice-when ( seq quot: ( elt -- ? ) -- seq' )
 125     seq length :> len
 126     0 [ len dupd < ] [
 127         dup seq quot find-from drop
 128         [ 2dup = [ 1 + ] when ] [ len ] if*
 129         [ seq <slice> ] keep len or swap
 130     ] produce nip ; inline
 131
 132 : ?<slice> ( from/f to/f sequence -- slice )
 133     [ [ 0 ] unless* ] 2dip
 134     over [ nip [ length ] [ ] bi ] unless
 135     <slice> ; inline
 136
 137 : sequence>slice ( sequence -- slice )
 138     [ drop 0 ] [ length ] [ ] tri <slice> ; inline
 139
 140 : slice-order-by-from ( slice1 slice2 -- slice-lt slice-gt )
 141     2dup [ from>> ] bi@ > [ swap ] when ; inline
 142
 143 : ordered-slices-range ( slice-lt slice-gt -- to from )
 144     [ to>> ] [ from>> ] bi* ;
 145
 146 : unordered-slices-range ( slice1 slice2 -- to from )
 147     slice-order-by-from ordered-slices-range ;
 148
 149 : ordered-slices-overlap? ( slice-lt slice-gt -- ? )
 150     ordered-slices-range > ; inline
 151
 152 : unordered-slices-overlap? ( slice1 slice2 -- ? )
 153     unordered-slices-range > ; inline
 154
 155 : slices-overlap? ( slice1 slice2 -- ? )
 156     unordered-slices-overlap? ;
 157
 158 : ordered-slices-touch? ( slice-lt slice-gt -- ? )
 159     ordered-slices-range >= ; inline
 160
 161 : unordered-slices-touch? ( slice1 slice2 -- ? )
 162     unordered-slices-range >= ; inline
 163
 164 : slices-touch? ( slice1 slice2 -- ? )
 165     unordered-slices-touch? ;
 166
 167 ERROR: slices-don't-touch slice1 slice2 ;
 168
 169 : merge-slices ( slice1 slice2 -- slice/* )
 170     slice-order-by-from
 171     2dup ordered-slices-touch? [
 172         [ from>> ] [ [ to>> ] [ seq>> ] bi ] bi* <slice>
 173     ] [
 174         slices-don't-touch
 175     ] if ;
 176
 177 : rotate ( seq n -- seq' )
 178     over length mod dup 0 >= [ cut ] [ abs cut* ] if prepend ;
 179
 180 ERROR: underlying-mismatch slice1 slice2 ;
 181
 182 : ensure-same-underlying ( slice1 slice2 -- slice1 slice2 )
 183     2dup [ seq>> ] bi@ eq? [ underlying-mismatch ] unless ;
 184
 185 : span-slices ( slice1 slice2 -- slice )
 186     ensure-same-underlying
 187     [ [ from>> ] bi@ min ]
 188     [ [ to>> ] bi@ max ]
 189     [ drop seq>> ] 2tri <slice> ;
 190
 191 : ?span-slices ( slice1/f slice2/f -- slice )
 192     2dup and [ span-slices ] [ or ] if ;
 193
 194 :: rotate! ( seq n -- )
 195     seq length :> len
 196     n len mod dup 0 < [ len + ] when seq bounds-check drop 0 over
 197     [ 2dup = ] [
 198         [ seq exchange-unsafe ] [ [ 1 + ] bi@ ] 2bi
 199         dup len = [ drop over ] when
 200         2over = [ -rot nip over ] when
 201     ] until 3drop ;
 202
 203 : all-rotations ( seq -- seq' )
 204     dup length <iota> [ rotate ] with map ;
 205
 206 <PRIVATE
 207
 208 : (appender-for) ( quot length exemplar -- appender accum )
 209     new-resizable [ [ push-all ] curry compose ] keep ; inline
 210
 211 PRIVATE>
 212
 213 : appender-for ( quot exemplar -- appender accum )
 214     [ length ] keep (appender-for) ; inline
 215
 216 : appender ( quot -- appender accum )
 217     V{ } appender-for ; inline
 218
 219 : map-concat-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 220     [ appender-for [ each ] dip ] keep like ; inline
 221
 222 : >resizable ( seq -- accum ) ! fixes map-concat "cannot apply call to run-time..."
 223     [ length ] keep [ new-resizable ] [ append! ] bi ;
 224
 225 : map-concat ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 226     over empty? [ 2drop { } ] [
 227         [ [ first ] dip call ] 2keep rot [
 228             >resizable [ '[ @ _ push-all ] 1 each-from ] keep
 229         ] keep like
 230     ] if ; inline
 231
 232 : map-filter-as ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) exemplar -- ... subseq )
 233     reach length over
 234     [ (selector-as) [ compose each ] dip ] 2curry dip like ; inline
 235
 236 : map-filter ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) -- ... subseq )
 237     pick map-filter-as ; inline
 238
 239 : map-sift ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 240     [ ] map-filter ; inline
 241
 242 : map-harvest ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 243     [ empty? not ] map-filter ; inline
 244
 245 : (each-integer-with-previous) ( ... prev i n quot: ( ... i -- ... ) -- ... )
 246     2over < [
 247         [ nip call ] 4keep nipdd
 248         [ 1 + ] 2dip (each-integer-with-previous)
 249     ] [
 250         4drop
 251     ] if ; inline recursive
 252
 253 : each-integer-with-previous ( ... n quot: ( ... i -- ... ) -- ... )
 254     [ f 0 ] 2dip (each-integer-with-previous) ; inline
 255
 256 : (collect-with-previous) ( quot into -- quot' )
 257     [ [ keep ] dip [ set-nth-unsafe ] keepdd ] 2curry ; inline
 258
 259 : collect-with-previous ( n quot into --  )
 260     (collect-with-previous) each-integer-with-previous ; inline
 261
 262 : map-integers-with ( ... len quot: ( ... prev i -- ... elt ) exemplar -- ... newseq )
 263     overd [ [ collect-with-previous ] keep ] new-like ; inline
 264
 265 : map-with-previous-as ( ... seq quot: ( ... elt prev/f -- ... newelt ) exemplar -- ... newseq )
 266     [ (1each) ] dip map-integers-with ; inline
 267
 268 : map-with-previous ( ... seq quot: ( ... elt prev/f -- ... newelt ) -- ... newseq )
 269     over map-with-previous-as ; inline
 270
 271 <PRIVATE
 272
 273 : (setup-each-from) ( i seq -- n quot )
 274     [ length over [-] swap ] keep '[ _ + _ nth-unsafe ] ; inline
 275
 276 : setup-each-from ( i seq quot -- n quot' )
 277     [ (setup-each-from) ] dip compose ; inline
 278
 279 PRIVATE>
 280
 281 : map-from-as ( ... seq quot: ( ... elt -- ... newelt ) i exemplar -- ... newseq )
 282     [ -rot setup-each-from ] dip map-integers ; inline
 283
 284 : map-from ( ... seq quot: ( ... elt -- ... newelt ) i -- ... newseq )
 285     pick map-from-as ; inline
 286
 287 <PRIVATE
 288
 289 : push-map-if ( ..a elt filter-quot: ( ..a elt -- ..b ? ) map-quot: ( ..a elt -- ..b newelt ) accum -- ..b )
 290     [ keep over ] 2dip [ when ] dip rot [ push ] [ 2drop ] if ; inline
 291
 292 : (filter-mapper-for) ( filter-quot map-quot length exempler -- filter-mapper accum )
 293     new-resizable [ [ push-map-if ] 3curry ] keep ; inline
 294
 295 : filter-mapper-for ( filter-quot map-quot exemplar -- filter-mapper accum )
 296     [ length ] keep (filter-mapper-for) ; inline
 297
 298 : filter-mapper ( filter-quot map-quot -- filter-mapper accum )
 299     V{ } filter-mapper-for ; inline
 300
 301 PRIVATE>
 302
 303 : filter-map-as ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 304     reach length over
 305     [ (filter-mapper-for) [ each ] dip ] 2curry dip like ; inline
 306
 307 : filter-map ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) -- ... newseq )
 308     pick filter-map-as ; inline
 309
 310 : 2map-sum ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... n ) -- ... n )
 311     [ 0 ] 3dip [ dip + ] curry [ rot ] prepose 2each ; inline
 312
 313 : 2count ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... n )
 314     [ 1 0 ? ] compose 2map-sum ; inline
 315
 316 : 3each-from
 317     ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... ) i -- ... )
 318     [ (3each) ] dip -rot (each-integer) ; inline
 319
 320 : 3map-reduce
 321     ( ..a seq1 seq2 seq3 map-quot: ( ..a elt1 elt2 elt3 -- ..b intermediate ) reduce-quot: ( ..b prev intermediate -- ..a next ) -- ..a result )
 322     [ [ [ [ first ] tri@ ] 3keep ] dip [ 3dip ] keep ] dip compose 1 3each-from ; inline
 323
 324 : round-robin ( seq -- newseq )
 325     [ { } ] [
 326         [ longest length <iota> ] keep
 327         [ [ ?nth ] with map ] curry map concat sift
 328     ] if-empty ;
 329
 330 : sift-as ( seq exemplar -- newseq )
 331     [ ] swap filter-as ;
 332
 333 : sift! ( seq -- newseq )
 334     [ ] filter! ;
 335
 336 : harvest-as ( seq exemplar -- newseq )
 337     [ empty? not ] swap filter-as ;
 338
 339 : harvest! ( seq -- newseq )
 340     [ empty? ] reject! ;
 341
 342 : head-as ( seq n exemplar -- seq' )
 343     [ head-slice ] [ like ] bi* ; inline
 344
 345 : head*-as ( seq n exemplar -- seq' )
 346     [ head-slice* ] [ like ] bi* ; inline
 347
 348 : tail-as ( seq n exemplar -- seq' )
 349     [ tail-slice ] [ like ] bi* ; inline
 350
 351 : tail*-as ( seq n exemplar -- seq' )
 352     [ tail-slice* ] [ like ] bi* ; inline
 353
 354 : trim-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... newseq )
 355     [ trim-slice ] [ like ] bi* ; inline
 356
 357 : ?trim ( seq quot: ( elt -- ? ) -- seq/newseq )
 358     over empty? [ drop ] [
 359         over [ first-unsafe ] [ last-unsafe ] bi pick either?
 360         [ trim ] [ drop ] if
 361     ] if ; inline
 362
 363 : ?trim-head ( seq quot: ( elt -- ? ) -- seq/newseq )
 364     over empty? [ drop ] [
 365         over first-unsafe over call
 366         [ trim-head ] [ drop ] if
 367     ] if ; inline
 368
 369 : ?trim-tail ( seq quot: ( elt -- ? ) -- seq/newseq )
 370     over empty? [ drop ] [
 371         over last-unsafe over call
 372         [ trim-tail ] [ drop ] if
 373     ] if ; inline
 374
 375 : unsurround ( newseq seq2 seq3 -- seq1 )
 376    [ ?head drop ] [ ?tail drop ] bi* ;
 377
 378 : >string-list ( seq -- seq' )
 379     [ "\"" 1surround ] map "," join ;
 380
 381 : one? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 382     [ find ] 2keep rot [
 383         [ 1 + ] 2dip find-from drop not
 384     ] [ 3drop f ] if ; inline
 385
 386 : map-index! ( ... seq quot: ( ... elt index -- ... newelt ) -- ... seq )
 387     over [ [ (each-index) ] dip collect ] keep ; inline
 388
 389 <PRIVATE
 390
 391 : (2each-index) ( seq1 seq2 quot -- n quot' )
 392     [ setup-2each [ keep ] curry ] dip compose ; inline
 393
 394 PRIVATE>
 395
 396 : 2each-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... ) -- ... )
 397     (2each-index) each-integer ; inline
 398
 399 : 2map-into ( seq1 seq2 quot into -- )
 400     [ (2each) ] dip collect ; inline
 401
 402 : 2map! ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... seq1 )
 403     pick [ 2map-into ] keep ; inline
 404
 405 : 2map-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... newelt ) -- ... newseq )
 406     pick [ (2each-index) ] dip map-integers ; inline
 407
 408 TUPLE: evens { seq read-only } ;
 409
 410 C: <evens> evens
 411
 412 M: evens length seq>> length 1 + 2/ ; inline
 413
 414 M: evens virtual@ [ 2 * ] [ seq>> ] bi* ; inline
 415
 416 M: evens virtual-exemplar seq>> ; inline
 417
 418 INSTANCE: evens virtual-sequence
 419
 420 TUPLE: odds { seq read-only } ;
 421
 422 C: <odds> odds
 423
 424 M: odds length seq>> length 2/ ; inline
 425
 426 M: odds virtual@ [ 2 * 1 + ] [ seq>> ] bi* ; inline
 427
 428 M: odds virtual-exemplar seq>> ; inline
 429
 430 INSTANCE: odds virtual-sequence
 431
 432 : until-empty ( seq quot -- )
 433     [ dup empty? ] swap until drop ; inline
 434
 435 : arg-max ( seq -- n )
 436     [ supremum ] keep index ;
 437
 438 : arg-min ( seq -- n )
 439     [ infimum ] keep index ;
 440
 441 <PRIVATE
 442
 443 : push-index-if ( ..a elt i quot: ( ..a elt -- ..b ? ) accum -- ..b )
 444     [ dip ] dip rot [ push ] [ 2drop ] if ; inline
 445
 446 PRIVATE>
 447
 448 : arg-where ( ... seq quot: ( ... elt -- ... ? ) -- ... indices )
 449     over length <vector> [
 450         [ push-index-if ] 2curry each-index
 451     ] keep ; inline
 452
 453 : arg-sort ( seq -- indices )
 454     zip-index sort-keys values ;
 455
 456 : first= ( seq elt -- ? ) [ first ] dip = ; inline
 457 : second= ( seq elt -- ? ) [ second ] dip = ; inline
 458 : third= ( seq elt -- ? ) [ third ] dip = ; inline
 459 : fourth= ( seq elt -- ? ) [ fourth ] dip = ; inline
 460 : last= ( seq elt -- ? ) [ last ] dip = ; inline
 461 : nth= ( n seq elt -- ? ) [ nth ] dip = ; inline
 462
 463 : first? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ first ] dip call ; inline
 464 : second? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ second ] dip call ; inline
 465 : third? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ third ] dip call ; inline
 466 : fourth? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ fourth ] dip call ; inline
 467 : last? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ last ] dip call ; inline
 468 : nth? ( ... n seq quot: ( ... elt -- ... ? ) -- ... ? ) [ nth ] dip call ; inline
 469
 470 : loop>sequence** ( ... quot: ( ... -- ... obj ? ) exemplar -- ... seq )
 471     [ ] swap produce-as nip ; inline
 472
 473 : loop>array** ( ... quot: ( ... -- ... obj ? ) -- ... array )
 474     { } loop>sequence** ; inline
 475
 476 : loop>sequence* ( ... quot: ( ... -- ... obj ? ) exemplar -- ... seq )
 477     [ t ] [ '[ [ _ dip ] [ f f f ] if* ] [ swap ] ] [ produce-as 2nip ] tri* ; inline
 478
 479 : loop>array* ( ... quot: ( ... -- ... obj ? ) -- ... array )
 480     { } loop>sequence* ; inline
 481
 482 : loop>sequence ( ... quot: ( ... -- ... obj/f ) exemplar -- ... seq )
 483     [ [ dup ] compose [ ] ] dip produce-as nip ; inline
 484
 485 : loop>array ( ... quot: ( ... -- ... obj/f ) -- ... array )
 486    { } loop>sequence ; inline
 487
 488 : zero-loop>sequence ( ... quot: ( ... n -- ... obj/f ) exemplar -- ... seq )
 489     [ 0 ] [ '[ _ keep 1 + swap ] ] [ loop>sequence ] tri* nip ; inline
 490
 491 : zero-loop>array ( quot: ( ..a n -- ..a obj ) -- seq )
 492     { } zero-loop>sequence ; inline
 493
 494 : iterate-heap-while ( heap quot1: ( value key -- slurp? ) quot2: ( value key -- obj/f ) -- obj/f loop? )
 495     pick heap-empty?
 496     [ 3drop f f ]
 497     [
 498         [ [ heap-peek ] 2dip drop 2keep ]
 499         [
 500             nip ! ( pop? value key heap quot2 )
 501             5roll [
 502                 swap heap-pop* call( value key -- obj/f ) t
 503             ] [
 504                 4drop f f
 505             ] if
 506         ] 3bi
 507     ] if ; inline
 508
 509 : slurp-heap-while-map ( heap quot1: ( value key -- slurp? ) quot2: ( value key -- obj/f ) -- seq )
 510     '[ _ _ _ iterate-heap-while ] loop>array* ; inline
 511
 512 : heap>pairs ( heap -- pairs )
 513     [ 2drop t ] [ swap 2array ] slurp-heap-while-map ;
 514
 515 : map-zip-swap ( quot: ( x -- y ) -- alist )
 516     '[ _ keep ] map>alist ; inline
 517
 518 : ?heap-pop-value>array ( heap -- array )
 519     dup heap-empty? [ drop { } ] [ heap-pop drop 1array ] if ;
 520
 521 <PRIVATE
 522
 523 : (reverse) ( seq -- newseq )
 524     dup [ length ] keep new-sequence
 525     [ 0 swap copy-unsafe ] keep reverse! ;
 526
 527 PRIVATE>
 528
 529 : reverse-as ( seq exemplar -- newseq )
 530     [ (reverse) ] [ like ] bi* ;
 531
 532 : map-product ( ... seq quot: ( ... elt -- ... n ) -- ... n )
 533     [ 1 ] 2dip [ dip * ] curry [ swap ] prepose each ; inline
 534
 535 : insert-nth! ( elt n seq -- )
 536     [ length ] keep ensure swap pick (a..b]
 537     over '[ [ 1 + ] keep _ move-unsafe ] each
 538     set-nth-unsafe ;
 539
 540 : set-nths ( value indices seq -- )
 541     swapd '[ _ swap _ set-nth ] each ; inline
 542
 543 : set-nths-unsafe ( value indices seq -- )
 544     swapd '[ _ swap _ set-nth-unsafe ] each ; inline
 545
 546 <PRIVATE
 547
 548 : (map-find-index) ( seq quot find-quot -- result i elt )
 549     [ [ f ] 2dip [ [ nip ] 2dip call dup ] curry ] dip call
 550     [ [ [ drop f ] unless ] keep ] dip ; inline
 551
 552 PRIVATE>
 553
 554 : map-find-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 555     [ find-index ] (map-find-index) ; inline
 556
 557 : filter-length ( seq n -- seq' ) '[ length _ = ] filter ;
 558
 559 : all-shortest ( seqs -- seqs' ) dup shortest length filter-length ;
 560
 561 : all-longest ( seqs -- seqs' ) dup longest length filter-length ;
 562
 563 : remove-first ( obj seq -- seq' )
 564     [ index ] keep over [ remove-nth ] [ nip ] if ;
 565
 566 : remove-first! ( obj seq -- seq )
 567     [ index ] keep over [ remove-nth! ] [ nip ] if ;
 568
 569 : remove-last ( obj seq -- seq' )
 570     [ last-index ] keep over [ remove-nth ] [ nip ] if ;
 571
 572 : remove-last! ( obj seq -- seq )
 573     [ last-index ] keep over [ remove-nth! ] [ nip ] if ;
 574
 575 : ?first2 ( seq -- first/f second/f )
 576     dup length {
 577         { 0 [ drop f f ] }
 578         { 1 [ first-unsafe f ] }
 579         [ drop first2-unsafe ]
 580     } case ;
 581
 582 : ?first3 ( seq -- first/f second/f third/f )
 583     dup length {
 584         { 0 [ drop f f f ] }
 585         { 1 [ first-unsafe f f ] }
 586         { 2 [ first2-unsafe f ] }
 587         [ drop first3-unsafe ]
 588     } case ;
 589
 590 : ?first4 ( seq -- first/f second/f third/f fourth/f )
 591     dup length {
 592         { 0 [ drop f f f f ] }
 593         { 1 [ first-unsafe f f f ] }
 594         { 2 [ first2-unsafe f f ] }
 595         { 3 [ first3-unsafe f ] }
 596         [ drop first4-unsafe ]
 597     } case ;
 598
 599 : cut-when ( ... seq quot: ( ... elt -- ... ? ) -- ... before after )
 600     [ find drop ] keepd swap
 601     [ cut ] [ f over like ] if* ; inline
 602
 603 : nth* ( n seq -- elt )
 604     [ length 1 - swap - ] [ nth ] bi ; inline
 605
 606 : each-index-from ( ... seq quot: ( ... elt index -- ... ) i -- ... )
 607     -rot (each-index) (each-integer) ; inline
 608
 609 <PRIVATE
 610
 611 : select-by* ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... i elt )
 612     [
 613         [ keep swap ] curry [ dip ] curry
 614         [ [ first 0 ] dip call ] 2keep
 615         [ 2curry 3dip 5 npick pick ] curry
 616     ] [
 617         [ [ 3drop ] [ [ 3drop ] 3dip ] if ] compose
 618     ] bi* compose 1 each-index-from nip swap ; inline
 619
 620 PRIVATE>
 621
 622 : supremum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 623     [ after? ] select-by* ; inline
 624
 625 : infimum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 626     [ before? ] select-by* ; inline
 627
 628 : ?supremum ( seq/f -- elt/f )
 629     [ f ] [
 630         [ ] [ 2dup and [ max ] [ dupd ? ] if ] map-reduce
 631     ] if-empty ;
 632
 633 : ?infimum ( seq/f -- elt/f )
 634     [ f ] [
 635         [ ] [ 2dup and [ min ] [ dupd ? ] if ] map-reduce
 636     ] if-empty ;
 637
 638 : change-last ( seq quot -- )
 639     [ drop length 1 - ] [ change-nth ] 2bi ; inline
 640
 641 : change-last-unsafe ( seq quot -- )
 642     [ drop length 1 - ] [ change-nth-unsafe ] 2bi ; inline
 643
 644 : replicate-into ( ... seq quot: ( ... -- ... newelt ) -- ... )
 645     over [ length ] 2dip '[ _ dip _ set-nth-unsafe ] each-integer ; inline
 646
 647 : count* ( ... seq quot: ( ... elt -- ... ? ) -- ... % )
 648     over [ count ] [ length ] bi* / ; inline
 649
 650 : find-last-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 651     [ [ 1 - ] dip find-last-integer ] (find-index) ; inline
 652
 653 : map-find-last-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 654     [ find-last-index ] (map-find-index) ; inline
 655
 656 :: (start-all) ( seq subseq increment -- indices )
 657     0
 658     [ [ subseq seq ] dip subseq-start-from dup ]
 659     [ [ increment + ] keep ] produce nip ;
 660
 661 : start-all ( seq subseq -- indices )
 662     dup length (start-all) ; inline
 663
 664 : start-all* ( seq subseq -- indices )
 665     1 (start-all) ; inline
 666
 667 : count-subseq ( seq subseq -- n )
 668     start-all length ; inline
 669
 670 : count-subseq* ( seq subseq -- n )
 671     start-all* length ; inline
 672
 673 : assoc-zip-with ( quot: ( key value -- calc ) -- alist )
 674     '[ _ 2keep 2array swap ] assoc-map ; inline
 675
 676 : take-while ( ... seq quot: ( ... elt -- ... ? ) -- head-slice )
 677     [ '[ @ not ] find drop ] keepd swap
 678     [ dup length ] unless* head-slice ; inline
 679
 680 : drop-while ( ... seq quot: ( ... elt -- ... ? ) -- tail-slice )
 681     [ '[ @ not ] find drop ] keepd swap
 682     [ dup length ] unless* tail-slice ; inline
 683
 684 : count-head ( seq quot -- n )
 685     [ not ] compose [ find drop ] keepd length or ; inline
 686
 687 : count-tail ( seq quot -- n )
 688     [ not ] compose [ find-last drop ] keepd
 689     length swap [ - 1 - ] when* ; inline
 690
 691 :: shorten* ( vector n -- seq )
 692     vector n tail
 693     n vector shorten ;
 694
 695 :: interleaved-as ( seq glue exemplar -- newseq )
 696     seq length dup 1 - + 0 max exemplar new-sequence :> newseq
 697     seq [ 2 * newseq set-nth-unsafe ] each-index
 698     seq length 1 - [ 2 * 1 + glue swap newseq set-nth-unsafe ] each-integer
 699     newseq ;
 700
 701 : interleaved ( seq glue -- newseq )
 702     over interleaved-as ;
 703
 704 : extract! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 705     [ dup ] compose over [ length ] keep new-resizable
 706     [ [ push-if ] 2curry reject! ] keep swap like ; inline
 707
 708 : find-pred-loop ( ... i n seq quot: ( ... elt -- ... calc ? ) -- ... calc/f i/f elt/f )
 709     2pick < [
 710         [ nipd call ] 4keep
 711         3 7 nrotates
 712         [ [ 3drop ] 2dip rot ]
 713         [ 2drop [ 1 + ] 3dip find-pred-loop ] if
 714     ] [
 715         4drop f f f
 716     ] if ; inline recursive
 717
 718 : find-pred ( ... seq quot: ( ... elt -- ... calc ) pred: ( ... calc -- ... ? ) -- ... calc/f i/f elt/f )
 719     [ 0 ] 3dip
 720     [ [ length check-length ] keep ] 2dip
 721     '[ nth-unsafe _ keep swap _ keep swap ] find-pred-loop swapd ; inline
 722
 723 ! https://en.wikipedia.org/wiki/Maximum_subarray_problem
 724 ! Kadane's algorithm O(n) largest sum in subarray
 725 : max-subarray-sum ( seq -- sum )
 726     [ -1/0. 0 ] dip
 727     [ [ + ] keep max [ max ] keep ] each drop ;
 728
 729 TUPLE: step-slice
 730     { from integer read-only initial: 0 }
 731     { to integer read-only initial: 0 }
 732     { seq read-only }
 733     { step integer read-only } ;
 734
 735 :: <step-slice> ( from to step seq -- step-slice )
 736     step zero? [ "can't be zero" throw ] when
 737     seq length :> len
 738     step 0 > [
 739         from [ 0 ] unless*
 740         to [ len ] unless*
 741     ] [
 742         from [ len ] unless*
 743         to [ 0 ] unless*
 744     ] if
 745     [ dup 0 < [ len + ] when 0 len clamp ] bi@
 746     ! FIXME: make this work with steps
 747     seq dup slice? [ collapse-slice ] when
 748     step step-slice boa ;
 749
 750 M: step-slice virtual-exemplar seq>> ; inline
 751
 752 M: step-slice virtual@
 753     [ step>> * ] [ from>> + ] [ seq>> ] tri ; inline
 754
 755 M: step-slice length
 756     [ to>> ] [ from>> - ] [ step>> ] tri
 757     dup 0 < [ [ neg 0 max ] dip neg ] when /mod
 758     zero? [ 1 + ] unless ; inline
 759
 760 INSTANCE: step-slice virtual-sequence