extra/sequences/extras/extras.factor

   1 USING: accessors arrays assocs combinators fry generalizations
   2 grouping growable kernel locals make math math.order math.ranges
   3 sequences sequences.deep sequences.private sorting splitting
   4 vectors ;
   5 IN: sequences.extras
   6
   7 : reduce1 ( seq quot -- result ) [ unclip ] dip reduce ; inline
   8
   9 :: reduce-r ( seq identity quot: ( obj1 obj2 -- obj ) -- result )
  10     seq [ identity ] [
  11         unclip [ identity quot reduce-r ] [ quot call ] bi*
  12     ] if-empty ; inline recursive
  13
  14 ! Quot must have static stack effect, unlike "reduce"
  15 :: reduce* ( seq identity quot: ( prev elt -- next ) -- result )
  16     seq [ identity ] [
  17         unclip identity swap quot call( prev elt -- next )
  18         quot reduce*
  19     ] if-empty ; inline recursive
  20
  21 :: combos ( list1 list2 -- result )
  22     list2 [ [ 2array ] curry list1 swap map ] map concat ;
  23
  24 : find-all ( seq quot: ( elt -- ? ) -- elts )
  25     [ [ length iota ] keep ] dip
  26     [ dupd call( a -- ? ) [ 2array ] [ 2drop f ] if ] curry
  27     2map sift ; inline
  28
  29 : reduce-from ( ... seq identity quot: ( ... prev elt -- ... next ) i -- ... result )
  30     [ swap ] 2dip each-from ; inline
  31
  32 :: subseq* ( from to seq -- subseq )
  33     seq length :> len
  34     from [ dup 0 < [ len + ] when ] [ 0 ] if*
  35     to [ dup 0 < [ len + ] when ] [ len ] if*
  36     [ 0 len clamp ] bi@ dupd max seq subseq ;
  37
  38 : safe-subseq ( from to seq -- subseq )
  39     [ length '[ 0 _ clamp ] bi@ ] keep subseq ;
  40
  41 : all-subseqs ( seq -- seqs )
  42     dup length [1,b] [ clump ] with map concat ;
  43
  44 :: each-subseq ( ... seq quot: ( ... x -- ... ) -- ... )
  45     seq length :> len
  46     len [0,b] [
  47         :> from
  48         from len (a,b] [
  49             :> to
  50             from to seq subseq quot call
  51         ] each
  52     ] each ; inline
  53
  54 : subseq-as ( from to seq exemplar -- subseq )
  55     [ check-slice subseq>copy (copy) ] dip like ;
  56
  57 : map-like ( seq exemplar -- seq' )
  58     '[ _ like ] map ; inline
  59
  60 : filter-all-subseqs-range ( ... seq range quot: ( ... x -- ... ) -- seq )
  61     [
  62         '[ <clumps> _ filter ] with map concat
  63     ] 3keep 2drop map-like ; inline
  64
  65 : filter-all-subseqs ( ... seq quot: ( ... x -- ... ) -- seq )
  66     [ dup length [1,b] ] dip filter-all-subseqs-range ; inline
  67
  68 :: longest-subseq ( seq1 seq2 -- subseq )
  69     seq1 length :> len1
  70     seq2 length :> len2
  71     0 :> n!
  72     0 :> end!
  73     len1 1 + [ len2 1 + 0 <array> ] replicate :> table
  74     len1 [1,b] [| x |
  75         len2 [1,b] [| y |
  76             x 1 - seq1 nth-unsafe
  77             y 1 - seq2 nth-unsafe = [
  78                 y 1 - x 1 - table nth-unsafe nth-unsafe 1 + :> len
  79                 len y x table nth-unsafe set-nth-unsafe
  80                 len n > [ len n! x end! ] when
  81             ] [ 0 y x table nth-unsafe set-nth-unsafe ] if
  82         ] each
  83     ] each end n - end seq1 subseq ;
  84
  85 : pad-longest ( seq1 seq2 elt -- seq1 seq2 )
  86     [ 2dup max-length ] dip [ pad-tail ] 2curry bi@ ;
  87
  88 : change-nths ( ... indices seq quot: ( ... elt -- ... elt' ) -- ... )
  89     [ change-nth ] 2curry each ; inline
  90
  91 : push-if-index ( ..a elt i quot: ( ..a elt i -- ..b ? ) accum -- ..b )
  92     [ 2keep drop ] dip rot [ push ] [ 2drop ] if ; inline
  93
  94 : push-if* ( ..a elt quot: ( ..a elt -- ..b obj/f ) accum -- ..b )
  95     [ call ] dip [ push ] [ drop ] if* ; inline
  96
  97 <PRIVATE
  98
  99 : (index-selector-for) ( quot length exampler -- selector accum )
 100     new-resizable [ [ push-if-index ] 2curry ] keep ; inline
 101
 102 : (selector-for*) ( quot length exemplar -- selector accum )
 103     new-resizable [ [ push-if* ] 2curry ] keep ; inline
 104
 105 PRIVATE>
 106
 107 : index-selector-for ( quot exemplar -- selector accum )
 108     [ length ] keep (index-selector-for) ; inline
 109
 110 : index-selector ( quot -- selector accum )
 111     V{ } index-selector-for ; inline
 112
 113 : selector-for* ( quot exemplar -- selector accum )
 114     [ length ] keep (selector-for*) ; inline
 115
 116 : selector* ( quot -- selector accum ) V{ } selector-for* ; inline
 117
 118 : filter-index-as ( ... seq quot: ( ... elt i -- ... ? ) exemplar -- ... seq' )
 119     pick length over [ (index-selector-for) [ each-index ] dip ] 2curry dip like ; inline
 120
 121 : filter-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... seq' )
 122     over filter-index-as ; inline
 123
 124 : even-indices ( seq -- seq' )
 125     [ length 1 + 2/ ] keep [
 126         [ [ 2 * ] dip nth-unsafe ] curry
 127     ] keep map-integers ;
 128
 129 : odd-indices ( seq -- seq' )
 130     [ length 2/ ] keep [
 131         [ [ 2 * 1 + ] dip nth-unsafe ] curry
 132     ] keep map-integers ;
 133
 134 : compact ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 135     [ split-when harvest ] dip join ; inline
 136
 137 : collapse ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 138     [ split-when ] dip
 139     [ [ harvest ] dip join ]
 140     [ [ first empty? ] dip [ prepend ] curry when ]
 141     [ [ last empty? ] dip [ append ] curry when ]
 142     2tri ; inline
 143
 144 :: slice-when ( seq quot: ( elt -- ? ) -- seq' )
 145     seq length :> len
 146     0 [ len dupd < ] [
 147         dup seq quot find-from drop
 148         [ 2dup = [ 1 + ] when ] [ len ] if*
 149         [ seq <slice> ] keep len or swap
 150     ] produce nip ; inline
 151
 152 : cut-slice* ( seq n -- before after )
 153     [ head-slice* ] [ tail-slice* ] 2bi ;
 154
 155 : ?<slice> ( from to/f sequence -- slice )
 156     over [ nip [ length ] [ ] bi ] unless <slice> ; inline
 157
 158 : sequence>slice ( sequence -- slice )
 159     [ drop 0 ] [ length ] [ ] tri <slice> ; inline
 160
 161 : slice-order-by-from ( slice1 slice2 -- slice-lt slice-gt )
 162     2dup [ from>> ] bi@ > [ swap ] when ; inline
 163
 164 : ordered-slices-range ( slice-lt slice-gt -- to from )
 165     [ to>> ] [ from>> ] bi* ;
 166
 167 : unordered-slices-range ( slice1 slice2 -- to from )
 168     slice-order-by-from ordered-slices-range ;
 169
 170 : ordered-slices-overlap? ( slice-lt slice-gt -- ? )
 171     ordered-slices-range > ; inline
 172
 173 : unordered-slices-overlap? ( slice1 slice2 -- ? )
 174     unordered-slices-range > ; inline
 175
 176 : slices-overlap? ( slice1 slice2 -- ? )
 177     unordered-slices-overlap? ;
 178
 179 : ordered-slices-touch? ( slice-lt slice-gt -- ? )
 180     ordered-slices-range >= ; inline
 181
 182 : unordered-slices-touch? ( slice1 slice2 -- ? )
 183     unordered-slices-range >= ; inline
 184
 185 : slices-touch? ( slice1 slice2 -- ? )
 186     unordered-slices-touch? ;
 187
 188 ERROR: slices-don't-touch slice1 slice2 ;
 189
 190 : merge-slices ( slice1 slice2 -- slice/* )
 191     slice-order-by-from
 192     2dup ordered-slices-touch? [
 193         [ from>> ] [ [ to>> ] [ seq>> ] bi ] bi* <slice>
 194     ] [
 195         slices-don't-touch
 196     ] if ;
 197
 198 : rotate ( seq n -- seq' )
 199     over length mod dup 0 >= [ cut ] [ abs cut* ] if prepend ;
 200
 201 ERROR: underlying-mismatch slice1 slice2 ;
 202 : ensure-same-underlying ( slice1 slice2 -- slice1 slice2 )
 203     2dup [ seq>> ] bi@ eq? [ underlying-mismatch ] unless ;
 204
 205 : span-slices ( slice1 slice2 -- slice )
 206     ensure-same-underlying
 207     [ [ from>> ] bi@ min ]
 208     [ [ to>> ] bi@ max ]
 209     [ drop seq>> ] 2tri <slice> ;
 210
 211 :: rotate! ( seq n -- )
 212     seq length :> len
 213     n len mod dup 0 < [ len + ] when seq bounds-check drop 0 over
 214     [ 2dup = ] [
 215         [ seq exchange-unsafe ] [ [ 1 + ] bi@ ] 2bi
 216         dup len = [ drop over ] when
 217         2over = [ -rot nip over ] when
 218     ] until 3drop ;
 219
 220 : all-rotations ( seq -- seq' )
 221     dup length iota [ rotate ] with map ;
 222
 223 <PRIVATE
 224
 225 : (appender-for) ( quot length exemplar -- appender accum )
 226     new-resizable [ [ push-all ] curry compose ] keep ; inline
 227
 228 PRIVATE>
 229
 230 : appender-for ( quot exemplar -- appender accum )
 231     [ length ] keep (appender-for) ; inline
 232
 233 : appender ( quot -- appender accum )
 234     V{ } appender-for ; inline
 235
 236 : map-concat-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 237     [ appender-for [ each ] dip ] keep like ; inline
 238
 239 : >resizable ( seq -- accum ) ! fixes map-concat "cannot apply call to run-time..."
 240     [ length ] keep [ new-resizable ] [ append! ] bi ;
 241
 242 : map-concat ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 243     over empty? [ 2drop { } ] [
 244         [ [ first ] dip call ] 2keep rot dup [
 245             >resizable [ [ push-all ] curry compose ] keep
 246             [ 1 ] 3dip [ setup-each (each-integer) ] dip
 247         ] curry dip like
 248     ] if ; inline
 249
 250 : map-filter-as ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) exemplar -- ... subseq )
 251     [ pick ] dip swap length over
 252     [ (selector-for) [ compose each ] dip ] 2curry dip like ; inline
 253
 254 : map-filter ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) -- ... subseq )
 255     pick map-filter-as ; inline
 256
 257 : map-sift ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 258     [ ] map-filter ; inline
 259
 260 : map-harvest ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 261     [ empty? not ] map-filter ; inline
 262
 263 <PRIVATE
 264
 265 : (setup-each-from) ( i seq -- n quot )
 266     [ length over [-] swap ] keep '[ _ + _ nth-unsafe ] ; inline
 267
 268 : setup-each-from ( i seq quot -- n quot' )
 269     [ (setup-each-from) ] dip compose ; inline
 270
 271 PRIVATE>
 272
 273 : map-from-as ( ... seq quot: ( ... elt -- ... newelt ) i exemplar -- ... newseq )
 274     [ -rot setup-each-from ] dip map-integers ; inline
 275
 276 : map-from ( ... seq quot: ( ... elt -- ... newelt ) i -- ... newseq )
 277     pick map-from-as ; inline
 278
 279 <PRIVATE
 280
 281 : push-map-if ( ..a elt filter-quot: ( ..a elt -- ..b ? ) map-quot: ( ..a elt -- ..b newelt ) accum -- ..b )
 282     [ keep over ] 2dip [ when ] dip rot [ push ] [ 2drop ] if ; inline
 283
 284 : (filter-mapper-for) ( filter-quot map-quot length exempler -- filter-mapper accum )
 285     new-resizable [ [ push-map-if ] 3curry ] keep ; inline
 286
 287 : filter-mapper-for ( filter-quot map-quot exemplar -- filter-mapper accum )
 288     [ length ] keep (filter-mapper-for) ; inline
 289
 290 : filter-mapper ( filter-quot map-quot -- filter-mapper accum )
 291     V{ } filter-mapper-for ; inline
 292
 293 PRIVATE>
 294
 295 : filter-map-as ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 296     [ pick ] dip swap length over
 297     [ (filter-mapper-for) [ each ] dip ] 2curry dip like ; inline
 298
 299 : filter-map ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) -- ... newseq )
 300     pick filter-map-as ; inline
 301
 302 : 2map-sum ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... n ) -- ... n )
 303     [ 0 ] 3dip [ dip + ] curry [ rot ] prepose 2each ; inline
 304
 305 : 2count ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... n )
 306     [ 1 0 ? ] compose 2map-sum ; inline
 307
 308 : round-robin ( seq -- newseq )
 309     [ { } ] [
 310         [ longest length iota ] keep
 311         [ [ ?nth ] with map ] curry map concat sift
 312     ] if-empty ;
 313
 314 : sift-as ( seq exemplar -- newseq )
 315     [ ] swap filter-as ;
 316
 317 : sift! ( seq -- newseq )
 318     [ ] filter! ;
 319
 320 : harvest-as ( seq exemplar -- newseq )
 321     [ empty? not ] swap filter-as ;
 322
 323 : harvest! ( seq -- newseq )
 324     [ empty? ] reject! ;
 325
 326 : head-as ( seq n exemplar -- seq' )
 327     [ head-slice ] [ like ] bi* ; inline
 328
 329 : head*-as ( seq n exemplar -- seq' )
 330     [ head-slice* ] [ like ] bi* ; inline
 331
 332 : tail-as ( seq n exemplar -- seq' )
 333     [ tail-slice ] [ like ] bi* ; inline
 334
 335 : tail*-as ( seq n exemplar -- seq' )
 336     [ tail-slice* ] [ like ] bi* ; inline
 337
 338 : trim-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... newseq )
 339     [ trim-slice ] [ like ] bi* ; inline
 340
 341 : ?trim ( seq quot: ( elt -- ? ) -- seq/newseq )
 342     over empty? [ drop ] [
 343         over [ first-unsafe ] [ last-unsafe ] bi pick either?
 344         [ trim ] [ drop ] if
 345     ] if ; inline
 346
 347 : ?trim-head ( seq quot: ( elt -- ? ) -- seq/newseq )
 348     over empty? [ drop ] [
 349         over first-unsafe over call
 350         [ trim-head ] [ drop ] if
 351     ] if ; inline
 352
 353 : ?trim-tail ( seq quot: ( elt -- ? ) -- seq/newseq )
 354     over empty? [ drop ] [
 355         over last-unsafe over call
 356         [ trim-tail ] [ drop ] if
 357     ] if ; inline
 358
 359 : unsurround ( newseq seq2 seq3 -- seq1 )
 360    [ ?head drop ] [ ?tail drop ] bi* ;
 361
 362 : none? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 363     any? not ; inline
 364
 365 : one? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 366     [ find ] 2keep rot [
 367         [ 1 + ] 2dip find-from drop not
 368     ] [ 3drop f ] if ; inline
 369
 370 : map-index! ( ... seq quot: ( ... elt index -- ... newelt ) -- ... seq )
 371     over [ [ (each-index) ] dip collect ] keep ; inline
 372
 373 <PRIVATE
 374
 375 : (2each-index) ( seq1 seq2 quot -- n quot' )
 376     [ setup-2each [ keep ] curry ] dip compose ; inline
 377
 378 PRIVATE>
 379
 380 : 2each-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... ) -- ... )
 381     (2each-index) each-integer ; inline
 382
 383 : 2map-into ( seq1 seq2 quot into -- )
 384     [ (2each) ] dip collect ; inline
 385
 386 : 2map! ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... seq1 )
 387     pick [ 2map-into ] keep ; inline
 388
 389 : 2map-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... newelt ) -- ... newseq )
 390     pick [ (2each-index) ] dip map-integers ; inline
 391
 392 TUPLE: evens seq length ;
 393
 394 : <evens> ( seq -- evens )
 395     dup length 1 + 2/ evens boa ; inline
 396
 397 M: evens length length>> ; inline
 398
 399 M: evens nth-unsafe [ 2 * ] [ seq>> nth-unsafe ] bi* ; inline
 400
 401 INSTANCE: evens immutable-sequence
 402
 403 TUPLE: odds seq length ;
 404
 405 : <odds> ( seq -- odds )
 406     dup length 2/ odds boa ; inline
 407
 408 M: odds length length>> ; inline
 409
 410 M: odds nth-unsafe [ 2 * 1 + ] [ seq>> nth-unsafe ] bi* ; inline
 411
 412 INSTANCE: odds immutable-sequence
 413
 414 : until-empty ( seq quot -- )
 415     [ dup empty? ] swap until drop ; inline
 416
 417 : arg-max ( seq -- n )
 418     <enum> [ second-unsafe ] supremum-by first ;
 419
 420 : arg-min ( seq -- n )
 421     <enum> [ second-unsafe ] infimum-by first ;
 422
 423 <PRIVATE
 424
 425 : push-index-if ( ..a elt i quot: ( ..a elt -- ..b ? ) accum -- ..b )
 426     [ dip ] dip rot [ push ] [ 2drop ] if ; inline
 427
 428 PRIVATE>
 429
 430 : arg-where ( ... seq quot: ( ... elt -- ... ? ) -- ... indices )
 431     over length <vector> [
 432         [ push-index-if ] 2curry each-index
 433     ] keep ; inline
 434
 435 : arg-sort ( seq -- indices )
 436     zip-index sort-keys values ;
 437
 438 : first= ( seq elt -- ? ) [ first ] dip = ; inline
 439 : second= ( seq elt -- ? ) [ second ] dip = ; inline
 440 : third= ( seq elt -- ? ) [ third ] dip = ; inline
 441 : fourth= ( seq elt -- ? ) [ fourth ] dip = ; inline
 442 : last= ( seq elt -- ? ) [ last ] dip = ; inline
 443 : nth= ( n seq elt -- ? ) [ nth ] dip = ; inline
 444
 445 : first? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ first ] dip call ; inline
 446 : second? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ second ] dip call ; inline
 447 : third? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ third ] dip call ; inline
 448 : fourth? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ fourth ] dip call ; inline
 449 : last? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ last ] dip call ; inline
 450 : nth? ( ... n seq quot: ( ... elt -- ... ? ) -- ... ? ) [ nth ] dip call ; inline
 451
 452 : loop>sequence ( quot exemplar -- seq )
 453    [ '[ [ @ [ [ , ] when* ] keep ] loop ] ] dip make ; inline
 454
 455 : loop>array ( quot -- seq )
 456    { } loop>sequence ; inline
 457
 458 <PRIVATE
 459
 460 : (reverse) ( seq -- newseq )
 461     dup [ length ] keep new-sequence
 462     [ 0 swap copy-unsafe ] keep reverse! ;
 463
 464 PRIVATE>
 465
 466 : reverse-as ( seq exemplar -- newseq )
 467     [ (reverse) ] [ like ] bi* ;
 468
 469 : map-product ( ... seq quot: ( ... elt -- ... n ) -- ... n )
 470     [ 1 ] 2dip [ dip * ] curry [ swap ] prepose each ; inline
 471
 472 : insert-nth! ( elt n seq -- )
 473     [ length ] keep ensure swap pick (a,b]
 474     over '[ [ 1 + ] keep _ move-unsafe ] each
 475     set-nth-unsafe ;
 476
 477 : set-nths ( value indices seq -- )
 478     swapd '[ _ swap _ set-nth ] each ; inline
 479
 480 : set-nths-unsafe ( value indices seq -- )
 481     swapd '[ _ swap _ set-nth-unsafe ] each ; inline
 482
 483 : flatten1 ( obj -- seq )
 484     [
 485         [
 486             dup branch? [
 487                 [ dup branch? [ % ] [ , ] if ] each
 488             ] [ , ] if
 489         ]
 490     ] keep dup branch? [ drop f ] unless make ;
 491
 492 <PRIVATE
 493
 494 : (map-find-index) ( seq quot find-quot -- result i elt )
 495     [ [ f ] 2dip [ [ nip ] 2dip call dup ] curry ] dip call
 496     [ [ [ drop f ] unless ] keep ] dip ; inline
 497
 498 PRIVATE>
 499
 500 : map-find-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 501     [ find-index ] (map-find-index) ; inline
 502
 503 : filter-length ( seq n -- seq' ) '[ length _ = ] filter ;
 504
 505 : all-shortest ( seqs -- seqs' ) dup shortest length filter-length ;
 506
 507 : all-longest ( seqs -- seqs' ) dup longest length filter-length ;
 508
 509 : remove-first ( obj seq -- seq' )
 510     [ index ] keep over [ remove-nth ] [ nip ] if ;
 511
 512 : remove-first! ( obj seq -- seq )
 513     [ index ] keep over [ remove-nth! ] [ nip ] if ;
 514
 515 : remove-last ( obj seq -- seq' )
 516     [ last-index ] keep over [ remove-nth ] [ nip ] if ;
 517
 518 : remove-last! ( obj seq -- seq )
 519     [ last-index ] keep over [ remove-nth! ] [ nip ] if ;
 520
 521 : ?first2 ( seq -- first/f second/f )
 522     dup length {
 523         { 0 [ drop f f ] }
 524         { 1 [ first-unsafe f ] }
 525         [ drop first2-unsafe ]
 526     } case ;
 527
 528 : ?first3 ( seq -- first/f second/f third/f )
 529     dup length {
 530         { 0 [ drop f f f ] }
 531         { 1 [ first-unsafe f f ] }
 532         { 2 [ first2-unsafe f ] }
 533         [ drop first3-unsafe ]
 534     } case ;
 535
 536 : ?first4 ( seq -- first/f second/f third/f fourth/f )
 537     dup length {
 538         { 0 [ drop f f f f ] }
 539         { 1 [ first-unsafe f f f ] }
 540         { 2 [ first2-unsafe f f ] }
 541         { 3 [ first3-unsafe f ] }
 542         [ drop first4-unsafe ]
 543     } case ;
 544
 545 : cut-when ( ... seq quot: ( ... elt -- ... ? ) -- ... before after )
 546     [ find drop ] 2keep drop swap
 547     [ cut ] [ f over like ] if* ; inline
 548
 549 : nth* ( n seq -- elt )
 550     [ length 1 - swap - ] [ nth ] bi ; inline
 551
 552 : each-index-from ( ... seq quot: ( ... elt index -- ... ) i -- ... )
 553     -rot (each-index) (each-integer) ; inline
 554
 555 <PRIVATE
 556
 557 : select-by* ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... i elt )
 558     [
 559         [ keep swap ] curry [ dip ] curry
 560         [ [ first 0 ] dip call ] 2keep
 561         [ 2curry 3dip 5 npick pick ] curry
 562     ] [
 563         [ [ 3drop ] [ [ 3drop ] 3dip ] if ] compose
 564     ] bi* compose 1 each-index-from nip swap ; inline
 565
 566 PRIVATE>
 567
 568 : supremum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 569     [ after? ] select-by* ; inline
 570
 571 : infimum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 572     [ before? ] select-by* ; inline
 573
 574 : change-last ( seq quot -- )
 575     [ drop length 1 - ] [ change-nth ] 2bi ; inline
 576
 577 : change-last-unsafe ( seq quot -- )
 578     [ drop length 1 - ] [ change-nth-unsafe ] 2bi ; inline
 579
 580 : replicate-into ( ... seq quot: ( ... -- ... newelt ) -- ... )
 581     over [ length ] 2dip '[ _ dip _ set-nth-unsafe ] each-integer ; inline
 582
 583 : count* ( ... seq quot: ( ... elt -- ... ? ) -- ... % )
 584     over [ count ] [ length ] bi* / ; inline
 585
 586 : find-last-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 587     [ [ 1 - ] dip find-last-integer ] (find-index) ; inline
 588
 589 : map-find-last-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 590     [ find-last-index ] (map-find-index) ; inline
 591
 592 :: (start-all) ( subseq seq increment -- indices )
 593     0
 594     [ [ subseq seq ] dip start* dup ]
 595     [ [ increment + ] keep ] produce nip ;
 596
 597 : start-all ( subseq seq -- indices )
 598     over length (start-all) ; inline
 599
 600 : start-all* ( subseq seq -- indices )
 601     1 (start-all) ; inline
 602
 603 : count-subseq ( subseq seq -- n )
 604     start-all length ; inline
 605
 606 : count-subseq* ( subseq seq -- n )
 607     start-all* length ; inline
 608
 609 : map-zip ( quot: ( x -- y ) -- alist )
 610     '[ _ keep swap ] map>alist ; inline