extra/sequences/extras/extras.factor

   1 USING: accessors arrays assocs fry grouping growable kernel
   2 locals make math math.order math.ranges sequences
   3 sequences.deep sequences.private sorting splitting ;
   4 FROM: sequences => change-nth ;
   5 IN: sequences.extras
   6
   7 : reduce1 ( seq quot -- result ) [ unclip ] dip reduce ; inline
   8
   9 :: reduce-r ( seq identity quot: ( obj1 obj2 -- obj ) -- result )
  10     seq [ identity ] [
  11         unclip [ identity quot reduce-r ] [ quot call ] bi*
  12     ] if-empty ; inline recursive
  13
  14 ! Quot must have static stack effect, unlike "reduce"
  15 :: reduce* ( seq identity quot: ( prev elt -- next ) -- result )
  16     seq [ identity ] [
  17         unclip identity swap quot call( prev elt -- next )
  18         quot reduce*
  19     ] if-empty ; inline recursive
  20
  21 :: combos ( list1 list2 -- result )
  22     list2 [ [ 2array ] curry list1 swap map ] map concat ;
  23
  24 : find-all ( seq quot -- elts )
  25     [ [ length iota ] keep ] dip
  26     [ dupd call( a -- ? ) [ 2array ] [ 2drop f ] if ] curry
  27     2map [ ] filter ; inline
  28
  29 : insert-sorted ( elt seq -- seq )
  30     2dup [ < ] with find drop over length or swap insert-nth ;
  31
  32 : reduce-from ( ... seq identity quot: ( ... prev elt -- ... next ) i -- ... result )
  33     [ swap ] 2dip each-from ; inline
  34
  35 : all-subseqs ( seq -- seqs )
  36     dup length [1,b] [ clump ] with map concat ;
  37
  38 :: each-subseq ( ... seq quot: ( ... x -- ... ) -- ... )
  39     seq length :> len
  40     len [0,b] [
  41         :> from
  42         from len (a,b] [
  43             :> to
  44             from to seq subseq quot call( x -- )
  45         ] each
  46     ] each ;
  47
  48 : subseq-as ( from to seq exemplar -- subseq )
  49     [ check-slice subseq>copy (copy) ] dip like ;
  50
  51 : map-like ( seq exemplar -- seq' )
  52     '[ _ like ] map ; inline
  53
  54 : filter-all-subseqs-range ( ... seq range quot: ( ... x -- ... ) -- seq )
  55     [
  56         '[ <clumps> _ filter ] with map concat
  57     ] 3keep 2drop map-like ; inline
  58
  59 : filter-all-subseqs ( ... seq quot: ( ... x -- ... ) -- seq )
  60     [ dup length [1,b] ] dip filter-all-subseqs-range ; inline
  61
  62 :: longest-subseq ( seq1 seq2 -- subseq )
  63     seq1 length :> len1
  64     seq2 length :> len2
  65     0 :> n!
  66     0 :> end!
  67     len1 1 + [ len2 1 + 0 <array> ] replicate :> table
  68     len1 [1,b] [| x |
  69         len2 [1,b] [| y |
  70             x 1 - seq1 nth-unsafe
  71             y 1 - seq2 nth-unsafe = [
  72                 y 1 - x 1 - table nth-unsafe nth-unsafe 1 + :> len
  73                 len y x table nth-unsafe set-nth-unsafe
  74                 len n > [ len n! x end! ] when
  75             ] [ 0 y x table nth-unsafe set-nth-unsafe ] if
  76         ] each
  77     ] each end n - end seq1 subseq ;
  78
  79 : pad-longest ( seq1 seq2 elt -- seq1 seq2 )
  80     [ 2dup max-length ] dip [ pad-tail ] 2curry bi@ ;
  81
  82 : change-nths ( ... indices seq quot: ( ... elt -- ... elt' ) -- ... )
  83     [ change-nth ] 2curry each ; inline
  84
  85 : push-if-index ( ..a elt i quot: ( ..a elt i -- ..b ? ) accum -- ..b )
  86     [ 2keep drop ] dip rot [ push ] [ 2drop ] if ; inline
  87
  88 : index-selector-for ( quot exemplar -- selector accum )
  89     [ length ] keep new-resizable [ [ push-if-index ] 2curry ] keep ; inline
  90
  91 : filter-index-as ( ... seq quot: ( ... elt i -- ... ? ) exemplar -- ... seq' )
  92     dup [ index-selector-for [ each-index ] dip ] curry dip like ; inline
  93
  94 : filter-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... seq' )
  95     over filter-index-as ; inline
  96
  97 : even-indices ( seq -- seq' )
  98     [ length 1 + 2/ ] keep [
  99         [ [ 2 * ] dip nth-unsafe ] curry
 100     ] keep map-integers ;
 101
 102 : odd-indices ( seq -- seq' )
 103     [ length 2/ ] keep [
 104         [ [ 2 * 1 + ] dip nth-unsafe ] curry
 105     ] keep map-integers ;
 106
 107 : compact ( seq quot elt -- seq' )
 108     [ split-when harvest ] dip join ; inline
 109
 110 : collapse ( seq quot elt -- seq' )
 111     [ split-when ] dip
 112     [ [ harvest ] dip join ]
 113     [ [ first empty? ] dip [ prepend ] curry when ]
 114     [ [ last empty? ] dip [ append ] curry when ]
 115     2tri ; inline
 116
 117 :: slice-when ( seq quot: ( elt -- ? ) -- seq' )
 118     seq length :> len
 119     0 [ len dupd < ] [
 120         dup seq quot find-from drop
 121         [ 2dup = [ 1 + ] when ] [ len ] if*
 122         [ seq <slice> ] keep len or swap
 123     ] produce nip ; inline
 124
 125 : rotate ( seq n -- seq' )
 126     cut prepend ;
 127
 128 :: rotate! ( seq n -- )
 129     n seq bounds-check length :> end
 130     0 n [ 2dup = ] [
 131         [ seq exchange-unsafe ] [ [ 1 + ] bi@ ] 2bi
 132         dup end = [ drop over ] when
 133         2over = [ -rot nip over ] when
 134     ] until 3drop ;
 135
 136 : all-rotations ( seq -- seq' )
 137     dup length iota [ rotate ] with map ;
 138
 139 : appender-for ( quot exemplar -- quot' vec )
 140     [ length ] keep new-resizable
 141     [ [ push-all ] curry compose ] keep ; inline
 142
 143 : appender ( quot -- quot' vec )
 144     V{ } appender-for ; inline
 145
 146 : map-concat-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 147     dup [ appender-for [ each ] dip ] curry dip like ; inline
 148
 149 : >resizable ( seq -- vec ) ! fixes map-concat "cannot apply call to run-time..."
 150     [ length ] keep [ new-resizable ] [ over push-all ] bi ;
 151
 152 : map-concat ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 153     over [ 2drop { } ] [
 154         first over call dup [
 155             >resizable [ [ push-all ] curry compose ] keep
 156             [ 1 ] 3dip [ (each) (each-integer) ] dip
 157         ] curry dip like
 158     ] if-empty ; inline
 159
 160 : map-filter-as ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) exemplar -- ... subseq )
 161     dup [ selector-for [ compose each ] dip ] curry dip like ; inline
 162
 163 : map-filter ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) -- ... subseq )
 164     pick map-filter-as ; inline
 165
 166 : map-sift ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 167     [ ] map-filter ; inline
 168
 169 : map-harvest ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 170     [ empty? not ] map-filter ; inline
 171
 172 <PRIVATE
 173
 174 : ((each-from)) ( i seq -- n quot )
 175     [ length over [-] swap ] keep '[ _ + _ nth-unsafe ] ; inline
 176
 177 : (each-from) ( i seq quot -- n quot' ) [ ((each-from)) ] dip compose ;
 178     inline
 179
 180 PRIVATE>
 181
 182 : map-from-as ( ... seq quot: ( ... elt -- ... newelt ) i exemplar -- ... newseq )
 183     [ -rot (each-from) ] dip map-integers ; inline
 184
 185 : map-from ( ... seq quot: ( ... elt -- ... newelt ) i -- ... newseq )
 186     pick map-from-as ; inline
 187
 188 <PRIVATE
 189
 190 : push-map-if ( ..a elt filter-quot: ( ..a elt -- ..b ? ) map-quot: ( ..a elt -- ..b newelt ) accum -- ..b )
 191     [ keep over ] 2dip [ when ] dip rot [ push ] [ 2drop ] if ; inline
 192
 193 : filter-mapper-for ( filter-quot map-quot exemplar -- quot' vec )
 194     [ length ] keep new-resizable [ [ push-map-if ] 3curry ] keep ; inline
 195
 196 : filter-mapper ( filter-quot map-quot -- quot' vec )
 197     V{ } filter-mapper-for ; inline
 198
 199 PRIVATE>
 200
 201 : filter-map-as ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 202     dup [ filter-mapper-for [ each ] dip ] curry dip like ; inline
 203
 204 : filter-map ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) -- ... newseq )
 205     pick filter-map-as ; inline
 206
 207 : 2map-sum ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... n ) -- ... n )
 208     [ 0 ] 3dip [ dip + ] curry [ rot ] prepose 2each ; inline
 209
 210 : 2count ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... n )
 211     [ 1 0 ? ] compose 2map-sum ; inline
 212
 213 : round-robin ( seq -- newseq )
 214     [ { } ] [
 215         [ longest length iota ] keep
 216         [ [ ?nth ] with map ] curry map concat sift
 217     ] if-empty ;
 218
 219 : sift-as ( seq exemplar -- newseq )
 220     [ ] swap filter-as ;
 221
 222 : sift! ( seq -- newseq )
 223     [ ] filter! ;
 224
 225 : harvest-as ( seq exemplar -- newseq )
 226     [ empty? not ] swap filter-as ;
 227
 228 : harvest! ( seq -- newseq )
 229     [ empty? not ] filter! ;
 230
 231 : contains? ( seq elts -- ? )
 232     [ member? ] curry any? ; inline
 233
 234 : head-as ( seq n exemplar -- seq' )
 235     [ head-slice ] [ like ] bi* ; inline
 236
 237 : head*-as ( seq n exemplar -- seq' )
 238     [ head-slice* ] [ like ] bi* ; inline
 239
 240 : tail-as ( seq n exemplar -- seq' )
 241     [ tail-slice ] [ like ] bi* ; inline
 242
 243 : tail*-as ( seq n exemplar -- seq' )
 244     [ tail-slice* ] [ like ] bi* ; inline
 245
 246 : trim-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... newseq )
 247     [ trim-slice ] [ like ] bi* ; inline
 248
 249 : ?trim ( seq quot: ( elt -- ? ) -- seq/newseq )
 250     over empty? [ drop ] [
 251         over [ first-unsafe ] [ last-unsafe ] bi pick bi@ or
 252         [ trim ] [ drop ] if
 253     ] if ; inline
 254
 255 : ?trim-head ( seq quot: ( elt -- ? ) -- seq/newseq )
 256     over empty? [ drop ] [
 257         over first-unsafe over call
 258         [ trim-head ] [ drop ] if
 259     ] if ; inline
 260
 261 : ?trim-tail ( seq quot: ( elt -- ? ) -- seq/newseq )
 262     over empty? [ drop ] [
 263         over last-unsafe over call
 264         [ trim-tail ] [ drop ] if
 265     ] if ; inline
 266
 267 : unsurround ( newseq seq2 seq3 -- seq1 )
 268    [ ?head drop ] [ ?tail drop ] bi* ;
 269
 270 : none? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 271     any? not ; inline
 272
 273 : one? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 274     [ find ] 2keep rot [
 275         [ 1 + ] 2dip find-from drop not
 276     ] [ 3drop f ] if ; inline
 277
 278 : map-index! ( ... seq quot: ( ... elt index -- ... newelt ) -- ... seq )
 279     over [ [ (each-index) ] dip collect ] keep ; inline
 280
 281 <PRIVATE
 282
 283 : (2each-index) ( seq1 seq2 quot -- n quot' )
 284     [ ((2each)) [ keep ] curry ] dip compose ; inline
 285
 286 PRIVATE>
 287
 288 : 2each-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... ) -- ... )
 289     (2each-index) each-integer ; inline
 290
 291 : 2map-into ( seq1 seq2 quot into -- )
 292     [ (2each) ] dip collect ; inline
 293
 294 : 2map! ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... seq1 )
 295     pick [ 2map-into ] keep ; inline
 296
 297 : 2map-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... newelt ) -- ... newseq )
 298     pick [ (2each-index) ] dip map-integers ; inline
 299
 300 TUPLE: evens seq length ;
 301
 302 : <evens> ( seq -- evens )
 303     dup length 1 + 2/ evens boa ; inline
 304
 305 M: evens length length>> ; inline
 306
 307 M: evens nth-unsafe [ 2 * ] [ seq>> nth-unsafe ] bi* ; inline
 308
 309 INSTANCE: evens immutable-sequence
 310
 311 TUPLE: odds seq length ;
 312
 313 : <odds> ( seq -- odds )
 314     dup length 2/ odds boa ; inline
 315
 316 M: odds length length>> ; inline
 317
 318 M: odds nth-unsafe [ 2 * 1 + ] [ seq>> nth-unsafe ] bi* ; inline
 319
 320 INSTANCE: odds immutable-sequence
 321
 322 : until-empty ( seq quot -- )
 323     [ dup empty? ] swap until drop ; inline
 324
 325 : arg-max ( seq -- n )
 326     dup length iota zip [ first-unsafe ] supremum-by second ;
 327
 328 : arg-min ( seq -- n )
 329     dup length iota zip [ first-unsafe ] infimum-by second ;
 330
 331 : arg-where ( ... seq quot: ( ... elt -- ... ? ) -- ... indices )
 332     [ dup length iota zip ] dip
 333     [ first-unsafe ] prepose filter values ; inline
 334
 335 : arg-sort ( seq -- indices )
 336     dup length iota zip sort-keys values ;
 337
 338 : first= ( seq elt -- ? ) [ first ] dip = ; inline
 339 : second= ( seq elt -- ? ) [ second ] dip = ; inline
 340 : third= ( seq elt -- ? ) [ third ] dip = ; inline
 341 : fourth= ( seq elt -- ? ) [ fourth ] dip = ; inline
 342 : last= ( seq elt -- ? ) [ last ] dip = ; inline
 343 : nth= ( n seq elt -- ? ) [ nth ] dip = ; inline
 344
 345 : first? ( seq quot -- ? ) [ first ] dip call ; inline
 346 : second? ( seq quot -- ? ) [ second ] dip call ; inline
 347 : third? ( seq quot -- ? ) [ third ] dip call ; inline
 348 : fourth? ( seq quot -- ? ) [ fourth ] dip call ; inline
 349 : last? ( seq quot -- ? ) [ last ] dip call ; inline
 350 : nth? ( n seq quot -- ? ) [ nth ] dip call ; inline
 351
 352 : loop>sequence ( quot exemplar -- seq )
 353    [ '[ [ @ [ [ , ] when* ] keep ] loop ] ] dip make ; inline
 354
 355 : loop>array ( quot -- seq )
 356    { } loop>sequence ; inline
 357
 358 <PRIVATE
 359
 360 : (reverse) ( seq -- newseq )
 361     dup [ length ] keep new-sequence [ 0 swap copy ] keep reverse! ;
 362
 363 PRIVATE>
 364
 365 : reverse-as ( seq exemplar -- newseq )
 366     [ (reverse) ] [ like ] bi* ;
 367
 368 : map-product ( ... seq quot: ( ... elt -- ... n ) -- ... n )
 369     [ 1 ] 2dip [ dip * ] curry [ swap ] prepose each ; inline
 370
 371 : insert-nth! ( elt n seq -- )
 372     [ length ] keep ensure swap pick (a,b]
 373     over '[ [ 1 + ] keep _ move-unsafe ] each
 374     set-nth-unsafe ;
 375
 376 : set-nths ( value indices seq -- )
 377     swapd '[ [ _ ] dip _ set-nth ] each ; inline
 378
 379 : set-nths-unsafe ( value indices seq -- )
 380     swapd '[ [ _ ] dip _ set-nth-unsafe ] each ; inline
 381
 382 : flatten1 ( obj -- seq )
 383     [
 384         [
 385             dup branch? [
 386                 [ dup branch? [ % ] [ , ] if ] each
 387             ] [ , ] if
 388         ]
 389     ] keep dup branch? [ drop f ] unless make ;
 390
 391 : (map-find-index) ( seq quot find-quot -- result elt index )
 392     [ [ f ] 2dip [ [ nip ] 2dip call dup ] curry ] dip call
 393     [ [ [ drop f ] unless ] keep ] dip ; inline
 394
 395 : map-find-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result elt index )
 396     [ find-index ] (map-find-index) ; inline
 397
 398 : filter-length ( seq n -- seq' ) swap [ length = ] with filter ;
 399
 400 : all-shortest ( seqs -- seqs' ) dup shortest length filter-length ;
 401
 402 : all-longest ( seqs -- seqs' ) dup longest length filter-length ;