extra/sequences/extras/extras.factor

   1 USING: accessors arrays assocs combinators fry generalizations
   2 grouping growable kernel locals make math math.order math.ranges
   3 sequences sequences.deep sequences.private sorting splitting
   4 vectors ;
   5 IN: sequences.extras
   6
   7 : reduce1 ( seq quot -- result ) [ unclip ] dip reduce ; inline
   8
   9 :: reduce-r ( seq identity quot: ( obj1 obj2 -- obj ) -- result )
  10     seq [ identity ] [
  11         unclip [ identity quot reduce-r ] [ quot call ] bi*
  12     ] if-empty ; inline recursive
  13
  14 ! Quot must have static stack effect, unlike "reduce"
  15 :: reduce* ( seq identity quot: ( prev elt -- next ) -- result )
  16     seq [ identity ] [
  17         unclip identity swap quot call( prev elt -- next )
  18         quot reduce*
  19     ] if-empty ; inline recursive
  20
  21 :: combos ( list1 list2 -- result )
  22     list2 [ [ 2array ] curry list1 swap map ] map concat ;
  23
  24 : find-all ( seq quot: ( elt -- ? ) -- elts )
  25     [ [ length iota ] keep ] dip
  26     [ dupd call( a -- ? ) [ 2array ] [ 2drop f ] if ] curry
  27     2map sift ; inline
  28
  29 : reduce-from ( ... seq identity quot: ( ... prev elt -- ... next ) i -- ... result )
  30     [ swap ] 2dip each-from ; inline
  31
  32 :: subseq* ( from to seq -- subseq )
  33     seq length :> len
  34     from [ dup 0 < [ len + ] when ] [ 0 ] if*
  35     to [ dup 0 < [ len + ] when ] [ len ] if*
  36     [ 0 len clamp ] bi@ dupd max seq subseq ;
  37
  38 : safe-subseq ( from to seq -- subseq )
  39     [ length '[ 0 _ clamp ] bi@ ] keep subseq ;
  40
  41 : all-subseqs ( seq -- seqs )
  42     dup length [1,b] [ clump ] with map concat ;
  43
  44 :: each-subseq ( ... seq quot: ( ... x -- ... ) -- ... )
  45     seq length :> len
  46     len [0,b] [
  47         :> from
  48         from len (a,b] [
  49             :> to
  50             from to seq subseq quot call
  51         ] each
  52     ] each ; inline
  53
  54 : map-like ( seq exemplar -- seq' )
  55     '[ _ like ] map ; inline
  56
  57 : filter-all-subseqs-range ( ... seq range quot: ( ... x -- ... ) -- seq )
  58     [
  59         '[ <clumps> _ filter ] with map concat
  60     ] 3keep 2drop map-like ; inline
  61
  62 : filter-all-subseqs ( ... seq quot: ( ... x -- ... ) -- seq )
  63     [ dup length [1,b] ] dip filter-all-subseqs-range ; inline
  64
  65 :: longest-subseq ( seq1 seq2 -- subseq )
  66     seq1 length :> len1
  67     seq2 length :> len2
  68     0 :> n!
  69     0 :> end!
  70     len1 1 + [ len2 1 + 0 <array> ] replicate :> table
  71     len1 [1,b] [| x |
  72         len2 [1,b] [| y |
  73             x 1 - seq1 nth-unsafe
  74             y 1 - seq2 nth-unsafe = [
  75                 y 1 - x 1 - table nth-unsafe nth-unsafe 1 + :> len
  76                 len y x table nth-unsafe set-nth-unsafe
  77                 len n > [ len n! x end! ] when
  78             ] [ 0 y x table nth-unsafe set-nth-unsafe ] if
  79         ] each
  80     ] each end n - end seq1 subseq ;
  81
  82 : pad-longest ( seq1 seq2 elt -- seq1 seq2 )
  83     [ 2dup max-length ] dip [ pad-tail ] 2curry bi@ ;
  84
  85 : change-nths ( ... indices seq quot: ( ... elt -- ... elt' ) -- ... )
  86     [ change-nth ] 2curry each ; inline
  87
  88 : push-if-index ( ..a elt i quot: ( ..a elt i -- ..b ? ) accum -- ..b )
  89     [ 2keep drop ] dip rot [ push ] [ 2drop ] if ; inline
  90
  91 : push-if* ( ..a elt quot: ( ..a elt -- ..b obj/f ) accum -- ..b )
  92     [ call ] dip [ push ] [ drop ] if* ; inline
  93
  94 <PRIVATE
  95
  96 : (index-selector-for) ( quot length exampler -- selector accum )
  97     new-resizable [ [ push-if-index ] 2curry ] keep ; inline
  98
  99 : (selector-for*) ( quot length exemplar -- selector accum )
 100     new-resizable [ [ push-if* ] 2curry ] keep ; inline
 101
 102 PRIVATE>
 103
 104 : index-selector-for ( quot exemplar -- selector accum )
 105     [ length ] keep (index-selector-for) ; inline
 106
 107 : index-selector ( quot -- selector accum )
 108     V{ } index-selector-for ; inline
 109
 110 : selector-for* ( quot exemplar -- selector accum )
 111     [ length ] keep (selector-for*) ; inline
 112
 113 : selector* ( quot -- selector accum ) V{ } selector-for* ; inline
 114
 115 : filter-index-as ( ... seq quot: ( ... elt i -- ... ? ) exemplar -- ... seq' )
 116     pick length over [ (index-selector-for) [ each-index ] dip ] 2curry dip like ; inline
 117
 118 : filter-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... seq' )
 119     over filter-index-as ; inline
 120
 121 : even-indices ( seq -- seq' )
 122     [ length 1 + 2/ ] keep [
 123         [ [ 2 * ] dip nth-unsafe ] curry
 124     ] keep map-integers ;
 125
 126 : odd-indices ( seq -- seq' )
 127     [ length 2/ ] keep [
 128         [ [ 2 * 1 + ] dip nth-unsafe ] curry
 129     ] keep map-integers ;
 130
 131 : compact ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 132     [ split-when harvest ] dip join ; inline
 133
 134 : collapse ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 135     [ split-when ] dip
 136     [ [ harvest ] dip join ]
 137     [ [ first empty? ] dip [ prepend ] curry when ]
 138     [ [ last empty? ] dip [ append ] curry when ]
 139     2tri ; inline
 140
 141 :: slice-when ( seq quot: ( elt -- ? ) -- seq' )
 142     seq length :> len
 143     0 [ len dupd < ] [
 144         dup seq quot find-from drop
 145         [ 2dup = [ 1 + ] when ] [ len ] if*
 146         [ seq <slice> ] keep len or swap
 147     ] produce nip ; inline
 148
 149 : cut-slice* ( seq n -- before after )
 150     [ head-slice* ] [ tail-slice* ] 2bi ;
 151
 152 : ?<slice> ( from to/f sequence -- slice )
 153     over [ nip [ length ] [ ] bi ] unless <slice> ; inline
 154
 155 : sequence>slice ( sequence -- slice )
 156     [ drop 0 ] [ length ] [ ] tri <slice> ; inline
 157
 158 : slice-order-by-from ( slice1 slice2 -- slice-lt slice-gt )
 159     2dup [ from>> ] bi@ > [ swap ] when ; inline
 160
 161 : ordered-slices-range ( slice-lt slice-gt -- to from )
 162     [ to>> ] [ from>> ] bi* ;
 163
 164 : unordered-slices-range ( slice1 slice2 -- to from )
 165     slice-order-by-from ordered-slices-range ;
 166
 167 : ordered-slices-overlap? ( slice-lt slice-gt -- ? )
 168     ordered-slices-range > ; inline
 169
 170 : unordered-slices-overlap? ( slice1 slice2 -- ? )
 171     unordered-slices-range > ; inline
 172
 173 : slices-overlap? ( slice1 slice2 -- ? )
 174     unordered-slices-overlap? ;
 175
 176 : ordered-slices-touch? ( slice-lt slice-gt -- ? )
 177     ordered-slices-range >= ; inline
 178
 179 : unordered-slices-touch? ( slice1 slice2 -- ? )
 180     unordered-slices-range >= ; inline
 181
 182 : slices-touch? ( slice1 slice2 -- ? )
 183     unordered-slices-touch? ;
 184
 185 ERROR: slices-don't-touch slice1 slice2 ;
 186
 187 : merge-slices ( slice1 slice2 -- slice/* )
 188     slice-order-by-from
 189     2dup ordered-slices-touch? [
 190         [ from>> ] [ [ to>> ] [ seq>> ] bi ] bi* <slice>
 191     ] [
 192         slices-don't-touch
 193     ] if ;
 194
 195 : rotate ( seq n -- seq' )
 196     over length mod dup 0 >= [ cut ] [ abs cut* ] if prepend ;
 197
 198 ERROR: underlying-mismatch slice1 slice2 ;
 199 : ensure-same-underlying ( slice1 slice2 -- slice1 slice2 )
 200     2dup [ seq>> ] bi@ eq? [ underlying-mismatch ] unless ;
 201
 202 : span-slices ( slice1 slice2 -- slice )
 203     ensure-same-underlying
 204     [ [ from>> ] bi@ min ]
 205     [ [ to>> ] bi@ max ]
 206     [ drop seq>> ] 2tri <slice> ;
 207
 208 :: rotate! ( seq n -- )
 209     seq length :> len
 210     n len mod dup 0 < [ len + ] when seq bounds-check drop 0 over
 211     [ 2dup = ] [
 212         [ seq exchange-unsafe ] [ [ 1 + ] bi@ ] 2bi
 213         dup len = [ drop over ] when
 214         2over = [ -rot nip over ] when
 215     ] until 3drop ;
 216
 217 : all-rotations ( seq -- seq' )
 218     dup length iota [ rotate ] with map ;
 219
 220 <PRIVATE
 221
 222 : (appender-for) ( quot length exemplar -- appender accum )
 223     new-resizable [ [ push-all ] curry compose ] keep ; inline
 224
 225 PRIVATE>
 226
 227 : appender-for ( quot exemplar -- appender accum )
 228     [ length ] keep (appender-for) ; inline
 229
 230 : appender ( quot -- appender accum )
 231     V{ } appender-for ; inline
 232
 233 : map-concat-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 234     [ appender-for [ each ] dip ] keep like ; inline
 235
 236 : >resizable ( seq -- accum ) ! fixes map-concat "cannot apply call to run-time..."
 237     [ length ] keep [ new-resizable ] [ append! ] bi ;
 238
 239 : map-concat ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 240     over empty? [ 2drop { } ] [
 241         [ [ first ] dip call ] 2keep rot dup [
 242             >resizable [ [ push-all ] curry compose ] keep
 243             [ 1 ] 3dip [ setup-each (each-integer) ] dip
 244         ] curry dip like
 245     ] if ; inline
 246
 247 : map-filter-as ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) exemplar -- ... subseq )
 248     [ pick ] dip swap length over
 249     [ (selector-for) [ compose each ] dip ] 2curry dip like ; inline
 250
 251 : map-filter ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) -- ... subseq )
 252     pick map-filter-as ; inline
 253
 254 : map-sift ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 255     [ ] map-filter ; inline
 256
 257 : map-harvest ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 258     [ empty? not ] map-filter ; inline
 259
 260 <PRIVATE
 261
 262 : (setup-each-from) ( i seq -- n quot )
 263     [ length over [-] swap ] keep '[ _ + _ nth-unsafe ] ; inline
 264
 265 : setup-each-from ( i seq quot -- n quot' )
 266     [ (setup-each-from) ] dip compose ; inline
 267
 268 PRIVATE>
 269
 270 : map-from-as ( ... seq quot: ( ... elt -- ... newelt ) i exemplar -- ... newseq )
 271     [ -rot setup-each-from ] dip map-integers ; inline
 272
 273 : map-from ( ... seq quot: ( ... elt -- ... newelt ) i -- ... newseq )
 274     pick map-from-as ; inline
 275
 276 <PRIVATE
 277
 278 : push-map-if ( ..a elt filter-quot: ( ..a elt -- ..b ? ) map-quot: ( ..a elt -- ..b newelt ) accum -- ..b )
 279     [ keep over ] 2dip [ when ] dip rot [ push ] [ 2drop ] if ; inline
 280
 281 : (filter-mapper-for) ( filter-quot map-quot length exempler -- filter-mapper accum )
 282     new-resizable [ [ push-map-if ] 3curry ] keep ; inline
 283
 284 : filter-mapper-for ( filter-quot map-quot exemplar -- filter-mapper accum )
 285     [ length ] keep (filter-mapper-for) ; inline
 286
 287 : filter-mapper ( filter-quot map-quot -- filter-mapper accum )
 288     V{ } filter-mapper-for ; inline
 289
 290 PRIVATE>
 291
 292 : filter-map-as ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 293     [ pick ] dip swap length over
 294     [ (filter-mapper-for) [ each ] dip ] 2curry dip like ; inline
 295
 296 : filter-map ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) -- ... newseq )
 297     pick filter-map-as ; inline
 298
 299 : 2map-sum ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... n ) -- ... n )
 300     [ 0 ] 3dip [ dip + ] curry [ rot ] prepose 2each ; inline
 301
 302 : 2count ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... n )
 303     [ 1 0 ? ] compose 2map-sum ; inline
 304
 305 : round-robin ( seq -- newseq )
 306     [ { } ] [
 307         [ longest length iota ] keep
 308         [ [ ?nth ] with map ] curry map concat sift
 309     ] if-empty ;
 310
 311 : sift-as ( seq exemplar -- newseq )
 312     [ ] swap filter-as ;
 313
 314 : sift! ( seq -- newseq )
 315     [ ] filter! ;
 316
 317 : harvest-as ( seq exemplar -- newseq )
 318     [ empty? not ] swap filter-as ;
 319
 320 : harvest! ( seq -- newseq )
 321     [ empty? ] reject! ;
 322
 323 : head-as ( seq n exemplar -- seq' )
 324     [ head-slice ] [ like ] bi* ; inline
 325
 326 : head*-as ( seq n exemplar -- seq' )
 327     [ head-slice* ] [ like ] bi* ; inline
 328
 329 : tail-as ( seq n exemplar -- seq' )
 330     [ tail-slice ] [ like ] bi* ; inline
 331
 332 : tail*-as ( seq n exemplar -- seq' )
 333     [ tail-slice* ] [ like ] bi* ; inline
 334
 335 : trim-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... newseq )
 336     [ trim-slice ] [ like ] bi* ; inline
 337
 338 : ?trim ( seq quot: ( elt -- ? ) -- seq/newseq )
 339     over empty? [ drop ] [
 340         over [ first-unsafe ] [ last-unsafe ] bi pick either?
 341         [ trim ] [ drop ] if
 342     ] if ; inline
 343
 344 : ?trim-head ( seq quot: ( elt -- ? ) -- seq/newseq )
 345     over empty? [ drop ] [
 346         over first-unsafe over call
 347         [ trim-head ] [ drop ] if
 348     ] if ; inline
 349
 350 : ?trim-tail ( seq quot: ( elt -- ? ) -- seq/newseq )
 351     over empty? [ drop ] [
 352         over last-unsafe over call
 353         [ trim-tail ] [ drop ] if
 354     ] if ; inline
 355
 356 : unsurround ( newseq seq2 seq3 -- seq1 )
 357    [ ?head drop ] [ ?tail drop ] bi* ;
 358
 359 : none? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 360     any? not ; inline
 361
 362 : one? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 363     [ find ] 2keep rot [
 364         [ 1 + ] 2dip find-from drop not
 365     ] [ 3drop f ] if ; inline
 366
 367 : map-index! ( ... seq quot: ( ... elt index -- ... newelt ) -- ... seq )
 368     over [ [ (each-index) ] dip collect ] keep ; inline
 369
 370 <PRIVATE
 371
 372 : (2each-index) ( seq1 seq2 quot -- n quot' )
 373     [ setup-2each [ keep ] curry ] dip compose ; inline
 374
 375 PRIVATE>
 376
 377 : 2each-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... ) -- ... )
 378     (2each-index) each-integer ; inline
 379
 380 : 2map-into ( seq1 seq2 quot into -- )
 381     [ (2each) ] dip collect ; inline
 382
 383 : 2map! ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... seq1 )
 384     pick [ 2map-into ] keep ; inline
 385
 386 : 2map-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... newelt ) -- ... newseq )
 387     pick [ (2each-index) ] dip map-integers ; inline
 388
 389 TUPLE: evens seq length ;
 390
 391 : <evens> ( seq -- evens )
 392     dup length 1 + 2/ evens boa ; inline
 393
 394 M: evens length length>> ; inline
 395
 396 M: evens nth-unsafe [ 2 * ] [ seq>> nth-unsafe ] bi* ; inline
 397
 398 INSTANCE: evens immutable-sequence
 399
 400 TUPLE: odds seq length ;
 401
 402 : <odds> ( seq -- odds )
 403     dup length 2/ odds boa ; inline
 404
 405 M: odds length length>> ; inline
 406
 407 M: odds nth-unsafe [ 2 * 1 + ] [ seq>> nth-unsafe ] bi* ; inline
 408
 409 INSTANCE: odds immutable-sequence
 410
 411 : until-empty ( seq quot -- )
 412     [ dup empty? ] swap until drop ; inline
 413
 414 : arg-max ( seq -- n )
 415     <enum> [ second-unsafe ] supremum-by first ;
 416
 417 : arg-min ( seq -- n )
 418     <enum> [ second-unsafe ] infimum-by first ;
 419
 420 <PRIVATE
 421
 422 : push-index-if ( ..a elt i quot: ( ..a elt -- ..b ? ) accum -- ..b )
 423     [ dip ] dip rot [ push ] [ 2drop ] if ; inline
 424
 425 PRIVATE>
 426
 427 : arg-where ( ... seq quot: ( ... elt -- ... ? ) -- ... indices )
 428     over length <vector> [
 429         [ push-index-if ] 2curry each-index
 430     ] keep ; inline
 431
 432 : arg-sort ( seq -- indices )
 433     zip-index sort-keys values ;
 434
 435 : first= ( seq elt -- ? ) [ first ] dip = ; inline
 436 : second= ( seq elt -- ? ) [ second ] dip = ; inline
 437 : third= ( seq elt -- ? ) [ third ] dip = ; inline
 438 : fourth= ( seq elt -- ? ) [ fourth ] dip = ; inline
 439 : last= ( seq elt -- ? ) [ last ] dip = ; inline
 440 : nth= ( n seq elt -- ? ) [ nth ] dip = ; inline
 441
 442 : first? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ first ] dip call ; inline
 443 : second? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ second ] dip call ; inline
 444 : third? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ third ] dip call ; inline
 445 : fourth? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ fourth ] dip call ; inline
 446 : last? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ last ] dip call ; inline
 447 : nth? ( ... n seq quot: ( ... elt -- ... ? ) -- ... ? ) [ nth ] dip call ; inline
 448
 449 : loop>sequence ( quot exemplar -- seq )
 450    [ '[ [ @ [ [ , ] when* ] keep ] loop ] ] dip make ; inline
 451
 452 : loop>array ( quot -- seq )
 453    { } loop>sequence ; inline
 454
 455 <PRIVATE
 456
 457 : (reverse) ( seq -- newseq )
 458     dup [ length ] keep new-sequence
 459     [ 0 swap copy-unsafe ] keep reverse! ;
 460
 461 PRIVATE>
 462
 463 : reverse-as ( seq exemplar -- newseq )
 464     [ (reverse) ] [ like ] bi* ;
 465
 466 : map-product ( ... seq quot: ( ... elt -- ... n ) -- ... n )
 467     [ 1 ] 2dip [ dip * ] curry [ swap ] prepose each ; inline
 468
 469 : insert-nth! ( elt n seq -- )
 470     [ length ] keep ensure swap pick (a,b]
 471     over '[ [ 1 + ] keep _ move-unsafe ] each
 472     set-nth-unsafe ;
 473
 474 : set-nths ( value indices seq -- )
 475     swapd '[ _ swap _ set-nth ] each ; inline
 476
 477 : set-nths-unsafe ( value indices seq -- )
 478     swapd '[ _ swap _ set-nth-unsafe ] each ; inline
 479
 480 : flatten1 ( obj -- seq )
 481     [
 482         [
 483             dup branch? [
 484                 [ dup branch? [ % ] [ , ] if ] each
 485             ] [ , ] if
 486         ]
 487     ] keep dup branch? [ drop f ] unless make ;
 488
 489 <PRIVATE
 490
 491 : (map-find-index) ( seq quot find-quot -- result i elt )
 492     [ [ f ] 2dip [ [ nip ] 2dip call dup ] curry ] dip call
 493     [ [ [ drop f ] unless ] keep ] dip ; inline
 494
 495 PRIVATE>
 496
 497 : map-find-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 498     [ find-index ] (map-find-index) ; inline
 499
 500 : filter-length ( seq n -- seq' ) '[ length _ = ] filter ;
 501
 502 : all-shortest ( seqs -- seqs' ) dup shortest length filter-length ;
 503
 504 : all-longest ( seqs -- seqs' ) dup longest length filter-length ;
 505
 506 : remove-first ( obj seq -- seq' )
 507     [ index ] keep over [ remove-nth ] [ nip ] if ;
 508
 509 : remove-first! ( obj seq -- seq )
 510     [ index ] keep over [ remove-nth! ] [ nip ] if ;
 511
 512 : remove-last ( obj seq -- seq' )
 513     [ last-index ] keep over [ remove-nth ] [ nip ] if ;
 514
 515 : remove-last! ( obj seq -- seq )
 516     [ last-index ] keep over [ remove-nth! ] [ nip ] if ;
 517
 518 : ?first2 ( seq -- first/f second/f )
 519     dup length {
 520         { 0 [ drop f f ] }
 521         { 1 [ first-unsafe f ] }
 522         [ drop first2-unsafe ]
 523     } case ;
 524
 525 : ?first3 ( seq -- first/f second/f third/f )
 526     dup length {
 527         { 0 [ drop f f f ] }
 528         { 1 [ first-unsafe f f ] }
 529         { 2 [ first2-unsafe f ] }
 530         [ drop first3-unsafe ]
 531     } case ;
 532
 533 : ?first4 ( seq -- first/f second/f third/f fourth/f )
 534     dup length {
 535         { 0 [ drop f f f f ] }
 536         { 1 [ first-unsafe f f f ] }
 537         { 2 [ first2-unsafe f f ] }
 538         { 3 [ first3-unsafe f ] }
 539         [ drop first4-unsafe ]
 540     } case ;
 541
 542 : cut-when ( ... seq quot: ( ... elt -- ... ? ) -- ... before after )
 543     [ find drop ] 2keep drop swap
 544     [ cut ] [ f over like ] if* ; inline
 545
 546 : nth* ( n seq -- elt )
 547     [ length 1 - swap - ] [ nth ] bi ; inline
 548
 549 : each-index-from ( ... seq quot: ( ... elt index -- ... ) i -- ... )
 550     -rot (each-index) (each-integer) ; inline
 551
 552 <PRIVATE
 553
 554 : select-by* ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... i elt )
 555     [
 556         [ keep swap ] curry [ dip ] curry
 557         [ [ first 0 ] dip call ] 2keep
 558         [ 2curry 3dip 5 npick pick ] curry
 559     ] [
 560         [ [ 3drop ] [ [ 3drop ] 3dip ] if ] compose
 561     ] bi* compose 1 each-index-from nip swap ; inline
 562
 563 PRIVATE>
 564
 565 : supremum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 566     [ after? ] select-by* ; inline
 567
 568 : infimum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 569     [ before? ] select-by* ; inline
 570
 571 : change-last ( seq quot -- )
 572     [ drop length 1 - ] [ change-nth ] 2bi ; inline
 573
 574 : change-last-unsafe ( seq quot -- )
 575     [ drop length 1 - ] [ change-nth-unsafe ] 2bi ; inline
 576
 577 : replicate-into ( ... seq quot: ( ... -- ... newelt ) -- ... )
 578     over [ length ] 2dip '[ _ dip _ set-nth-unsafe ] each-integer ; inline
 579
 580 : count* ( ... seq quot: ( ... elt -- ... ? ) -- ... % )
 581     over [ count ] [ length ] bi* / ; inline
 582
 583 : find-last-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 584     [ [ 1 - ] dip find-last-integer ] (find-index) ; inline
 585
 586 : map-find-last-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 587     [ find-last-index ] (map-find-index) ; inline
 588
 589 :: (start-all) ( subseq seq increment -- indices )
 590     0
 591     [ [ subseq seq ] dip start* dup ]
 592     [ [ increment + ] keep ] produce nip ;
 593
 594 : start-all ( subseq seq -- indices )
 595     over length (start-all) ; inline
 596
 597 : start-all* ( subseq seq -- indices )
 598     1 (start-all) ; inline
 599
 600 : count-subseq ( subseq seq -- n )
 601     start-all length ; inline
 602
 603 : count-subseq* ( subseq seq -- n )
 604     start-all* length ; inline
 605
 606 : map-zip ( quot: ( x -- y ) -- alist )
 607     '[ _ keep swap ] map>alist ; inline