extra/sequences/extras/extras.factor

   1 USING: accessors arrays assocs combinators fry generalizations
   2 grouping growable kernel locals make math math.order math.ranges
   3 sequences sequences.deep sequences.private sorting splitting
   4 vectors ;
   5 IN: sequences.extras
   6
   7 : reduce1 ( seq quot -- result ) [ unclip ] dip reduce ; inline
   8
   9 :: reduce-r ( seq identity quot: ( obj1 obj2 -- obj ) -- result )
  10     seq [ identity ] [
  11         unclip [ identity quot reduce-r ] [ quot call ] bi*
  12     ] if-empty ; inline recursive
  13
  14 ! Quot must have static stack effect, unlike "reduce"
  15 :: reduce* ( seq identity quot: ( prev elt -- next ) -- result )
  16     seq [ identity ] [
  17         unclip identity swap quot call( prev elt -- next )
  18         quot reduce*
  19     ] if-empty ; inline recursive
  20
  21 :: combos ( list1 list2 -- result )
  22     list2 [ [ 2array ] curry list1 swap map ] map concat ;
  23
  24 : find-all ( seq quot: ( elt -- ? ) -- elts )
  25     [ [ length iota ] keep ] dip
  26     [ dupd call( a -- ? ) [ 2array ] [ 2drop f ] if ] curry
  27     2map sift ; inline
  28
  29 : reduce-from ( ... seq identity quot: ( ... prev elt -- ... next ) i -- ... result )
  30     [ swap ] 2dip each-from ; inline
  31
  32 :: subseq* ( from to seq -- subseq )
  33     seq length :> len
  34     from [ dup 0 < [ len + ] when ] [ 0 ] if*
  35     to [ dup 0 < [ len + ] when ] [ len ] if*
  36     [ 0 len clamp ] bi@ dupd max seq subseq ;
  37
  38 : safe-subseq ( from to seq -- subseq )
  39     [ length '[ 0 _ clamp ] bi@ ] keep subseq ;
  40
  41 : all-subseqs ( seq -- seqs )
  42     dup length [1,b] [ clump ] with map concat ;
  43
  44 :: each-subseq ( ... seq quot: ( ... x -- ... ) -- ... )
  45     seq length :> len
  46     len [0,b] [
  47         :> from
  48         from len (a,b] [
  49             :> to
  50             from to seq subseq quot call
  51         ] each
  52     ] each ; inline
  53
  54 : subseq-as ( from to seq exemplar -- subseq )
  55     [ check-slice subseq>copy (copy) ] dip like ;
  56
  57 : map-like ( seq exemplar -- seq' )
  58     '[ _ like ] map ; inline
  59
  60 : filter-all-subseqs-range ( ... seq range quot: ( ... x -- ... ) -- seq )
  61     [
  62         '[ <clumps> _ filter ] with map concat
  63     ] 3keep 2drop map-like ; inline
  64
  65 : filter-all-subseqs ( ... seq quot: ( ... x -- ... ) -- seq )
  66     [ dup length [1,b] ] dip filter-all-subseqs-range ; inline
  67
  68 :: longest-subseq ( seq1 seq2 -- subseq )
  69     seq1 length :> len1
  70     seq2 length :> len2
  71     0 :> n!
  72     0 :> end!
  73     len1 1 + [ len2 1 + 0 <array> ] replicate :> table
  74     len1 [1,b] [| x |
  75         len2 [1,b] [| y |
  76             x 1 - seq1 nth-unsafe
  77             y 1 - seq2 nth-unsafe = [
  78                 y 1 - x 1 - table nth-unsafe nth-unsafe 1 + :> len
  79                 len y x table nth-unsafe set-nth-unsafe
  80                 len n > [ len n! x end! ] when
  81             ] [ 0 y x table nth-unsafe set-nth-unsafe ] if
  82         ] each
  83     ] each end n - end seq1 subseq ;
  84
  85 : pad-longest ( seq1 seq2 elt -- seq1 seq2 )
  86     [ 2dup max-length ] dip [ pad-tail ] 2curry bi@ ;
  87
  88 : change-nths ( ... indices seq quot: ( ... elt -- ... elt' ) -- ... )
  89     [ change-nth ] 2curry each ; inline
  90
  91 : push-if-index ( ..a elt i quot: ( ..a elt i -- ..b ? ) accum -- ..b )
  92     [ 2keep drop ] dip rot [ push ] [ 2drop ] if ; inline
  93
  94 : push-if* ( ..a elt quot: ( ..a elt -- ..b obj/f ) accum -- ..b )
  95     [ call ] dip [ push ] [ drop ] if* ; inline
  96
  97 <PRIVATE
  98
  99 : (index-selector-for) ( quot length exampler -- selector accum )
 100     new-resizable [ [ push-if-index ] 2curry ] keep ; inline
 101
 102 : (selector-for*) ( quot length exemplar -- selector accum )
 103     new-resizable [ [ push-if* ] 2curry ] keep ; inline
 104
 105 PRIVATE>
 106
 107 : index-selector-for ( quot exemplar -- selector accum )
 108     [ length ] keep (index-selector-for) ; inline
 109
 110 : index-selector ( quot -- selector accum )
 111     V{ } index-selector-for ; inline
 112
 113 : selector-for* ( quot exemplar -- selector accum )
 114     [ length ] keep (selector-for*) ; inline
 115
 116 : selector* ( quot -- selector accum ) V{ } selector-for* ; inline
 117
 118 : filter-index-as ( ... seq quot: ( ... elt i -- ... ? ) exemplar -- ... seq' )
 119     pick length over [ (index-selector-for) [ each-index ] dip ] 2curry dip like ; inline
 120
 121 : filter-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... seq' )
 122     over filter-index-as ; inline
 123
 124 : even-indices ( seq -- seq' )
 125     [ length 1 + 2/ ] keep [
 126         [ [ 2 * ] dip nth-unsafe ] curry
 127     ] keep map-integers ;
 128
 129 : odd-indices ( seq -- seq' )
 130     [ length 2/ ] keep [
 131         [ [ 2 * 1 + ] dip nth-unsafe ] curry
 132     ] keep map-integers ;
 133
 134 : compact ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 135     [ split-when harvest ] dip join ; inline
 136
 137 : collapse ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 138     [ split-when ] dip
 139     [ [ harvest ] dip join ]
 140     [ [ first empty? ] dip [ prepend ] curry when ]
 141     [ [ last empty? ] dip [ append ] curry when ]
 142     2tri ; inline
 143
 144 :: slice-when ( seq quot: ( elt -- ? ) -- seq' )
 145     seq length :> len
 146     0 [ len dupd < ] [
 147         dup seq quot find-from drop
 148         [ 2dup = [ 1 + ] when ] [ len ] if*
 149         [ seq <slice> ] keep len or swap
 150     ] produce nip ; inline
 151
 152 : cut-slice* ( seq n -- before after )
 153     [ head-slice* ] [ tail-slice* ] 2bi ;
 154
 155 : ?<slice> ( from to/f sequence -- slice )
 156     over [ nip [ length ] [ ] bi ] unless <slice> ; inline
 157
 158 : sequence>slice ( sequence -- slice )
 159     [ drop 0 ] [ length ] [ ] tri <slice> ; inline
 160
 161 : length- ( n sequence -- m ) length swap - ; inline
 162
 163 : rotate-headwards ( seq n -- seq' )
 164     cut prepend ;
 165
 166 : rotate-tailwards ( seq n -- seq' )
 167     over length- cut prepend ;
 168
 169 :: rotate-headwards! ( seq n -- )
 170     n seq bounds-check length :> end
 171     0 n [ 2dup = ] [
 172         [ seq exchange-unsafe ] [ [ 1 + ] bi@ ] 2bi
 173         dup end = [ drop over ] when
 174         2over = [ -rot nip over ] when
 175     ] until 3drop ;
 176
 177 : all-rotations ( seq -- seq' )
 178     dup length iota [ rotate-headwards ] with map ;
 179
 180 <PRIVATE
 181
 182 : (appender-for) ( quot length exemplar -- appender accum )
 183     new-resizable [ [ push-all ] curry compose ] keep ; inline
 184
 185 PRIVATE>
 186
 187 : appender-for ( quot exemplar -- appender accum )
 188     [ length ] keep (appender-for) ; inline
 189
 190 : appender ( quot -- appender accum )
 191     V{ } appender-for ; inline
 192
 193 : map-concat-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 194     [ appender-for [ each ] dip ] keep like ; inline
 195
 196 : >resizable ( seq -- accum ) ! fixes map-concat "cannot apply call to run-time..."
 197     [ length ] keep [ new-resizable ] [ append! ] bi ;
 198
 199 : map-concat ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 200     over empty? [ 2drop { } ] [
 201         [ [ first ] dip call ] 2keep rot dup [
 202             >resizable [ [ push-all ] curry compose ] keep
 203             [ 1 ] 3dip [ setup-each (each-integer) ] dip
 204         ] curry dip like
 205     ] if ; inline
 206
 207 : map-filter-as ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) exemplar -- ... subseq )
 208     [ pick ] dip swap length over
 209     [ (selector-for) [ compose each ] dip ] 2curry dip like ; inline
 210
 211 : map-filter ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) -- ... subseq )
 212     pick map-filter-as ; inline
 213
 214 : map-sift ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 215     [ ] map-filter ; inline
 216
 217 : map-harvest ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 218     [ empty? not ] map-filter ; inline
 219
 220 <PRIVATE
 221
 222 : (setup-each-from) ( i seq -- n quot )
 223     [ length over [-] swap ] keep '[ _ + _ nth-unsafe ] ; inline
 224
 225 : setup-each-from ( i seq quot -- n quot' )
 226     [ (setup-each-from) ] dip compose ; inline
 227
 228 PRIVATE>
 229
 230 : map-from-as ( ... seq quot: ( ... elt -- ... newelt ) i exemplar -- ... newseq )
 231     [ -rot setup-each-from ] dip map-integers ; inline
 232
 233 : map-from ( ... seq quot: ( ... elt -- ... newelt ) i -- ... newseq )
 234     pick map-from-as ; inline
 235
 236 <PRIVATE
 237
 238 : push-map-if ( ..a elt filter-quot: ( ..a elt -- ..b ? ) map-quot: ( ..a elt -- ..b newelt ) accum -- ..b )
 239     [ keep over ] 2dip [ when ] dip rot [ push ] [ 2drop ] if ; inline
 240
 241 : (filter-mapper-for) ( filter-quot map-quot length exempler -- filter-mapper accum )
 242     new-resizable [ [ push-map-if ] 3curry ] keep ; inline
 243
 244 : filter-mapper-for ( filter-quot map-quot exemplar -- filter-mapper accum )
 245     [ length ] keep (filter-mapper-for) ; inline
 246
 247 : filter-mapper ( filter-quot map-quot -- filter-mapper accum )
 248     V{ } filter-mapper-for ; inline
 249
 250 PRIVATE>
 251
 252 : filter-map-as ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 253     [ pick ] dip swap length over
 254     [ (filter-mapper-for) [ each ] dip ] 2curry dip like ; inline
 255
 256 : filter-map ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) -- ... newseq )
 257     pick filter-map-as ; inline
 258
 259 : 2map-sum ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... n ) -- ... n )
 260     [ 0 ] 3dip [ dip + ] curry [ rot ] prepose 2each ; inline
 261
 262 : 2count ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... n )
 263     [ 1 0 ? ] compose 2map-sum ; inline
 264
 265 : round-robin ( seq -- newseq )
 266     [ { } ] [
 267         [ longest length iota ] keep
 268         [ [ ?nth ] with map ] curry map concat sift
 269     ] if-empty ;
 270
 271 : sift-as ( seq exemplar -- newseq )
 272     [ ] swap filter-as ;
 273
 274 : sift! ( seq -- newseq )
 275     [ ] filter! ;
 276
 277 : harvest-as ( seq exemplar -- newseq )
 278     [ empty? not ] swap filter-as ;
 279
 280 : harvest! ( seq -- newseq )
 281     [ empty? ] reject! ;
 282
 283 : head-as ( seq n exemplar -- seq' )
 284     [ head-slice ] [ like ] bi* ; inline
 285
 286 : head*-as ( seq n exemplar -- seq' )
 287     [ head-slice* ] [ like ] bi* ; inline
 288
 289 : tail-as ( seq n exemplar -- seq' )
 290     [ tail-slice ] [ like ] bi* ; inline
 291
 292 : tail*-as ( seq n exemplar -- seq' )
 293     [ tail-slice* ] [ like ] bi* ; inline
 294
 295 : trim-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... newseq )
 296     [ trim-slice ] [ like ] bi* ; inline
 297
 298 : ?trim ( seq quot: ( elt -- ? ) -- seq/newseq )
 299     over empty? [ drop ] [
 300         over [ first-unsafe ] [ last-unsafe ] bi pick either?
 301         [ trim ] [ drop ] if
 302     ] if ; inline
 303
 304 : ?trim-head ( seq quot: ( elt -- ? ) -- seq/newseq )
 305     over empty? [ drop ] [
 306         over first-unsafe over call
 307         [ trim-head ] [ drop ] if
 308     ] if ; inline
 309
 310 : ?trim-tail ( seq quot: ( elt -- ? ) -- seq/newseq )
 311     over empty? [ drop ] [
 312         over last-unsafe over call
 313         [ trim-tail ] [ drop ] if
 314     ] if ; inline
 315
 316 : unsurround ( newseq seq2 seq3 -- seq1 )
 317    [ ?head drop ] [ ?tail drop ] bi* ;
 318
 319 : none? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 320     any? not ; inline
 321
 322 : one? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 323     [ find ] 2keep rot [
 324         [ 1 + ] 2dip find-from drop not
 325     ] [ 3drop f ] if ; inline
 326
 327 : map-index! ( ... seq quot: ( ... elt index -- ... newelt ) -- ... seq )
 328     over [ [ (each-index) ] dip collect ] keep ; inline
 329
 330 <PRIVATE
 331
 332 : (2each-index) ( seq1 seq2 quot -- n quot' )
 333     [ setup-2each [ keep ] curry ] dip compose ; inline
 334
 335 PRIVATE>
 336
 337 : 2each-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... ) -- ... )
 338     (2each-index) each-integer ; inline
 339
 340 : 2map-into ( seq1 seq2 quot into -- )
 341     [ (2each) ] dip collect ; inline
 342
 343 : 2map! ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... seq1 )
 344     pick [ 2map-into ] keep ; inline
 345
 346 : 2map-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... newelt ) -- ... newseq )
 347     pick [ (2each-index) ] dip map-integers ; inline
 348
 349 TUPLE: evens seq length ;
 350
 351 : <evens> ( seq -- evens )
 352     dup length 1 + 2/ evens boa ; inline
 353
 354 M: evens length length>> ; inline
 355
 356 M: evens nth-unsafe [ 2 * ] [ seq>> nth-unsafe ] bi* ; inline
 357
 358 INSTANCE: evens immutable-sequence
 359
 360 TUPLE: odds seq length ;
 361
 362 : <odds> ( seq -- odds )
 363     dup length 2/ odds boa ; inline
 364
 365 M: odds length length>> ; inline
 366
 367 M: odds nth-unsafe [ 2 * 1 + ] [ seq>> nth-unsafe ] bi* ; inline
 368
 369 INSTANCE: odds immutable-sequence
 370
 371 : until-empty ( seq quot -- )
 372     [ dup empty? ] swap until drop ; inline
 373
 374 : arg-max ( seq -- n )
 375     <enum> [ second-unsafe ] supremum-by first ;
 376
 377 : arg-min ( seq -- n )
 378     <enum> [ second-unsafe ] infimum-by first ;
 379
 380 <PRIVATE
 381
 382 : push-index-if ( ..a elt i quot: ( ..a elt -- ..b ? ) accum -- ..b )
 383     [ dip ] dip rot [ push ] [ 2drop ] if ; inline
 384
 385 PRIVATE>
 386
 387 : arg-where ( ... seq quot: ( ... elt -- ... ? ) -- ... indices )
 388     over length <vector> [
 389         [ push-index-if ] 2curry each-index
 390     ] keep ; inline
 391
 392 : arg-sort ( seq -- indices )
 393     zip-index sort-keys values ;
 394
 395 : first= ( seq elt -- ? ) [ first ] dip = ; inline
 396 : second= ( seq elt -- ? ) [ second ] dip = ; inline
 397 : third= ( seq elt -- ? ) [ third ] dip = ; inline
 398 : fourth= ( seq elt -- ? ) [ fourth ] dip = ; inline
 399 : last= ( seq elt -- ? ) [ last ] dip = ; inline
 400 : nth= ( n seq elt -- ? ) [ nth ] dip = ; inline
 401
 402 : first? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ first ] dip call ; inline
 403 : second? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ second ] dip call ; inline
 404 : third? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ third ] dip call ; inline
 405 : fourth? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ fourth ] dip call ; inline
 406 : last? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ last ] dip call ; inline
 407 : nth? ( ... n seq quot: ( ... elt -- ... ? ) -- ... ? ) [ nth ] dip call ; inline
 408
 409 : loop>sequence ( quot exemplar -- seq )
 410    [ '[ [ @ [ [ , ] when* ] keep ] loop ] ] dip make ; inline
 411
 412 : loop>array ( quot -- seq )
 413    { } loop>sequence ; inline
 414
 415 <PRIVATE
 416
 417 : (reverse) ( seq -- newseq )
 418     dup [ length ] keep new-sequence
 419     [ 0 swap copy-unsafe ] keep reverse! ;
 420
 421 PRIVATE>
 422
 423 : reverse-as ( seq exemplar -- newseq )
 424     [ (reverse) ] [ like ] bi* ;
 425
 426 : map-product ( ... seq quot: ( ... elt -- ... n ) -- ... n )
 427     [ 1 ] 2dip [ dip * ] curry [ swap ] prepose each ; inline
 428
 429 : insert-nth! ( elt n seq -- )
 430     [ length ] keep ensure swap pick (a,b]
 431     over '[ [ 1 + ] keep _ move-unsafe ] each
 432     set-nth-unsafe ;
 433
 434 : set-nths ( value indices seq -- )
 435     swapd '[ _ swap _ set-nth ] each ; inline
 436
 437 : set-nths-unsafe ( value indices seq -- )
 438     swapd '[ _ swap _ set-nth-unsafe ] each ; inline
 439
 440 : flatten1 ( obj -- seq )
 441     [
 442         [
 443             dup branch? [
 444                 [ dup branch? [ % ] [ , ] if ] each
 445             ] [ , ] if
 446         ]
 447     ] keep dup branch? [ drop f ] unless make ;
 448
 449 <PRIVATE
 450
 451 : (map-find-index) ( seq quot find-quot -- result i elt )
 452     [ [ f ] 2dip [ [ nip ] 2dip call dup ] curry ] dip call
 453     [ [ [ drop f ] unless ] keep ] dip ; inline
 454
 455 PRIVATE>
 456
 457 : map-find-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 458     [ find-index ] (map-find-index) ; inline
 459
 460 : filter-length ( seq n -- seq' ) '[ length _ = ] filter ;
 461
 462 : all-shortest ( seqs -- seqs' ) dup shortest length filter-length ;
 463
 464 : all-longest ( seqs -- seqs' ) dup longest length filter-length ;
 465
 466 : remove-first ( obj seq -- seq' )
 467     [ index ] keep over [ remove-nth ] [ nip ] if ;
 468
 469 : remove-first! ( obj seq -- seq )
 470     [ index ] keep over [ remove-nth! ] [ nip ] if ;
 471
 472 : remove-last ( obj seq -- seq' )
 473     [ last-index ] keep over [ remove-nth ] [ nip ] if ;
 474
 475 : remove-last! ( obj seq -- seq )
 476     [ last-index ] keep over [ remove-nth! ] [ nip ] if ;
 477
 478 : ?first2 ( seq -- first/f second/f )
 479     dup length {
 480         { 0 [ drop f f ] }
 481         { 1 [ first-unsafe f ] }
 482         [ drop first2-unsafe ]
 483     } case ;
 484
 485 : ?first3 ( seq -- first/f second/f third/f )
 486     dup length {
 487         { 0 [ drop f f f ] }
 488         { 1 [ first-unsafe f f ] }
 489         { 2 [ first2-unsafe f ] }
 490         [ drop first3-unsafe ]
 491     } case ;
 492
 493 : ?first4 ( seq -- first/f second/f third/f fourth/f )
 494     dup length {
 495         { 0 [ drop f f f f ] }
 496         { 1 [ first-unsafe f f f ] }
 497         { 2 [ first2-unsafe f f ] }
 498         { 3 [ first3-unsafe f ] }
 499         [ drop first4-unsafe ]
 500     } case ;
 501
 502 : cut-when ( ... seq quot: ( ... elt -- ... ? ) -- ... before after )
 503     [ find drop ] 2keep drop swap
 504     [ cut ] [ f over like ] if* ; inline
 505
 506 : nth* ( n seq -- elt )
 507     [ length 1 - swap - ] [ nth ] bi ; inline
 508
 509 : each-index-from ( ... seq quot: ( ... elt index -- ... ) i -- ... )
 510     -rot (each-index) (each-integer) ; inline
 511
 512 <PRIVATE
 513
 514 : select-by* ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... i elt )
 515     [
 516         [ keep swap ] curry [ dip ] curry
 517         [ [ first 0 ] dip call ] 2keep
 518         [ 2curry 3dip 5 npick pick ] curry
 519     ] [
 520         [ [ 3drop ] [ [ 3drop ] 3dip ] if ] compose
 521     ] bi* compose 1 each-index-from nip swap ; inline
 522
 523 PRIVATE>
 524
 525 : supremum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 526     [ after? ] select-by* ; inline
 527
 528 : infimum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 529     [ before? ] select-by* ; inline
 530
 531 : change-last ( seq quot -- )
 532     [ drop length 1 - ] [ change-nth ] 2bi ; inline
 533
 534 : change-last-unsafe ( seq quot -- )
 535     [ drop length 1 - ] [ change-nth-unsafe ] 2bi ; inline
 536
 537 : replicate-into ( ... seq quot: ( ... -- ... newelt ) -- ... )
 538     over [ length ] 2dip '[ _ dip _ set-nth-unsafe ] each-integer ; inline
 539
 540 : count* ( ... seq quot: ( ... elt -- ... ? ) -- ... % )
 541     over [ count ] [ length ] bi* / ; inline
 542
 543 : find-last-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 544     [ [ 1 - ] dip find-last-integer ] (find-index) ; inline
 545
 546 : map-find-last-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 547     [ find-last-index ] (map-find-index) ; inline
 548
 549 :: (start-all) ( subseq seq increment -- indices )
 550     0
 551     [ [ subseq seq ] dip start* dup ]
 552     [ [ increment + ] keep ] produce nip ;
 553
 554 : start-all ( subseq seq -- indices )
 555     over length (start-all) ; inline
 556
 557 : start-all* ( subseq seq -- indices )
 558     1 (start-all) ; inline
 559
 560 : count-subseq ( subseq seq -- n )
 561     start-all length ; inline
 562
 563 : count-subseq* ( subseq seq -- n )
 564     start-all* length ; inline
 565
 566 : map-zip ( quot: ( x -- y ) -- alist )
 567     '[ _ keep swap ] map>alist ; inline