extra/sequences/extras/extras.factor

   1 USING: accessors arrays assocs combinators fry generalizations
   2 grouping growable kernel locals make math math.order math.ranges
   3 sequences sequences.deep sequences.private sorting splitting
   4 vectors ;
   5 IN: sequences.extras
   6
   7 : reduce1 ( seq quot -- result ) [ unclip ] dip reduce ; inline
   8
   9 :: reduce-r ( seq identity quot: ( obj1 obj2 -- obj ) -- result )
  10     seq [ identity ] [
  11         unclip [ identity quot reduce-r ] [ quot call ] bi*
  12     ] if-empty ; inline recursive
  13
  14 ! Quot must have static stack effect, unlike "reduce"
  15 :: reduce* ( seq identity quot: ( prev elt -- next ) -- result )
  16     seq [ identity ] [
  17         unclip identity swap quot call( prev elt -- next )
  18         quot reduce*
  19     ] if-empty ; inline recursive
  20
  21 :: combos ( list1 list2 -- result )
  22     list2 [ [ 2array ] curry list1 swap map ] map concat ;
  23
  24 : find-all ( ... seq quot: ( ... elt -- ... ? ) -- ... elts )
  25     [ <enum> ] dip '[ nip @ ] assoc-filter ; inline
  26
  27 : reduce-from ( ... seq identity quot: ( ... prev elt -- ... next ) i -- ... result )
  28     [ swap ] 2dip each-from ; inline
  29
  30 :: subseq* ( from to seq -- subseq )
  31     seq length :> len
  32     from [ dup 0 < [ len + ] when ] [ 0 ] if*
  33     to [ dup 0 < [ len + ] when ] [ len ] if*
  34     [ 0 len clamp ] bi@ dupd max seq subseq ;
  35
  36 : safe-subseq ( from to seq -- subseq )
  37     [ length '[ 0 _ clamp ] bi@ ] keep subseq ;
  38
  39 : all-subseqs ( seq -- seqs )
  40     dup length [1,b] [ clump ] with map concat ;
  41
  42 :: each-subseq ( ... seq quot: ( ... x -- ... ) -- ... )
  43     seq length :> len
  44     len [0,b] [
  45         :> from
  46         from len (a,b] [
  47             :> to
  48             from to seq subseq quot call
  49         ] each
  50     ] each ; inline
  51
  52 : map-like ( seq exemplar -- seq' )
  53     '[ _ like ] map ; inline
  54
  55 : filter-all-subseqs-range ( ... seq range quot: ( ... x -- ... ) -- seq )
  56     [
  57         '[ <clumps> _ filter ] with map concat
  58     ] 3keep 2drop map-like ; inline
  59
  60 : filter-all-subseqs ( ... seq quot: ( ... x -- ... ) -- seq )
  61     [ dup length [1,b] ] dip filter-all-subseqs-range ; inline
  62
  63 :: longest-subseq ( seq1 seq2 -- subseq )
  64     seq1 length :> len1
  65     seq2 length :> len2
  66     0 :> n!
  67     0 :> end!
  68     len1 1 + [ len2 1 + 0 <array> ] replicate :> table
  69     len1 [1,b] [| x |
  70         len2 [1,b] [| y |
  71             x 1 - seq1 nth-unsafe
  72             y 1 - seq2 nth-unsafe = [
  73                 y 1 - x 1 - table nth-unsafe nth-unsafe 1 + :> len
  74                 len y x table nth-unsafe set-nth-unsafe
  75                 len n > [ len n! x end! ] when
  76             ] [ 0 y x table nth-unsafe set-nth-unsafe ] if
  77         ] each
  78     ] each end n - end seq1 subseq ;
  79
  80 : pad-longest ( seq1 seq2 elt -- seq1 seq2 )
  81     [ 2dup max-length ] dip [ pad-tail ] 2curry bi@ ;
  82
  83 :: pad-center ( seq n elt -- padded )
  84     n seq length [-] :> extra
  85     extra 2/ :> left
  86     extra left - :> right
  87     left elt <repetition> seq right elt <repetition>
  88     seq 3append-as ;
  89
  90 : change-nths ( ... indices seq quot: ( ... elt -- ... elt' ) -- ... )
  91     [ change-nth ] 2curry each ; inline
  92
  93 : push-if-index ( ..a elt i quot: ( ..a elt i -- ..b ? ) accum -- ..b )
  94     [ 2keep drop ] dip rot [ push ] [ 2drop ] if ; inline
  95
  96 : push-if* ( ..a elt quot: ( ..a elt -- ..b obj/f ) accum -- ..b )
  97     [ call ] dip [ push ] [ drop ] if* ; inline
  98
  99 <PRIVATE
 100
 101 : (index-selector-as) ( quot length exampler -- selector accum )
 102     new-resizable [ [ push-if-index ] 2curry ] keep ; inline
 103
 104 : (selector-as*) ( quot length exemplar -- selector accum )
 105     new-resizable [ [ push-if* ] 2curry ] keep ; inline
 106
 107 PRIVATE>
 108
 109 : index-selector-as ( quot exemplar -- selector accum )
 110     [ length ] keep (index-selector-as) ; inline
 111
 112 : index-selector ( quot -- selector accum )
 113     V{ } index-selector-as ; inline
 114
 115 : selector-as* ( quot exemplar -- selector accum )
 116     [ length ] keep (selector-as*) ; inline
 117
 118 : selector* ( quot -- selector accum ) V{ } selector-as* ; inline
 119
 120 : filter-index-as ( ... seq quot: ( ... elt i -- ... ? ) exemplar -- ... seq' )
 121     pick length over [ (index-selector-as) [ each-index ] dip ] 2curry dip like ; inline
 122
 123 : filter-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... seq' )
 124     over filter-index-as ; inline
 125
 126 : even-indices ( seq -- seq' )
 127     [ length 1 + 2/ ] keep [
 128         [ [ 2 * ] dip nth-unsafe ] curry
 129     ] keep map-integers ;
 130
 131 : odd-indices ( seq -- seq' )
 132     [ length 2/ ] keep [
 133         [ [ 2 * 1 + ] dip nth-unsafe ] curry
 134     ] keep map-integers ;
 135
 136 : compact ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 137     [ split-when harvest ] dip join ; inline
 138
 139 : collapse ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 140     [ split-when ] dip
 141     [ [ harvest ] dip join ]
 142     [ [ first empty? ] dip [ prepend ] curry when ]
 143     [ [ last empty? ] dip [ append ] curry when ]
 144     2tri ; inline
 145
 146 :: slice-when ( seq quot: ( elt -- ? ) -- seq' )
 147     seq length :> len
 148     0 [ len dupd < ] [
 149         dup seq quot find-from drop
 150         [ 2dup = [ 1 + ] when ] [ len ] if*
 151         [ seq <slice> ] keep len or swap
 152     ] produce nip ; inline
 153
 154 : cut-slice* ( seq n -- before after )
 155     [ head-slice* ] [ tail-slice* ] 2bi ;
 156
 157 : ?<slice> ( from/f to/f sequence -- slice )
 158     [ [ 0 ] unless* ] 2dip
 159     over [ nip [ length ] [ ] bi ] unless
 160     <slice> ; inline
 161
 162 : sequence>slice ( sequence -- slice )
 163     [ drop 0 ] [ length ] [ ] tri <slice> ; inline
 164
 165 : slice-order-by-from ( slice1 slice2 -- slice-lt slice-gt )
 166     2dup [ from>> ] bi@ > [ swap ] when ; inline
 167
 168 : ordered-slices-range ( slice-lt slice-gt -- to from )
 169     [ to>> ] [ from>> ] bi* ;
 170
 171 : unordered-slices-range ( slice1 slice2 -- to from )
 172     slice-order-by-from ordered-slices-range ;
 173
 174 : ordered-slices-overlap? ( slice-lt slice-gt -- ? )
 175     ordered-slices-range > ; inline
 176
 177 : unordered-slices-overlap? ( slice1 slice2 -- ? )
 178     unordered-slices-range > ; inline
 179
 180 : slices-overlap? ( slice1 slice2 -- ? )
 181     unordered-slices-overlap? ;
 182
 183 : ordered-slices-touch? ( slice-lt slice-gt -- ? )
 184     ordered-slices-range >= ; inline
 185
 186 : unordered-slices-touch? ( slice1 slice2 -- ? )
 187     unordered-slices-range >= ; inline
 188
 189 : slices-touch? ( slice1 slice2 -- ? )
 190     unordered-slices-touch? ;
 191
 192 ERROR: slices-don't-touch slice1 slice2 ;
 193
 194 : merge-slices ( slice1 slice2 -- slice/* )
 195     slice-order-by-from
 196     2dup ordered-slices-touch? [
 197         [ from>> ] [ [ to>> ] [ seq>> ] bi ] bi* <slice>
 198     ] [
 199         slices-don't-touch
 200     ] if ;
 201
 202 : rotate ( seq n -- seq' )
 203     over length mod dup 0 >= [ cut ] [ abs cut* ] if prepend ;
 204
 205 ERROR: underlying-mismatch slice1 slice2 ;
 206 : ensure-same-underlying ( slice1 slice2 -- slice1 slice2 )
 207     2dup [ seq>> ] bi@ eq? [ underlying-mismatch ] unless ;
 208
 209 : span-slices ( slice1 slice2 -- slice )
 210     ensure-same-underlying
 211     [ [ from>> ] bi@ min ]
 212     [ [ to>> ] bi@ max ]
 213     [ drop seq>> ] 2tri <slice> ;
 214
 215 : ?span-slices ( slice1/f slice2/f -- slice )
 216     2dup and [ span-slices ] [ or ] if ;
 217
 218 :: rotate! ( seq n -- )
 219     seq length :> len
 220     n len mod dup 0 < [ len + ] when seq bounds-check drop 0 over
 221     [ 2dup = ] [
 222         [ seq exchange-unsafe ] [ [ 1 + ] bi@ ] 2bi
 223         dup len = [ drop over ] when
 224         2over = [ -rot nip over ] when
 225     ] until 3drop ;
 226
 227 : all-rotations ( seq -- seq' )
 228     dup length iota [ rotate ] with map ;
 229
 230 <PRIVATE
 231
 232 : (appender-for) ( quot length exemplar -- appender accum )
 233     new-resizable [ [ push-all ] curry compose ] keep ; inline
 234
 235 PRIVATE>
 236
 237 : appender-for ( quot exemplar -- appender accum )
 238     [ length ] keep (appender-for) ; inline
 239
 240 : appender ( quot -- appender accum )
 241     V{ } appender-for ; inline
 242
 243 : map-concat-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 244     [ appender-for [ each ] dip ] keep like ; inline
 245
 246 : >resizable ( seq -- accum ) ! fixes map-concat "cannot apply call to run-time..."
 247     [ length ] keep [ new-resizable ] [ append! ] bi ;
 248
 249 : map-concat ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 250     over empty? [ 2drop { } ] [
 251         [ [ first ] dip call ] 2keep rot dup [
 252             >resizable [ [ push-all ] curry compose ] keep
 253             [ 1 ] 3dip [ setup-each (each-integer) ] dip
 254         ] curry dip like
 255     ] if ; inline
 256
 257 : map-filter-as ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) exemplar -- ... subseq )
 258     [ pick ] dip swap length over
 259     [ (selector-as) [ compose each ] dip ] 2curry dip like ; inline
 260
 261 : map-filter ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) -- ... subseq )
 262     pick map-filter-as ; inline
 263
 264 : map-sift ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 265     [ ] map-filter ; inline
 266
 267 : map-harvest ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 268     [ empty? not ] map-filter ; inline
 269
 270 <PRIVATE
 271
 272 : (setup-each-from) ( i seq -- n quot )
 273     [ length over [-] swap ] keep '[ _ + _ nth-unsafe ] ; inline
 274
 275 : setup-each-from ( i seq quot -- n quot' )
 276     [ (setup-each-from) ] dip compose ; inline
 277
 278 PRIVATE>
 279
 280 : map-from-as ( ... seq quot: ( ... elt -- ... newelt ) i exemplar -- ... newseq )
 281     [ -rot setup-each-from ] dip map-integers ; inline
 282
 283 : map-from ( ... seq quot: ( ... elt -- ... newelt ) i -- ... newseq )
 284     pick map-from-as ; inline
 285
 286 <PRIVATE
 287
 288 : push-map-if ( ..a elt filter-quot: ( ..a elt -- ..b ? ) map-quot: ( ..a elt -- ..b newelt ) accum -- ..b )
 289     [ keep over ] 2dip [ when ] dip rot [ push ] [ 2drop ] if ; inline
 290
 291 : (filter-mapper-for) ( filter-quot map-quot length exempler -- filter-mapper accum )
 292     new-resizable [ [ push-map-if ] 3curry ] keep ; inline
 293
 294 : filter-mapper-for ( filter-quot map-quot exemplar -- filter-mapper accum )
 295     [ length ] keep (filter-mapper-for) ; inline
 296
 297 : filter-mapper ( filter-quot map-quot -- filter-mapper accum )
 298     V{ } filter-mapper-for ; inline
 299
 300 PRIVATE>
 301
 302 : filter-map-as ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 303     [ pick ] dip swap length over
 304     [ (filter-mapper-for) [ each ] dip ] 2curry dip like ; inline
 305
 306 : filter-map ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) -- ... newseq )
 307     pick filter-map-as ; inline
 308
 309 : 2map-sum ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... n ) -- ... n )
 310     [ 0 ] 3dip [ dip + ] curry [ rot ] prepose 2each ; inline
 311
 312 : 2count ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... n )
 313     [ 1 0 ? ] compose 2map-sum ; inline
 314
 315 : round-robin ( seq -- newseq )
 316     [ { } ] [
 317         [ longest length iota ] keep
 318         [ [ ?nth ] with map ] curry map concat sift
 319     ] if-empty ;
 320
 321 : sift-as ( seq exemplar -- newseq )
 322     [ ] swap filter-as ;
 323
 324 : sift! ( seq -- newseq )
 325     [ ] filter! ;
 326
 327 : harvest-as ( seq exemplar -- newseq )
 328     [ empty? not ] swap filter-as ;
 329
 330 : harvest! ( seq -- newseq )
 331     [ empty? ] reject! ;
 332
 333 : head-as ( seq n exemplar -- seq' )
 334     [ head-slice ] [ like ] bi* ; inline
 335
 336 : head*-as ( seq n exemplar -- seq' )
 337     [ head-slice* ] [ like ] bi* ; inline
 338
 339 : tail-as ( seq n exemplar -- seq' )
 340     [ tail-slice ] [ like ] bi* ; inline
 341
 342 : tail*-as ( seq n exemplar -- seq' )
 343     [ tail-slice* ] [ like ] bi* ; inline
 344
 345 : trim-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... newseq )
 346     [ trim-slice ] [ like ] bi* ; inline
 347
 348 : ?trim ( seq quot: ( elt -- ? ) -- seq/newseq )
 349     over empty? [ drop ] [
 350         over [ first-unsafe ] [ last-unsafe ] bi pick either?
 351         [ trim ] [ drop ] if
 352     ] if ; inline
 353
 354 : ?trim-head ( seq quot: ( elt -- ? ) -- seq/newseq )
 355     over empty? [ drop ] [
 356         over first-unsafe over call
 357         [ trim-head ] [ drop ] if
 358     ] if ; inline
 359
 360 : ?trim-tail ( seq quot: ( elt -- ? ) -- seq/newseq )
 361     over empty? [ drop ] [
 362         over last-unsafe over call
 363         [ trim-tail ] [ drop ] if
 364     ] if ; inline
 365
 366 : unsurround ( newseq seq2 seq3 -- seq1 )
 367    [ ?head drop ] [ ?tail drop ] bi* ;
 368
 369 : none? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 370     any? not ; inline
 371
 372 : one? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 373     [ find ] 2keep rot [
 374         [ 1 + ] 2dip find-from drop not
 375     ] [ 3drop f ] if ; inline
 376
 377 : map-index! ( ... seq quot: ( ... elt index -- ... newelt ) -- ... seq )
 378     over [ [ (each-index) ] dip collect ] keep ; inline
 379
 380 <PRIVATE
 381
 382 : (2each-index) ( seq1 seq2 quot -- n quot' )
 383     [ setup-2each [ keep ] curry ] dip compose ; inline
 384
 385 PRIVATE>
 386
 387 : 2each-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... ) -- ... )
 388     (2each-index) each-integer ; inline
 389
 390 : 2map-into ( seq1 seq2 quot into -- )
 391     [ (2each) ] dip collect ; inline
 392
 393 : 2map! ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... seq1 )
 394     pick [ 2map-into ] keep ; inline
 395
 396 : 2map-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... newelt ) -- ... newseq )
 397     pick [ (2each-index) ] dip map-integers ; inline
 398
 399 TUPLE: evens seq length ;
 400
 401 : <evens> ( seq -- evens )
 402     dup length 1 + 2/ evens boa ; inline
 403
 404 M: evens length length>> ; inline
 405
 406 M: evens nth-unsafe [ 2 * ] [ seq>> nth-unsafe ] bi* ; inline
 407
 408 INSTANCE: evens immutable-sequence
 409
 410 TUPLE: odds seq length ;
 411
 412 : <odds> ( seq -- odds )
 413     dup length 2/ odds boa ; inline
 414
 415 M: odds length length>> ; inline
 416
 417 M: odds nth-unsafe [ 2 * 1 + ] [ seq>> nth-unsafe ] bi* ; inline
 418
 419 INSTANCE: odds immutable-sequence
 420
 421 : until-empty ( seq quot -- )
 422     [ dup empty? ] swap until drop ; inline
 423
 424 : arg-max ( seq -- n )
 425     <enum> [ second-unsafe ] supremum-by first ;
 426
 427 : arg-min ( seq -- n )
 428     <enum> [ second-unsafe ] infimum-by first ;
 429
 430 <PRIVATE
 431
 432 : push-index-if ( ..a elt i quot: ( ..a elt -- ..b ? ) accum -- ..b )
 433     [ dip ] dip rot [ push ] [ 2drop ] if ; inline
 434
 435 PRIVATE>
 436
 437 : arg-where ( ... seq quot: ( ... elt -- ... ? ) -- ... indices )
 438     over length <vector> [
 439         [ push-index-if ] 2curry each-index
 440     ] keep ; inline
 441
 442 : arg-sort ( seq -- indices )
 443     zip-index sort-keys values ;
 444
 445 : first= ( seq elt -- ? ) [ first ] dip = ; inline
 446 : second= ( seq elt -- ? ) [ second ] dip = ; inline
 447 : third= ( seq elt -- ? ) [ third ] dip = ; inline
 448 : fourth= ( seq elt -- ? ) [ fourth ] dip = ; inline
 449 : last= ( seq elt -- ? ) [ last ] dip = ; inline
 450 : nth= ( n seq elt -- ? ) [ nth ] dip = ; inline
 451
 452 : first? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ first ] dip call ; inline
 453 : second? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ second ] dip call ; inline
 454 : third? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ third ] dip call ; inline
 455 : fourth? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ fourth ] dip call ; inline
 456 : last? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ last ] dip call ; inline
 457 : nth? ( ... n seq quot: ( ... elt -- ... ? ) -- ... ? ) [ nth ] dip call ; inline
 458
 459 : loop>sequence ( quot exemplar -- seq )
 460    [ '[ [ @ [ [ , ] when* ] keep ] loop ] ] dip make ; inline
 461
 462 : loop>array ( quot -- seq )
 463    { } loop>sequence ; inline
 464
 465 <PRIVATE
 466
 467 : (reverse) ( seq -- newseq )
 468     dup [ length ] keep new-sequence
 469     [ 0 swap copy-unsafe ] keep reverse! ;
 470
 471 PRIVATE>
 472
 473 : reverse-as ( seq exemplar -- newseq )
 474     [ (reverse) ] [ like ] bi* ;
 475
 476 : map-product ( ... seq quot: ( ... elt -- ... n ) -- ... n )
 477     [ 1 ] 2dip [ dip * ] curry [ swap ] prepose each ; inline
 478
 479 : insert-nth! ( elt n seq -- )
 480     [ length ] keep ensure swap pick (a,b]
 481     over '[ [ 1 + ] keep _ move-unsafe ] each
 482     set-nth-unsafe ;
 483
 484 : set-nths ( value indices seq -- )
 485     swapd '[ _ swap _ set-nth ] each ; inline
 486
 487 : set-nths-unsafe ( value indices seq -- )
 488     swapd '[ _ swap _ set-nth-unsafe ] each ; inline
 489
 490 : flatten1 ( obj -- seq )
 491     [
 492         [
 493             dup branch? [
 494                 [ dup branch? [ % ] [ , ] if ] each
 495             ] [ , ] if
 496         ]
 497     ] keep dup branch? [ drop f ] unless make ;
 498
 499 <PRIVATE
 500
 501 : (map-find-index) ( seq quot find-quot -- result i elt )
 502     [ [ f ] 2dip [ [ nip ] 2dip call dup ] curry ] dip call
 503     [ [ [ drop f ] unless ] keep ] dip ; inline
 504
 505 PRIVATE>
 506
 507 : map-find-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 508     [ find-index ] (map-find-index) ; inline
 509
 510 : filter-length ( seq n -- seq' ) '[ length _ = ] filter ;
 511
 512 : all-shortest ( seqs -- seqs' ) dup shortest length filter-length ;
 513
 514 : all-longest ( seqs -- seqs' ) dup longest length filter-length ;
 515
 516 : remove-first ( obj seq -- seq' )
 517     [ index ] keep over [ remove-nth ] [ nip ] if ;
 518
 519 : remove-first! ( obj seq -- seq )
 520     [ index ] keep over [ remove-nth! ] [ nip ] if ;
 521
 522 : remove-last ( obj seq -- seq' )
 523     [ last-index ] keep over [ remove-nth ] [ nip ] if ;
 524
 525 : remove-last! ( obj seq -- seq )
 526     [ last-index ] keep over [ remove-nth! ] [ nip ] if ;
 527
 528 : ?first2 ( seq -- first/f second/f )
 529     dup length {
 530         { 0 [ drop f f ] }
 531         { 1 [ first-unsafe f ] }
 532         [ drop first2-unsafe ]
 533     } case ;
 534
 535 : ?first3 ( seq -- first/f second/f third/f )
 536     dup length {
 537         { 0 [ drop f f f ] }
 538         { 1 [ first-unsafe f f ] }
 539         { 2 [ first2-unsafe f ] }
 540         [ drop first3-unsafe ]
 541     } case ;
 542
 543 : ?first4 ( seq -- first/f second/f third/f fourth/f )
 544     dup length {
 545         { 0 [ drop f f f f ] }
 546         { 1 [ first-unsafe f f f ] }
 547         { 2 [ first2-unsafe f f ] }
 548         { 3 [ first3-unsafe f ] }
 549         [ drop first4-unsafe ]
 550     } case ;
 551
 552 : cut-when ( ... seq quot: ( ... elt -- ... ? ) -- ... before after )
 553     [ find drop ] 2keep drop swap
 554     [ cut ] [ f over like ] if* ; inline
 555
 556 : nth* ( n seq -- elt )
 557     [ length 1 - swap - ] [ nth ] bi ; inline
 558
 559 : each-index-from ( ... seq quot: ( ... elt index -- ... ) i -- ... )
 560     -rot (each-index) (each-integer) ; inline
 561
 562 <PRIVATE
 563
 564 : select-by* ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... i elt )
 565     [
 566         [ keep swap ] curry [ dip ] curry
 567         [ [ first 0 ] dip call ] 2keep
 568         [ 2curry 3dip 5 npick pick ] curry
 569     ] [
 570         [ [ 3drop ] [ [ 3drop ] 3dip ] if ] compose
 571     ] bi* compose 1 each-index-from nip swap ; inline
 572
 573 PRIVATE>
 574
 575 : supremum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 576     [ after? ] select-by* ; inline
 577
 578 : infimum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 579     [ before? ] select-by* ; inline
 580
 581 : change-last ( seq quot -- )
 582     [ drop length 1 - ] [ change-nth ] 2bi ; inline
 583
 584 : change-last-unsafe ( seq quot -- )
 585     [ drop length 1 - ] [ change-nth-unsafe ] 2bi ; inline
 586
 587 : replicate-into ( ... seq quot: ( ... -- ... newelt ) -- ... )
 588     over [ length ] 2dip '[ _ dip _ set-nth-unsafe ] each-integer ; inline
 589
 590 : count* ( ... seq quot: ( ... elt -- ... ? ) -- ... % )
 591     over [ count ] [ length ] bi* / ; inline
 592
 593 : find-last-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 594     [ [ 1 - ] dip find-last-integer ] (find-index) ; inline
 595
 596 : map-find-last-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 597     [ find-last-index ] (map-find-index) ; inline
 598
 599 :: (start-all) ( subseq seq increment -- indices )
 600     0
 601     [ [ subseq seq ] dip start* dup ]
 602     [ [ increment + ] keep ] produce nip ;
 603
 604 : start-all ( subseq seq -- indices )
 605     over length (start-all) ; inline
 606
 607 : start-all* ( subseq seq -- indices )
 608     1 (start-all) ; inline
 609
 610 : count-subseq ( subseq seq -- n )
 611     start-all length ; inline
 612
 613 : count-subseq* ( subseq seq -- n )
 614     start-all* length ; inline
 615
 616 : map-zip ( quot: ( x -- y ) -- alist )
 617     '[ _ keep swap ] map>alist ; inline
 618
 619 : map-keys ( assoc quot: ( key -- key' ) -- assoc )
 620     '[ _ dip ] assoc-map ; inline
 621
 622 : map-values ( assoc quot: ( value -- value' ) -- assoc )
 623     '[ swap _ dip swap ] assoc-map ; inline