extra/sequences/extras/extras.factor

   1 USING: accessors arrays assocs combinators fry generalizations
   2 grouping growable kernel locals make math math.order math.ranges
   3 sequences sequences.deep sequences.private sorting splitting
   4 vectors ;
   5 FROM: sequences => change-nth ;
   6 IN: sequences.extras
   7
   8 : reduce1 ( seq quot -- result ) [ unclip ] dip reduce ; inline
   9
  10 :: reduce-r ( seq identity quot: ( obj1 obj2 -- obj ) -- result )
  11     seq [ identity ] [
  12         unclip [ identity quot reduce-r ] [ quot call ] bi*
  13     ] if-empty ; inline recursive
  14
  15 ! Quot must have static stack effect, unlike "reduce"
  16 :: reduce* ( seq identity quot: ( prev elt -- next ) -- result )
  17     seq [ identity ] [
  18         unclip identity swap quot call( prev elt -- next )
  19         quot reduce*
  20     ] if-empty ; inline recursive
  21
  22 :: combos ( list1 list2 -- result )
  23     list2 [ [ 2array ] curry list1 swap map ] map concat ;
  24
  25 : find-all ( seq quot: ( elt -- ? ) -- elts )
  26     [ [ length iota ] keep ] dip
  27     [ dupd call( a -- ? ) [ 2array ] [ 2drop f ] if ] curry
  28     2map [ ] filter ; inline
  29
  30 : insert-sorted ( elt seq -- seq )
  31     2dup [ < ] with find drop over length or swap insert-nth ;
  32
  33 : reduce-from ( ... seq identity quot: ( ... prev elt -- ... next ) i -- ... result )
  34     [ swap ] 2dip each-from ; inline
  35
  36 :: subseq* ( from to seq -- subseq )
  37     seq length :> len
  38     from [ dup 0 < [ len + ] when ] [ 0 ] if*
  39     to [ dup 0 < [ len + ] when ] [ len ] if*
  40     [ 0 len clamp ] bi@ dupd max seq subseq ;
  41
  42 : safe-subseq ( from to seq -- subseq )
  43     [ length '[ 0 _ clamp ] bi@ ] keep subseq ;
  44
  45 : all-subseqs ( seq -- seqs )
  46     dup length [1,b] [ clump ] with map concat ;
  47
  48 :: each-subseq ( ... seq quot: ( ... x -- ... ) -- ... )
  49     seq length :> len
  50     len [0,b] [
  51         :> from
  52         from len (a,b] [
  53             :> to
  54             from to seq subseq quot call
  55         ] each
  56     ] each ; inline
  57
  58 : subseq-as ( from to seq exemplar -- subseq )
  59     [ check-slice subseq>copy (copy) ] dip like ;
  60
  61 : map-like ( seq exemplar -- seq' )
  62     '[ _ like ] map ; inline
  63
  64 : filter-all-subseqs-range ( ... seq range quot: ( ... x -- ... ) -- seq )
  65     [
  66         '[ <clumps> _ filter ] with map concat
  67     ] 3keep 2drop map-like ; inline
  68
  69 : filter-all-subseqs ( ... seq quot: ( ... x -- ... ) -- seq )
  70     [ dup length [1,b] ] dip filter-all-subseqs-range ; inline
  71
  72 :: longest-subseq ( seq1 seq2 -- subseq )
  73     seq1 length :> len1
  74     seq2 length :> len2
  75     0 :> n!
  76     0 :> end!
  77     len1 1 + [ len2 1 + 0 <array> ] replicate :> table
  78     len1 [1,b] [| x |
  79         len2 [1,b] [| y |
  80             x 1 - seq1 nth-unsafe
  81             y 1 - seq2 nth-unsafe = [
  82                 y 1 - x 1 - table nth-unsafe nth-unsafe 1 + :> len
  83                 len y x table nth-unsafe set-nth-unsafe
  84                 len n > [ len n! x end! ] when
  85             ] [ 0 y x table nth-unsafe set-nth-unsafe ] if
  86         ] each
  87     ] each end n - end seq1 subseq ;
  88
  89 : pad-longest ( seq1 seq2 elt -- seq1 seq2 )
  90     [ 2dup max-length ] dip [ pad-tail ] 2curry bi@ ;
  91
  92 : change-nths ( ... indices seq quot: ( ... elt -- ... elt' ) -- ... )
  93     [ change-nth ] 2curry each ; inline
  94
  95 : push-if-index ( ..a elt i quot: ( ..a elt i -- ..b ? ) accum -- ..b )
  96     [ 2keep drop ] dip rot [ push ] [ 2drop ] if ; inline
  97
  98 <PRIVATE
  99
 100 : (index-selector-for) ( quot length exampler -- selector accum )
 101     new-resizable [ [ push-if-index ] 2curry ] keep ; inline
 102
 103 PRIVATE>
 104
 105 : index-selector-for ( quot exemplar -- selector accum )
 106     [ length ] keep (index-selector-for) ; inline
 107
 108 : index-selector ( quot -- selector accum )
 109     V{ } index-selector-for ; inline
 110
 111 : filter-index-as ( ... seq quot: ( ... elt i -- ... ? ) exemplar -- ... seq' )
 112     pick length over [ (index-selector-for) [ each-index ] dip ] 2curry dip like ; inline
 113
 114 : filter-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... seq' )
 115     over filter-index-as ; inline
 116
 117 : even-indices ( seq -- seq' )
 118     [ length 1 + 2/ ] keep [
 119         [ [ 2 * ] dip nth-unsafe ] curry
 120     ] keep map-integers ;
 121
 122 : odd-indices ( seq -- seq' )
 123     [ length 2/ ] keep [
 124         [ [ 2 * 1 + ] dip nth-unsafe ] curry
 125     ] keep map-integers ;
 126
 127 : compact ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 128     [ split-when harvest ] dip join ; inline
 129
 130 : collapse ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 131     [ split-when ] dip
 132     [ [ harvest ] dip join ]
 133     [ [ first empty? ] dip [ prepend ] curry when ]
 134     [ [ last empty? ] dip [ append ] curry when ]
 135     2tri ; inline
 136
 137 :: slice-when ( seq quot: ( elt -- ? ) -- seq' )
 138     seq length :> len
 139     0 [ len dupd < ] [
 140         dup seq quot find-from drop
 141         [ 2dup = [ 1 + ] when ] [ len ] if*
 142         [ seq <slice> ] keep len or swap
 143     ] produce nip ; inline
 144
 145 : cut-slice* ( seq n -- before after )
 146     [ head-slice* ] [ tail-slice* ] 2bi ;
 147
 148 : rotate ( seq n -- seq' )
 149     cut prepend ;
 150
 151 :: rotate! ( seq n -- )
 152     n seq bounds-check length :> end
 153     0 n [ 2dup = ] [
 154         [ seq exchange-unsafe ] [ [ 1 + ] bi@ ] 2bi
 155         dup end = [ drop over ] when
 156         2over = [ -rot nip over ] when
 157     ] until 3drop ;
 158
 159 : all-rotations ( seq -- seq' )
 160     dup length iota [ rotate ] with map ;
 161
 162 <PRIVATE
 163
 164 : (appender-for) ( quot length exemplar -- appender accum )
 165     new-resizable [ [ push-all ] curry compose ] keep ; inline
 166
 167 PRIVATE>
 168
 169 : appender-for ( quot exemplar -- appender accum )
 170     [ length ] keep (appender-for) ; inline
 171
 172 : appender ( quot -- appender accum )
 173     V{ } appender-for ; inline
 174
 175 : map-concat-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 176     [ appender-for [ each ] dip ] keep like ; inline
 177
 178 : >resizable ( seq -- accum ) ! fixes map-concat "cannot apply call to run-time..."
 179     [ length ] keep [ new-resizable ] [ over push-all ] bi ;
 180
 181 : map-concat ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 182     over empty? [ 2drop { } ] [
 183         [ [ first ] dip call ] 2keep rot dup [
 184             >resizable [ [ push-all ] curry compose ] keep
 185             [ 1 ] 3dip [ (each) (each-integer) ] dip
 186         ] curry dip like
 187     ] if ; inline
 188
 189 : map-filter-as ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) exemplar -- ... subseq )
 190     [ pick ] dip swap length over
 191     [ (selector-for) [ compose each ] dip ] 2curry dip like ; inline
 192
 193 : map-filter ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) -- ... subseq )
 194     pick map-filter-as ; inline
 195
 196 : map-sift ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 197     [ ] map-filter ; inline
 198
 199 : map-harvest ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 200     [ empty? not ] map-filter ; inline
 201
 202 <PRIVATE
 203
 204 : ((each-from)) ( i seq -- n quot )
 205     [ length over [-] swap ] keep '[ _ + _ nth-unsafe ] ; inline
 206
 207 : (each-from) ( i seq quot -- n quot' ) [ ((each-from)) ] dip compose ;
 208     inline
 209
 210 PRIVATE>
 211
 212 : map-from-as ( ... seq quot: ( ... elt -- ... newelt ) i exemplar -- ... newseq )
 213     [ -rot (each-from) ] dip map-integers ; inline
 214
 215 : map-from ( ... seq quot: ( ... elt -- ... newelt ) i -- ... newseq )
 216     pick map-from-as ; inline
 217
 218 <PRIVATE
 219
 220 : push-map-if ( ..a elt filter-quot: ( ..a elt -- ..b ? ) map-quot: ( ..a elt -- ..b newelt ) accum -- ..b )
 221     [ keep over ] 2dip [ when ] dip rot [ push ] [ 2drop ] if ; inline
 222
 223 : (filter-mapper-for) ( filter-quot map-quot length exempler -- filter-mapper accum )
 224     new-resizable [ [ push-map-if ] 3curry ] keep ; inline
 225
 226 : filter-mapper-for ( filter-quot map-quot exemplar -- filter-mapper accum )
 227     [ length ] keep (filter-mapper-for) ; inline
 228
 229 : filter-mapper ( filter-quot map-quot -- filter-mapper accum )
 230     V{ } filter-mapper-for ; inline
 231
 232 PRIVATE>
 233
 234 : filter-map-as ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 235     [ pick ] dip swap length over
 236     [ (filter-mapper-for) [ each ] dip ] 2curry dip like ; inline
 237
 238 : filter-map ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) -- ... newseq )
 239     pick filter-map-as ; inline
 240
 241 : 2map-sum ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... n ) -- ... n )
 242     [ 0 ] 3dip [ dip + ] curry [ rot ] prepose 2each ; inline
 243
 244 : 2count ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... n )
 245     [ 1 0 ? ] compose 2map-sum ; inline
 246
 247 : round-robin ( seq -- newseq )
 248     [ { } ] [
 249         [ longest length iota ] keep
 250         [ [ ?nth ] with map ] curry map concat sift
 251     ] if-empty ;
 252
 253 : sift-as ( seq exemplar -- newseq )
 254     [ ] swap filter-as ;
 255
 256 : sift! ( seq -- newseq )
 257     [ ] filter! ;
 258
 259 : harvest-as ( seq exemplar -- newseq )
 260     [ empty? not ] swap filter-as ;
 261
 262 : harvest! ( seq -- newseq )
 263     [ empty? not ] filter! ;
 264
 265 : contains? ( seq elts -- ? )
 266     [ member? ] curry any? ; inline
 267
 268 : head-as ( seq n exemplar -- seq' )
 269     [ head-slice ] [ like ] bi* ; inline
 270
 271 : head*-as ( seq n exemplar -- seq' )
 272     [ head-slice* ] [ like ] bi* ; inline
 273
 274 : tail-as ( seq n exemplar -- seq' )
 275     [ tail-slice ] [ like ] bi* ; inline
 276
 277 : tail*-as ( seq n exemplar -- seq' )
 278     [ tail-slice* ] [ like ] bi* ; inline
 279
 280 : trim-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... newseq )
 281     [ trim-slice ] [ like ] bi* ; inline
 282
 283 : ?trim ( seq quot: ( elt -- ? ) -- seq/newseq )
 284     over empty? [ drop ] [
 285         over [ first-unsafe ] [ last-unsafe ] bi pick bi@ or
 286         [ trim ] [ drop ] if
 287     ] if ; inline
 288
 289 : ?trim-head ( seq quot: ( elt -- ? ) -- seq/newseq )
 290     over empty? [ drop ] [
 291         over first-unsafe over call
 292         [ trim-head ] [ drop ] if
 293     ] if ; inline
 294
 295 : ?trim-tail ( seq quot: ( elt -- ? ) -- seq/newseq )
 296     over empty? [ drop ] [
 297         over last-unsafe over call
 298         [ trim-tail ] [ drop ] if
 299     ] if ; inline
 300
 301 : unsurround ( newseq seq2 seq3 -- seq1 )
 302    [ ?head drop ] [ ?tail drop ] bi* ;
 303
 304 : none? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 305     any? not ; inline
 306
 307 : one? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 308     [ find ] 2keep rot [
 309         [ 1 + ] 2dip find-from drop not
 310     ] [ 3drop f ] if ; inline
 311
 312 : map-index! ( ... seq quot: ( ... elt index -- ... newelt ) -- ... seq )
 313     over [ [ (each-index) ] dip collect ] keep ; inline
 314
 315 <PRIVATE
 316
 317 : (2each-index) ( seq1 seq2 quot -- n quot' )
 318     [ ((2each)) [ keep ] curry ] dip compose ; inline
 319
 320 PRIVATE>
 321
 322 : 2each-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... ) -- ... )
 323     (2each-index) each-integer ; inline
 324
 325 : 2map-into ( seq1 seq2 quot into -- )
 326     [ (2each) ] dip collect ; inline
 327
 328 : 2map! ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... seq1 )
 329     pick [ 2map-into ] keep ; inline
 330
 331 : 2map-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... newelt ) -- ... newseq )
 332     pick [ (2each-index) ] dip map-integers ; inline
 333
 334 TUPLE: evens seq length ;
 335
 336 : <evens> ( seq -- evens )
 337     dup length 1 + 2/ evens boa ; inline
 338
 339 M: evens length length>> ; inline
 340
 341 M: evens nth-unsafe [ 2 * ] [ seq>> nth-unsafe ] bi* ; inline
 342
 343 INSTANCE: evens immutable-sequence
 344
 345 TUPLE: odds seq length ;
 346
 347 : <odds> ( seq -- odds )
 348     dup length 2/ odds boa ; inline
 349
 350 M: odds length length>> ; inline
 351
 352 M: odds nth-unsafe [ 2 * 1 + ] [ seq>> nth-unsafe ] bi* ; inline
 353
 354 INSTANCE: odds immutable-sequence
 355
 356 : until-empty ( seq quot -- )
 357     [ dup empty? ] swap until drop ; inline
 358
 359 : arg-max ( seq -- n )
 360     <enum> [ second-unsafe ] supremum-by first ;
 361
 362 : arg-min ( seq -- n )
 363     <enum> [ second-unsafe ] infimum-by first ;
 364
 365 <PRIVATE
 366
 367 : push-index-if ( ..a elt i quot: ( ..a elt -- ..b ? ) accum -- ..b )
 368     [ dip ] dip rot [ push ] [ 2drop ] if ; inline
 369
 370 PRIVATE>
 371
 372 : arg-where ( ... seq quot: ( ... elt -- ... ? ) -- ... indices )
 373     over length <vector> [
 374         [ push-index-if ] 2curry each-index
 375     ] keep ; inline
 376
 377 : arg-sort ( seq -- indices )
 378     dup length iota zip sort-keys values ;
 379
 380 : first= ( seq elt -- ? ) [ first ] dip = ; inline
 381 : second= ( seq elt -- ? ) [ second ] dip = ; inline
 382 : third= ( seq elt -- ? ) [ third ] dip = ; inline
 383 : fourth= ( seq elt -- ? ) [ fourth ] dip = ; inline
 384 : last= ( seq elt -- ? ) [ last ] dip = ; inline
 385 : nth= ( n seq elt -- ? ) [ nth ] dip = ; inline
 386
 387 : first? ( seq quot -- ? ) [ first ] dip call ; inline
 388 : second? ( seq quot -- ? ) [ second ] dip call ; inline
 389 : third? ( seq quot -- ? ) [ third ] dip call ; inline
 390 : fourth? ( seq quot -- ? ) [ fourth ] dip call ; inline
 391 : last? ( seq quot -- ? ) [ last ] dip call ; inline
 392 : nth? ( n seq quot -- ? ) [ nth ] dip call ; inline
 393
 394 : loop>sequence ( quot exemplar -- seq )
 395    [ '[ [ @ [ [ , ] when* ] keep ] loop ] ] dip make ; inline
 396
 397 : loop>array ( quot -- seq )
 398    { } loop>sequence ; inline
 399
 400 <PRIVATE
 401
 402 : (reverse) ( seq -- newseq )
 403     dup [ length ] keep new-sequence
 404     [ 0 swap copy-unsafe ] keep reverse! ;
 405
 406 PRIVATE>
 407
 408 : reverse-as ( seq exemplar -- newseq )
 409     [ (reverse) ] [ like ] bi* ;
 410
 411 : map-product ( ... seq quot: ( ... elt -- ... n ) -- ... n )
 412     [ 1 ] 2dip [ dip * ] curry [ swap ] prepose each ; inline
 413
 414 : insert-nth! ( elt n seq -- )
 415     [ length ] keep ensure swap pick (a,b]
 416     over '[ [ 1 + ] keep _ move-unsafe ] each
 417     set-nth-unsafe ;
 418
 419 : set-nths ( value indices seq -- )
 420     swapd '[ [ _ ] dip _ set-nth ] each ; inline
 421
 422 : set-nths-unsafe ( value indices seq -- )
 423     swapd '[ [ _ ] dip _ set-nth-unsafe ] each ; inline
 424
 425 : flatten1 ( obj -- seq )
 426     [
 427         [
 428             dup branch? [
 429                 [ dup branch? [ % ] [ , ] if ] each
 430             ] [ , ] if
 431         ]
 432     ] keep dup branch? [ drop f ] unless make ;
 433
 434 <PRIVATE
 435
 436 : (map-find-index) ( seq quot find-quot -- result elt index )
 437     [ [ f ] 2dip [ [ nip ] 2dip call dup ] curry ] dip call
 438     [ [ [ drop f ] unless ] keep ] dip ; inline
 439
 440 PRIVATE>
 441
 442 : map-find-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result elt index )
 443     [ find-index ] (map-find-index) ; inline
 444
 445 : filter-length ( seq n -- seq' ) '[ length _ = ] filter ;
 446
 447 : all-shortest ( seqs -- seqs' ) dup shortest length filter-length ;
 448
 449 : all-longest ( seqs -- seqs' ) dup longest length filter-length ;
 450
 451 : remove-first ( obj seq -- seq' )
 452     [ index ] keep over [ remove-nth ] [ nip ] if ;
 453
 454 : remove-first! ( obj seq -- seq )
 455     [ index ] keep over [ remove-nth! ] [ nip ] if ;
 456
 457 : remove-last ( obj seq -- seq' )
 458     [ last-index ] keep over [ remove-nth ] [ nip ] if ;
 459
 460 : remove-last! ( obj seq -- seq )
 461     [ last-index ] keep over [ remove-nth! ] [ nip ] if ;
 462
 463 : ?first2 ( seq -- first/f second/f )
 464     dup length {
 465         { 0 [ drop f f ] }
 466         { 1 [ first-unsafe f ] }
 467         [ drop first2-unsafe ]
 468     } case ;
 469
 470 : ?first3 ( seq -- first/f second/f third/f )
 471     dup length {
 472         { 0 [ drop f f f ] }
 473         { 1 [ first-unsafe f f ] }
 474         { 2 [ first2-unsafe f ] }
 475         [ drop first3-unsafe ]
 476     } case ;
 477
 478 : ?first4 ( seq -- first/f second/f third/f fourth/f )
 479     dup length {
 480         { 0 [ drop f f f f ] }
 481         { 1 [ first-unsafe f f f ] }
 482         { 2 [ first2-unsafe f f ] }
 483         { 3 [ first3-unsafe f ] }
 484         [ drop first4-unsafe ]
 485     } case ;
 486
 487 : cut-when ( ... seq quot: ( ... elt -- ... ? ) -- ... before after )
 488     [ find drop ] 2keep drop swap
 489     [ cut ] [ f over like ] if* ; inline
 490
 491 : nth* ( n seq -- elt )
 492     [ length 1 - swap - ] [ nth ] bi ; inline
 493
 494 : each-index-from ( ... seq quot: ( ... elt index -- ... ) i -- ... )
 495     -rot (each-index) (each-integer) ; inline
 496
 497 <PRIVATE
 498
 499 : select-by* ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... i elt )
 500     [
 501         [ keep swap ] curry [ dip ] curry
 502         [ [ first 0 ] dip call ] 2keep
 503         [ 2curry 3dip 5 npick pick ] curry
 504     ] [
 505         [ [ 3drop ] [ [ 3drop ] 3dip ] if ] compose
 506     ] bi* compose 1 each-index-from nip swap ; inline
 507
 508 PRIVATE>
 509
 510 : supremum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 511     [ after? ] select-by* ; inline
 512
 513 : infimum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 514     [ before? ] select-by* ; inline
 515
 516 : reject-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... subseq )
 517     [ [ not ] compose ] [ filter-as ] bi* ; inline
 518
 519 : reject ( ... seq quot: ( ... elt -- ... ? ) -- ... subseq )
 520     over reject-as ; inline