extra/sequences/extras/extras.factor

   1 USING: arrays grouping kernel locals math math.order math.ranges
   2 sequences sequences.private splitting ;
   3
   4 IN: sequences.extras
   5
   6 : reduce1 ( seq quot -- result ) [ unclip ] dip reduce ; inline
   7
   8 :: reduce-r ( list identity quot: ( obj1 obj2 -- obj ) -- result )
   9     list empty?
  10     [ identity ]
  11     [ list rest identity quot reduce-r list first quot call ] if ;
  12     inline recursive
  13
  14 ! Quot must have static stack effect, unlike "reduce"
  15 :: reduce* ( seq id quot -- result ) seq
  16     [ id ]
  17     [ unclip id swap quot call( prev elt -- next ) quot reduce* ] if-empty ; inline recursive
  18
  19 :: combos ( list1 list2 -- result )
  20     list2 [ [ 2array ] curry list1 swap map ] map concat ;
  21
  22 : find-all ( seq quot -- elts )
  23     [ [ length iota ] keep ] dip
  24     [ dupd call( a -- ? ) [ 2array ] [ 2drop f ] if ] curry
  25     2map [ ] filter ; inline
  26
  27 : insert-sorted ( elt seq -- seq )
  28     2dup [ < ] with find drop over length or swap insert-nth ;
  29
  30 : each-from ( ... seq quot: ( ... x -- ... ) i -- ... )
  31     -rot (each) (each-integer) ; inline
  32
  33 : reduce-from ( ... seq identity quot: ( ... prev elt -- ... next ) i -- ... result )
  34     [ swap ] 2dip each-from ; inline
  35
  36 : max-by ( obj1 obj2 quot: ( obj -- n ) -- obj1/obj2 )
  37     [ bi@ dupd max = ] curry most ; inline
  38
  39 : min-by ( obj1 obj2 quot: ( obj -- n ) -- obj1/obj2 )
  40     [ bi@ dupd min = ] curry most ; inline
  41
  42 : maximum ( seq quot: ( ... elt -- ... x ) -- elt )
  43     [ dup ?first ] dip [ max-by ] curry reduce ; inline
  44
  45 : minimum ( seq quot: ( ... elt -- ... x ) -- elt )
  46     [ dup ?first ] dip [ min-by ] curry reduce ; inline
  47
  48 : supremum-by ( seq quot: ( ... elt -- ... x ) -- elt )
  49     [ [ first dup ] dip call ] 2keep [
  50         dupd call pick dupd max over =
  51         [ [ 2drop ] 2dip ] [ 2nip ] if
  52     ] curry 1 each-from drop ; inline
  53
  54 : infimum-by ( seq quot: ( ... elt -- ... x ) -- elt )
  55     [ [ first dup ] dip call ] 2keep [
  56         dupd call pick dupd min over =
  57         [ [ 2drop ] 2dip ] [ 2nip ] if
  58     ] curry 1 each-from drop ; inline
  59
  60 : all-subseqs ( seq -- seqs )
  61     dup length [1,b] [ <clumps> ] with map concat ;
  62
  63 :: each-subseq ( ... seq quot: ( ... x -- ... ) -- ... )
  64     seq length :> len
  65     len [0,b] [
  66         :> from
  67         from len (a,b] [
  68             :> to
  69             from to seq subseq quot call( x -- )
  70         ] each
  71     ] each ;
  72
  73 :: longest-subseq ( seq1 seq2 -- subseq )
  74     seq1 length :> len1
  75     seq2 length :> len2
  76     0 :> n!
  77     0 :> end!
  78     len1 1 + [ len2 1 + 0 <array> ] replicate :> table
  79     len1 [1,b] [| x |
  80         len2 [1,b] [| y |
  81             x 1 - seq1 nth-unsafe
  82             y 1 - seq2 nth-unsafe = [
  83                 y 1 - x 1 - table nth-unsafe nth-unsafe 1 + :> len
  84                 len y x table nth-unsafe set-nth-unsafe
  85                 len n > [ len n! x end! ] when
  86             ] [ 0 y x table nth-unsafe set-nth-unsafe ] if
  87         ] each
  88     ] each end n - end seq1 subseq ;
  89
  90 : pad-longest ( seq1 seq2 elt -- seq1 seq2 )
  91     [ 2dup max-length ] dip [ pad-tail ] 2curry bi@ ;
  92
  93 : change-nths ( ... indices seq quot: ( ... elt -- ... elt' ) -- ... )
  94     [ change-nth ] 2curry each ; inline
  95
  96 : push-if-index ( ..a elt i quot: ( ..a elt i -- ..b ? ) accum -- ..b )
  97     [ 2keep drop ] dip rot [ push ] [ 2drop ] if ; inline
  98
  99 : index-selector-for ( quot exemplar -- selector accum )
 100     [ length ] keep new-resizable [ [ push-if-index ] 2curry ] keep ; inline
 101
 102 : filter-index-as ( ... seq quot: ( ... elt i -- ... ? ) exemplar -- ... seq' )
 103     dup [ index-selector-for [ each-index ] dip ] curry dip like ; inline
 104
 105 : filter-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... seq' )
 106     over filter-index-as ; inline
 107
 108 : even-indices ( seq -- seq' ) [ nip even? ] filter-index ;
 109
 110 : odd-indices ( seq -- seq' ) [ nip odd? ] filter-index ;
 111
 112 : compact ( seq quot elt -- seq' )
 113     [ split-when harvest ] dip join ; inline
 114
 115 : collapse ( seq quot elt -- seq' )
 116     [ split-when ] dip
 117     [ [ harvest ] dip join ]
 118     [ [ first empty? ] dip [ prepend ] curry when ]
 119     [ [ last empty? ] dip [ append ] curry when ]
 120     2tri ; inline
 121
 122 :: slice-when ( seq quot: ( elt -- ? ) -- seq' )
 123     seq length :> len
 124     0 [ len dupd < ] [
 125         dup seq quot find-from drop
 126         [ 2dup = [ 1 + ] when ] [ len ] if*
 127         [ seq <slice> ] keep len or swap
 128     ] produce nip ; inline
 129
 130 : rotate ( seq n -- seq' )
 131     cut prepend ;
 132
 133 :: rotate! ( seq n -- )
 134     seq length :> end
 135     n 0 n [ 2dup = ] [
 136         [ seq exchange ] [ [ 1 + ] bi@ ] 2bi
 137         dup end = [ drop over ] when
 138         2over = [ -rot nip over ] when
 139     ] until 3drop ;
 140
 141 : appender-for ( quot exemplar -- quot' vec )
 142     [ length ] keep new-resizable
 143     [ [ push-all ] curry compose ] keep ; inline
 144
 145 : appender ( quot -- quot' vec )
 146     V{ } appender-for ; inline
 147
 148 : map-concat-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 149     dup [ appender-for [ each ] dip ] curry dip like ; inline
 150
 151 : >resizable ( seq -- vec ) ! fixes map-concat "cannot apply call to run-time..."
 152     [ length ] keep [ new-resizable ] [ over push-all ] bi ;
 153
 154 : map-concat ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 155     over [ 2drop { } ] [
 156         first over call dup [
 157             >resizable [ [ push-all ] curry compose ] keep
 158             [ 1 ] 3dip [ (each) (each-integer) ] dip
 159         ] curry dip like
 160     ] if-empty ; inline
 161
 162 : map-filter-as ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) exemplar -- ... subseq )
 163     dup [ selector-for [ compose each ] dip ] curry dip like ; inline
 164
 165 : map-filter ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) -- ... subseq )
 166     pick map-filter-as ; inline
 167
 168 : map-sift ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 169     [ ] map-filter ; inline
 170
 171 : map-harvest ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 172     [ empty? not ] map-filter ; inline
 173
 174 <PRIVATE
 175
 176 : push-map-if ( ..a elt filter-quot: ( ..a elt -- ..b ? ) map-quot: ( ..a elt -- ..b newelt ) accum -- ..b )
 177     [ keep over ] 2dip [ when ] dip rot [ push ] [ 2drop ] if ; inline
 178
 179 : filter-mapper-for ( filter-quot map-quot exemplar -- quot' vec )
 180     [ length ] keep new-resizable [ [ push-map-if ] 3curry ] keep ; inline
 181
 182 : filter-mapper ( filter-quot map-quot -- quot' vec )
 183     V{ } filter-mapper-for ; inline
 184
 185 PRIVATE>
 186
 187 : filter-map-as ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 188     dup [ filter-mapper-for [ each ] dip ] curry dip like ; inline
 189
 190 : filter-map ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) -- ... newseq )
 191     pick filter-map-as ; inline
 192
 193 : 2map-sum ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... n ) -- ... n )
 194     [ 0 ] 3dip [ dip + ] curry [ rot ] prepose 2each ; inline
 195
 196 : 2count ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... n )
 197     [ 1 0 ? ] compose 2map-sum ; inline