extra/sequences/extras/extras.factor

   1 USING: accessors arrays assocs combinators fry generalizations
   2 grouping growable kernel locals make math math.order math.ranges
   3 sequences sequences.deep sequences.private sorting splitting
   4 vectors ;
   5 IN: sequences.extras
   6
   7 : find-all ( ... seq quot: ( ... elt -- ... ? ) -- ... elts )
   8     [ <enumerated> ] dip '[ nip @ ] assoc-filter ; inline
   9
  10 : reduce-from ( ... seq identity quot: ( ... prev elt -- ... next ) i -- ... result )
  11     [ swap ] 2dip each-from ; inline
  12
  13 :: subseq* ( from to seq -- subseq )
  14     seq length :> len
  15     from [ dup 0 < [ len + ] when ] [ 0 ] if*
  16     to [ dup 0 < [ len + ] when ] [ len ] if*
  17     [ 0 len clamp ] bi@ dupd max seq subseq ;
  18
  19 : safe-subseq ( from to seq -- subseq )
  20     [ length '[ 0 _ clamp ] bi@ ] keep subseq ;
  21
  22 : all-subseqs ( seq -- seqs )
  23     dup length [1,b] [ clump ] with map concat ;
  24
  25 :: each-subseq ( ... seq quot: ( ... subseq -- ... ) -- ... )
  26     seq length :> len
  27     len [0,b] [| from |
  28         from len (a,b] [| to |
  29             from to seq subseq quot call
  30         ] each
  31     ] each ; inline
  32
  33 : map-like ( seq exemplar -- seq' )
  34     '[ _ like ] map ; inline
  35
  36 : filter-all-subseqs-range ( ... seq range quot: ( ... subseq -- ... ? ) -- seq )
  37     [
  38         '[ <clumps> _ filter ] with map concat
  39     ] keepdd map-like ; inline
  40
  41 : filter-all-subseqs ( ... seq quot: ( ... subseq -- ... ? ) -- seq )
  42     [ dup length [1,b] ] dip filter-all-subseqs-range ; inline
  43
  44 :: longest-subseq ( seq1 seq2 -- subseq )
  45     seq1 length :> len1
  46     seq2 length :> len2
  47     0 :> n!
  48     0 :> end!
  49     len1 1 + [ len2 1 + 0 <array> ] replicate :> table
  50     len1 [1,b] [| x |
  51         len2 [1,b] [| y |
  52             x 1 - seq1 nth-unsafe
  53             y 1 - seq2 nth-unsafe = [
  54                 y 1 - x 1 - table nth-unsafe nth-unsafe 1 + :> len
  55                 len y x table nth-unsafe set-nth-unsafe
  56                 len n > [ len n! x end! ] when
  57             ] [ 0 y x table nth-unsafe set-nth-unsafe ] if
  58         ] each
  59     ] each end n - end seq1 subseq ;
  60
  61 : pad-longest ( seq1 seq2 elt -- seq1 seq2 )
  62     [ 2dup max-length ] dip [ pad-tail ] 2curry bi@ ;
  63
  64 : pad-center ( seq n elt -- padded )
  65     swap pick length [-] [ drop ] [
  66         [ 2/ ] [ over - ] bi rot '[ _ <repetition> ] bi@ surround
  67     ] if-zero ;
  68
  69 : change-nths ( ... indices seq quot: ( ... elt -- ... elt' ) -- ... )
  70     [ change-nth ] 2curry each ; inline
  71
  72 : push-if-index ( ..a elt i quot: ( ..a elt i -- ..b ? ) accum -- ..b )
  73     [ keepd ] dip rot [ push ] [ 2drop ] if ; inline
  74
  75 : push-if* ( ..a elt quot: ( ..a elt -- ..b obj/f ) accum -- ..b )
  76     [ call ] dip [ push ] [ drop ] if* ; inline
  77
  78 <PRIVATE
  79
  80 : (index-selector-as) ( quot length exampler -- selector accum )
  81     new-resizable [ [ push-if-index ] 2curry ] keep ; inline
  82
  83 : (selector-as*) ( quot length exemplar -- selector accum )
  84     new-resizable [ [ push-if* ] 2curry ] keep ; inline
  85
  86 PRIVATE>
  87
  88 : index-selector-as ( quot exemplar -- selector accum )
  89     [ length ] keep (index-selector-as) ; inline
  90
  91 : index-selector ( quot -- selector accum )
  92     V{ } index-selector-as ; inline
  93
  94 : selector-as* ( quot exemplar -- selector accum )
  95     [ length ] keep (selector-as*) ; inline
  96
  97 : selector* ( quot -- selector accum ) V{ } selector-as* ; inline
  98
  99 : filter-index-as ( ... seq quot: ( ... elt i -- ... ? ) exemplar -- ... seq' )
 100     pick length over [ (index-selector-as) [ each-index ] dip ] 2curry dip like ; inline
 101
 102 : filter-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... seq' )
 103     over filter-index-as ; inline
 104
 105 : even-indices ( seq -- seq' )
 106     [ length 1 + 2/ ] keep [
 107         [ [ 2 * ] dip nth-unsafe ] curry
 108     ] keep map-integers ;
 109
 110 : odd-indices ( seq -- seq' )
 111     [ length 2/ ] keep [
 112         [ [ 2 * 1 + ] dip nth-unsafe ] curry
 113     ] keep map-integers ;
 114
 115 : compact ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 116     [ split-when harvest ] dip join ; inline
 117
 118 : collapse ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 119     [ split-when ] dip
 120     [ [ harvest ] dip join ]
 121     [ [ first empty? ] dip [ prepend ] curry when ]
 122     [ [ last empty? ] dip [ append ] curry when ]
 123     2tri ; inline
 124
 125 :: slice-when ( seq quot: ( elt -- ? ) -- seq' )
 126     seq length :> len
 127     0 [ len dupd < ] [
 128         dup seq quot find-from drop
 129         [ 2dup = [ 1 + ] when ] [ len ] if*
 130         [ seq <slice> ] keep len or swap
 131     ] produce nip ; inline
 132
 133 : cut-slice* ( seq n -- before after )
 134     [ head-slice* ] [ tail-slice* ] 2bi ;
 135
 136 : ?<slice> ( from/f to/f sequence -- slice )
 137     [ [ 0 ] unless* ] 2dip
 138     over [ nip [ length ] [ ] bi ] unless
 139     <slice> ; inline
 140
 141 : sequence>slice ( sequence -- slice )
 142     [ drop 0 ] [ length ] [ ] tri <slice> ; inline
 143
 144 : slice-order-by-from ( slice1 slice2 -- slice-lt slice-gt )
 145     2dup [ from>> ] bi@ > [ swap ] when ; inline
 146
 147 : ordered-slices-range ( slice-lt slice-gt -- to from )
 148     [ to>> ] [ from>> ] bi* ;
 149
 150 : unordered-slices-range ( slice1 slice2 -- to from )
 151     slice-order-by-from ordered-slices-range ;
 152
 153 : ordered-slices-overlap? ( slice-lt slice-gt -- ? )
 154     ordered-slices-range > ; inline
 155
 156 : unordered-slices-overlap? ( slice1 slice2 -- ? )
 157     unordered-slices-range > ; inline
 158
 159 : slices-overlap? ( slice1 slice2 -- ? )
 160     unordered-slices-overlap? ;
 161
 162 : ordered-slices-touch? ( slice-lt slice-gt -- ? )
 163     ordered-slices-range >= ; inline
 164
 165 : unordered-slices-touch? ( slice1 slice2 -- ? )
 166     unordered-slices-range >= ; inline
 167
 168 : slices-touch? ( slice1 slice2 -- ? )
 169     unordered-slices-touch? ;
 170
 171 ERROR: slices-don't-touch slice1 slice2 ;
 172
 173 : merge-slices ( slice1 slice2 -- slice/* )
 174     slice-order-by-from
 175     2dup ordered-slices-touch? [
 176         [ from>> ] [ [ to>> ] [ seq>> ] bi ] bi* <slice>
 177     ] [
 178         slices-don't-touch
 179     ] if ;
 180
 181 : rotate ( seq n -- seq' )
 182     over length mod dup 0 >= [ cut ] [ abs cut* ] if prepend ;
 183
 184 ERROR: underlying-mismatch slice1 slice2 ;
 185
 186 : ensure-same-underlying ( slice1 slice2 -- slice1 slice2 )
 187     2dup [ seq>> ] bi@ eq? [ underlying-mismatch ] unless ;
 188
 189 : span-slices ( slice1 slice2 -- slice )
 190     ensure-same-underlying
 191     [ [ from>> ] bi@ min ]
 192     [ [ to>> ] bi@ max ]
 193     [ drop seq>> ] 2tri <slice> ;
 194
 195 : ?span-slices ( slice1/f slice2/f -- slice )
 196     2dup and [ span-slices ] [ or ] if ;
 197
 198 :: rotate! ( seq n -- )
 199     seq length :> len
 200     n len mod dup 0 < [ len + ] when seq bounds-check drop 0 over
 201     [ 2dup = ] [
 202         [ seq exchange-unsafe ] [ [ 1 + ] bi@ ] 2bi
 203         dup len = [ drop over ] when
 204         2over = [ -rot nip over ] when
 205     ] until 3drop ;
 206
 207 : all-rotations ( seq -- seq' )
 208     dup length <iota> [ rotate ] with map ;
 209
 210 <PRIVATE
 211
 212 : (appender-for) ( quot length exemplar -- appender accum )
 213     new-resizable [ [ push-all ] curry compose ] keep ; inline
 214
 215 PRIVATE>
 216
 217 : appender-for ( quot exemplar -- appender accum )
 218     [ length ] keep (appender-for) ; inline
 219
 220 : appender ( quot -- appender accum )
 221     V{ } appender-for ; inline
 222
 223 : map-concat-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 224     [ appender-for [ each ] dip ] keep like ; inline
 225
 226 : >resizable ( seq -- accum ) ! fixes map-concat "cannot apply call to run-time..."
 227     [ length ] keep [ new-resizable ] [ append! ] bi ;
 228
 229 : map-concat ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 230     over empty? [ 2drop { } ] [
 231         [ [ first ] dip call ] 2keep rot [
 232             >resizable [ '[ @ _ push-all ] 1 each-from ] keep
 233         ] keep like
 234     ] if ; inline
 235
 236 : map-filter-as ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) exemplar -- ... subseq )
 237     reach length over
 238     [ (selector-as) [ compose each ] dip ] 2curry dip like ; inline
 239
 240 : map-filter ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) -- ... subseq )
 241     pick map-filter-as ; inline
 242
 243 : map-sift ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 244     [ ] map-filter ; inline
 245
 246 : map-harvest ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 247     [ empty? not ] map-filter ; inline
 248
 249 <PRIVATE
 250
 251 : (setup-each-from) ( i seq -- n quot )
 252     [ length over [-] swap ] keep '[ _ + _ nth-unsafe ] ; inline
 253
 254 : setup-each-from ( i seq quot -- n quot' )
 255     [ (setup-each-from) ] dip compose ; inline
 256
 257 PRIVATE>
 258
 259 : map-from-as ( ... seq quot: ( ... elt -- ... newelt ) i exemplar -- ... newseq )
 260     [ -rot setup-each-from ] dip map-integers ; inline
 261
 262 : map-from ( ... seq quot: ( ... elt -- ... newelt ) i -- ... newseq )
 263     pick map-from-as ; inline
 264
 265 <PRIVATE
 266
 267 : push-map-if ( ..a elt filter-quot: ( ..a elt -- ..b ? ) map-quot: ( ..a elt -- ..b newelt ) accum -- ..b )
 268     [ keep over ] 2dip [ when ] dip rot [ push ] [ 2drop ] if ; inline
 269
 270 : (filter-mapper-for) ( filter-quot map-quot length exempler -- filter-mapper accum )
 271     new-resizable [ [ push-map-if ] 3curry ] keep ; inline
 272
 273 : filter-mapper-for ( filter-quot map-quot exemplar -- filter-mapper accum )
 274     [ length ] keep (filter-mapper-for) ; inline
 275
 276 : filter-mapper ( filter-quot map-quot -- filter-mapper accum )
 277     V{ } filter-mapper-for ; inline
 278
 279 PRIVATE>
 280
 281 : filter-map-as ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 282     reach length over
 283     [ (filter-mapper-for) [ each ] dip ] 2curry dip like ; inline
 284
 285 : filter-map ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) -- ... newseq )
 286     pick filter-map-as ; inline
 287
 288 : 2map-sum ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... n ) -- ... n )
 289     [ 0 ] 3dip [ dip + ] curry [ rot ] prepose 2each ; inline
 290
 291 : 2count ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... n )
 292     [ 1 0 ? ] compose 2map-sum ; inline
 293
 294 : 3each-from
 295     ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... ) i -- ... )
 296     [ (3each) ] dip -rot (each-integer) ; inline
 297
 298 : 3map-reduce
 299     ( ..a seq1 seq2 seq3 map-quot: ( ..a elt1 elt2 elt3 -- ..b intermediate ) reduce-quot: ( ..b prev intermediate -- ..a next ) -- ..a result )
 300     [ [ [ [ first ] tri@ ] 3keep ] dip [ 3dip ] keep ] dip compose 1 3each-from ; inline
 301
 302 : round-robin ( seq -- newseq )
 303     [ { } ] [
 304         [ longest length <iota> ] keep
 305         [ [ ?nth ] with map ] curry map concat sift
 306     ] if-empty ;
 307
 308 : sift-as ( seq exemplar -- newseq )
 309     [ ] swap filter-as ;
 310
 311 : sift! ( seq -- newseq )
 312     [ ] filter! ;
 313
 314 : harvest-as ( seq exemplar -- newseq )
 315     [ empty? not ] swap filter-as ;
 316
 317 : harvest! ( seq -- newseq )
 318     [ empty? ] reject! ;
 319
 320 : head-as ( seq n exemplar -- seq' )
 321     [ head-slice ] [ like ] bi* ; inline
 322
 323 : head*-as ( seq n exemplar -- seq' )
 324     [ head-slice* ] [ like ] bi* ; inline
 325
 326 : tail-as ( seq n exemplar -- seq' )
 327     [ tail-slice ] [ like ] bi* ; inline
 328
 329 : tail*-as ( seq n exemplar -- seq' )
 330     [ tail-slice* ] [ like ] bi* ; inline
 331
 332 : trim-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... newseq )
 333     [ trim-slice ] [ like ] bi* ; inline
 334
 335 : ?trim ( seq quot: ( elt -- ? ) -- seq/newseq )
 336     over empty? [ drop ] [
 337         over [ first-unsafe ] [ last-unsafe ] bi pick either?
 338         [ trim ] [ drop ] if
 339     ] if ; inline
 340
 341 : ?trim-head ( seq quot: ( elt -- ? ) -- seq/newseq )
 342     over empty? [ drop ] [
 343         over first-unsafe over call
 344         [ trim-head ] [ drop ] if
 345     ] if ; inline
 346
 347 : ?trim-tail ( seq quot: ( elt -- ? ) -- seq/newseq )
 348     over empty? [ drop ] [
 349         over last-unsafe over call
 350         [ trim-tail ] [ drop ] if
 351     ] if ; inline
 352
 353 : unsurround ( newseq seq2 seq3 -- seq1 )
 354    [ ?head drop ] [ ?tail drop ] bi* ;
 355
 356 : one? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 357     [ find ] 2keep rot [
 358         [ 1 + ] 2dip find-from drop not
 359     ] [ 3drop f ] if ; inline
 360
 361 : map-index! ( ... seq quot: ( ... elt index -- ... newelt ) -- ... seq )
 362     over [ [ (each-index) ] dip collect ] keep ; inline
 363
 364 <PRIVATE
 365
 366 : (2each-index) ( seq1 seq2 quot -- n quot' )
 367     [ setup-2each [ keep ] curry ] dip compose ; inline
 368
 369 PRIVATE>
 370
 371 : 2each-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... ) -- ... )
 372     (2each-index) each-integer ; inline
 373
 374 : 2map-into ( seq1 seq2 quot into -- )
 375     [ (2each) ] dip collect ; inline
 376
 377 : 2map! ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... seq1 )
 378     pick [ 2map-into ] keep ; inline
 379
 380 : 2map-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... newelt ) -- ... newseq )
 381     pick [ (2each-index) ] dip map-integers ; inline
 382
 383 TUPLE: evens { seq read-only } ;
 384
 385 C: <evens> evens
 386
 387 M: evens length seq>> length 1 + 2/ ; inline
 388
 389 M: evens virtual@ [ 2 * ] [ seq>> ] bi* ; inline
 390
 391 M: evens virtual-exemplar seq>> ; inline
 392
 393 INSTANCE: evens virtual-sequence
 394
 395 TUPLE: odds { seq read-only } ;
 396
 397 C: <odds> odds
 398
 399 M: odds length seq>> length 2/ ; inline
 400
 401 M: odds virtual@ [ 2 * 1 + ] [ seq>> ] bi* ; inline
 402
 403 M: odds virtual-exemplar seq>> ; inline
 404
 405 INSTANCE: odds virtual-sequence
 406
 407 : until-empty ( seq quot -- )
 408     [ dup empty? ] swap until drop ; inline
 409
 410 : arg-max ( seq -- n )
 411     [ supremum ] keep index ;
 412
 413 : arg-min ( seq -- n )
 414     [ infimum ] keep index ;
 415
 416 <PRIVATE
 417
 418 : push-index-if ( ..a elt i quot: ( ..a elt -- ..b ? ) accum -- ..b )
 419     [ dip ] dip rot [ push ] [ 2drop ] if ; inline
 420
 421 PRIVATE>
 422
 423 : arg-where ( ... seq quot: ( ... elt -- ... ? ) -- ... indices )
 424     over length <vector> [
 425         [ push-index-if ] 2curry each-index
 426     ] keep ; inline
 427
 428 : arg-sort ( seq -- indices )
 429     zip-index sort-keys values ;
 430
 431 : first= ( seq elt -- ? ) [ first ] dip = ; inline
 432 : second= ( seq elt -- ? ) [ second ] dip = ; inline
 433 : third= ( seq elt -- ? ) [ third ] dip = ; inline
 434 : fourth= ( seq elt -- ? ) [ fourth ] dip = ; inline
 435 : last= ( seq elt -- ? ) [ last ] dip = ; inline
 436 : nth= ( n seq elt -- ? ) [ nth ] dip = ; inline
 437
 438 : first? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ first ] dip call ; inline
 439 : second? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ second ] dip call ; inline
 440 : third? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ third ] dip call ; inline
 441 : fourth? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ fourth ] dip call ; inline
 442 : last? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ last ] dip call ; inline
 443 : nth? ( ... n seq quot: ( ... elt -- ... ? ) -- ... ? ) [ nth ] dip call ; inline
 444
 445 : loop>sequence** ( ... quot: ( ... -- ... obj ? ) exemplar -- ... seq )
 446     [ ] swap produce-as nip ; inline
 447
 448 : loop>array** ( ... quot: ( ... -- ... obj ? ) -- ... array )
 449     { } loop>sequence** ; inline
 450
 451 : loop>sequence* ( ... quot: ( ... -- ... obj ? ) exemplar -- ... seq )
 452     [ t ] [ '[ [ _ dip ] [ f f f ] if* ] [ swap ] ] [ produce-as 2nip ] tri* ; inline
 453
 454 : loop>array* ( ... quot: ( ... -- ... obj ? ) -- ... array )
 455     { } loop>sequence* ; inline
 456
 457 : loop>sequence ( ... quot: ( ... -- ... obj/f ) exemplar -- ... seq )
 458     [ [ dup ] compose [ ] ] dip produce-as nip ; inline
 459
 460 : loop>array ( ... quot: ( ... -- ... obj/f ) -- ... array )
 461    { } loop>sequence ; inline
 462
 463 : zero-loop>sequence ( ... quot: ( ... n -- ... obj/f ) exemplar -- ... seq )
 464     [ 0 ] [ '[ _ keep 1 + swap ] ] [ loop>sequence ] tri* nip ; inline
 465
 466 : zero-loop>array ( quot: ( ..a n -- ..a obj ) -- seq )
 467     { } zero-loop>sequence ; inline
 468
 469 <PRIVATE
 470
 471 : (reverse) ( seq -- newseq )
 472     dup [ length ] keep new-sequence
 473     [ 0 swap copy-unsafe ] keep reverse! ;
 474
 475 PRIVATE>
 476
 477 : reverse-as ( seq exemplar -- newseq )
 478     [ (reverse) ] [ like ] bi* ;
 479
 480 : map-product ( ... seq quot: ( ... elt -- ... n ) -- ... n )
 481     [ 1 ] 2dip [ dip * ] curry [ swap ] prepose each ; inline
 482
 483 : insert-nth! ( elt n seq -- )
 484     [ length ] keep ensure swap pick (a,b]
 485     over '[ [ 1 + ] keep _ move-unsafe ] each
 486     set-nth-unsafe ;
 487
 488 : set-nths ( value indices seq -- )
 489     swapd '[ _ swap _ set-nth ] each ; inline
 490
 491 : set-nths-unsafe ( value indices seq -- )
 492     swapd '[ _ swap _ set-nth-unsafe ] each ; inline
 493
 494 <PRIVATE
 495
 496 : (map-find-index) ( seq quot find-quot -- result i elt )
 497     [ [ f ] 2dip [ [ nip ] 2dip call dup ] curry ] dip call
 498     [ [ [ drop f ] unless ] keep ] dip ; inline
 499
 500 PRIVATE>
 501
 502 : map-find-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 503     [ find-index ] (map-find-index) ; inline
 504
 505 : filter-length ( seq n -- seq' ) '[ length _ = ] filter ;
 506
 507 : all-shortest ( seqs -- seqs' ) dup shortest length filter-length ;
 508
 509 : all-longest ( seqs -- seqs' ) dup longest length filter-length ;
 510
 511 : remove-first ( obj seq -- seq' )
 512     [ index ] keep over [ remove-nth ] [ nip ] if ;
 513
 514 : remove-first! ( obj seq -- seq )
 515     [ index ] keep over [ remove-nth! ] [ nip ] if ;
 516
 517 : remove-last ( obj seq -- seq' )
 518     [ last-index ] keep over [ remove-nth ] [ nip ] if ;
 519
 520 : remove-last! ( obj seq -- seq )
 521     [ last-index ] keep over [ remove-nth! ] [ nip ] if ;
 522
 523 : ?first2 ( seq -- first/f second/f )
 524     dup length {
 525         { 0 [ drop f f ] }
 526         { 1 [ first-unsafe f ] }
 527         [ drop first2-unsafe ]
 528     } case ;
 529
 530 : ?first3 ( seq -- first/f second/f third/f )
 531     dup length {
 532         { 0 [ drop f f f ] }
 533         { 1 [ first-unsafe f f ] }
 534         { 2 [ first2-unsafe f ] }
 535         [ drop first3-unsafe ]
 536     } case ;
 537
 538 : ?first4 ( seq -- first/f second/f third/f fourth/f )
 539     dup length {
 540         { 0 [ drop f f f f ] }
 541         { 1 [ first-unsafe f f f ] }
 542         { 2 [ first2-unsafe f f ] }
 543         { 3 [ first3-unsafe f ] }
 544         [ drop first4-unsafe ]
 545     } case ;
 546
 547 : cut-when ( ... seq quot: ( ... elt -- ... ? ) -- ... before after )
 548     [ find drop ] keepd swap
 549     [ cut ] [ f over like ] if* ; inline
 550
 551 : nth* ( n seq -- elt )
 552     [ length 1 - swap - ] [ nth ] bi ; inline
 553
 554 : each-index-from ( ... seq quot: ( ... elt index -- ... ) i -- ... )
 555     -rot (each-index) (each-integer) ; inline
 556
 557 <PRIVATE
 558
 559 : select-by* ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... i elt )
 560     [
 561         [ keep swap ] curry [ dip ] curry
 562         [ [ first 0 ] dip call ] 2keep
 563         [ 2curry 3dip 5 npick pick ] curry
 564     ] [
 565         [ [ 3drop ] [ [ 3drop ] 3dip ] if ] compose
 566     ] bi* compose 1 each-index-from nip swap ; inline
 567
 568 PRIVATE>
 569
 570 : supremum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 571     [ after? ] select-by* ; inline
 572
 573 : infimum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 574     [ before? ] select-by* ; inline
 575
 576 : ?supremum ( seq/f -- elt/f )
 577     [ f ] [
 578         [ ] [ 2dup and [ max ] [ dupd ? ] if ] map-reduce
 579     ] if-empty ;
 580
 581 : ?infimum ( seq/f -- elt/f )
 582     [ f ] [
 583         [ ] [ 2dup and [ min ] [ dupd ? ] if ] map-reduce
 584     ] if-empty ;
 585
 586 : change-last ( seq quot -- )
 587     [ drop length 1 - ] [ change-nth ] 2bi ; inline
 588
 589 : change-last-unsafe ( seq quot -- )
 590     [ drop length 1 - ] [ change-nth-unsafe ] 2bi ; inline
 591
 592 : replicate-into ( ... seq quot: ( ... -- ... newelt ) -- ... )
 593     over [ length ] 2dip '[ _ dip _ set-nth-unsafe ] each-integer ; inline
 594
 595 : count* ( ... seq quot: ( ... elt -- ... ? ) -- ... % )
 596     over [ count ] [ length ] bi* / ; inline
 597
 598 : find-last-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 599     [ [ 1 - ] dip find-last-integer ] (find-index) ; inline
 600
 601 : map-find-last-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 602     [ find-last-index ] (map-find-index) ; inline
 603
 604 :: (start-all) ( subseq seq increment -- indices )
 605     0
 606     [ [ subseq seq ] dip subseq-start-from dup ]
 607     [ [ increment + ] keep ] produce nip ;
 608
 609 : start-all ( subseq seq -- indices )
 610     over length (start-all) ; inline
 611
 612 : start-all* ( subseq seq -- indices )
 613     1 (start-all) ; inline
 614
 615 : count-subseq ( subseq seq -- n )
 616     start-all length ; inline
 617
 618 : count-subseq* ( subseq seq -- n )
 619     start-all* length ; inline
 620
 621 : map-zip ( quot: ( key -- value ) -- alist )
 622     '[ _ keep swap ] map>alist ; inline
 623
 624 : take-while ( ... seq quot: ( ... elt -- ... ? ) -- head-slice )
 625     [ '[ @ not ] find drop ] keepd swap
 626     [ dup length ] unless* head-slice ; inline
 627
 628 : drop-while ( ... seq quot: ( ... elt -- ... ? ) -- tail-slice )
 629     [ '[ @ not ] find drop ] keepd swap
 630     [ dup length ] unless* tail-slice ; inline
 631
 632 : count-head ( seq quot -- n )
 633     [ not ] compose [ find drop ] 2keep drop length or ; inline
 634
 635 : count-tail ( seq quot -- n )
 636     [ not ] compose [ find-last drop ] 2keep drop
 637     length swap [ - 1 - ] when* ; inline
 638
 639 :: interleaved-as ( seq glue exemplar -- newseq )
 640     seq length dup 1 - + 0 max exemplar new-sequence :> newseq
 641     seq [ 2 * newseq set-nth-unsafe ] each-index
 642     seq length 1 - [ 2 * 1 + glue swap newseq set-nth-unsafe ] each-integer
 643     newseq ;
 644
 645 : interleaved ( seq glue -- newseq )
 646     over interleaved-as ;
 647
 648 : extract! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 649     [ dup ] compose over [ length ] keep new-resizable
 650     [ [ push-if ] 2curry reject! ] keep swap like ; inline