extra/sequences/extras/extras.factor

   1 USING: accessors arrays assocs combinators fry generalizations
   2 grouping growable kernel locals make math math.order math.ranges
   3 sequences sequences.deep sequences.private sorting splitting
   4 vectors ;
   5 IN: sequences.extras
   6
   7 : reduce1 ( seq quot -- result ) [ unclip ] dip reduce ; inline
   8
   9 :: reduce-r ( seq identity quot: ( obj1 obj2 -- obj ) -- result )
  10     seq [ identity ] [
  11         unclip [ identity quot reduce-r ] [ quot call ] bi*
  12     ] if-empty ; inline recursive
  13
  14 ! Quot must have static stack effect, unlike "reduce"
  15 :: reduce* ( seq identity quot: ( prev elt -- next ) -- result )
  16     seq [ identity ] [
  17         unclip identity swap quot call( prev elt -- next )
  18         quot reduce*
  19     ] if-empty ; inline recursive
  20
  21 :: combos ( list1 list2 -- result )
  22     list2 [ [ 2array ] curry list1 swap map ] map concat ;
  23
  24 : find-all ( seq quot: ( elt -- ? ) -- elts )
  25     [ [ length iota ] keep ] dip
  26     [ dupd call( a -- ? ) [ 2array ] [ 2drop f ] if ] curry
  27     2map sift ; inline
  28
  29 : reduce-from ( ... seq identity quot: ( ... prev elt -- ... next ) i -- ... result )
  30     [ swap ] 2dip each-from ; inline
  31
  32 :: subseq* ( from to seq -- subseq )
  33     seq length :> len
  34     from [ dup 0 < [ len + ] when ] [ 0 ] if*
  35     to [ dup 0 < [ len + ] when ] [ len ] if*
  36     [ 0 len clamp ] bi@ dupd max seq subseq ;
  37
  38 : safe-subseq ( from to seq -- subseq )
  39     [ length '[ 0 _ clamp ] bi@ ] keep subseq ;
  40
  41 : all-subseqs ( seq -- seqs )
  42     dup length [1,b] [ clump ] with map concat ;
  43
  44 :: each-subseq ( ... seq quot: ( ... x -- ... ) -- ... )
  45     seq length :> len
  46     len [0,b] [
  47         :> from
  48         from len (a,b] [
  49             :> to
  50             from to seq subseq quot call
  51         ] each
  52     ] each ; inline
  53
  54 : map-like ( seq exemplar -- seq' )
  55     '[ _ like ] map ; inline
  56
  57 : filter-all-subseqs-range ( ... seq range quot: ( ... x -- ... ) -- seq )
  58     [
  59         '[ <clumps> _ filter ] with map concat
  60     ] 3keep 2drop map-like ; inline
  61
  62 : filter-all-subseqs ( ... seq quot: ( ... x -- ... ) -- seq )
  63     [ dup length [1,b] ] dip filter-all-subseqs-range ; inline
  64
  65 :: longest-subseq ( seq1 seq2 -- subseq )
  66     seq1 length :> len1
  67     seq2 length :> len2
  68     0 :> n!
  69     0 :> end!
  70     len1 1 + [ len2 1 + 0 <array> ] replicate :> table
  71     len1 [1,b] [| x |
  72         len2 [1,b] [| y |
  73             x 1 - seq1 nth-unsafe
  74             y 1 - seq2 nth-unsafe = [
  75                 y 1 - x 1 - table nth-unsafe nth-unsafe 1 + :> len
  76                 len y x table nth-unsafe set-nth-unsafe
  77                 len n > [ len n! x end! ] when
  78             ] [ 0 y x table nth-unsafe set-nth-unsafe ] if
  79         ] each
  80     ] each end n - end seq1 subseq ;
  81
  82 : pad-longest ( seq1 seq2 elt -- seq1 seq2 )
  83     [ 2dup max-length ] dip [ pad-tail ] 2curry bi@ ;
  84
  85 : change-nths ( ... indices seq quot: ( ... elt -- ... elt' ) -- ... )
  86     [ change-nth ] 2curry each ; inline
  87
  88 : push-if-index ( ..a elt i quot: ( ..a elt i -- ..b ? ) accum -- ..b )
  89     [ 2keep drop ] dip rot [ push ] [ 2drop ] if ; inline
  90
  91 : push-if* ( ..a elt quot: ( ..a elt -- ..b obj/f ) accum -- ..b )
  92     [ call ] dip [ push ] [ drop ] if* ; inline
  93
  94 <PRIVATE
  95
  96 : (index-selector-for) ( quot length exampler -- selector accum )
  97     new-resizable [ [ push-if-index ] 2curry ] keep ; inline
  98
  99 : (selector-for*) ( quot length exemplar -- selector accum )
 100     new-resizable [ [ push-if* ] 2curry ] keep ; inline
 101
 102 PRIVATE>
 103
 104 : index-selector-for ( quot exemplar -- selector accum )
 105     [ length ] keep (index-selector-for) ; inline
 106
 107 : index-selector ( quot -- selector accum )
 108     V{ } index-selector-for ; inline
 109
 110 : selector-for* ( quot exemplar -- selector accum )
 111     [ length ] keep (selector-for*) ; inline
 112
 113 : selector* ( quot -- selector accum ) V{ } selector-for* ; inline
 114
 115 : filter-index-as ( ... seq quot: ( ... elt i -- ... ? ) exemplar -- ... seq' )
 116     pick length over [ (index-selector-for) [ each-index ] dip ] 2curry dip like ; inline
 117
 118 : filter-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... seq' )
 119     over filter-index-as ; inline
 120
 121 : even-indices ( seq -- seq' )
 122     [ length 1 + 2/ ] keep [
 123         [ [ 2 * ] dip nth-unsafe ] curry
 124     ] keep map-integers ;
 125
 126 : odd-indices ( seq -- seq' )
 127     [ length 2/ ] keep [
 128         [ [ 2 * 1 + ] dip nth-unsafe ] curry
 129     ] keep map-integers ;
 130
 131 : compact ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 132     [ split-when harvest ] dip join ; inline
 133
 134 : collapse ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 135     [ split-when ] dip
 136     [ [ harvest ] dip join ]
 137     [ [ first empty? ] dip [ prepend ] curry when ]
 138     [ [ last empty? ] dip [ append ] curry when ]
 139     2tri ; inline
 140
 141 :: slice-when ( seq quot: ( elt -- ? ) -- seq' )
 142     seq length :> len
 143     0 [ len dupd < ] [
 144         dup seq quot find-from drop
 145         [ 2dup = [ 1 + ] when ] [ len ] if*
 146         [ seq <slice> ] keep len or swap
 147     ] produce nip ; inline
 148
 149 : cut-slice* ( seq n -- before after )
 150     [ head-slice* ] [ tail-slice* ] 2bi ;
 151
 152 : ?<slice> ( from/f to/f sequence -- slice )
 153     [ [ 0 ] unless* ] 2dip
 154     over [ nip [ length ] [ ] bi ] unless
 155     <slice> ; inline
 156
 157 : sequence>slice ( sequence -- slice )
 158     [ drop 0 ] [ length ] [ ] tri <slice> ; inline
 159
 160 : slice-order-by-from ( slice1 slice2 -- slice-lt slice-gt )
 161     2dup [ from>> ] bi@ > [ swap ] when ; inline
 162
 163 : ordered-slices-range ( slice-lt slice-gt -- to from )
 164     [ to>> ] [ from>> ] bi* ;
 165
 166 : unordered-slices-range ( slice1 slice2 -- to from )
 167     slice-order-by-from ordered-slices-range ;
 168
 169 : ordered-slices-overlap? ( slice-lt slice-gt -- ? )
 170     ordered-slices-range > ; inline
 171
 172 : unordered-slices-overlap? ( slice1 slice2 -- ? )
 173     unordered-slices-range > ; inline
 174
 175 : slices-overlap? ( slice1 slice2 -- ? )
 176     unordered-slices-overlap? ;
 177
 178 : ordered-slices-touch? ( slice-lt slice-gt -- ? )
 179     ordered-slices-range >= ; inline
 180
 181 : unordered-slices-touch? ( slice1 slice2 -- ? )
 182     unordered-slices-range >= ; inline
 183
 184 : slices-touch? ( slice1 slice2 -- ? )
 185     unordered-slices-touch? ;
 186
 187 ERROR: slices-don't-touch slice1 slice2 ;
 188
 189 : merge-slices ( slice1 slice2 -- slice/* )
 190     slice-order-by-from
 191     2dup ordered-slices-touch? [
 192         [ from>> ] [ [ to>> ] [ seq>> ] bi ] bi* <slice>
 193     ] [
 194         slices-don't-touch
 195     ] if ;
 196
 197 : rotate ( seq n -- seq' )
 198     over length mod dup 0 >= [ cut ] [ abs cut* ] if prepend ;
 199
 200 ERROR: underlying-mismatch slice1 slice2 ;
 201 : ensure-same-underlying ( slice1 slice2 -- slice1 slice2 )
 202     2dup [ seq>> ] bi@ eq? [ underlying-mismatch ] unless ;
 203
 204 : span-slices ( slice1 slice2 -- slice )
 205     ensure-same-underlying
 206     [ [ from>> ] bi@ min ]
 207     [ [ to>> ] bi@ max ]
 208     [ drop seq>> ] 2tri <slice> ;
 209
 210 : ?span-slices ( slice1/f slice2/f -- slice )
 211     2dup and [ span-slices ] [ or ] if ;
 212
 213 :: rotate! ( seq n -- )
 214     seq length :> len
 215     n len mod dup 0 < [ len + ] when seq bounds-check drop 0 over
 216     [ 2dup = ] [
 217         [ seq exchange-unsafe ] [ [ 1 + ] bi@ ] 2bi
 218         dup len = [ drop over ] when
 219         2over = [ -rot nip over ] when
 220     ] until 3drop ;
 221
 222 : all-rotations ( seq -- seq' )
 223     dup length iota [ rotate ] with map ;
 224
 225 <PRIVATE
 226
 227 : (appender-for) ( quot length exemplar -- appender accum )
 228     new-resizable [ [ push-all ] curry compose ] keep ; inline
 229
 230 PRIVATE>
 231
 232 : appender-for ( quot exemplar -- appender accum )
 233     [ length ] keep (appender-for) ; inline
 234
 235 : appender ( quot -- appender accum )
 236     V{ } appender-for ; inline
 237
 238 : map-concat-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 239     [ appender-for [ each ] dip ] keep like ; inline
 240
 241 : >resizable ( seq -- accum ) ! fixes map-concat "cannot apply call to run-time..."
 242     [ length ] keep [ new-resizable ] [ append! ] bi ;
 243
 244 : map-concat ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 245     over empty? [ 2drop { } ] [
 246         [ [ first ] dip call ] 2keep rot dup [
 247             >resizable [ [ push-all ] curry compose ] keep
 248             [ 1 ] 3dip [ setup-each (each-integer) ] dip
 249         ] curry dip like
 250     ] if ; inline
 251
 252 : map-filter-as ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) exemplar -- ... subseq )
 253     [ pick ] dip swap length over
 254     [ (selector-for) [ compose each ] dip ] 2curry dip like ; inline
 255
 256 : map-filter ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) -- ... subseq )
 257     pick map-filter-as ; inline
 258
 259 : map-sift ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 260     [ ] map-filter ; inline
 261
 262 : map-harvest ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 263     [ empty? not ] map-filter ; inline
 264
 265 <PRIVATE
 266
 267 : (setup-each-from) ( i seq -- n quot )
 268     [ length over [-] swap ] keep '[ _ + _ nth-unsafe ] ; inline
 269
 270 : setup-each-from ( i seq quot -- n quot' )
 271     [ (setup-each-from) ] dip compose ; inline
 272
 273 PRIVATE>
 274
 275 : map-from-as ( ... seq quot: ( ... elt -- ... newelt ) i exemplar -- ... newseq )
 276     [ -rot setup-each-from ] dip map-integers ; inline
 277
 278 : map-from ( ... seq quot: ( ... elt -- ... newelt ) i -- ... newseq )
 279     pick map-from-as ; inline
 280
 281 <PRIVATE
 282
 283 : push-map-if ( ..a elt filter-quot: ( ..a elt -- ..b ? ) map-quot: ( ..a elt -- ..b newelt ) accum -- ..b )
 284     [ keep over ] 2dip [ when ] dip rot [ push ] [ 2drop ] if ; inline
 285
 286 : (filter-mapper-for) ( filter-quot map-quot length exempler -- filter-mapper accum )
 287     new-resizable [ [ push-map-if ] 3curry ] keep ; inline
 288
 289 : filter-mapper-for ( filter-quot map-quot exemplar -- filter-mapper accum )
 290     [ length ] keep (filter-mapper-for) ; inline
 291
 292 : filter-mapper ( filter-quot map-quot -- filter-mapper accum )
 293     V{ } filter-mapper-for ; inline
 294
 295 PRIVATE>
 296
 297 : filter-map-as ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 298     [ pick ] dip swap length over
 299     [ (filter-mapper-for) [ each ] dip ] 2curry dip like ; inline
 300
 301 : filter-map ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) -- ... newseq )
 302     pick filter-map-as ; inline
 303
 304 : 2map-sum ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... n ) -- ... n )
 305     [ 0 ] 3dip [ dip + ] curry [ rot ] prepose 2each ; inline
 306
 307 : 2count ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... n )
 308     [ 1 0 ? ] compose 2map-sum ; inline
 309
 310 : round-robin ( seq -- newseq )
 311     [ { } ] [
 312         [ longest length iota ] keep
 313         [ [ ?nth ] with map ] curry map concat sift
 314     ] if-empty ;
 315
 316 : sift-as ( seq exemplar -- newseq )
 317     [ ] swap filter-as ;
 318
 319 : sift! ( seq -- newseq )
 320     [ ] filter! ;
 321
 322 : harvest-as ( seq exemplar -- newseq )
 323     [ empty? not ] swap filter-as ;
 324
 325 : harvest! ( seq -- newseq )
 326     [ empty? ] reject! ;
 327
 328 : head-as ( seq n exemplar -- seq' )
 329     [ head-slice ] [ like ] bi* ; inline
 330
 331 : head*-as ( seq n exemplar -- seq' )
 332     [ head-slice* ] [ like ] bi* ; inline
 333
 334 : tail-as ( seq n exemplar -- seq' )
 335     [ tail-slice ] [ like ] bi* ; inline
 336
 337 : tail*-as ( seq n exemplar -- seq' )
 338     [ tail-slice* ] [ like ] bi* ; inline
 339
 340 : trim-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... newseq )
 341     [ trim-slice ] [ like ] bi* ; inline
 342
 343 : ?trim ( seq quot: ( elt -- ? ) -- seq/newseq )
 344     over empty? [ drop ] [
 345         over [ first-unsafe ] [ last-unsafe ] bi pick either?
 346         [ trim ] [ drop ] if
 347     ] if ; inline
 348
 349 : ?trim-head ( seq quot: ( elt -- ? ) -- seq/newseq )
 350     over empty? [ drop ] [
 351         over first-unsafe over call
 352         [ trim-head ] [ drop ] if
 353     ] if ; inline
 354
 355 : ?trim-tail ( seq quot: ( elt -- ? ) -- seq/newseq )
 356     over empty? [ drop ] [
 357         over last-unsafe over call
 358         [ trim-tail ] [ drop ] if
 359     ] if ; inline
 360
 361 : unsurround ( newseq seq2 seq3 -- seq1 )
 362    [ ?head drop ] [ ?tail drop ] bi* ;
 363
 364 : none? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 365     any? not ; inline
 366
 367 : one? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 368     [ find ] 2keep rot [
 369         [ 1 + ] 2dip find-from drop not
 370     ] [ 3drop f ] if ; inline
 371
 372 : map-index! ( ... seq quot: ( ... elt index -- ... newelt ) -- ... seq )
 373     over [ [ (each-index) ] dip collect ] keep ; inline
 374
 375 <PRIVATE
 376
 377 : (2each-index) ( seq1 seq2 quot -- n quot' )
 378     [ setup-2each [ keep ] curry ] dip compose ; inline
 379
 380 PRIVATE>
 381
 382 : 2each-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... ) -- ... )
 383     (2each-index) each-integer ; inline
 384
 385 : 2map-into ( seq1 seq2 quot into -- )
 386     [ (2each) ] dip collect ; inline
 387
 388 : 2map! ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... seq1 )
 389     pick [ 2map-into ] keep ; inline
 390
 391 : 2map-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... newelt ) -- ... newseq )
 392     pick [ (2each-index) ] dip map-integers ; inline
 393
 394 TUPLE: evens seq length ;
 395
 396 : <evens> ( seq -- evens )
 397     dup length 1 + 2/ evens boa ; inline
 398
 399 M: evens length length>> ; inline
 400
 401 M: evens nth-unsafe [ 2 * ] [ seq>> nth-unsafe ] bi* ; inline
 402
 403 INSTANCE: evens immutable-sequence
 404
 405 TUPLE: odds seq length ;
 406
 407 : <odds> ( seq -- odds )
 408     dup length 2/ odds boa ; inline
 409
 410 M: odds length length>> ; inline
 411
 412 M: odds nth-unsafe [ 2 * 1 + ] [ seq>> nth-unsafe ] bi* ; inline
 413
 414 INSTANCE: odds immutable-sequence
 415
 416 : until-empty ( seq quot -- )
 417     [ dup empty? ] swap until drop ; inline
 418
 419 : arg-max ( seq -- n )
 420     <enum> [ second-unsafe ] supremum-by first ;
 421
 422 : arg-min ( seq -- n )
 423     <enum> [ second-unsafe ] infimum-by first ;
 424
 425 <PRIVATE
 426
 427 : push-index-if ( ..a elt i quot: ( ..a elt -- ..b ? ) accum -- ..b )
 428     [ dip ] dip rot [ push ] [ 2drop ] if ; inline
 429
 430 PRIVATE>
 431
 432 : arg-where ( ... seq quot: ( ... elt -- ... ? ) -- ... indices )
 433     over length <vector> [
 434         [ push-index-if ] 2curry each-index
 435     ] keep ; inline
 436
 437 : arg-sort ( seq -- indices )
 438     zip-index sort-keys values ;
 439
 440 : first= ( seq elt -- ? ) [ first ] dip = ; inline
 441 : second= ( seq elt -- ? ) [ second ] dip = ; inline
 442 : third= ( seq elt -- ? ) [ third ] dip = ; inline
 443 : fourth= ( seq elt -- ? ) [ fourth ] dip = ; inline
 444 : last= ( seq elt -- ? ) [ last ] dip = ; inline
 445 : nth= ( n seq elt -- ? ) [ nth ] dip = ; inline
 446
 447 : first? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ first ] dip call ; inline
 448 : second? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ second ] dip call ; inline
 449 : third? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ third ] dip call ; inline
 450 : fourth? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ fourth ] dip call ; inline
 451 : last? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ last ] dip call ; inline
 452 : nth? ( ... n seq quot: ( ... elt -- ... ? ) -- ... ? ) [ nth ] dip call ; inline
 453
 454 : loop>sequence ( quot exemplar -- seq )
 455    [ '[ [ @ [ [ , ] when* ] keep ] loop ] ] dip make ; inline
 456
 457 : loop>array ( quot -- seq )
 458    { } loop>sequence ; inline
 459
 460 <PRIVATE
 461
 462 : (reverse) ( seq -- newseq )
 463     dup [ length ] keep new-sequence
 464     [ 0 swap copy-unsafe ] keep reverse! ;
 465
 466 PRIVATE>
 467
 468 : reverse-as ( seq exemplar -- newseq )
 469     [ (reverse) ] [ like ] bi* ;
 470
 471 : map-product ( ... seq quot: ( ... elt -- ... n ) -- ... n )
 472     [ 1 ] 2dip [ dip * ] curry [ swap ] prepose each ; inline
 473
 474 : insert-nth! ( elt n seq -- )
 475     [ length ] keep ensure swap pick (a,b]
 476     over '[ [ 1 + ] keep _ move-unsafe ] each
 477     set-nth-unsafe ;
 478
 479 : set-nths ( value indices seq -- )
 480     swapd '[ _ swap _ set-nth ] each ; inline
 481
 482 : set-nths-unsafe ( value indices seq -- )
 483     swapd '[ _ swap _ set-nth-unsafe ] each ; inline
 484
 485 : flatten1 ( obj -- seq )
 486     [
 487         [
 488             dup branch? [
 489                 [ dup branch? [ % ] [ , ] if ] each
 490             ] [ , ] if
 491         ]
 492     ] keep dup branch? [ drop f ] unless make ;
 493
 494 <PRIVATE
 495
 496 : (map-find-index) ( seq quot find-quot -- result i elt )
 497     [ [ f ] 2dip [ [ nip ] 2dip call dup ] curry ] dip call
 498     [ [ [ drop f ] unless ] keep ] dip ; inline
 499
 500 PRIVATE>
 501
 502 : map-find-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 503     [ find-index ] (map-find-index) ; inline
 504
 505 : filter-length ( seq n -- seq' ) '[ length _ = ] filter ;
 506
 507 : all-shortest ( seqs -- seqs' ) dup shortest length filter-length ;
 508
 509 : all-longest ( seqs -- seqs' ) dup longest length filter-length ;
 510
 511 : remove-first ( obj seq -- seq' )
 512     [ index ] keep over [ remove-nth ] [ nip ] if ;
 513
 514 : remove-first! ( obj seq -- seq )
 515     [ index ] keep over [ remove-nth! ] [ nip ] if ;
 516
 517 : remove-last ( obj seq -- seq' )
 518     [ last-index ] keep over [ remove-nth ] [ nip ] if ;
 519
 520 : remove-last! ( obj seq -- seq )
 521     [ last-index ] keep over [ remove-nth! ] [ nip ] if ;
 522
 523 : ?first2 ( seq -- first/f second/f )
 524     dup length {
 525         { 0 [ drop f f ] }
 526         { 1 [ first-unsafe f ] }
 527         [ drop first2-unsafe ]
 528     } case ;
 529
 530 : ?first3 ( seq -- first/f second/f third/f )
 531     dup length {
 532         { 0 [ drop f f f ] }
 533         { 1 [ first-unsafe f f ] }
 534         { 2 [ first2-unsafe f ] }
 535         [ drop first3-unsafe ]
 536     } case ;
 537
 538 : ?first4 ( seq -- first/f second/f third/f fourth/f )
 539     dup length {
 540         { 0 [ drop f f f f ] }
 541         { 1 [ first-unsafe f f f ] }
 542         { 2 [ first2-unsafe f f ] }
 543         { 3 [ first3-unsafe f ] }
 544         [ drop first4-unsafe ]
 545     } case ;
 546
 547 : cut-when ( ... seq quot: ( ... elt -- ... ? ) -- ... before after )
 548     [ find drop ] 2keep drop swap
 549     [ cut ] [ f over like ] if* ; inline
 550
 551 : nth* ( n seq -- elt )
 552     [ length 1 - swap - ] [ nth ] bi ; inline
 553
 554 : each-index-from ( ... seq quot: ( ... elt index -- ... ) i -- ... )
 555     -rot (each-index) (each-integer) ; inline
 556
 557 <PRIVATE
 558
 559 : select-by* ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... i elt )
 560     [
 561         [ keep swap ] curry [ dip ] curry
 562         [ [ first 0 ] dip call ] 2keep
 563         [ 2curry 3dip 5 npick pick ] curry
 564     ] [
 565         [ [ 3drop ] [ [ 3drop ] 3dip ] if ] compose
 566     ] bi* compose 1 each-index-from nip swap ; inline
 567
 568 PRIVATE>
 569
 570 : supremum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 571     [ after? ] select-by* ; inline
 572
 573 : infimum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 574     [ before? ] select-by* ; inline
 575
 576 : change-last ( seq quot -- )
 577     [ drop length 1 - ] [ change-nth ] 2bi ; inline
 578
 579 : change-last-unsafe ( seq quot -- )
 580     [ drop length 1 - ] [ change-nth-unsafe ] 2bi ; inline
 581
 582 : replicate-into ( ... seq quot: ( ... -- ... newelt ) -- ... )
 583     over [ length ] 2dip '[ _ dip _ set-nth-unsafe ] each-integer ; inline
 584
 585 : count* ( ... seq quot: ( ... elt -- ... ? ) -- ... % )
 586     over [ count ] [ length ] bi* / ; inline
 587
 588 : find-last-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 589     [ [ 1 - ] dip find-last-integer ] (find-index) ; inline
 590
 591 : map-find-last-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 592     [ find-last-index ] (map-find-index) ; inline
 593
 594 :: (start-all) ( subseq seq increment -- indices )
 595     0
 596     [ [ subseq seq ] dip start* dup ]
 597     [ [ increment + ] keep ] produce nip ;
 598
 599 : start-all ( subseq seq -- indices )
 600     over length (start-all) ; inline
 601
 602 : start-all* ( subseq seq -- indices )
 603     1 (start-all) ; inline
 604
 605 : count-subseq ( subseq seq -- n )
 606     start-all length ; inline
 607
 608 : count-subseq* ( subseq seq -- n )
 609     start-all* length ; inline
 610
 611 : map-zip ( quot: ( x -- y ) -- alist )
 612     '[ _ keep swap ] map>alist ; inline