extra/sequences/extras/extras.factor

   1 USING: accessors arrays assocs fry grouping growable kernel
   2 locals make math math.order math.ranges sequences
   3 sequences.deep sequences.private sorting splitting vectors ;
   4 FROM: sequences => change-nth ;
   5 IN: sequences.extras
   6
   7 : reduce1 ( seq quot -- result ) [ unclip ] dip reduce ; inline
   8
   9 :: reduce-r ( seq identity quot: ( obj1 obj2 -- obj ) -- result )
  10     seq [ identity ] [
  11         unclip [ identity quot reduce-r ] [ quot call ] bi*
  12     ] if-empty ; inline recursive
  13
  14 ! Quot must have static stack effect, unlike "reduce"
  15 :: reduce* ( seq identity quot: ( prev elt -- next ) -- result )
  16     seq [ identity ] [
  17         unclip identity swap quot call( prev elt -- next )
  18         quot reduce*
  19     ] if-empty ; inline recursive
  20
  21 :: combos ( list1 list2 -- result )
  22     list2 [ [ 2array ] curry list1 swap map ] map concat ;
  23
  24 : find-all ( seq quot: ( elt -- ? ) -- elts )
  25     [ [ length iota ] keep ] dip
  26     [ dupd call( a -- ? ) [ 2array ] [ 2drop f ] if ] curry
  27     2map [ ] filter ; inline
  28
  29 : insert-sorted ( elt seq -- seq )
  30     2dup [ < ] with find drop over length or swap insert-nth ;
  31
  32 : reduce-from ( ... seq identity quot: ( ... prev elt -- ... next ) i -- ... result )
  33     [ swap ] 2dip each-from ; inline
  34
  35 :: subseq* ( from to seq -- subseq )
  36     seq length :> len
  37     from [ dup 0 < [ len + ] when ] [ 0 ] if*
  38     to [ dup 0 < [ len + ] when ] [ len ] if*
  39     [ 0 len clamp ] bi@ dupd max seq subseq ;
  40
  41 : safe-subseq ( from to seq -- subseq )
  42     [ length '[ 0 _ clamp ] bi@ ] keep subseq ;
  43
  44 : all-subseqs ( seq -- seqs )
  45     dup length [1,b] [ clump ] with map concat ;
  46
  47 :: each-subseq ( ... seq quot: ( ... x -- ... ) -- ... )
  48     seq length :> len
  49     len [0,b] [
  50         :> from
  51         from len (a,b] [
  52             :> to
  53             from to seq subseq quot call
  54         ] each
  55     ] each ; inline
  56
  57 : subseq-as ( from to seq exemplar -- subseq )
  58     [ check-slice subseq>copy (copy) ] dip like ;
  59
  60 : map-like ( seq exemplar -- seq' )
  61     '[ _ like ] map ; inline
  62
  63 : filter-all-subseqs-range ( ... seq range quot: ( ... x -- ... ) -- seq )
  64     [
  65         '[ <clumps> _ filter ] with map concat
  66     ] 3keep 2drop map-like ; inline
  67
  68 : filter-all-subseqs ( ... seq quot: ( ... x -- ... ) -- seq )
  69     [ dup length [1,b] ] dip filter-all-subseqs-range ; inline
  70
  71 :: longest-subseq ( seq1 seq2 -- subseq )
  72     seq1 length :> len1
  73     seq2 length :> len2
  74     0 :> n!
  75     0 :> end!
  76     len1 1 + [ len2 1 + 0 <array> ] replicate :> table
  77     len1 [1,b] [| x |
  78         len2 [1,b] [| y |
  79             x 1 - seq1 nth-unsafe
  80             y 1 - seq2 nth-unsafe = [
  81                 y 1 - x 1 - table nth-unsafe nth-unsafe 1 + :> len
  82                 len y x table nth-unsafe set-nth-unsafe
  83                 len n > [ len n! x end! ] when
  84             ] [ 0 y x table nth-unsafe set-nth-unsafe ] if
  85         ] each
  86     ] each end n - end seq1 subseq ;
  87
  88 : pad-longest ( seq1 seq2 elt -- seq1 seq2 )
  89     [ 2dup max-length ] dip [ pad-tail ] 2curry bi@ ;
  90
  91 : change-nths ( ... indices seq quot: ( ... elt -- ... elt' ) -- ... )
  92     [ change-nth ] 2curry each ; inline
  93
  94 : push-if-index ( ..a elt i quot: ( ..a elt i -- ..b ? ) accum -- ..b )
  95     [ 2keep drop ] dip rot [ push ] [ 2drop ] if ; inline
  96
  97 <PRIVATE
  98
  99 : (index-selector-for) ( quot length exampler -- selector accum )
 100     new-resizable [ [ push-if-index ] 2curry ] keep ; inline
 101
 102 PRIVATE>
 103
 104 : index-selector-for ( quot exemplar -- selector accum )
 105     [ length ] keep (index-selector-for) ; inline
 106
 107 : index-selector ( quot -- selector accum )
 108     V{ } index-selector-for ; inline
 109
 110 : filter-index-as ( ... seq quot: ( ... elt i -- ... ? ) exemplar -- ... seq' )
 111     pick length over [ (index-selector-for) [ each-index ] dip ] 2curry dip like ; inline
 112
 113 : filter-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... seq' )
 114     over filter-index-as ; inline
 115
 116 : even-indices ( seq -- seq' )
 117     [ length 1 + 2/ ] keep [
 118         [ [ 2 * ] dip nth-unsafe ] curry
 119     ] keep map-integers ;
 120
 121 : odd-indices ( seq -- seq' )
 122     [ length 2/ ] keep [
 123         [ [ 2 * 1 + ] dip nth-unsafe ] curry
 124     ] keep map-integers ;
 125
 126 : compact ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 127     [ split-when harvest ] dip join ; inline
 128
 129 : collapse ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 130     [ split-when ] dip
 131     [ [ harvest ] dip join ]
 132     [ [ first empty? ] dip [ prepend ] curry when ]
 133     [ [ last empty? ] dip [ append ] curry when ]
 134     2tri ; inline
 135
 136 :: slice-when ( seq quot: ( elt -- ? ) -- seq' )
 137     seq length :> len
 138     0 [ len dupd < ] [
 139         dup seq quot find-from drop
 140         [ 2dup = [ 1 + ] when ] [ len ] if*
 141         [ seq <slice> ] keep len or swap
 142     ] produce nip ; inline
 143
 144 : cut-slice* ( seq n -- before after )
 145     [ head-slice* ] [ tail-slice* ] 2bi ;
 146
 147 : rotate ( seq n -- seq' )
 148     cut prepend ;
 149
 150 :: rotate! ( seq n -- )
 151     n seq bounds-check length :> end
 152     0 n [ 2dup = ] [
 153         [ seq exchange-unsafe ] [ [ 1 + ] bi@ ] 2bi
 154         dup end = [ drop over ] when
 155         2over = [ -rot nip over ] when
 156     ] until 3drop ;
 157
 158 : all-rotations ( seq -- seq' )
 159     dup length iota [ rotate ] with map ;
 160
 161 <PRIVATE
 162
 163 : (appender-for) ( quot length exemplar -- appender accum )
 164     new-resizable [ [ push-all ] curry compose ] keep ; inline
 165
 166 PRIVATE>
 167
 168 : appender-for ( quot exemplar -- appender accum )
 169     [ length ] keep (appender-for) ; inline
 170
 171 : appender ( quot -- appender accum )
 172     V{ } appender-for ; inline
 173
 174 : map-concat-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 175     [ appender-for [ each ] dip ] keep like ; inline
 176
 177 : >resizable ( seq -- accum ) ! fixes map-concat "cannot apply call to run-time..."
 178     [ length ] keep [ new-resizable ] [ over push-all ] bi ;
 179
 180 : map-concat ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 181     over empty? [ 2drop { } ] [
 182         [ [ first ] dip call ] 2keep rot dup [
 183             >resizable [ [ push-all ] curry compose ] keep
 184             [ 1 ] 3dip [ (each) (each-integer) ] dip
 185         ] curry dip like
 186     ] if ; inline
 187
 188 : map-filter-as ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) exemplar -- ... subseq )
 189     [ pick ] dip swap length over
 190     [ (selector-for) [ compose each ] dip ] 2curry dip like ; inline
 191
 192 : map-filter ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) -- ... subseq )
 193     pick map-filter-as ; inline
 194
 195 : map-sift ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 196     [ ] map-filter ; inline
 197
 198 : map-harvest ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 199     [ empty? not ] map-filter ; inline
 200
 201 <PRIVATE
 202
 203 : ((each-from)) ( i seq -- n quot )
 204     [ length over [-] swap ] keep '[ _ + _ nth-unsafe ] ; inline
 205
 206 : (each-from) ( i seq quot -- n quot' ) [ ((each-from)) ] dip compose ;
 207     inline
 208
 209 PRIVATE>
 210
 211 : map-from-as ( ... seq quot: ( ... elt -- ... newelt ) i exemplar -- ... newseq )
 212     [ -rot (each-from) ] dip map-integers ; inline
 213
 214 : map-from ( ... seq quot: ( ... elt -- ... newelt ) i -- ... newseq )
 215     pick map-from-as ; inline
 216
 217 <PRIVATE
 218
 219 : push-map-if ( ..a elt filter-quot: ( ..a elt -- ..b ? ) map-quot: ( ..a elt -- ..b newelt ) accum -- ..b )
 220     [ keep over ] 2dip [ when ] dip rot [ push ] [ 2drop ] if ; inline
 221
 222 : (filter-mapper-for) ( filter-quot map-quot length exempler -- filter-mapper accum )
 223     new-resizable [ [ push-map-if ] 3curry ] keep ; inline
 224
 225 : filter-mapper-for ( filter-quot map-quot exemplar -- filter-mapper accum )
 226     [ length ] keep (filter-mapper-for) ; inline
 227
 228 : filter-mapper ( filter-quot map-quot -- filter-mapper accum )
 229     V{ } filter-mapper-for ; inline
 230
 231 PRIVATE>
 232
 233 : filter-map-as ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 234     [ pick ] dip swap length over
 235     [ (filter-mapper-for) [ each ] dip ] 2curry dip like ; inline
 236
 237 : filter-map ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) -- ... newseq )
 238     pick filter-map-as ; inline
 239
 240 : 2map-sum ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... n ) -- ... n )
 241     [ 0 ] 3dip [ dip + ] curry [ rot ] prepose 2each ; inline
 242
 243 : 2count ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... n )
 244     [ 1 0 ? ] compose 2map-sum ; inline
 245
 246 : round-robin ( seq -- newseq )
 247     [ { } ] [
 248         [ longest length iota ] keep
 249         [ [ ?nth ] with map ] curry map concat sift
 250     ] if-empty ;
 251
 252 : sift-as ( seq exemplar -- newseq )
 253     [ ] swap filter-as ;
 254
 255 : sift! ( seq -- newseq )
 256     [ ] filter! ;
 257
 258 : harvest-as ( seq exemplar -- newseq )
 259     [ empty? not ] swap filter-as ;
 260
 261 : harvest! ( seq -- newseq )
 262     [ empty? not ] filter! ;
 263
 264 : contains? ( seq elts -- ? )
 265     [ member? ] curry any? ; inline
 266
 267 : head-as ( seq n exemplar -- seq' )
 268     [ head-slice ] [ like ] bi* ; inline
 269
 270 : head*-as ( seq n exemplar -- seq' )
 271     [ head-slice* ] [ like ] bi* ; inline
 272
 273 : tail-as ( seq n exemplar -- seq' )
 274     [ tail-slice ] [ like ] bi* ; inline
 275
 276 : tail*-as ( seq n exemplar -- seq' )
 277     [ tail-slice* ] [ like ] bi* ; inline
 278
 279 : trim-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... newseq )
 280     [ trim-slice ] [ like ] bi* ; inline
 281
 282 : ?trim ( seq quot: ( elt -- ? ) -- seq/newseq )
 283     over empty? [ drop ] [
 284         over [ first-unsafe ] [ last-unsafe ] bi pick bi@ or
 285         [ trim ] [ drop ] if
 286     ] if ; inline
 287
 288 : ?trim-head ( seq quot: ( elt -- ? ) -- seq/newseq )
 289     over empty? [ drop ] [
 290         over first-unsafe over call
 291         [ trim-head ] [ drop ] if
 292     ] if ; inline
 293
 294 : ?trim-tail ( seq quot: ( elt -- ? ) -- seq/newseq )
 295     over empty? [ drop ] [
 296         over last-unsafe over call
 297         [ trim-tail ] [ drop ] if
 298     ] if ; inline
 299
 300 : unsurround ( newseq seq2 seq3 -- seq1 )
 301    [ ?head drop ] [ ?tail drop ] bi* ;
 302
 303 : none? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 304     any? not ; inline
 305
 306 : one? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 307     [ find ] 2keep rot [
 308         [ 1 + ] 2dip find-from drop not
 309     ] [ 3drop f ] if ; inline
 310
 311 : map-index! ( ... seq quot: ( ... elt index -- ... newelt ) -- ... seq )
 312     over [ [ (each-index) ] dip collect ] keep ; inline
 313
 314 <PRIVATE
 315
 316 : (2each-index) ( seq1 seq2 quot -- n quot' )
 317     [ ((2each)) [ keep ] curry ] dip compose ; inline
 318
 319 PRIVATE>
 320
 321 : 2each-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... ) -- ... )
 322     (2each-index) each-integer ; inline
 323
 324 : 2map-into ( seq1 seq2 quot into -- )
 325     [ (2each) ] dip collect ; inline
 326
 327 : 2map! ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... seq1 )
 328     pick [ 2map-into ] keep ; inline
 329
 330 : 2map-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... newelt ) -- ... newseq )
 331     pick [ (2each-index) ] dip map-integers ; inline
 332
 333 TUPLE: evens seq length ;
 334
 335 : <evens> ( seq -- evens )
 336     dup length 1 + 2/ evens boa ; inline
 337
 338 M: evens length length>> ; inline
 339
 340 M: evens nth-unsafe [ 2 * ] [ seq>> nth-unsafe ] bi* ; inline
 341
 342 INSTANCE: evens immutable-sequence
 343
 344 TUPLE: odds seq length ;
 345
 346 : <odds> ( seq -- odds )
 347     dup length 2/ odds boa ; inline
 348
 349 M: odds length length>> ; inline
 350
 351 M: odds nth-unsafe [ 2 * 1 + ] [ seq>> nth-unsafe ] bi* ; inline
 352
 353 INSTANCE: odds immutable-sequence
 354
 355 : until-empty ( seq quot -- )
 356     [ dup empty? ] swap until drop ; inline
 357
 358 : arg-max ( seq -- n )
 359     <enum> [ second-unsafe ] supremum-by first ;
 360
 361 : arg-min ( seq -- n )
 362     <enum> [ second-unsafe ] infimum-by first ;
 363
 364 <PRIVATE
 365
 366 : push-index-if ( ..a elt i quot: ( ..a elt -- ..b ? ) accum -- ..b )
 367     [ dip ] dip rot [ push ] [ 2drop ] if ; inline
 368
 369 PRIVATE>
 370
 371 : arg-where ( ... seq quot: ( ... elt -- ... ? ) -- ... indices )
 372     over length <vector> [
 373         [ push-index-if ] 2curry each-index
 374     ] keep ; inline
 375
 376 : arg-sort ( seq -- indices )
 377     dup length iota zip sort-keys values ;
 378
 379 : first= ( seq elt -- ? ) [ first ] dip = ; inline
 380 : second= ( seq elt -- ? ) [ second ] dip = ; inline
 381 : third= ( seq elt -- ? ) [ third ] dip = ; inline
 382 : fourth= ( seq elt -- ? ) [ fourth ] dip = ; inline
 383 : last= ( seq elt -- ? ) [ last ] dip = ; inline
 384 : nth= ( n seq elt -- ? ) [ nth ] dip = ; inline
 385
 386 : first? ( seq quot -- ? ) [ first ] dip call ; inline
 387 : second? ( seq quot -- ? ) [ second ] dip call ; inline
 388 : third? ( seq quot -- ? ) [ third ] dip call ; inline
 389 : fourth? ( seq quot -- ? ) [ fourth ] dip call ; inline
 390 : last? ( seq quot -- ? ) [ last ] dip call ; inline
 391 : nth? ( n seq quot -- ? ) [ nth ] dip call ; inline
 392
 393 : loop>sequence ( quot exemplar -- seq )
 394    [ '[ [ @ [ [ , ] when* ] keep ] loop ] ] dip make ; inline
 395
 396 : loop>array ( quot -- seq )
 397    { } loop>sequence ; inline
 398
 399 <PRIVATE
 400
 401 : (reverse) ( seq -- newseq )
 402     dup [ length ] keep new-sequence
 403     [ 0 swap copy-unsafe ] keep reverse! ;
 404
 405 PRIVATE>
 406
 407 : reverse-as ( seq exemplar -- newseq )
 408     [ (reverse) ] [ like ] bi* ;
 409
 410 : map-product ( ... seq quot: ( ... elt -- ... n ) -- ... n )
 411     [ 1 ] 2dip [ dip * ] curry [ swap ] prepose each ; inline
 412
 413 : insert-nth! ( elt n seq -- )
 414     [ length ] keep ensure swap pick (a,b]
 415     over '[ [ 1 + ] keep _ move-unsafe ] each
 416     set-nth-unsafe ;
 417
 418 : set-nths ( value indices seq -- )
 419     swapd '[ [ _ ] dip _ set-nth ] each ; inline
 420
 421 : set-nths-unsafe ( value indices seq -- )
 422     swapd '[ [ _ ] dip _ set-nth-unsafe ] each ; inline
 423
 424 : flatten1 ( obj -- seq )
 425     [
 426         [
 427             dup branch? [
 428                 [ dup branch? [ % ] [ , ] if ] each
 429             ] [ , ] if
 430         ]
 431     ] keep dup branch? [ drop f ] unless make ;
 432
 433 <PRIVATE
 434
 435 : (map-find-index) ( seq quot find-quot -- result elt index )
 436     [ [ f ] 2dip [ [ nip ] 2dip call dup ] curry ] dip call
 437     [ [ [ drop f ] unless ] keep ] dip ; inline
 438
 439 PRIVATE>
 440
 441 : map-find-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result elt index )
 442     [ find-index ] (map-find-index) ; inline
 443
 444 : filter-length ( seq n -- seq' ) '[ length _ = ] filter ;
 445
 446 : all-shortest ( seqs -- seqs' ) dup shortest length filter-length ;
 447
 448 : all-longest ( seqs -- seqs' ) dup longest length filter-length ;
 449
 450 : remove-first ( obj seq -- seq' )
 451     [ index ] keep over [ remove-nth ] [ nip ] if ;
 452
 453 : remove-first! ( obj seq -- seq )
 454     [ index ] keep over [ remove-nth! ] [ nip ] if ;
 455
 456 : remove-last ( obj seq -- seq' )
 457     [ last-index ] keep over [ remove-nth ] [ nip ] if ;
 458
 459 : remove-last! ( obj seq -- seq )
 460     [ last-index ] keep over [ remove-nth! ] [ nip ] if ;