extra/sequences/extras/extras.factor

   1 USING: accessors arrays assocs combinators fry generalizations
   2 grouping growable kernel locals make math math.order math.ranges
   3 sequences sequences.deep sequences.private sorting splitting
   4 vectors ;
   5 IN: sequences.extras
   6
   7 : reduce1 ( seq quot -- result ) [ unclip ] dip reduce ; inline
   8
   9 :: reduce-r ( seq identity quot: ( obj1 obj2 -- obj ) -- result )
  10     seq [ identity ] [
  11         unclip [ identity quot reduce-r ] [ quot call ] bi*
  12     ] if-empty ; inline recursive
  13
  14 ! Quot must have static stack effect, unlike "reduce"
  15 :: reduce* ( seq identity quot: ( prev elt -- next ) -- result )
  16     seq [ identity ] [
  17         unclip identity swap quot call( prev elt -- next )
  18         quot reduce*
  19     ] if-empty ; inline recursive
  20
  21 :: combos ( list1 list2 -- result )
  22     list2 [ [ 2array ] curry list1 swap map ] map concat ;
  23
  24 : find-all ( seq quot: ( elt -- ? ) -- elts )
  25     [ [ length iota ] keep ] dip
  26     [ dupd call( a -- ? ) [ 2array ] [ 2drop f ] if ] curry
  27     2map sift ; inline
  28
  29 : reduce-from ( ... seq identity quot: ( ... prev elt -- ... next ) i -- ... result )
  30     [ swap ] 2dip each-from ; inline
  31
  32 :: subseq* ( from to seq -- subseq )
  33     seq length :> len
  34     from [ dup 0 < [ len + ] when ] [ 0 ] if*
  35     to [ dup 0 < [ len + ] when ] [ len ] if*
  36     [ 0 len clamp ] bi@ dupd max seq subseq ;
  37
  38 : safe-subseq ( from to seq -- subseq )
  39     [ length '[ 0 _ clamp ] bi@ ] keep subseq ;
  40
  41 : all-subseqs ( seq -- seqs )
  42     dup length [1,b] [ clump ] with map concat ;
  43
  44 :: each-subseq ( ... seq quot: ( ... x -- ... ) -- ... )
  45     seq length :> len
  46     len [0,b] [
  47         :> from
  48         from len (a,b] [
  49             :> to
  50             from to seq subseq quot call
  51         ] each
  52     ] each ; inline
  53
  54 : map-like ( seq exemplar -- seq' )
  55     '[ _ like ] map ; inline
  56
  57 : filter-all-subseqs-range ( ... seq range quot: ( ... x -- ... ) -- seq )
  58     [
  59         '[ <clumps> _ filter ] with map concat
  60     ] 3keep 2drop map-like ; inline
  61
  62 : filter-all-subseqs ( ... seq quot: ( ... x -- ... ) -- seq )
  63     [ dup length [1,b] ] dip filter-all-subseqs-range ; inline
  64
  65 :: longest-subseq ( seq1 seq2 -- subseq )
  66     seq1 length :> len1
  67     seq2 length :> len2
  68     0 :> n!
  69     0 :> end!
  70     len1 1 + [ len2 1 + 0 <array> ] replicate :> table
  71     len1 [1,b] [| x |
  72         len2 [1,b] [| y |
  73             x 1 - seq1 nth-unsafe
  74             y 1 - seq2 nth-unsafe = [
  75                 y 1 - x 1 - table nth-unsafe nth-unsafe 1 + :> len
  76                 len y x table nth-unsafe set-nth-unsafe
  77                 len n > [ len n! x end! ] when
  78             ] [ 0 y x table nth-unsafe set-nth-unsafe ] if
  79         ] each
  80     ] each end n - end seq1 subseq ;
  81
  82 : pad-longest ( seq1 seq2 elt -- seq1 seq2 )
  83     [ 2dup max-length ] dip [ pad-tail ] 2curry bi@ ;
  84
  85 : change-nths ( ... indices seq quot: ( ... elt -- ... elt' ) -- ... )
  86     [ change-nth ] 2curry each ; inline
  87
  88 : push-if-index ( ..a elt i quot: ( ..a elt i -- ..b ? ) accum -- ..b )
  89     [ 2keep drop ] dip rot [ push ] [ 2drop ] if ; inline
  90
  91 : push-if* ( ..a elt quot: ( ..a elt -- ..b obj/f ) accum -- ..b )
  92     [ call ] dip [ push ] [ drop ] if* ; inline
  93
  94 <PRIVATE
  95
  96 : (index-selector-for) ( quot length exampler -- selector accum )
  97     new-resizable [ [ push-if-index ] 2curry ] keep ; inline
  98
  99 : (selector-for*) ( quot length exemplar -- selector accum )
 100     new-resizable [ [ push-if* ] 2curry ] keep ; inline
 101
 102 PRIVATE>
 103
 104 : index-selector-for ( quot exemplar -- selector accum )
 105     [ length ] keep (index-selector-for) ; inline
 106
 107 : index-selector ( quot -- selector accum )
 108     V{ } index-selector-for ; inline
 109
 110 : selector-for* ( quot exemplar -- selector accum )
 111     [ length ] keep (selector-for*) ; inline
 112
 113 : selector* ( quot -- selector accum ) V{ } selector-for* ; inline
 114
 115 : filter-index-as ( ... seq quot: ( ... elt i -- ... ? ) exemplar -- ... seq' )
 116     pick length over [ (index-selector-for) [ each-index ] dip ] 2curry dip like ; inline
 117
 118 : filter-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... seq' )
 119     over filter-index-as ; inline
 120
 121 : even-indices ( seq -- seq' )
 122     [ length 1 + 2/ ] keep [
 123         [ [ 2 * ] dip nth-unsafe ] curry
 124     ] keep map-integers ;
 125
 126 : odd-indices ( seq -- seq' )
 127     [ length 2/ ] keep [
 128         [ [ 2 * 1 + ] dip nth-unsafe ] curry
 129     ] keep map-integers ;
 130
 131 : compact ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 132     [ split-when harvest ] dip join ; inline
 133
 134 : collapse ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 135     [ split-when ] dip
 136     [ [ harvest ] dip join ]
 137     [ [ first empty? ] dip [ prepend ] curry when ]
 138     [ [ last empty? ] dip [ append ] curry when ]
 139     2tri ; inline
 140
 141 :: slice-when ( seq quot: ( elt -- ? ) -- seq' )
 142     seq length :> len
 143     0 [ len dupd < ] [
 144         dup seq quot find-from drop
 145         [ 2dup = [ 1 + ] when ] [ len ] if*
 146         [ seq <slice> ] keep len or swap
 147     ] produce nip ; inline
 148
 149 : cut-slice* ( seq n -- before after )
 150     [ head-slice* ] [ tail-slice* ] 2bi ;
 151
 152 : ?<slice> ( from/f to/f sequence -- slice )
 153     [ [ 0 ] unless* ] 2dip
 154     over [ nip [ length ] [ ] bi ] unless
 155     <slice> ; inline
 156
 157 : sequence>slice ( sequence -- slice )
 158     [ drop 0 ] [ length ] [ ] tri <slice> ; inline
 159
 160 : slice-order-by-from ( slice1 slice2 -- slice-lt slice-gt )
 161     2dup [ from>> ] bi@ > [ swap ] when ; inline
 162
 163 : ordered-slices-range ( slice-lt slice-gt -- to from )
 164     [ to>> ] [ from>> ] bi* ;
 165
 166 : unordered-slices-range ( slice1 slice2 -- to from )
 167     slice-order-by-from ordered-slices-range ;
 168
 169 : ordered-slices-overlap? ( slice-lt slice-gt -- ? )
 170     ordered-slices-range > ; inline
 171
 172 : unordered-slices-overlap? ( slice1 slice2 -- ? )
 173     unordered-slices-range > ; inline
 174
 175 : slices-overlap? ( slice1 slice2 -- ? )
 176     unordered-slices-overlap? ;
 177
 178 : ordered-slices-touch? ( slice-lt slice-gt -- ? )
 179     ordered-slices-range >= ; inline
 180
 181 : unordered-slices-touch? ( slice1 slice2 -- ? )
 182     unordered-slices-range >= ; inline
 183
 184 : slices-touch? ( slice1 slice2 -- ? )
 185     unordered-slices-touch? ;
 186
 187 ERROR: slices-don't-touch slice1 slice2 ;
 188
 189 : merge-slices ( slice1 slice2 -- slice/* )
 190     slice-order-by-from
 191     2dup ordered-slices-touch? [
 192         [ from>> ] [ [ to>> ] [ seq>> ] bi ] bi* <slice>
 193     ] [
 194         slices-don't-touch
 195     ] if ;
 196
 197 : rotate ( seq n -- seq' )
 198     over length mod dup 0 >= [ cut ] [ abs cut* ] if prepend ;
 199
 200 ERROR: underlying-mismatch slice1 slice2 ;
 201 : ensure-same-underlying ( slice1 slice2 -- slice1 slice2 )
 202     2dup [ seq>> ] bi@ eq? [ underlying-mismatch ] unless ;
 203
 204 : span-slices ( slice1 slice2 -- slice )
 205     ensure-same-underlying
 206     [ [ from>> ] bi@ min ]
 207     [ [ to>> ] bi@ max ]
 208     [ drop seq>> ] 2tri <slice> ;
 209
 210 :: rotate! ( seq n -- )
 211     seq length :> len
 212     n len mod dup 0 < [ len + ] when seq bounds-check drop 0 over
 213     [ 2dup = ] [
 214         [ seq exchange-unsafe ] [ [ 1 + ] bi@ ] 2bi
 215         dup len = [ drop over ] when
 216         2over = [ -rot nip over ] when
 217     ] until 3drop ;
 218
 219 : all-rotations ( seq -- seq' )
 220     dup length iota [ rotate ] with map ;
 221
 222 <PRIVATE
 223
 224 : (appender-for) ( quot length exemplar -- appender accum )
 225     new-resizable [ [ push-all ] curry compose ] keep ; inline
 226
 227 PRIVATE>
 228
 229 : appender-for ( quot exemplar -- appender accum )
 230     [ length ] keep (appender-for) ; inline
 231
 232 : appender ( quot -- appender accum )
 233     V{ } appender-for ; inline
 234
 235 : map-concat-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 236     [ appender-for [ each ] dip ] keep like ; inline
 237
 238 : >resizable ( seq -- accum ) ! fixes map-concat "cannot apply call to run-time..."
 239     [ length ] keep [ new-resizable ] [ append! ] bi ;
 240
 241 : map-concat ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 242     over empty? [ 2drop { } ] [
 243         [ [ first ] dip call ] 2keep rot dup [
 244             >resizable [ [ push-all ] curry compose ] keep
 245             [ 1 ] 3dip [ setup-each (each-integer) ] dip
 246         ] curry dip like
 247     ] if ; inline
 248
 249 : map-filter-as ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) exemplar -- ... subseq )
 250     [ pick ] dip swap length over
 251     [ (selector-for) [ compose each ] dip ] 2curry dip like ; inline
 252
 253 : map-filter ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) -- ... subseq )
 254     pick map-filter-as ; inline
 255
 256 : map-sift ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 257     [ ] map-filter ; inline
 258
 259 : map-harvest ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 260     [ empty? not ] map-filter ; inline
 261
 262 <PRIVATE
 263
 264 : (setup-each-from) ( i seq -- n quot )
 265     [ length over [-] swap ] keep '[ _ + _ nth-unsafe ] ; inline
 266
 267 : setup-each-from ( i seq quot -- n quot' )
 268     [ (setup-each-from) ] dip compose ; inline
 269
 270 PRIVATE>
 271
 272 : map-from-as ( ... seq quot: ( ... elt -- ... newelt ) i exemplar -- ... newseq )
 273     [ -rot setup-each-from ] dip map-integers ; inline
 274
 275 : map-from ( ... seq quot: ( ... elt -- ... newelt ) i -- ... newseq )
 276     pick map-from-as ; inline
 277
 278 <PRIVATE
 279
 280 : push-map-if ( ..a elt filter-quot: ( ..a elt -- ..b ? ) map-quot: ( ..a elt -- ..b newelt ) accum -- ..b )
 281     [ keep over ] 2dip [ when ] dip rot [ push ] [ 2drop ] if ; inline
 282
 283 : (filter-mapper-for) ( filter-quot map-quot length exempler -- filter-mapper accum )
 284     new-resizable [ [ push-map-if ] 3curry ] keep ; inline
 285
 286 : filter-mapper-for ( filter-quot map-quot exemplar -- filter-mapper accum )
 287     [ length ] keep (filter-mapper-for) ; inline
 288
 289 : filter-mapper ( filter-quot map-quot -- filter-mapper accum )
 290     V{ } filter-mapper-for ; inline
 291
 292 PRIVATE>
 293
 294 : filter-map-as ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 295     [ pick ] dip swap length over
 296     [ (filter-mapper-for) [ each ] dip ] 2curry dip like ; inline
 297
 298 : filter-map ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) -- ... newseq )
 299     pick filter-map-as ; inline
 300
 301 : 2map-sum ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... n ) -- ... n )
 302     [ 0 ] 3dip [ dip + ] curry [ rot ] prepose 2each ; inline
 303
 304 : 2count ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... n )
 305     [ 1 0 ? ] compose 2map-sum ; inline
 306
 307 : round-robin ( seq -- newseq )
 308     [ { } ] [
 309         [ longest length iota ] keep
 310         [ [ ?nth ] with map ] curry map concat sift
 311     ] if-empty ;
 312
 313 : sift-as ( seq exemplar -- newseq )
 314     [ ] swap filter-as ;
 315
 316 : sift! ( seq -- newseq )
 317     [ ] filter! ;
 318
 319 : harvest-as ( seq exemplar -- newseq )
 320     [ empty? not ] swap filter-as ;
 321
 322 : harvest! ( seq -- newseq )
 323     [ empty? ] reject! ;
 324
 325 : head-as ( seq n exemplar -- seq' )
 326     [ head-slice ] [ like ] bi* ; inline
 327
 328 : head*-as ( seq n exemplar -- seq' )
 329     [ head-slice* ] [ like ] bi* ; inline
 330
 331 : tail-as ( seq n exemplar -- seq' )
 332     [ tail-slice ] [ like ] bi* ; inline
 333
 334 : tail*-as ( seq n exemplar -- seq' )
 335     [ tail-slice* ] [ like ] bi* ; inline
 336
 337 : trim-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... newseq )
 338     [ trim-slice ] [ like ] bi* ; inline
 339
 340 : ?trim ( seq quot: ( elt -- ? ) -- seq/newseq )
 341     over empty? [ drop ] [
 342         over [ first-unsafe ] [ last-unsafe ] bi pick either?
 343         [ trim ] [ drop ] if
 344     ] if ; inline
 345
 346 : ?trim-head ( seq quot: ( elt -- ? ) -- seq/newseq )
 347     over empty? [ drop ] [
 348         over first-unsafe over call
 349         [ trim-head ] [ drop ] if
 350     ] if ; inline
 351
 352 : ?trim-tail ( seq quot: ( elt -- ? ) -- seq/newseq )
 353     over empty? [ drop ] [
 354         over last-unsafe over call
 355         [ trim-tail ] [ drop ] if
 356     ] if ; inline
 357
 358 : unsurround ( newseq seq2 seq3 -- seq1 )
 359    [ ?head drop ] [ ?tail drop ] bi* ;
 360
 361 : none? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 362     any? not ; inline
 363
 364 : one? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 365     [ find ] 2keep rot [
 366         [ 1 + ] 2dip find-from drop not
 367     ] [ 3drop f ] if ; inline
 368
 369 : map-index! ( ... seq quot: ( ... elt index -- ... newelt ) -- ... seq )
 370     over [ [ (each-index) ] dip collect ] keep ; inline
 371
 372 <PRIVATE
 373
 374 : (2each-index) ( seq1 seq2 quot -- n quot' )
 375     [ setup-2each [ keep ] curry ] dip compose ; inline
 376
 377 PRIVATE>
 378
 379 : 2each-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... ) -- ... )
 380     (2each-index) each-integer ; inline
 381
 382 : 2map-into ( seq1 seq2 quot into -- )
 383     [ (2each) ] dip collect ; inline
 384
 385 : 2map! ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... seq1 )
 386     pick [ 2map-into ] keep ; inline
 387
 388 : 2map-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... newelt ) -- ... newseq )
 389     pick [ (2each-index) ] dip map-integers ; inline
 390
 391 TUPLE: evens seq length ;
 392
 393 : <evens> ( seq -- evens )
 394     dup length 1 + 2/ evens boa ; inline
 395
 396 M: evens length length>> ; inline
 397
 398 M: evens nth-unsafe [ 2 * ] [ seq>> nth-unsafe ] bi* ; inline
 399
 400 INSTANCE: evens immutable-sequence
 401
 402 TUPLE: odds seq length ;
 403
 404 : <odds> ( seq -- odds )
 405     dup length 2/ odds boa ; inline
 406
 407 M: odds length length>> ; inline
 408
 409 M: odds nth-unsafe [ 2 * 1 + ] [ seq>> nth-unsafe ] bi* ; inline
 410
 411 INSTANCE: odds immutable-sequence
 412
 413 : until-empty ( seq quot -- )
 414     [ dup empty? ] swap until drop ; inline
 415
 416 : arg-max ( seq -- n )
 417     <enum> [ second-unsafe ] supremum-by first ;
 418
 419 : arg-min ( seq -- n )
 420     <enum> [ second-unsafe ] infimum-by first ;
 421
 422 <PRIVATE
 423
 424 : push-index-if ( ..a elt i quot: ( ..a elt -- ..b ? ) accum -- ..b )
 425     [ dip ] dip rot [ push ] [ 2drop ] if ; inline
 426
 427 PRIVATE>
 428
 429 : arg-where ( ... seq quot: ( ... elt -- ... ? ) -- ... indices )
 430     over length <vector> [
 431         [ push-index-if ] 2curry each-index
 432     ] keep ; inline
 433
 434 : arg-sort ( seq -- indices )
 435     zip-index sort-keys values ;
 436
 437 : first= ( seq elt -- ? ) [ first ] dip = ; inline
 438 : second= ( seq elt -- ? ) [ second ] dip = ; inline
 439 : third= ( seq elt -- ? ) [ third ] dip = ; inline
 440 : fourth= ( seq elt -- ? ) [ fourth ] dip = ; inline
 441 : last= ( seq elt -- ? ) [ last ] dip = ; inline
 442 : nth= ( n seq elt -- ? ) [ nth ] dip = ; inline
 443
 444 : first? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ first ] dip call ; inline
 445 : second? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ second ] dip call ; inline
 446 : third? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ third ] dip call ; inline
 447 : fourth? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ fourth ] dip call ; inline
 448 : last? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ last ] dip call ; inline
 449 : nth? ( ... n seq quot: ( ... elt -- ... ? ) -- ... ? ) [ nth ] dip call ; inline
 450
 451 : loop>sequence ( quot exemplar -- seq )
 452    [ '[ [ @ [ [ , ] when* ] keep ] loop ] ] dip make ; inline
 453
 454 : loop>array ( quot -- seq )
 455    { } loop>sequence ; inline
 456
 457 <PRIVATE
 458
 459 : (reverse) ( seq -- newseq )
 460     dup [ length ] keep new-sequence
 461     [ 0 swap copy-unsafe ] keep reverse! ;
 462
 463 PRIVATE>
 464
 465 : reverse-as ( seq exemplar -- newseq )
 466     [ (reverse) ] [ like ] bi* ;
 467
 468 : map-product ( ... seq quot: ( ... elt -- ... n ) -- ... n )
 469     [ 1 ] 2dip [ dip * ] curry [ swap ] prepose each ; inline
 470
 471 : insert-nth! ( elt n seq -- )
 472     [ length ] keep ensure swap pick (a,b]
 473     over '[ [ 1 + ] keep _ move-unsafe ] each
 474     set-nth-unsafe ;
 475
 476 : set-nths ( value indices seq -- )
 477     swapd '[ _ swap _ set-nth ] each ; inline
 478
 479 : set-nths-unsafe ( value indices seq -- )
 480     swapd '[ _ swap _ set-nth-unsafe ] each ; inline
 481
 482 : flatten1 ( obj -- seq )
 483     [
 484         [
 485             dup branch? [
 486                 [ dup branch? [ % ] [ , ] if ] each
 487             ] [ , ] if
 488         ]
 489     ] keep dup branch? [ drop f ] unless make ;
 490
 491 <PRIVATE
 492
 493 : (map-find-index) ( seq quot find-quot -- result i elt )
 494     [ [ f ] 2dip [ [ nip ] 2dip call dup ] curry ] dip call
 495     [ [ [ drop f ] unless ] keep ] dip ; inline
 496
 497 PRIVATE>
 498
 499 : map-find-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 500     [ find-index ] (map-find-index) ; inline
 501
 502 : filter-length ( seq n -- seq' ) '[ length _ = ] filter ;
 503
 504 : all-shortest ( seqs -- seqs' ) dup shortest length filter-length ;
 505
 506 : all-longest ( seqs -- seqs' ) dup longest length filter-length ;
 507
 508 : remove-first ( obj seq -- seq' )
 509     [ index ] keep over [ remove-nth ] [ nip ] if ;
 510
 511 : remove-first! ( obj seq -- seq )
 512     [ index ] keep over [ remove-nth! ] [ nip ] if ;
 513
 514 : remove-last ( obj seq -- seq' )
 515     [ last-index ] keep over [ remove-nth ] [ nip ] if ;
 516
 517 : remove-last! ( obj seq -- seq )
 518     [ last-index ] keep over [ remove-nth! ] [ nip ] if ;
 519
 520 : ?first2 ( seq -- first/f second/f )
 521     dup length {
 522         { 0 [ drop f f ] }
 523         { 1 [ first-unsafe f ] }
 524         [ drop first2-unsafe ]
 525     } case ;
 526
 527 : ?first3 ( seq -- first/f second/f third/f )
 528     dup length {
 529         { 0 [ drop f f f ] }
 530         { 1 [ first-unsafe f f ] }
 531         { 2 [ first2-unsafe f ] }
 532         [ drop first3-unsafe ]
 533     } case ;
 534
 535 : ?first4 ( seq -- first/f second/f third/f fourth/f )
 536     dup length {
 537         { 0 [ drop f f f f ] }
 538         { 1 [ first-unsafe f f f ] }
 539         { 2 [ first2-unsafe f f ] }
 540         { 3 [ first3-unsafe f ] }
 541         [ drop first4-unsafe ]
 542     } case ;
 543
 544 : cut-when ( ... seq quot: ( ... elt -- ... ? ) -- ... before after )
 545     [ find drop ] 2keep drop swap
 546     [ cut ] [ f over like ] if* ; inline
 547
 548 : nth* ( n seq -- elt )
 549     [ length 1 - swap - ] [ nth ] bi ; inline
 550
 551 : each-index-from ( ... seq quot: ( ... elt index -- ... ) i -- ... )
 552     -rot (each-index) (each-integer) ; inline
 553
 554 <PRIVATE
 555
 556 : select-by* ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... i elt )
 557     [
 558         [ keep swap ] curry [ dip ] curry
 559         [ [ first 0 ] dip call ] 2keep
 560         [ 2curry 3dip 5 npick pick ] curry
 561     ] [
 562         [ [ 3drop ] [ [ 3drop ] 3dip ] if ] compose
 563     ] bi* compose 1 each-index-from nip swap ; inline
 564
 565 PRIVATE>
 566
 567 : supremum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 568     [ after? ] select-by* ; inline
 569
 570 : infimum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 571     [ before? ] select-by* ; inline
 572
 573 : change-last ( seq quot -- )
 574     [ drop length 1 - ] [ change-nth ] 2bi ; inline
 575
 576 : change-last-unsafe ( seq quot -- )
 577     [ drop length 1 - ] [ change-nth-unsafe ] 2bi ; inline
 578
 579 : replicate-into ( ... seq quot: ( ... -- ... newelt ) -- ... )
 580     over [ length ] 2dip '[ _ dip _ set-nth-unsafe ] each-integer ; inline
 581
 582 : count* ( ... seq quot: ( ... elt -- ... ? ) -- ... % )
 583     over [ count ] [ length ] bi* / ; inline
 584
 585 : find-last-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 586     [ [ 1 - ] dip find-last-integer ] (find-index) ; inline
 587
 588 : map-find-last-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 589     [ find-last-index ] (map-find-index) ; inline
 590
 591 :: (start-all) ( subseq seq increment -- indices )
 592     0
 593     [ [ subseq seq ] dip start* dup ]
 594     [ [ increment + ] keep ] produce nip ;
 595
 596 : start-all ( subseq seq -- indices )
 597     over length (start-all) ; inline
 598
 599 : start-all* ( subseq seq -- indices )
 600     1 (start-all) ; inline
 601
 602 : count-subseq ( subseq seq -- n )
 603     start-all length ; inline
 604
 605 : count-subseq* ( subseq seq -- n )
 606     start-all* length ; inline
 607
 608 : map-zip ( quot: ( x -- y ) -- alist )
 609     '[ _ keep swap ] map>alist ; inline