extra/sequences/extras/extras.factor

   1 USING: accessors arrays assocs combinators fry generalizations
   2 grouping growable kernel locals make math math.order math.ranges
   3 sequences sequences.deep sequences.private sorting splitting
   4 vectors ;
   5 IN: sequences.extras
   6
   7 : reduce1 ( seq quot -- result ) [ unclip ] dip reduce ; inline
   8
   9 :: reduce-r ( seq identity quot: ( obj1 obj2 -- obj ) -- result )
  10     seq [ identity ] [
  11         unclip [ identity quot reduce-r ] [ quot call ] bi*
  12     ] if-empty ; inline recursive
  13
  14 ! Quot must have static stack effect, unlike "reduce"
  15 :: reduce* ( seq identity quot: ( prev elt -- next ) -- result )
  16     seq [ identity ] [
  17         unclip identity swap quot call( prev elt -- next )
  18         quot reduce*
  19     ] if-empty ; inline recursive
  20
  21 :: combos ( list1 list2 -- result )
  22     list2 [ [ 2array ] curry list1 swap map ] map concat ;
  23
  24 : find-all ( seq quot: ( elt -- ? ) -- elts )
  25     [ [ length iota ] keep ] dip
  26     [ dupd call( a -- ? ) [ 2array ] [ 2drop f ] if ] curry
  27     2map sift ; inline
  28
  29 : reduce-from ( ... seq identity quot: ( ... prev elt -- ... next ) i -- ... result )
  30     [ swap ] 2dip each-from ; inline
  31
  32 :: subseq* ( from to seq -- subseq )
  33     seq length :> len
  34     from [ dup 0 < [ len + ] when ] [ 0 ] if*
  35     to [ dup 0 < [ len + ] when ] [ len ] if*
  36     [ 0 len clamp ] bi@ dupd max seq subseq ;
  37
  38 : safe-subseq ( from to seq -- subseq )
  39     [ length '[ 0 _ clamp ] bi@ ] keep subseq ;
  40
  41 : all-subseqs ( seq -- seqs )
  42     dup length [1,b] [ clump ] with map concat ;
  43
  44 :: each-subseq ( ... seq quot: ( ... x -- ... ) -- ... )
  45     seq length :> len
  46     len [0,b] [
  47         :> from
  48         from len (a,b] [
  49             :> to
  50             from to seq subseq quot call
  51         ] each
  52     ] each ; inline
  53
  54 : subseq-as ( from to seq exemplar -- subseq )
  55     [ check-slice subseq>copy (copy) ] dip like ;
  56
  57 : map-like ( seq exemplar -- seq' )
  58     '[ _ like ] map ; inline
  59
  60 : filter-all-subseqs-range ( ... seq range quot: ( ... x -- ... ) -- seq )
  61     [
  62         '[ <clumps> _ filter ] with map concat
  63     ] 3keep 2drop map-like ; inline
  64
  65 : filter-all-subseqs ( ... seq quot: ( ... x -- ... ) -- seq )
  66     [ dup length [1,b] ] dip filter-all-subseqs-range ; inline
  67
  68 :: longest-subseq ( seq1 seq2 -- subseq )
  69     seq1 length :> len1
  70     seq2 length :> len2
  71     0 :> n!
  72     0 :> end!
  73     len1 1 + [ len2 1 + 0 <array> ] replicate :> table
  74     len1 [1,b] [| x |
  75         len2 [1,b] [| y |
  76             x 1 - seq1 nth-unsafe
  77             y 1 - seq2 nth-unsafe = [
  78                 y 1 - x 1 - table nth-unsafe nth-unsafe 1 + :> len
  79                 len y x table nth-unsafe set-nth-unsafe
  80                 len n > [ len n! x end! ] when
  81             ] [ 0 y x table nth-unsafe set-nth-unsafe ] if
  82         ] each
  83     ] each end n - end seq1 subseq ;
  84
  85 : pad-longest ( seq1 seq2 elt -- seq1 seq2 )
  86     [ 2dup max-length ] dip [ pad-tail ] 2curry bi@ ;
  87
  88 : change-nths ( ... indices seq quot: ( ... elt -- ... elt' ) -- ... )
  89     [ change-nth ] 2curry each ; inline
  90
  91 : push-if-index ( ..a elt i quot: ( ..a elt i -- ..b ? ) accum -- ..b )
  92     [ 2keep drop ] dip rot [ push ] [ 2drop ] if ; inline
  93
  94 : push-if* ( ..a elt quot: ( ..a elt -- ..b obj/f ) accum -- ..b )
  95     [ call ] dip [ push ] [ drop ] if* ; inline
  96
  97 <PRIVATE
  98
  99 : (index-selector-for) ( quot length exampler -- selector accum )
 100     new-resizable [ [ push-if-index ] 2curry ] keep ; inline
 101
 102 : (selector-for*) ( quot length exemplar -- selector accum )
 103     new-resizable [ [ push-if* ] 2curry ] keep ; inline
 104
 105 PRIVATE>
 106
 107 : index-selector-for ( quot exemplar -- selector accum )
 108     [ length ] keep (index-selector-for) ; inline
 109
 110 : index-selector ( quot -- selector accum )
 111     V{ } index-selector-for ; inline
 112
 113 : selector-for* ( quot exemplar -- selector accum )
 114     [ length ] keep (selector-for*) ; inline
 115
 116 : selector* ( quot -- selector accum ) V{ } selector-for* ; inline
 117
 118 : filter-index-as ( ... seq quot: ( ... elt i -- ... ? ) exemplar -- ... seq' )
 119     pick length over [ (index-selector-for) [ each-index ] dip ] 2curry dip like ; inline
 120
 121 : filter-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... seq' )
 122     over filter-index-as ; inline
 123
 124 : even-indices ( seq -- seq' )
 125     [ length 1 + 2/ ] keep [
 126         [ [ 2 * ] dip nth-unsafe ] curry
 127     ] keep map-integers ;
 128
 129 : odd-indices ( seq -- seq' )
 130     [ length 2/ ] keep [
 131         [ [ 2 * 1 + ] dip nth-unsafe ] curry
 132     ] keep map-integers ;
 133
 134 : compact ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 135     [ split-when harvest ] dip join ; inline
 136
 137 : collapse ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 138     [ split-when ] dip
 139     [ [ harvest ] dip join ]
 140     [ [ first empty? ] dip [ prepend ] curry when ]
 141     [ [ last empty? ] dip [ append ] curry when ]
 142     2tri ; inline
 143
 144 :: slice-when ( seq quot: ( elt -- ? ) -- seq' )
 145     seq length :> len
 146     0 [ len dupd < ] [
 147         dup seq quot find-from drop
 148         [ 2dup = [ 1 + ] when ] [ len ] if*
 149         [ seq <slice> ] keep len or swap
 150     ] produce nip ; inline
 151
 152 : cut-slice* ( seq n -- before after )
 153     [ head-slice* ] [ tail-slice* ] 2bi ;
 154
 155 : ?<slice> ( from to/f sequence -- slice )
 156     over [ nip [ length ] [ ] bi ] unless <slice> ; inline
 157
 158 : sequence>slice ( sequence -- slice )
 159     [ drop 0 ] [ length ] [ ] tri <slice> ; inline
 160
 161 : slice-order-by-from ( slice1 slice2 -- slice-lt slice-gt )
 162     2dup [ from>> ] bi@ > [ swap ] when ; inline
 163
 164 : ordered-slices-range ( slice-lt slice-gt -- to from )
 165     [ to>> ] [ from>> ] bi* ;
 166
 167 : unordered-slices-range ( slice1 slice2 -- to from )
 168     slice-order-by-from ordered-slices-range ;
 169
 170 : ordered-slices-overlap? ( slice-lt slice-gt -- ? )
 171     ordered-slices-range > ; inline
 172
 173 : unordered-slices-overlap? ( slice1 slice2 -- ? )
 174     unordered-slices-range > ; inline
 175
 176 : slices-overlap? ( slice1 slice2 -- ? )
 177     unordered-slices-overlap? ;
 178
 179 : ordered-slices-touch? ( slice-lt slice-gt -- ? )
 180     ordered-slices-range >= ; inline
 181
 182 : unordered-slices-touch? ( slice1 slice2 -- ? )
 183     unordered-slices-range >= ; inline
 184
 185 : slices-touch? ( slice1 slice2 -- ? )
 186     unordered-slices-touch? ;
 187
 188 ERROR: slices-don't-touch slice1 slice2 ;
 189
 190 : merge-slices ( slice1 slice2 -- slice/* )
 191     slice-order-by-from
 192     2dup ordered-slices-touch? [
 193         [ from>> ] [ [ to>> ] [ seq>> ] bi ] bi* <slice>
 194     ] [
 195         slices-don't-touch
 196     ] if ;
 197
 198 : rotate ( seq n -- seq' )
 199     dup 0 >= [ cut ] [ abs cut* ] if prepend ;
 200
 201 :: rotate! ( seq n -- )
 202     seq length :> len
 203     n dup 0 < [ len + ] when seq bounds-check drop 0 over
 204     [ 2dup = ] [
 205         [ seq exchange-unsafe ] [ [ 1 + ] bi@ ] 2bi
 206         dup len = [ drop over ] when
 207         2over = [ -rot nip over ] when
 208     ] until 3drop ;
 209
 210 : all-rotations ( seq -- seq' )
 211     dup length iota [ rotate ] with map ;
 212
 213 <PRIVATE
 214
 215 : (appender-for) ( quot length exemplar -- appender accum )
 216     new-resizable [ [ push-all ] curry compose ] keep ; inline
 217
 218 PRIVATE>
 219
 220 : appender-for ( quot exemplar -- appender accum )
 221     [ length ] keep (appender-for) ; inline
 222
 223 : appender ( quot -- appender accum )
 224     V{ } appender-for ; inline
 225
 226 : map-concat-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 227     [ appender-for [ each ] dip ] keep like ; inline
 228
 229 : >resizable ( seq -- accum ) ! fixes map-concat "cannot apply call to run-time..."
 230     [ length ] keep [ new-resizable ] [ append! ] bi ;
 231
 232 : map-concat ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 233     over empty? [ 2drop { } ] [
 234         [ [ first ] dip call ] 2keep rot dup [
 235             >resizable [ [ push-all ] curry compose ] keep
 236             [ 1 ] 3dip [ setup-each (each-integer) ] dip
 237         ] curry dip like
 238     ] if ; inline
 239
 240 : map-filter-as ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) exemplar -- ... subseq )
 241     [ pick ] dip swap length over
 242     [ (selector-for) [ compose each ] dip ] 2curry dip like ; inline
 243
 244 : map-filter ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) -- ... subseq )
 245     pick map-filter-as ; inline
 246
 247 : map-sift ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 248     [ ] map-filter ; inline
 249
 250 : map-harvest ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 251     [ empty? not ] map-filter ; inline
 252
 253 <PRIVATE
 254
 255 : (setup-each-from) ( i seq -- n quot )
 256     [ length over [-] swap ] keep '[ _ + _ nth-unsafe ] ; inline
 257
 258 : setup-each-from ( i seq quot -- n quot' )
 259     [ (setup-each-from) ] dip compose ; inline
 260
 261 PRIVATE>
 262
 263 : map-from-as ( ... seq quot: ( ... elt -- ... newelt ) i exemplar -- ... newseq )
 264     [ -rot setup-each-from ] dip map-integers ; inline
 265
 266 : map-from ( ... seq quot: ( ... elt -- ... newelt ) i -- ... newseq )
 267     pick map-from-as ; inline
 268
 269 <PRIVATE
 270
 271 : push-map-if ( ..a elt filter-quot: ( ..a elt -- ..b ? ) map-quot: ( ..a elt -- ..b newelt ) accum -- ..b )
 272     [ keep over ] 2dip [ when ] dip rot [ push ] [ 2drop ] if ; inline
 273
 274 : (filter-mapper-for) ( filter-quot map-quot length exempler -- filter-mapper accum )
 275     new-resizable [ [ push-map-if ] 3curry ] keep ; inline
 276
 277 : filter-mapper-for ( filter-quot map-quot exemplar -- filter-mapper accum )
 278     [ length ] keep (filter-mapper-for) ; inline
 279
 280 : filter-mapper ( filter-quot map-quot -- filter-mapper accum )
 281     V{ } filter-mapper-for ; inline
 282
 283 PRIVATE>
 284
 285 : filter-map-as ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 286     [ pick ] dip swap length over
 287     [ (filter-mapper-for) [ each ] dip ] 2curry dip like ; inline
 288
 289 : filter-map ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) -- ... newseq )
 290     pick filter-map-as ; inline
 291
 292 : 2map-sum ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... n ) -- ... n )
 293     [ 0 ] 3dip [ dip + ] curry [ rot ] prepose 2each ; inline
 294
 295 : 2count ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... n )
 296     [ 1 0 ? ] compose 2map-sum ; inline
 297
 298 : round-robin ( seq -- newseq )
 299     [ { } ] [
 300         [ longest length iota ] keep
 301         [ [ ?nth ] with map ] curry map concat sift
 302     ] if-empty ;
 303
 304 : sift-as ( seq exemplar -- newseq )
 305     [ ] swap filter-as ;
 306
 307 : sift! ( seq -- newseq )
 308     [ ] filter! ;
 309
 310 : harvest-as ( seq exemplar -- newseq )
 311     [ empty? not ] swap filter-as ;
 312
 313 : harvest! ( seq -- newseq )
 314     [ empty? ] reject! ;
 315
 316 : head-as ( seq n exemplar -- seq' )
 317     [ head-slice ] [ like ] bi* ; inline
 318
 319 : head*-as ( seq n exemplar -- seq' )
 320     [ head-slice* ] [ like ] bi* ; inline
 321
 322 : tail-as ( seq n exemplar -- seq' )
 323     [ tail-slice ] [ like ] bi* ; inline
 324
 325 : tail*-as ( seq n exemplar -- seq' )
 326     [ tail-slice* ] [ like ] bi* ; inline
 327
 328 : trim-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... newseq )
 329     [ trim-slice ] [ like ] bi* ; inline
 330
 331 : ?trim ( seq quot: ( elt -- ? ) -- seq/newseq )
 332     over empty? [ drop ] [
 333         over [ first-unsafe ] [ last-unsafe ] bi pick either?
 334         [ trim ] [ drop ] if
 335     ] if ; inline
 336
 337 : ?trim-head ( seq quot: ( elt -- ? ) -- seq/newseq )
 338     over empty? [ drop ] [
 339         over first-unsafe over call
 340         [ trim-head ] [ drop ] if
 341     ] if ; inline
 342
 343 : ?trim-tail ( seq quot: ( elt -- ? ) -- seq/newseq )
 344     over empty? [ drop ] [
 345         over last-unsafe over call
 346         [ trim-tail ] [ drop ] if
 347     ] if ; inline
 348
 349 : unsurround ( newseq seq2 seq3 -- seq1 )
 350    [ ?head drop ] [ ?tail drop ] bi* ;
 351
 352 : none? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 353     any? not ; inline
 354
 355 : one? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 356     [ find ] 2keep rot [
 357         [ 1 + ] 2dip find-from drop not
 358     ] [ 3drop f ] if ; inline
 359
 360 : map-index! ( ... seq quot: ( ... elt index -- ... newelt ) -- ... seq )
 361     over [ [ (each-index) ] dip collect ] keep ; inline
 362
 363 <PRIVATE
 364
 365 : (2each-index) ( seq1 seq2 quot -- n quot' )
 366     [ setup-2each [ keep ] curry ] dip compose ; inline
 367
 368 PRIVATE>
 369
 370 : 2each-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... ) -- ... )
 371     (2each-index) each-integer ; inline
 372
 373 : 2map-into ( seq1 seq2 quot into -- )
 374     [ (2each) ] dip collect ; inline
 375
 376 : 2map! ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... seq1 )
 377     pick [ 2map-into ] keep ; inline
 378
 379 : 2map-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... newelt ) -- ... newseq )
 380     pick [ (2each-index) ] dip map-integers ; inline
 381
 382 TUPLE: evens seq length ;
 383
 384 : <evens> ( seq -- evens )
 385     dup length 1 + 2/ evens boa ; inline
 386
 387 M: evens length length>> ; inline
 388
 389 M: evens nth-unsafe [ 2 * ] [ seq>> nth-unsafe ] bi* ; inline
 390
 391 INSTANCE: evens immutable-sequence
 392
 393 TUPLE: odds seq length ;
 394
 395 : <odds> ( seq -- odds )
 396     dup length 2/ odds boa ; inline
 397
 398 M: odds length length>> ; inline
 399
 400 M: odds nth-unsafe [ 2 * 1 + ] [ seq>> nth-unsafe ] bi* ; inline
 401
 402 INSTANCE: odds immutable-sequence
 403
 404 : until-empty ( seq quot -- )
 405     [ dup empty? ] swap until drop ; inline
 406
 407 : arg-max ( seq -- n )
 408     <enum> [ second-unsafe ] supremum-by first ;
 409
 410 : arg-min ( seq -- n )
 411     <enum> [ second-unsafe ] infimum-by first ;
 412
 413 <PRIVATE
 414
 415 : push-index-if ( ..a elt i quot: ( ..a elt -- ..b ? ) accum -- ..b )
 416     [ dip ] dip rot [ push ] [ 2drop ] if ; inline
 417
 418 PRIVATE>
 419
 420 : arg-where ( ... seq quot: ( ... elt -- ... ? ) -- ... indices )
 421     over length <vector> [
 422         [ push-index-if ] 2curry each-index
 423     ] keep ; inline
 424
 425 : arg-sort ( seq -- indices )
 426     zip-index sort-keys values ;
 427
 428 : first= ( seq elt -- ? ) [ first ] dip = ; inline
 429 : second= ( seq elt -- ? ) [ second ] dip = ; inline
 430 : third= ( seq elt -- ? ) [ third ] dip = ; inline
 431 : fourth= ( seq elt -- ? ) [ fourth ] dip = ; inline
 432 : last= ( seq elt -- ? ) [ last ] dip = ; inline
 433 : nth= ( n seq elt -- ? ) [ nth ] dip = ; inline
 434
 435 : first? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ first ] dip call ; inline
 436 : second? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ second ] dip call ; inline
 437 : third? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ third ] dip call ; inline
 438 : fourth? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ fourth ] dip call ; inline
 439 : last? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ last ] dip call ; inline
 440 : nth? ( ... n seq quot: ( ... elt -- ... ? ) -- ... ? ) [ nth ] dip call ; inline
 441
 442 : loop>sequence ( quot exemplar -- seq )
 443    [ '[ [ @ [ [ , ] when* ] keep ] loop ] ] dip make ; inline
 444
 445 : loop>array ( quot -- seq )
 446    { } loop>sequence ; inline
 447
 448 <PRIVATE
 449
 450 : (reverse) ( seq -- newseq )
 451     dup [ length ] keep new-sequence
 452     [ 0 swap copy-unsafe ] keep reverse! ;
 453
 454 PRIVATE>
 455
 456 : reverse-as ( seq exemplar -- newseq )
 457     [ (reverse) ] [ like ] bi* ;
 458
 459 : map-product ( ... seq quot: ( ... elt -- ... n ) -- ... n )
 460     [ 1 ] 2dip [ dip * ] curry [ swap ] prepose each ; inline
 461
 462 : insert-nth! ( elt n seq -- )
 463     [ length ] keep ensure swap pick (a,b]
 464     over '[ [ 1 + ] keep _ move-unsafe ] each
 465     set-nth-unsafe ;
 466
 467 : set-nths ( value indices seq -- )
 468     swapd '[ _ swap _ set-nth ] each ; inline
 469
 470 : set-nths-unsafe ( value indices seq -- )
 471     swapd '[ _ swap _ set-nth-unsafe ] each ; inline
 472
 473 : flatten1 ( obj -- seq )
 474     [
 475         [
 476             dup branch? [
 477                 [ dup branch? [ % ] [ , ] if ] each
 478             ] [ , ] if
 479         ]
 480     ] keep dup branch? [ drop f ] unless make ;
 481
 482 <PRIVATE
 483
 484 : (map-find-index) ( seq quot find-quot -- result i elt )
 485     [ [ f ] 2dip [ [ nip ] 2dip call dup ] curry ] dip call
 486     [ [ [ drop f ] unless ] keep ] dip ; inline
 487
 488 PRIVATE>
 489
 490 : map-find-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 491     [ find-index ] (map-find-index) ; inline
 492
 493 : filter-length ( seq n -- seq' ) '[ length _ = ] filter ;
 494
 495 : all-shortest ( seqs -- seqs' ) dup shortest length filter-length ;
 496
 497 : all-longest ( seqs -- seqs' ) dup longest length filter-length ;
 498
 499 : remove-first ( obj seq -- seq' )
 500     [ index ] keep over [ remove-nth ] [ nip ] if ;
 501
 502 : remove-first! ( obj seq -- seq )
 503     [ index ] keep over [ remove-nth! ] [ nip ] if ;
 504
 505 : remove-last ( obj seq -- seq' )
 506     [ last-index ] keep over [ remove-nth ] [ nip ] if ;
 507
 508 : remove-last! ( obj seq -- seq )
 509     [ last-index ] keep over [ remove-nth! ] [ nip ] if ;
 510
 511 : ?first2 ( seq -- first/f second/f )
 512     dup length {
 513         { 0 [ drop f f ] }
 514         { 1 [ first-unsafe f ] }
 515         [ drop first2-unsafe ]
 516     } case ;
 517
 518 : ?first3 ( seq -- first/f second/f third/f )
 519     dup length {
 520         { 0 [ drop f f f ] }
 521         { 1 [ first-unsafe f f ] }
 522         { 2 [ first2-unsafe f ] }
 523         [ drop first3-unsafe ]
 524     } case ;
 525
 526 : ?first4 ( seq -- first/f second/f third/f fourth/f )
 527     dup length {
 528         { 0 [ drop f f f f ] }
 529         { 1 [ first-unsafe f f f ] }
 530         { 2 [ first2-unsafe f f ] }
 531         { 3 [ first3-unsafe f ] }
 532         [ drop first4-unsafe ]
 533     } case ;
 534
 535 : cut-when ( ... seq quot: ( ... elt -- ... ? ) -- ... before after )
 536     [ find drop ] 2keep drop swap
 537     [ cut ] [ f over like ] if* ; inline
 538
 539 : nth* ( n seq -- elt )
 540     [ length 1 - swap - ] [ nth ] bi ; inline
 541
 542 : each-index-from ( ... seq quot: ( ... elt index -- ... ) i -- ... )
 543     -rot (each-index) (each-integer) ; inline
 544
 545 <PRIVATE
 546
 547 : select-by* ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... i elt )
 548     [
 549         [ keep swap ] curry [ dip ] curry
 550         [ [ first 0 ] dip call ] 2keep
 551         [ 2curry 3dip 5 npick pick ] curry
 552     ] [
 553         [ [ 3drop ] [ [ 3drop ] 3dip ] if ] compose
 554     ] bi* compose 1 each-index-from nip swap ; inline
 555
 556 PRIVATE>
 557
 558 : supremum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 559     [ after? ] select-by* ; inline
 560
 561 : infimum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 562     [ before? ] select-by* ; inline
 563
 564 : change-last ( seq quot -- )
 565     [ drop length 1 - ] [ change-nth ] 2bi ; inline
 566
 567 : change-last-unsafe ( seq quot -- )
 568     [ drop length 1 - ] [ change-nth-unsafe ] 2bi ; inline
 569
 570 : replicate-into ( ... seq quot: ( ... -- ... newelt ) -- ... )
 571     over [ length ] 2dip '[ _ dip _ set-nth-unsafe ] each-integer ; inline
 572
 573 : count* ( ... seq quot: ( ... elt -- ... ? ) -- ... % )
 574     over [ count ] [ length ] bi* / ; inline
 575
 576 : find-last-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 577     [ [ 1 - ] dip find-last-integer ] (find-index) ; inline
 578
 579 : map-find-last-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 580     [ find-last-index ] (map-find-index) ; inline
 581
 582 :: (start-all) ( subseq seq increment -- indices )
 583     0
 584     [ [ subseq seq ] dip start* dup ]
 585     [ [ increment + ] keep ] produce nip ;
 586
 587 : start-all ( subseq seq -- indices )
 588     over length (start-all) ; inline
 589
 590 : start-all* ( subseq seq -- indices )
 591     1 (start-all) ; inline
 592
 593 : count-subseq ( subseq seq -- n )
 594     start-all length ; inline
 595
 596 : count-subseq* ( subseq seq -- n )
 597     start-all* length ; inline
 598
 599 : map-zip ( quot: ( x -- y ) -- alist )
 600     '[ _ keep swap ] map>alist ; inline