extra/sequences/extras/extras.factor

   1 USING: accessors arrays assocs combinators fry generalizations
   2 grouping growable kernel locals make math math.order math.ranges
   3 sequences sequences.deep sequences.private sorting splitting
   4 vectors ;
   5 IN: sequences.extras
   6
   7 : reduce1 ( seq quot -- result ) [ unclip ] dip reduce ; inline
   8
   9 :: reduce-r ( seq identity quot: ( obj1 obj2 -- obj ) -- result )
  10     seq [ identity ] [
  11         unclip [ identity quot reduce-r ] [ quot call ] bi*
  12     ] if-empty ; inline recursive
  13
  14 ! Quot must have static stack effect, unlike "reduce"
  15 :: reduce* ( seq identity quot: ( prev elt -- next ) -- result )
  16     seq [ identity ] [
  17         unclip identity swap quot call( prev elt -- next )
  18         quot reduce*
  19     ] if-empty ; inline recursive
  20
  21 :: combos ( list1 list2 -- result )
  22     list2 [ [ 2array ] curry list1 swap map ] map concat ;
  23
  24 : find-all ( seq quot: ( elt -- ? ) -- elts )
  25     [ [ length iota ] keep ] dip
  26     [ dupd call( a -- ? ) [ 2array ] [ 2drop f ] if ] curry
  27     2map sift ; inline
  28
  29 : reduce-from ( ... seq identity quot: ( ... prev elt -- ... next ) i -- ... result )
  30     [ swap ] 2dip each-from ; inline
  31
  32 :: subseq* ( from to seq -- subseq )
  33     seq length :> len
  34     from [ dup 0 < [ len + ] when ] [ 0 ] if*
  35     to [ dup 0 < [ len + ] when ] [ len ] if*
  36     [ 0 len clamp ] bi@ dupd max seq subseq ;
  37
  38 : safe-subseq ( from to seq -- subseq )
  39     [ length '[ 0 _ clamp ] bi@ ] keep subseq ;
  40
  41 : all-subseqs ( seq -- seqs )
  42     dup length [1,b] [ clump ] with map concat ;
  43
  44 :: each-subseq ( ... seq quot: ( ... x -- ... ) -- ... )
  45     seq length :> len
  46     len [0,b] [
  47         :> from
  48         from len (a,b] [
  49             :> to
  50             from to seq subseq quot call
  51         ] each
  52     ] each ; inline
  53
  54 : subseq-as ( from to seq exemplar -- subseq )
  55     [ check-slice subseq>copy (copy) ] dip like ;
  56
  57 : map-like ( seq exemplar -- seq' )
  58     '[ _ like ] map ; inline
  59
  60 : filter-all-subseqs-range ( ... seq range quot: ( ... x -- ... ) -- seq )
  61     [
  62         '[ <clumps> _ filter ] with map concat
  63     ] 3keep 2drop map-like ; inline
  64
  65 : filter-all-subseqs ( ... seq quot: ( ... x -- ... ) -- seq )
  66     [ dup length [1,b] ] dip filter-all-subseqs-range ; inline
  67
  68 :: longest-subseq ( seq1 seq2 -- subseq )
  69     seq1 length :> len1
  70     seq2 length :> len2
  71     0 :> n!
  72     0 :> end!
  73     len1 1 + [ len2 1 + 0 <array> ] replicate :> table
  74     len1 [1,b] [| x |
  75         len2 [1,b] [| y |
  76             x 1 - seq1 nth-unsafe
  77             y 1 - seq2 nth-unsafe = [
  78                 y 1 - x 1 - table nth-unsafe nth-unsafe 1 + :> len
  79                 len y x table nth-unsafe set-nth-unsafe
  80                 len n > [ len n! x end! ] when
  81             ] [ 0 y x table nth-unsafe set-nth-unsafe ] if
  82         ] each
  83     ] each end n - end seq1 subseq ;
  84
  85 : pad-longest ( seq1 seq2 elt -- seq1 seq2 )
  86     [ 2dup max-length ] dip [ pad-tail ] 2curry bi@ ;
  87
  88 : change-nths ( ... indices seq quot: ( ... elt -- ... elt' ) -- ... )
  89     [ change-nth ] 2curry each ; inline
  90
  91 : push-if-index ( ..a elt i quot: ( ..a elt i -- ..b ? ) accum -- ..b )
  92     [ 2keep drop ] dip rot [ push ] [ 2drop ] if ; inline
  93
  94 : push-if* ( ..a elt quot: ( ..a elt -- ..b obj/f ) accum -- ..b )
  95     [ call ] dip [ push ] [ drop ] if* ; inline
  96
  97 <PRIVATE
  98
  99 : (index-selector-for) ( quot length exampler -- selector accum )
 100     new-resizable [ [ push-if-index ] 2curry ] keep ; inline
 101
 102 : (selector-for*) ( quot length exemplar -- selector accum )
 103     new-resizable [ [ push-if* ] 2curry ] keep ; inline
 104
 105 PRIVATE>
 106
 107 : index-selector-for ( quot exemplar -- selector accum )
 108     [ length ] keep (index-selector-for) ; inline
 109
 110 : index-selector ( quot -- selector accum )
 111     V{ } index-selector-for ; inline
 112
 113 : selector-for* ( quot exemplar -- selector accum )
 114     [ length ] keep (selector-for*) ; inline
 115
 116 : selector* ( quot -- selector accum ) V{ } selector-for* ; inline
 117
 118 : filter-index-as ( ... seq quot: ( ... elt i -- ... ? ) exemplar -- ... seq' )
 119     pick length over [ (index-selector-for) [ each-index ] dip ] 2curry dip like ; inline
 120
 121 : filter-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... seq' )
 122     over filter-index-as ; inline
 123
 124 : even-indices ( seq -- seq' )
 125     [ length 1 + 2/ ] keep [
 126         [ [ 2 * ] dip nth-unsafe ] curry
 127     ] keep map-integers ;
 128
 129 : odd-indices ( seq -- seq' )
 130     [ length 2/ ] keep [
 131         [ [ 2 * 1 + ] dip nth-unsafe ] curry
 132     ] keep map-integers ;
 133
 134 : compact ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 135     [ split-when harvest ] dip join ; inline
 136
 137 : collapse ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 138     [ split-when ] dip
 139     [ [ harvest ] dip join ]
 140     [ [ first empty? ] dip [ prepend ] curry when ]
 141     [ [ last empty? ] dip [ append ] curry when ]
 142     2tri ; inline
 143
 144 :: slice-when ( seq quot: ( elt -- ? ) -- seq' )
 145     seq length :> len
 146     0 [ len dupd < ] [
 147         dup seq quot find-from drop
 148         [ 2dup = [ 1 + ] when ] [ len ] if*
 149         [ seq <slice> ] keep len or swap
 150     ] produce nip ; inline
 151
 152 : cut-slice* ( seq n -- before after )
 153     [ head-slice* ] [ tail-slice* ] 2bi ;
 154
 155 : ?<slice> ( from to/f sequence -- slice )
 156     over [ nip [ length ] [ ] bi ] unless <slice> ; inline
 157
 158 : sequence>slice ( sequence -- slice )
 159     [ drop 0 ] [ length ] [ ] tri <slice> ; inline
 160
 161 : slice-order-by-from ( slice1 slice2 -- slice-lt slice-gt )
 162     2dup [ from>> ] bi@ > [ swap ] when ; inline
 163
 164 : ordered-slices-range ( slice-lt slice-gt -- to from )
 165     [ to>> ] [ from>> ] bi* ;
 166
 167 : unordered-slices-range ( slice1 slice2 -- to from )
 168     slice-order-by-from ordered-slices-range ;
 169
 170 : ordered-slices-overlap? ( slice-lt slice-gt -- ? )
 171     ordered-slices-range > ; inline
 172
 173 : unordered-slices-overlap? ( slice1 slice2 -- ? )
 174     unordered-slices-range > ; inline
 175
 176 : slices-overlap? ( slice1 slice2 -- ? )
 177     unordered-slices-overlap? ;
 178
 179 : ordered-slices-touch? ( slice-lt slice-gt -- ? )
 180     ordered-slices-range >= ; inline
 181
 182 : unordered-slices-touch? ( slice1 slice2 -- ? )
 183     unordered-slices-range >= ; inline
 184
 185 : slices-touch? ( slice1 slice2 -- ? )
 186     unordered-slices-touch? ;
 187
 188 ERROR: slices-don't-touch slice1 slice2 ;
 189
 190 : merge-slices ( slice1 slice2 -- slice/* )
 191     slice-order-by-from
 192     2dup ordered-slices-touch? [
 193         [ from>> ] [ [ to>> ] [ seq>> ] bi ] bi* <slice>
 194     ] [
 195         slices-don't-touch
 196     ] if ;
 197
 198 : rotate ( seq n -- seq' )
 199     dup 0 > [ cut ] [ abs cut* ] if prepend ;
 200
 201 :: rotate! ( seq n -- )
 202     n seq bounds-check length :> end
 203     0 n [ 2dup = ] [
 204         [ seq exchange-unsafe ] [ [ 1 + ] bi@ ] 2bi
 205         dup end = [ drop over ] when
 206         2over = [ -rot nip over ] when
 207     ] until 3drop ;
 208
 209 : all-rotations ( seq -- seq' )
 210     dup length iota [ rotate ] with map ;
 211
 212 <PRIVATE
 213
 214 : (appender-for) ( quot length exemplar -- appender accum )
 215     new-resizable [ [ push-all ] curry compose ] keep ; inline
 216
 217 PRIVATE>
 218
 219 : appender-for ( quot exemplar -- appender accum )
 220     [ length ] keep (appender-for) ; inline
 221
 222 : appender ( quot -- appender accum )
 223     V{ } appender-for ; inline
 224
 225 : map-concat-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 226     [ appender-for [ each ] dip ] keep like ; inline
 227
 228 : >resizable ( seq -- accum ) ! fixes map-concat "cannot apply call to run-time..."
 229     [ length ] keep [ new-resizable ] [ append! ] bi ;
 230
 231 : map-concat ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 232     over empty? [ 2drop { } ] [
 233         [ [ first ] dip call ] 2keep rot dup [
 234             >resizable [ [ push-all ] curry compose ] keep
 235             [ 1 ] 3dip [ setup-each (each-integer) ] dip
 236         ] curry dip like
 237     ] if ; inline
 238
 239 : map-filter-as ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) exemplar -- ... subseq )
 240     [ pick ] dip swap length over
 241     [ (selector-for) [ compose each ] dip ] 2curry dip like ; inline
 242
 243 : map-filter ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) -- ... subseq )
 244     pick map-filter-as ; inline
 245
 246 : map-sift ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 247     [ ] map-filter ; inline
 248
 249 : map-harvest ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 250     [ empty? not ] map-filter ; inline
 251
 252 <PRIVATE
 253
 254 : (setup-each-from) ( i seq -- n quot )
 255     [ length over [-] swap ] keep '[ _ + _ nth-unsafe ] ; inline
 256
 257 : setup-each-from ( i seq quot -- n quot' )
 258     [ (setup-each-from) ] dip compose ; inline
 259
 260 PRIVATE>
 261
 262 : map-from-as ( ... seq quot: ( ... elt -- ... newelt ) i exemplar -- ... newseq )
 263     [ -rot setup-each-from ] dip map-integers ; inline
 264
 265 : map-from ( ... seq quot: ( ... elt -- ... newelt ) i -- ... newseq )
 266     pick map-from-as ; inline
 267
 268 <PRIVATE
 269
 270 : push-map-if ( ..a elt filter-quot: ( ..a elt -- ..b ? ) map-quot: ( ..a elt -- ..b newelt ) accum -- ..b )
 271     [ keep over ] 2dip [ when ] dip rot [ push ] [ 2drop ] if ; inline
 272
 273 : (filter-mapper-for) ( filter-quot map-quot length exempler -- filter-mapper accum )
 274     new-resizable [ [ push-map-if ] 3curry ] keep ; inline
 275
 276 : filter-mapper-for ( filter-quot map-quot exemplar -- filter-mapper accum )
 277     [ length ] keep (filter-mapper-for) ; inline
 278
 279 : filter-mapper ( filter-quot map-quot -- filter-mapper accum )
 280     V{ } filter-mapper-for ; inline
 281
 282 PRIVATE>
 283
 284 : filter-map-as ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 285     [ pick ] dip swap length over
 286     [ (filter-mapper-for) [ each ] dip ] 2curry dip like ; inline
 287
 288 : filter-map ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) -- ... newseq )
 289     pick filter-map-as ; inline
 290
 291 : 2map-sum ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... n ) -- ... n )
 292     [ 0 ] 3dip [ dip + ] curry [ rot ] prepose 2each ; inline
 293
 294 : 2count ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... n )
 295     [ 1 0 ? ] compose 2map-sum ; inline
 296
 297 : round-robin ( seq -- newseq )
 298     [ { } ] [
 299         [ longest length iota ] keep
 300         [ [ ?nth ] with map ] curry map concat sift
 301     ] if-empty ;
 302
 303 : sift-as ( seq exemplar -- newseq )
 304     [ ] swap filter-as ;
 305
 306 : sift! ( seq -- newseq )
 307     [ ] filter! ;
 308
 309 : harvest-as ( seq exemplar -- newseq )
 310     [ empty? not ] swap filter-as ;
 311
 312 : harvest! ( seq -- newseq )
 313     [ empty? ] reject! ;
 314
 315 : head-as ( seq n exemplar -- seq' )
 316     [ head-slice ] [ like ] bi* ; inline
 317
 318 : head*-as ( seq n exemplar -- seq' )
 319     [ head-slice* ] [ like ] bi* ; inline
 320
 321 : tail-as ( seq n exemplar -- seq' )
 322     [ tail-slice ] [ like ] bi* ; inline
 323
 324 : tail*-as ( seq n exemplar -- seq' )
 325     [ tail-slice* ] [ like ] bi* ; inline
 326
 327 : trim-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... newseq )
 328     [ trim-slice ] [ like ] bi* ; inline
 329
 330 : ?trim ( seq quot: ( elt -- ? ) -- seq/newseq )
 331     over empty? [ drop ] [
 332         over [ first-unsafe ] [ last-unsafe ] bi pick either?
 333         [ trim ] [ drop ] if
 334     ] if ; inline
 335
 336 : ?trim-head ( seq quot: ( elt -- ? ) -- seq/newseq )
 337     over empty? [ drop ] [
 338         over first-unsafe over call
 339         [ trim-head ] [ drop ] if
 340     ] if ; inline
 341
 342 : ?trim-tail ( seq quot: ( elt -- ? ) -- seq/newseq )
 343     over empty? [ drop ] [
 344         over last-unsafe over call
 345         [ trim-tail ] [ drop ] if
 346     ] if ; inline
 347
 348 : unsurround ( newseq seq2 seq3 -- seq1 )
 349    [ ?head drop ] [ ?tail drop ] bi* ;
 350
 351 : none? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 352     any? not ; inline
 353
 354 : one? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 355     [ find ] 2keep rot [
 356         [ 1 + ] 2dip find-from drop not
 357     ] [ 3drop f ] if ; inline
 358
 359 : map-index! ( ... seq quot: ( ... elt index -- ... newelt ) -- ... seq )
 360     over [ [ (each-index) ] dip collect ] keep ; inline
 361
 362 <PRIVATE
 363
 364 : (2each-index) ( seq1 seq2 quot -- n quot' )
 365     [ setup-2each [ keep ] curry ] dip compose ; inline
 366
 367 PRIVATE>
 368
 369 : 2each-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... ) -- ... )
 370     (2each-index) each-integer ; inline
 371
 372 : 2map-into ( seq1 seq2 quot into -- )
 373     [ (2each) ] dip collect ; inline
 374
 375 : 2map! ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... seq1 )
 376     pick [ 2map-into ] keep ; inline
 377
 378 : 2map-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... newelt ) -- ... newseq )
 379     pick [ (2each-index) ] dip map-integers ; inline
 380
 381 TUPLE: evens seq length ;
 382
 383 : <evens> ( seq -- evens )
 384     dup length 1 + 2/ evens boa ; inline
 385
 386 M: evens length length>> ; inline
 387
 388 M: evens nth-unsafe [ 2 * ] [ seq>> nth-unsafe ] bi* ; inline
 389
 390 INSTANCE: evens immutable-sequence
 391
 392 TUPLE: odds seq length ;
 393
 394 : <odds> ( seq -- odds )
 395     dup length 2/ odds boa ; inline
 396
 397 M: odds length length>> ; inline
 398
 399 M: odds nth-unsafe [ 2 * 1 + ] [ seq>> nth-unsafe ] bi* ; inline
 400
 401 INSTANCE: odds immutable-sequence
 402
 403 : until-empty ( seq quot -- )
 404     [ dup empty? ] swap until drop ; inline
 405
 406 : arg-max ( seq -- n )
 407     <enum> [ second-unsafe ] supremum-by first ;
 408
 409 : arg-min ( seq -- n )
 410     <enum> [ second-unsafe ] infimum-by first ;
 411
 412 <PRIVATE
 413
 414 : push-index-if ( ..a elt i quot: ( ..a elt -- ..b ? ) accum -- ..b )
 415     [ dip ] dip rot [ push ] [ 2drop ] if ; inline
 416
 417 PRIVATE>
 418
 419 : arg-where ( ... seq quot: ( ... elt -- ... ? ) -- ... indices )
 420     over length <vector> [
 421         [ push-index-if ] 2curry each-index
 422     ] keep ; inline
 423
 424 : arg-sort ( seq -- indices )
 425     zip-index sort-keys values ;
 426
 427 : first= ( seq elt -- ? ) [ first ] dip = ; inline
 428 : second= ( seq elt -- ? ) [ second ] dip = ; inline
 429 : third= ( seq elt -- ? ) [ third ] dip = ; inline
 430 : fourth= ( seq elt -- ? ) [ fourth ] dip = ; inline
 431 : last= ( seq elt -- ? ) [ last ] dip = ; inline
 432 : nth= ( n seq elt -- ? ) [ nth ] dip = ; inline
 433
 434 : first? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ first ] dip call ; inline
 435 : second? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ second ] dip call ; inline
 436 : third? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ third ] dip call ; inline
 437 : fourth? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ fourth ] dip call ; inline
 438 : last? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ last ] dip call ; inline
 439 : nth? ( ... n seq quot: ( ... elt -- ... ? ) -- ... ? ) [ nth ] dip call ; inline
 440
 441 : loop>sequence ( quot exemplar -- seq )
 442    [ '[ [ @ [ [ , ] when* ] keep ] loop ] ] dip make ; inline
 443
 444 : loop>array ( quot -- seq )
 445    { } loop>sequence ; inline
 446
 447 <PRIVATE
 448
 449 : (reverse) ( seq -- newseq )
 450     dup [ length ] keep new-sequence
 451     [ 0 swap copy-unsafe ] keep reverse! ;
 452
 453 PRIVATE>
 454
 455 : reverse-as ( seq exemplar -- newseq )
 456     [ (reverse) ] [ like ] bi* ;
 457
 458 : map-product ( ... seq quot: ( ... elt -- ... n ) -- ... n )
 459     [ 1 ] 2dip [ dip * ] curry [ swap ] prepose each ; inline
 460
 461 : insert-nth! ( elt n seq -- )
 462     [ length ] keep ensure swap pick (a,b]
 463     over '[ [ 1 + ] keep _ move-unsafe ] each
 464     set-nth-unsafe ;
 465
 466 : set-nths ( value indices seq -- )
 467     swapd '[ _ swap _ set-nth ] each ; inline
 468
 469 : set-nths-unsafe ( value indices seq -- )
 470     swapd '[ _ swap _ set-nth-unsafe ] each ; inline
 471
 472 : flatten1 ( obj -- seq )
 473     [
 474         [
 475             dup branch? [
 476                 [ dup branch? [ % ] [ , ] if ] each
 477             ] [ , ] if
 478         ]
 479     ] keep dup branch? [ drop f ] unless make ;
 480
 481 <PRIVATE
 482
 483 : (map-find-index) ( seq quot find-quot -- result i elt )
 484     [ [ f ] 2dip [ [ nip ] 2dip call dup ] curry ] dip call
 485     [ [ [ drop f ] unless ] keep ] dip ; inline
 486
 487 PRIVATE>
 488
 489 : map-find-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 490     [ find-index ] (map-find-index) ; inline
 491
 492 : filter-length ( seq n -- seq' ) '[ length _ = ] filter ;
 493
 494 : all-shortest ( seqs -- seqs' ) dup shortest length filter-length ;
 495
 496 : all-longest ( seqs -- seqs' ) dup longest length filter-length ;
 497
 498 : remove-first ( obj seq -- seq' )
 499     [ index ] keep over [ remove-nth ] [ nip ] if ;
 500
 501 : remove-first! ( obj seq -- seq )
 502     [ index ] keep over [ remove-nth! ] [ nip ] if ;
 503
 504 : remove-last ( obj seq -- seq' )
 505     [ last-index ] keep over [ remove-nth ] [ nip ] if ;
 506
 507 : remove-last! ( obj seq -- seq )
 508     [ last-index ] keep over [ remove-nth! ] [ nip ] if ;
 509
 510 : ?first2 ( seq -- first/f second/f )
 511     dup length {
 512         { 0 [ drop f f ] }
 513         { 1 [ first-unsafe f ] }
 514         [ drop first2-unsafe ]
 515     } case ;
 516
 517 : ?first3 ( seq -- first/f second/f third/f )
 518     dup length {
 519         { 0 [ drop f f f ] }
 520         { 1 [ first-unsafe f f ] }
 521         { 2 [ first2-unsafe f ] }
 522         [ drop first3-unsafe ]
 523     } case ;
 524
 525 : ?first4 ( seq -- first/f second/f third/f fourth/f )
 526     dup length {
 527         { 0 [ drop f f f f ] }
 528         { 1 [ first-unsafe f f f ] }
 529         { 2 [ first2-unsafe f f ] }
 530         { 3 [ first3-unsafe f ] }
 531         [ drop first4-unsafe ]
 532     } case ;
 533
 534 : cut-when ( ... seq quot: ( ... elt -- ... ? ) -- ... before after )
 535     [ find drop ] 2keep drop swap
 536     [ cut ] [ f over like ] if* ; inline
 537
 538 : nth* ( n seq -- elt )
 539     [ length 1 - swap - ] [ nth ] bi ; inline
 540
 541 : each-index-from ( ... seq quot: ( ... elt index -- ... ) i -- ... )
 542     -rot (each-index) (each-integer) ; inline
 543
 544 <PRIVATE
 545
 546 : select-by* ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... i elt )
 547     [
 548         [ keep swap ] curry [ dip ] curry
 549         [ [ first 0 ] dip call ] 2keep
 550         [ 2curry 3dip 5 npick pick ] curry
 551     ] [
 552         [ [ 3drop ] [ [ 3drop ] 3dip ] if ] compose
 553     ] bi* compose 1 each-index-from nip swap ; inline
 554
 555 PRIVATE>
 556
 557 : supremum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 558     [ after? ] select-by* ; inline
 559
 560 : infimum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 561     [ before? ] select-by* ; inline
 562
 563 : change-last ( seq quot -- )
 564     [ drop length 1 - ] [ change-nth ] 2bi ; inline
 565
 566 : change-last-unsafe ( seq quot -- )
 567     [ drop length 1 - ] [ change-nth-unsafe ] 2bi ; inline
 568
 569 : replicate-into ( ... seq quot: ( ... -- ... newelt ) -- ... )
 570     over [ length ] 2dip '[ _ dip _ set-nth-unsafe ] each-integer ; inline
 571
 572 : count* ( ... seq quot: ( ... elt -- ... ? ) -- ... % )
 573     over [ count ] [ length ] bi* / ; inline
 574
 575 : find-last-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 576     [ [ 1 - ] dip find-last-integer ] (find-index) ; inline
 577
 578 : map-find-last-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 579     [ find-last-index ] (map-find-index) ; inline
 580
 581 :: (start-all) ( subseq seq increment -- indices )
 582     0
 583     [ [ subseq seq ] dip start* dup ]
 584     [ [ increment + ] keep ] produce nip ;
 585
 586 : start-all ( subseq seq -- indices )
 587     over length (start-all) ; inline
 588
 589 : start-all* ( subseq seq -- indices )
 590     1 (start-all) ; inline
 591
 592 : count-subseq ( subseq seq -- n )
 593     start-all length ; inline
 594
 595 : count-subseq* ( subseq seq -- n )
 596     start-all* length ; inline
 597
 598 : map-zip ( quot: ( x -- y ) -- alist )
 599     '[ _ keep swap ] map>alist ; inline