extra/sequences/extras/extras.factor

   1 USING: arrays grouping kernel locals math math.order math.ranges
   2 sequences sequences.private splitting ;
   3
   4 IN: sequences.extras
   5
   6 : reduce1 ( seq quot -- result ) [ unclip ] dip reduce ; inline
   7
   8 :: reduce-r ( list identity quot: ( obj1 obj2 -- obj ) -- result )
   9     list empty?
  10     [ identity ]
  11     [ list rest identity quot reduce-r list first quot call ] if ;
  12     inline recursive
  13
  14 ! Quot must have static stack effect, unlike "reduce"
  15 :: reduce* ( seq id quot -- result ) seq
  16     [ id ]
  17     [ unclip id swap quot call( prev elt -- next ) quot reduce* ] if-empty ; inline recursive
  18
  19 :: combos ( list1 list2 -- result )
  20     list2 [ [ 2array ] curry list1 swap map ] map concat ;
  21
  22 : find-all ( seq quot -- elts )
  23     [ [ length iota ] keep ] dip
  24     [ dupd call( a -- ? ) [ 2array ] [ 2drop f ] if ] curry
  25     2map [ ] filter ; inline
  26
  27 : insert-sorted ( elt seq -- seq )
  28     2dup [ < ] with find drop over length or swap insert-nth ;
  29
  30 : max-by ( obj1 obj2 quot: ( obj -- n ) -- obj1/obj2 )
  31     [ bi@ [ max ] keep eq? not ] curry most ; inline
  32
  33 : min-by ( obj1 obj2 quot: ( obj -- n ) -- obj1/obj2 )
  34     [ bi@ [ min ] keep eq? not ] curry most ; inline
  35
  36 : maximum ( seq quot: ( ... elt -- ... x ) -- elt )
  37     [ dup ?first ] dip [ max-by ] curry reduce ; inline
  38
  39 : minimum ( seq quot: ( ... elt -- ... x ) -- elt )
  40     [ dup ?first ] dip [ min-by ] curry reduce ; inline
  41
  42 : all-subseqs ( seq -- seqs )
  43     dup length [1,b] [ <clumps> ] with map concat ;
  44
  45 :: each-subseq ( ... seq quot: ( ... x -- ... ) -- ... )
  46     seq length :> len
  47     len [0,b] [
  48         :> from
  49         from len (a,b] [
  50             :> to
  51             from to seq subseq quot call( x -- )
  52         ] each
  53     ] each ;
  54
  55 :: longest-subseq ( seq1 seq2 -- subseq )
  56     seq1 length :> len1
  57     seq2 length :> len2
  58     0 :> n!
  59     0 :> end!
  60     len1 1 + [ len2 1 + 0 <array> ] replicate :> table
  61     len1 [1,b] [| x |
  62         len2 [1,b] [| y |
  63             x 1 - seq1 nth-unsafe
  64             y 1 - seq2 nth-unsafe = [
  65                 y 1 - x 1 - table nth-unsafe nth-unsafe 1 + :> len
  66                 len y x table nth-unsafe set-nth-unsafe
  67                 len n > [ len n! x end! ] when
  68             ] [ 0 y x table nth-unsafe set-nth-unsafe ] if
  69         ] each
  70     ] each end n - end seq1 subseq ;
  71
  72 : pad-longest ( seq1 seq2 elt -- seq1 seq2 )
  73     [ 2dup max-length ] dip [ pad-tail ] 2curry bi@ ;
  74
  75 : change-nths ( ... indices seq quot: ( ... elt -- ... elt' ) -- ... )
  76     [ change-nth ] 2curry each ; inline
  77
  78 : push-if-index ( ..a elt i quot: ( ..a elt i -- ..b ? ) accum -- ..b )
  79     [ 2keep drop ] dip rot [ push ] [ 2drop ] if ; inline
  80
  81 : index-selector-for ( quot exemplar -- selector accum )
  82     [ length ] keep new-resizable [ [ push-if-index ] 2curry ] keep ; inline
  83
  84 : filter-index-as ( ... seq quot: ( ... elt i -- ... ? ) exemplar -- ... seq' )
  85     dup [ index-selector-for [ each-index ] dip ] curry dip like ; inline
  86
  87 : filter-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... seq' )
  88     over filter-index-as ; inline
  89
  90 : even-indices ( seq -- seq' ) [ nip even? ] filter-index ;
  91
  92 : odd-indices ( seq -- seq' ) [ nip odd? ] filter-index ;
  93
  94 : compact ( seq quot elt -- seq' )
  95     [ split-when harvest ] dip join ; inline
  96
  97 : collapse ( seq quot elt -- seq' )
  98     [ split-when ] dip
  99     [ [ harvest ] dip join ]
 100     [ [ first empty? ] dip [ prepend ] curry when ]
 101     [ [ last empty? ] dip [ append ] curry when ]
 102     2tri ; inline
 103
 104 :: slice-when ( seq quot: ( elt -- ? ) -- seq' )
 105     seq length :> len
 106     0 [ len dupd < ] [
 107         dup seq quot find-from drop
 108         [ 2dup = [ 1 + ] when ] [ len ] if*
 109         [ seq <slice> ] keep len or swap
 110     ] produce nip ; inline
 111
 112 : rotate ( seq n -- seq' )
 113     cut prepend ;
 114
 115 :: rotate! ( seq n -- )
 116     seq length :> end
 117     n 0 n [ 2dup = ] [
 118         [ seq exchange ] [ [ 1 + ] bi@ ] 2bi
 119         dup end = [ drop over ] when
 120         2over = [ -rot nip over ] when
 121     ] until 3drop ;
 122
 123 : appender-for ( quot exemplar -- quot' vec )
 124     [ length ] keep new-resizable
 125     [ [ push-all ] curry compose ] keep ; inline
 126
 127 : appender ( quot -- quot' vec )
 128     V{ } appender-for ; inline
 129
 130 : map-concat-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 131     dup [ appender-for [ each ] dip ] curry dip like ; inline
 132
 133 : >resizable ( seq -- vec ) ! fixes map-concat "cannot apply call to run-time..."
 134     [ length ] keep [ new-resizable ] [ over push-all ] bi ;
 135
 136 : map-concat ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 137     over [ 2drop { } ] [
 138         first over call dup [
 139             >resizable [ [ push-all ] curry compose ] keep
 140             [ 1 ] 3dip [ (each) (each-integer) ] dip
 141         ] curry dip like
 142     ] if-empty ; inline
 143
 144 : map-filter-as ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) exemplar -- ... subseq )
 145     dup [ selector-for [ compose each ] dip ] curry dip like ; inline
 146
 147 : map-filter ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) -- ... subseq )
 148     pick map-filter-as ; inline
 149
 150 : map-sift ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 151     [ ] map-filter ; inline
 152
 153 : map-harvest ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 154     [ empty? not ] map-filter ; inline
 155
 156 <PRIVATE
 157
 158 : push-map-if ( ..a elt filter-quot: ( ..a elt -- ..b ? ) map-quot: ( ..a elt -- ..b newelt ) accum -- ..b )
 159     [ keep over ] 2dip [ when ] dip rot [ push ] [ 2drop ] if ; inline
 160
 161 : filter-mapper-for ( filter-quot map-quot exemplar -- quot' vec )
 162     [ length ] keep new-resizable [ [ push-map-if ] 3curry ] keep ; inline
 163
 164 : filter-mapper ( filter-quot map-quot -- quot' vec )
 165     V{ } filter-mapper-for ; inline
 166
 167 PRIVATE>
 168
 169 : filter-map-as ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 170     dup [ filter-mapper-for [ each ] dip ] curry dip like ; inline
 171
 172 : filter-map ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) -- ... newseq )
 173     pick filter-map-as ; inline