extra/sequences/extras/extras.factor

   1 USING: accessors arrays assocs fry grouping growable kernel
   2 locals make math math.order math.ranges sequences
   3 sequences.deep sequences.private sorting splitting vectors ;
   4 FROM: sequences => change-nth ;
   5 IN: sequences.extras
   6
   7 : reduce1 ( seq quot -- result ) [ unclip ] dip reduce ; inline
   8
   9 :: reduce-r ( seq identity quot: ( obj1 obj2 -- obj ) -- result )
  10     seq [ identity ] [
  11         unclip [ identity quot reduce-r ] [ quot call ] bi*
  12     ] if-empty ; inline recursive
  13
  14 ! Quot must have static stack effect, unlike "reduce"
  15 :: reduce* ( seq identity quot: ( prev elt -- next ) -- result )
  16     seq [ identity ] [
  17         unclip identity swap quot call( prev elt -- next )
  18         quot reduce*
  19     ] if-empty ; inline recursive
  20
  21 :: combos ( list1 list2 -- result )
  22     list2 [ [ 2array ] curry list1 swap map ] map concat ;
  23
  24 : find-all ( seq quot: ( elt -- ? ) -- elts )
  25     [ [ length iota ] keep ] dip
  26     [ dupd call( a -- ? ) [ 2array ] [ 2drop f ] if ] curry
  27     2map [ ] filter ; inline
  28
  29 : insert-sorted ( elt seq -- seq )
  30     2dup [ < ] with find drop over length or swap insert-nth ;
  31
  32 : reduce-from ( ... seq identity quot: ( ... prev elt -- ... next ) i -- ... result )
  33     [ swap ] 2dip each-from ; inline
  34
  35 : all-subseqs ( seq -- seqs )
  36     dup length [1,b] [ clump ] with map concat ;
  37
  38 :: each-subseq ( ... seq quot: ( ... x -- ... ) -- ... )
  39     seq length :> len
  40     len [0,b] [
  41         :> from
  42         from len (a,b] [
  43             :> to
  44             from to seq subseq quot call
  45         ] each
  46     ] each ; inline
  47
  48 : subseq-as ( from to seq exemplar -- subseq )
  49     [ check-slice subseq>copy (copy) ] dip like ;
  50
  51 : map-like ( seq exemplar -- seq' )
  52     '[ _ like ] map ; inline
  53
  54 : filter-all-subseqs-range ( ... seq range quot: ( ... x -- ... ) -- seq )
  55     [
  56         '[ <clumps> _ filter ] with map concat
  57     ] 3keep 2drop map-like ; inline
  58
  59 : filter-all-subseqs ( ... seq quot: ( ... x -- ... ) -- seq )
  60     [ dup length [1,b] ] dip filter-all-subseqs-range ; inline
  61
  62 :: longest-subseq ( seq1 seq2 -- subseq )
  63     seq1 length :> len1
  64     seq2 length :> len2
  65     0 :> n!
  66     0 :> end!
  67     len1 1 + [ len2 1 + 0 <array> ] replicate :> table
  68     len1 [1,b] [| x |
  69         len2 [1,b] [| y |
  70             x 1 - seq1 nth-unsafe
  71             y 1 - seq2 nth-unsafe = [
  72                 y 1 - x 1 - table nth-unsafe nth-unsafe 1 + :> len
  73                 len y x table nth-unsafe set-nth-unsafe
  74                 len n > [ len n! x end! ] when
  75             ] [ 0 y x table nth-unsafe set-nth-unsafe ] if
  76         ] each
  77     ] each end n - end seq1 subseq ;
  78
  79 : pad-longest ( seq1 seq2 elt -- seq1 seq2 )
  80     [ 2dup max-length ] dip [ pad-tail ] 2curry bi@ ;
  81
  82 : change-nths ( ... indices seq quot: ( ... elt -- ... elt' ) -- ... )
  83     [ change-nth ] 2curry each ; inline
  84
  85 : push-if-index ( ..a elt i quot: ( ..a elt i -- ..b ? ) accum -- ..b )
  86     [ 2keep drop ] dip rot [ push ] [ 2drop ] if ; inline
  87
  88 <PRIVATE
  89
  90 : (index-selector-for) ( quot length exampler -- selector accum )
  91     new-resizable [ [ push-if-index ] 2curry ] keep ; inline
  92
  93 PRIVATE>
  94
  95 : index-selector-for ( quot exemplar -- selector accum )
  96     [ length ] keep (index-selector-for) ; inline
  97
  98 : filter-index-as ( ... seq quot: ( ... elt i -- ... ? ) exemplar -- ... seq' )
  99     pick length over [ (index-selector-for) [ each-index ] dip ] 2curry dip like ; inline
 100
 101 : filter-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... seq' )
 102     over filter-index-as ; inline
 103
 104 : even-indices ( seq -- seq' )
 105     [ length 1 + 2/ ] keep [
 106         [ [ 2 * ] dip nth-unsafe ] curry
 107     ] keep map-integers ;
 108
 109 : odd-indices ( seq -- seq' )
 110     [ length 2/ ] keep [
 111         [ [ 2 * 1 + ] dip nth-unsafe ] curry
 112     ] keep map-integers ;
 113
 114 : compact ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 115     [ split-when harvest ] dip join ; inline
 116
 117 : collapse ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 118     [ split-when ] dip
 119     [ [ harvest ] dip join ]
 120     [ [ first empty? ] dip [ prepend ] curry when ]
 121     [ [ last empty? ] dip [ append ] curry when ]
 122     2tri ; inline
 123
 124 :: slice-when ( seq quot: ( elt -- ? ) -- seq' )
 125     seq length :> len
 126     0 [ len dupd < ] [
 127         dup seq quot find-from drop
 128         [ 2dup = [ 1 + ] when ] [ len ] if*
 129         [ seq <slice> ] keep len or swap
 130     ] produce nip ; inline
 131
 132 : cut-slice* ( seq n -- before after )
 133     [ head-slice* ] [ tail-slice* ] 2bi ;
 134
 135 : rotate ( seq n -- seq' )
 136     cut prepend ;
 137
 138 :: rotate! ( seq n -- )
 139     n seq bounds-check length :> end
 140     0 n [ 2dup = ] [
 141         [ seq exchange-unsafe ] [ [ 1 + ] bi@ ] 2bi
 142         dup end = [ drop over ] when
 143         2over = [ -rot nip over ] when
 144     ] until 3drop ;
 145
 146 : all-rotations ( seq -- seq' )
 147     dup length iota [ rotate ] with map ;
 148
 149 : appender-for ( quot exemplar -- quot' vec )
 150     [ length ] keep new-resizable
 151     [ [ push-all ] curry compose ] keep ; inline
 152
 153 : appender ( quot -- quot' vec )
 154     V{ } appender-for ; inline
 155
 156 : map-concat-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 157     dup [ appender-for [ each ] dip ] curry dip like ; inline
 158
 159 : >resizable ( seq -- vec ) ! fixes map-concat "cannot apply call to run-time..."
 160     [ length ] keep [ new-resizable ] [ over push-all ] bi ;
 161
 162 : map-concat ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 163     over [ 2drop { } ] [
 164         first over call dup [
 165             >resizable [ [ push-all ] curry compose ] keep
 166             [ 1 ] 3dip [ (each) (each-integer) ] dip
 167         ] curry dip like
 168     ] if-empty ; inline
 169
 170 : map-filter-as ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) exemplar -- ... subseq )
 171     dup [ selector-for [ compose each ] dip ] curry dip like ; inline
 172
 173 : map-filter ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) -- ... subseq )
 174     pick map-filter-as ; inline
 175
 176 : map-sift ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 177     [ ] map-filter ; inline
 178
 179 : map-harvest ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 180     [ empty? not ] map-filter ; inline
 181
 182 <PRIVATE
 183
 184 : ((each-from)) ( i seq -- n quot )
 185     [ length over [-] swap ] keep '[ _ + _ nth-unsafe ] ; inline
 186
 187 : (each-from) ( i seq quot -- n quot' ) [ ((each-from)) ] dip compose ;
 188     inline
 189
 190 PRIVATE>
 191
 192 : map-from-as ( ... seq quot: ( ... elt -- ... newelt ) i exemplar -- ... newseq )
 193     [ -rot (each-from) ] dip map-integers ; inline
 194
 195 : map-from ( ... seq quot: ( ... elt -- ... newelt ) i -- ... newseq )
 196     pick map-from-as ; inline
 197
 198 <PRIVATE
 199
 200 : push-map-if ( ..a elt filter-quot: ( ..a elt -- ..b ? ) map-quot: ( ..a elt -- ..b newelt ) accum -- ..b )
 201     [ keep over ] 2dip [ when ] dip rot [ push ] [ 2drop ] if ; inline
 202
 203 : filter-mapper-for ( filter-quot map-quot exemplar -- quot' vec )
 204     [ length ] keep new-resizable [ [ push-map-if ] 3curry ] keep ; inline
 205
 206 : filter-mapper ( filter-quot map-quot -- quot' vec )
 207     V{ } filter-mapper-for ; inline
 208
 209 PRIVATE>
 210
 211 : filter-map-as ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 212     dup [ filter-mapper-for [ each ] dip ] curry dip like ; inline
 213
 214 : filter-map ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) -- ... newseq )
 215     pick filter-map-as ; inline
 216
 217 : 2map-sum ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... n ) -- ... n )
 218     [ 0 ] 3dip [ dip + ] curry [ rot ] prepose 2each ; inline
 219
 220 : 2count ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... n )
 221     [ 1 0 ? ] compose 2map-sum ; inline
 222
 223 : round-robin ( seq -- newseq )
 224     [ { } ] [
 225         [ longest length iota ] keep
 226         [ [ ?nth ] with map ] curry map concat sift
 227     ] if-empty ;
 228
 229 : sift-as ( seq exemplar -- newseq )
 230     [ ] swap filter-as ;
 231
 232 : sift! ( seq -- newseq )
 233     [ ] filter! ;
 234
 235 : harvest-as ( seq exemplar -- newseq )
 236     [ empty? not ] swap filter-as ;
 237
 238 : harvest! ( seq -- newseq )
 239     [ empty? not ] filter! ;
 240
 241 : contains? ( seq elts -- ? )
 242     [ member? ] curry any? ; inline
 243
 244 : head-as ( seq n exemplar -- seq' )
 245     [ head-slice ] [ like ] bi* ; inline
 246
 247 : head*-as ( seq n exemplar -- seq' )
 248     [ head-slice* ] [ like ] bi* ; inline
 249
 250 : tail-as ( seq n exemplar -- seq' )
 251     [ tail-slice ] [ like ] bi* ; inline
 252
 253 : tail*-as ( seq n exemplar -- seq' )
 254     [ tail-slice* ] [ like ] bi* ; inline
 255
 256 : trim-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... newseq )
 257     [ trim-slice ] [ like ] bi* ; inline
 258
 259 : ?trim ( seq quot: ( elt -- ? ) -- seq/newseq )
 260     over empty? [ drop ] [
 261         over [ first-unsafe ] [ last-unsafe ] bi pick bi@ or
 262         [ trim ] [ drop ] if
 263     ] if ; inline
 264
 265 : ?trim-head ( seq quot: ( elt -- ? ) -- seq/newseq )
 266     over empty? [ drop ] [
 267         over first-unsafe over call
 268         [ trim-head ] [ drop ] if
 269     ] if ; inline
 270
 271 : ?trim-tail ( seq quot: ( elt -- ? ) -- seq/newseq )
 272     over empty? [ drop ] [
 273         over last-unsafe over call
 274         [ trim-tail ] [ drop ] if
 275     ] if ; inline
 276
 277 : unsurround ( newseq seq2 seq3 -- seq1 )
 278    [ ?head drop ] [ ?tail drop ] bi* ;
 279
 280 : none? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 281     any? not ; inline
 282
 283 : one? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 284     [ find ] 2keep rot [
 285         [ 1 + ] 2dip find-from drop not
 286     ] [ 3drop f ] if ; inline
 287
 288 : map-index! ( ... seq quot: ( ... elt index -- ... newelt ) -- ... seq )
 289     over [ [ (each-index) ] dip collect ] keep ; inline
 290
 291 <PRIVATE
 292
 293 : (2each-index) ( seq1 seq2 quot -- n quot' )
 294     [ ((2each)) [ keep ] curry ] dip compose ; inline
 295
 296 PRIVATE>
 297
 298 : 2each-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... ) -- ... )
 299     (2each-index) each-integer ; inline
 300
 301 : 2map-into ( seq1 seq2 quot into -- )
 302     [ (2each) ] dip collect ; inline
 303
 304 : 2map! ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... seq1 )
 305     pick [ 2map-into ] keep ; inline
 306
 307 : 2map-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... newelt ) -- ... newseq )
 308     pick [ (2each-index) ] dip map-integers ; inline
 309
 310 TUPLE: evens seq length ;
 311
 312 : <evens> ( seq -- evens )
 313     dup length 1 + 2/ evens boa ; inline
 314
 315 M: evens length length>> ; inline
 316
 317 M: evens nth-unsafe [ 2 * ] [ seq>> nth-unsafe ] bi* ; inline
 318
 319 INSTANCE: evens immutable-sequence
 320
 321 TUPLE: odds seq length ;
 322
 323 : <odds> ( seq -- odds )
 324     dup length 2/ odds boa ; inline
 325
 326 M: odds length length>> ; inline
 327
 328 M: odds nth-unsafe [ 2 * 1 + ] [ seq>> nth-unsafe ] bi* ; inline
 329
 330 INSTANCE: odds immutable-sequence
 331
 332 : until-empty ( seq quot -- )
 333     [ dup empty? ] swap until drop ; inline
 334
 335 : arg-max ( seq -- n )
 336     <enum> [ second-unsafe ] supremum-by first ;
 337
 338 : arg-min ( seq -- n )
 339     <enum> [ second-unsafe ] infimum-by first ;
 340
 341 <PRIVATE
 342
 343 : push-index-if ( ..a elt i quot: ( ..a elt -- ..b ? ) accum -- ..b )
 344     [ dip ] dip rot [ push ] [ 2drop ] if ; inline
 345
 346 PRIVATE>
 347
 348 : arg-where ( ... seq quot: ( ... elt -- ... ? ) -- ... indices )
 349     over length <vector> [
 350         [ push-index-if ] 2curry each-index
 351     ] keep ; inline
 352
 353 : arg-sort ( seq -- indices )
 354     dup length iota zip sort-keys values ;
 355
 356 : first= ( seq elt -- ? ) [ first ] dip = ; inline
 357 : second= ( seq elt -- ? ) [ second ] dip = ; inline
 358 : third= ( seq elt -- ? ) [ third ] dip = ; inline
 359 : fourth= ( seq elt -- ? ) [ fourth ] dip = ; inline
 360 : last= ( seq elt -- ? ) [ last ] dip = ; inline
 361 : nth= ( n seq elt -- ? ) [ nth ] dip = ; inline
 362
 363 : first? ( seq quot -- ? ) [ first ] dip call ; inline
 364 : second? ( seq quot -- ? ) [ second ] dip call ; inline
 365 : third? ( seq quot -- ? ) [ third ] dip call ; inline
 366 : fourth? ( seq quot -- ? ) [ fourth ] dip call ; inline
 367 : last? ( seq quot -- ? ) [ last ] dip call ; inline
 368 : nth? ( n seq quot -- ? ) [ nth ] dip call ; inline
 369
 370 : loop>sequence ( quot exemplar -- seq )
 371    [ '[ [ @ [ [ , ] when* ] keep ] loop ] ] dip make ; inline
 372
 373 : loop>array ( quot -- seq )
 374    { } loop>sequence ; inline
 375
 376 <PRIVATE
 377
 378 : (reverse) ( seq -- newseq )
 379     dup [ length ] keep new-sequence
 380     [ 0 swap copy-unsafe ] keep reverse! ;
 381
 382 PRIVATE>
 383
 384 : reverse-as ( seq exemplar -- newseq )
 385     [ (reverse) ] [ like ] bi* ;
 386
 387 : map-product ( ... seq quot: ( ... elt -- ... n ) -- ... n )
 388     [ 1 ] 2dip [ dip * ] curry [ swap ] prepose each ; inline
 389
 390 : insert-nth! ( elt n seq -- )
 391     [ length ] keep ensure swap pick (a,b]
 392     over '[ [ 1 + ] keep _ move-unsafe ] each
 393     set-nth-unsafe ;
 394
 395 : set-nths ( value indices seq -- )
 396     swapd '[ [ _ ] dip _ set-nth ] each ; inline
 397
 398 : set-nths-unsafe ( value indices seq -- )
 399     swapd '[ [ _ ] dip _ set-nth-unsafe ] each ; inline
 400
 401 : flatten1 ( obj -- seq )
 402     [
 403         [
 404             dup branch? [
 405                 [ dup branch? [ % ] [ , ] if ] each
 406             ] [ , ] if
 407         ]
 408     ] keep dup branch? [ drop f ] unless make ;
 409
 410 <PRIVATE
 411
 412 : (map-find-index) ( seq quot find-quot -- result elt index )
 413     [ [ f ] 2dip [ [ nip ] 2dip call dup ] curry ] dip call
 414     [ [ [ drop f ] unless ] keep ] dip ; inline
 415
 416 PRIVATE>
 417
 418 : map-find-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result elt index )
 419     [ find-index ] (map-find-index) ; inline
 420
 421 : filter-length ( seq n -- seq' ) '[ length _ = ] filter ;
 422
 423 : all-shortest ( seqs -- seqs' ) dup shortest length filter-length ;
 424
 425 : all-longest ( seqs -- seqs' ) dup longest length filter-length ;
 426
 427 : remove-first ( obj seq -- seq' )
 428     [ index ] keep over [ remove-nth ] [ nip ] if ;
 429
 430 : remove-first! ( obj seq -- seq )
 431     [ index ] keep over [ remove-nth! ] [ nip ] if ;
 432
 433 : remove-last ( obj seq -- seq' )
 434     [ last-index ] keep over [ remove-nth ] [ nip ] if ;
 435
 436 : remove-last! ( obj seq -- seq )
 437     [ last-index ] keep over [ remove-nth! ] [ nip ] if ;