extra/sequences/extras/extras.factor

   1 USING: accessors arrays assocs combinators generalizations
   2 grouping growable kernel math math.order ranges sequences
   3 sequences.private shuffle sorting splitting vectors ;
   4 IN: sequences.extras
   5
   6 : find-all ( ... seq quot: ( ... elt -- ... ? ) -- ... elts )
   7     [ <enumerated> ] dip '[ nip @ ] assoc-filter ; inline
   8
   9 : reduce-from ( ... seq identity quot: ( ... prev elt -- ... next ) i -- ... result )
  10     [ swap ] 2dip each-from ; inline
  11
  12 :: subseq* ( from to seq -- subseq )
  13     seq length :> len
  14     from [ dup 0 < [ len + ] when ] [ 0 ] if*
  15     to [ dup 0 < [ len + ] when ] [ len ] if* [ 0 len clamp ] bi@ dupd max seq subseq ;
  16
  17 : safe-subseq ( from to seq -- subseq )
  18     [ length '[ 0 _ clamp ] bi@ ] keep subseq ;
  19
  20 : all-subseqs ( seq -- seqs )
  21     dup length [1..b] [ clump ] with map concat ;
  22
  23 :: each-subseq ( ... seq quot: ( ... subseq -- ... ) -- ... )
  24     seq length :> len
  25     len [0..b] [| from |
  26         from len (a..b] [| to |
  27             from to seq subseq quot call
  28         ] each
  29     ] each ; inline
  30
  31 : map-like ( seq exemplar -- seq' )
  32     '[ _ like ] map ; inline
  33
  34 : filter-all-subseqs-range ( ... seq range quot: ( ... subseq -- ... ? ) -- seq )
  35     [
  36         '[ <clumps> _ filter ] with map concat
  37     ] keepdd map-like ; inline
  38
  39 : filter-all-subseqs ( ... seq quot: ( ... subseq -- ... ? ) -- seq )
  40     [ dup length [1..b] ] dip filter-all-subseqs-range ; inline
  41
  42 :: longest-subseq ( seq1 seq2 -- subseq )
  43     seq1 length :> len1
  44     seq2 length :> len2
  45     0 :> n!
  46     0 :> end!
  47     len1 1 + [ len2 1 + 0 <array> ] replicate :> table
  48     len1 [1..b] [| x |
  49         len2 [1..b] [| y |
  50             x 1 - seq1 nth-unsafe
  51             y 1 - seq2 nth-unsafe = [
  52                 y 1 - x 1 - table nth-unsafe nth-unsafe 1 + :> len
  53                 len y x table nth-unsafe set-nth-unsafe
  54                 len n > [ len n! x end! ] when
  55             ] [ 0 y x table nth-unsafe set-nth-unsafe ] if
  56         ] each
  57     ] each end n - end seq1 subseq ;
  58
  59 : pad-longest ( seq1 seq2 elt -- seq1 seq2 )
  60     [ 2dup max-length ] dip [ pad-tail ] 2curry bi@ ;
  61
  62 : pad-center ( seq n elt -- padded )
  63     swap pick length [-] [ drop ] [
  64         [ 2/ ] [ over - ] bi rot '[ _ <repetition> ] bi@
  65         pick surround-as
  66     ] if-zero ;
  67
  68 : change-nths ( ... indices seq quot: ( ... elt -- ... elt' ) -- ... )
  69     [ change-nth ] 2curry each ; inline
  70
  71 : push-if-index ( ..a elt i quot: ( ..a elt i -- ..b ? ) accum -- ..b )
  72     [ keepd ] dip rot [ push ] [ 2drop ] if ; inline
  73
  74 : push-if* ( ..a elt quot: ( ..a elt -- ..b obj/f ) accum -- ..b )
  75     [ call ] dip [ push ] [ drop ] if* ; inline
  76
  77 <PRIVATE
  78
  79 : (index-selector-as) ( quot length exampler -- selector accum )
  80     new-resizable [ [ push-if-index ] 2curry ] keep ; inline
  81
  82 : (selector-as*) ( quot length exemplar -- selector accum )
  83     new-resizable [ [ push-if* ] 2curry ] keep ; inline
  84
  85 PRIVATE>
  86
  87 : index-selector-as ( quot exemplar -- selector accum )
  88     [ length ] keep (index-selector-as) ; inline
  89
  90 : index-selector ( quot -- selector accum )
  91     V{ } index-selector-as ; inline
  92
  93 : selector-as* ( quot exemplar -- selector accum )
  94     [ length ] keep (selector-as*) ; inline
  95
  96 : selector* ( quot -- selector accum ) V{ } selector-as* ; inline
  97
  98 : filter-index-as ( ... seq quot: ( ... elt i -- ... ? ) exemplar -- ... seq' )
  99     pick length over [ (index-selector-as) [ each-index ] dip ] 2curry dip like ; inline
 100
 101 : filter-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... seq' )
 102     over filter-index-as ; inline
 103
 104 : even-indices ( seq -- seq' )
 105     [ length 1 + 2/ ] keep [
 106         [ [ 2 * ] dip nth-unsafe ] curry
 107     ] keep map-integers ;
 108
 109 : odd-indices ( seq -- seq' )
 110     [ length 2/ ] keep [
 111         [ [ 2 * 1 + ] dip nth-unsafe ] curry
 112     ] keep map-integers ;
 113
 114 : compact ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 115     [ split-when harvest ] dip join ; inline
 116
 117 : collapse ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 118     [ split-when ] dip
 119     [ [ harvest ] dip join ]
 120     [ [ first empty? ] dip [ prepend ] curry when ]
 121     [ [ last empty? ] dip [ append ] curry when ]
 122     2tri ; inline
 123
 124 :: slice-when ( seq quot: ( elt -- ? ) -- seq' )
 125     seq length :> len
 126     0 [ len dupd < ] [
 127         dup seq quot find-from drop
 128         [ 2dup = [ 1 + ] when ] [ len ] if*
 129         [ seq <slice> ] keep len or swap
 130     ] produce nip ; inline
 131
 132 : ?<slice> ( from/f to/f sequence -- slice )
 133     [ [ 0 ] unless* ] 2dip
 134     over [ nip [ length ] [ ] bi ] unless
 135     <slice> ; inline
 136
 137 : sequence>slice ( sequence -- slice )
 138     [ drop 0 ] [ length ] [ ] tri <slice> ; inline
 139
 140 : slice-order-by-from ( slice1 slice2 -- slice-lt slice-gt )
 141     2dup [ from>> ] bi@ > [ swap ] when ; inline
 142
 143 : ordered-slices-range ( slice-lt slice-gt -- to from )
 144     [ to>> ] [ from>> ] bi* ;
 145
 146 : unordered-slices-range ( slice1 slice2 -- to from )
 147     slice-order-by-from ordered-slices-range ;
 148
 149 : ordered-slices-overlap? ( slice-lt slice-gt -- ? )
 150     ordered-slices-range > ; inline
 151
 152 : unordered-slices-overlap? ( slice1 slice2 -- ? )
 153     unordered-slices-range > ; inline
 154
 155 : slices-overlap? ( slice1 slice2 -- ? )
 156     unordered-slices-overlap? ;
 157
 158 : ordered-slices-touch? ( slice-lt slice-gt -- ? )
 159     ordered-slices-range >= ; inline
 160
 161 : unordered-slices-touch? ( slice1 slice2 -- ? )
 162     unordered-slices-range >= ; inline
 163
 164 : slices-touch? ( slice1 slice2 -- ? )
 165     unordered-slices-touch? ;
 166
 167 ERROR: slices-don't-touch slice1 slice2 ;
 168
 169 : merge-slices ( slice1 slice2 -- slice/* )
 170     slice-order-by-from
 171     2dup ordered-slices-touch? [
 172         [ from>> ] [ [ to>> ] [ seq>> ] bi ] bi* <slice>
 173     ] [
 174         slices-don't-touch
 175     ] if ;
 176
 177 : rotate ( seq n -- seq' )
 178     over length mod dup 0 >= [ cut ] [ abs cut* ] if prepend ;
 179
 180 ERROR: underlying-mismatch slice1 slice2 ;
 181
 182 : ensure-same-underlying ( slice1 slice2 -- slice1 slice2 )
 183     2dup [ seq>> ] bi@ eq? [ underlying-mismatch ] unless ;
 184
 185 : span-slices ( slice1 slice2 -- slice )
 186     ensure-same-underlying
 187     [ [ from>> ] bi@ min ]
 188     [ [ to>> ] bi@ max ]
 189     [ drop seq>> ] 2tri <slice> ;
 190
 191 : ?span-slices ( slice1/f slice2/f -- slice )
 192     2dup and [ span-slices ] [ or ] if ;
 193
 194 :: rotate! ( seq n -- )
 195     seq length :> len
 196     n len mod dup 0 < [ len + ] when seq bounds-check drop 0 over
 197     [ 2dup = ] [
 198         [ seq exchange-unsafe ] [ [ 1 + ] bi@ ] 2bi
 199         dup len = [ drop over ] when
 200         2over = [ -rot nip over ] when
 201     ] until 3drop ;
 202
 203 : all-rotations ( seq -- seq' )
 204     dup length <iota> [ rotate ] with map ;
 205
 206 <PRIVATE
 207
 208 : (appender-for) ( quot length exemplar -- appender accum )
 209     new-resizable [ [ push-all ] curry compose ] keep ; inline
 210
 211 PRIVATE>
 212
 213 : appender-for ( quot exemplar -- appender accum )
 214     [ length ] keep (appender-for) ; inline
 215
 216 : appender ( quot -- appender accum )
 217     V{ } appender-for ; inline
 218
 219 : map-concat-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 220     [ appender-for [ each ] dip ] keep like ; inline
 221
 222 : >resizable ( seq -- accum ) ! fixes map-concat "cannot apply call to run-time..."
 223     [ length ] keep [ new-resizable ] [ append! ] bi ;
 224
 225 : map-concat ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 226     over empty? [ 2drop { } ] [
 227         [ [ first ] dip call ] 2keep rot [
 228             >resizable [ '[ @ _ push-all ] 1 each-from ] keep
 229         ] keep like
 230     ] if ; inline
 231
 232 : map-filter-as ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) exemplar -- ... subseq )
 233     reach length over
 234     [ (selector-as) [ compose each ] dip ] 2curry dip like ; inline
 235
 236 : map-filter ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) -- ... subseq )
 237     pick map-filter-as ; inline
 238
 239 : map-sift ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 240     [ ] map-filter ; inline
 241
 242 : map-harvest ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 243     [ empty? not ] map-filter ; inline
 244
 245 <PRIVATE
 246
 247 : (setup-each-from) ( i seq -- n quot )
 248     [ length over [-] swap ] keep '[ _ + _ nth-unsafe ] ; inline
 249
 250 : setup-each-from ( i seq quot -- n quot' )
 251     [ (setup-each-from) ] dip compose ; inline
 252
 253 PRIVATE>
 254
 255 : map-from-as ( ... seq quot: ( ... elt -- ... newelt ) i exemplar -- ... newseq )
 256     [ -rot setup-each-from ] dip map-integers ; inline
 257
 258 : map-from ( ... seq quot: ( ... elt -- ... newelt ) i -- ... newseq )
 259     pick map-from-as ; inline
 260
 261 <PRIVATE
 262
 263 : push-map-if ( ..a elt filter-quot: ( ..a elt -- ..b ? ) map-quot: ( ..a elt -- ..b newelt ) accum -- ..b )
 264     [ keep over ] 2dip [ when ] dip rot [ push ] [ 2drop ] if ; inline
 265
 266 : (filter-mapper-for) ( filter-quot map-quot length exempler -- filter-mapper accum )
 267     new-resizable [ [ push-map-if ] 3curry ] keep ; inline
 268
 269 : filter-mapper-for ( filter-quot map-quot exemplar -- filter-mapper accum )
 270     [ length ] keep (filter-mapper-for) ; inline
 271
 272 : filter-mapper ( filter-quot map-quot -- filter-mapper accum )
 273     V{ } filter-mapper-for ; inline
 274
 275 PRIVATE>
 276
 277 : filter-map-as ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 278     reach length over
 279     [ (filter-mapper-for) [ each ] dip ] 2curry dip like ; inline
 280
 281 : filter-map ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) -- ... newseq )
 282     pick filter-map-as ; inline
 283
 284 : 2map-sum ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... n ) -- ... n )
 285     [ 0 ] 3dip [ dip + ] curry [ rot ] prepose 2each ; inline
 286
 287 : 2count ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... n )
 288     [ 1 0 ? ] compose 2map-sum ; inline
 289
 290 : 3each-from
 291     ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... ) i -- ... )
 292     [ (3each) ] dip -rot (each-integer) ; inline
 293
 294 : 3map-reduce
 295     ( ..a seq1 seq2 seq3 map-quot: ( ..a elt1 elt2 elt3 -- ..b intermediate ) reduce-quot: ( ..b prev intermediate -- ..a next ) -- ..a result )
 296     [ [ [ [ first ] tri@ ] 3keep ] dip [ 3dip ] keep ] dip compose 1 3each-from ; inline
 297
 298 : round-robin ( seq -- newseq )
 299     [ { } ] [
 300         [ longest length <iota> ] keep
 301         [ [ ?nth ] with map ] curry map concat sift
 302     ] if-empty ;
 303
 304 : sift-as ( seq exemplar -- newseq )
 305     [ ] swap filter-as ;
 306
 307 : sift! ( seq -- newseq )
 308     [ ] filter! ;
 309
 310 : harvest-as ( seq exemplar -- newseq )
 311     [ empty? not ] swap filter-as ;
 312
 313 : harvest! ( seq -- newseq )
 314     [ empty? ] reject! ;
 315
 316 : head-as ( seq n exemplar -- seq' )
 317     [ head-slice ] [ like ] bi* ; inline
 318
 319 : head*-as ( seq n exemplar -- seq' )
 320     [ head-slice* ] [ like ] bi* ; inline
 321
 322 : tail-as ( seq n exemplar -- seq' )
 323     [ tail-slice ] [ like ] bi* ; inline
 324
 325 : tail*-as ( seq n exemplar -- seq' )
 326     [ tail-slice* ] [ like ] bi* ; inline
 327
 328 : trim-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... newseq )
 329     [ trim-slice ] [ like ] bi* ; inline
 330
 331 : ?trim ( seq quot: ( elt -- ? ) -- seq/newseq )
 332     over empty? [ drop ] [
 333         over [ first-unsafe ] [ last-unsafe ] bi pick either?
 334         [ trim ] [ drop ] if
 335     ] if ; inline
 336
 337 : ?trim-head ( seq quot: ( elt -- ? ) -- seq/newseq )
 338     over empty? [ drop ] [
 339         over first-unsafe over call
 340         [ trim-head ] [ drop ] if
 341     ] if ; inline
 342
 343 : ?trim-tail ( seq quot: ( elt -- ? ) -- seq/newseq )
 344     over empty? [ drop ] [
 345         over last-unsafe over call
 346         [ trim-tail ] [ drop ] if
 347     ] if ; inline
 348
 349 : unsurround ( newseq seq2 seq3 -- seq1 )
 350    [ ?head drop ] [ ?tail drop ] bi* ;
 351
 352 : >string-list ( seq -- seq' )
 353     [ "\"" 1surround ] map "," join ;
 354
 355 : one? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 356     [ find ] 2keep rot [
 357         [ 1 + ] 2dip find-from drop not
 358     ] [ 3drop f ] if ; inline
 359
 360 : map-index! ( ... seq quot: ( ... elt index -- ... newelt ) -- ... seq )
 361     over [ [ (each-index) ] dip collect ] keep ; inline
 362
 363 <PRIVATE
 364
 365 : (2each-index) ( seq1 seq2 quot -- n quot' )
 366     [ setup-2each [ keep ] curry ] dip compose ; inline
 367
 368 PRIVATE>
 369
 370 : 2each-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... ) -- ... )
 371     (2each-index) each-integer ; inline
 372
 373 : 2map-into ( seq1 seq2 quot into -- )
 374     [ (2each) ] dip collect ; inline
 375
 376 : 2map! ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... seq1 )
 377     pick [ 2map-into ] keep ; inline
 378
 379 : 2map-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... newelt ) -- ... newseq )
 380     pick [ (2each-index) ] dip map-integers ; inline
 381
 382 TUPLE: evens { seq read-only } ;
 383
 384 C: <evens> evens
 385
 386 M: evens length seq>> length 1 + 2/ ; inline
 387
 388 M: evens virtual@ [ 2 * ] [ seq>> ] bi* ; inline
 389
 390 M: evens virtual-exemplar seq>> ; inline
 391
 392 INSTANCE: evens virtual-sequence
 393
 394 TUPLE: odds { seq read-only } ;
 395
 396 C: <odds> odds
 397
 398 M: odds length seq>> length 2/ ; inline
 399
 400 M: odds virtual@ [ 2 * 1 + ] [ seq>> ] bi* ; inline
 401
 402 M: odds virtual-exemplar seq>> ; inline
 403
 404 INSTANCE: odds virtual-sequence
 405
 406 : until-empty ( seq quot -- )
 407     [ dup empty? ] swap until drop ; inline
 408
 409 : arg-max ( seq -- n )
 410     [ supremum ] keep index ;
 411
 412 : arg-min ( seq -- n )
 413     [ infimum ] keep index ;
 414
 415 <PRIVATE
 416
 417 : push-index-if ( ..a elt i quot: ( ..a elt -- ..b ? ) accum -- ..b )
 418     [ dip ] dip rot [ push ] [ 2drop ] if ; inline
 419
 420 PRIVATE>
 421
 422 : arg-where ( ... seq quot: ( ... elt -- ... ? ) -- ... indices )
 423     over length <vector> [
 424         [ push-index-if ] 2curry each-index
 425     ] keep ; inline
 426
 427 : arg-sort ( seq -- indices )
 428     zip-index sort-keys values ;
 429
 430 : first= ( seq elt -- ? ) [ first ] dip = ; inline
 431 : second= ( seq elt -- ? ) [ second ] dip = ; inline
 432 : third= ( seq elt -- ? ) [ third ] dip = ; inline
 433 : fourth= ( seq elt -- ? ) [ fourth ] dip = ; inline
 434 : last= ( seq elt -- ? ) [ last ] dip = ; inline
 435 : nth= ( n seq elt -- ? ) [ nth ] dip = ; inline
 436
 437 : first? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ first ] dip call ; inline
 438 : second? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ second ] dip call ; inline
 439 : third? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ third ] dip call ; inline
 440 : fourth? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ fourth ] dip call ; inline
 441 : last? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ last ] dip call ; inline
 442 : nth? ( ... n seq quot: ( ... elt -- ... ? ) -- ... ? ) [ nth ] dip call ; inline
 443
 444 : loop>sequence** ( ... quot: ( ... -- ... obj ? ) exemplar -- ... seq )
 445     [ ] swap produce-as nip ; inline
 446
 447 : loop>array** ( ... quot: ( ... -- ... obj ? ) -- ... array )
 448     { } loop>sequence** ; inline
 449
 450 : loop>sequence* ( ... quot: ( ... -- ... obj ? ) exemplar -- ... seq )
 451     [ t ] [ '[ [ _ dip ] [ f f f ] if* ] [ swap ] ] [ produce-as 2nip ] tri* ; inline
 452
 453 : loop>array* ( ... quot: ( ... -- ... obj ? ) -- ... array )
 454     { } loop>sequence* ; inline
 455
 456 : loop>sequence ( ... quot: ( ... -- ... obj/f ) exemplar -- ... seq )
 457     [ [ dup ] compose [ ] ] dip produce-as nip ; inline
 458
 459 : loop>array ( ... quot: ( ... -- ... obj/f ) -- ... array )
 460    { } loop>sequence ; inline
 461
 462 : zero-loop>sequence ( ... quot: ( ... n -- ... obj/f ) exemplar -- ... seq )
 463     [ 0 ] [ '[ _ keep 1 + swap ] ] [ loop>sequence ] tri* nip ; inline
 464
 465 : zero-loop>array ( quot: ( ..a n -- ..a obj ) -- seq )
 466     { } zero-loop>sequence ; inline
 467
 468 <PRIVATE
 469
 470 : (reverse) ( seq -- newseq )
 471     dup [ length ] keep new-sequence
 472     [ 0 swap copy-unsafe ] keep reverse! ;
 473
 474 PRIVATE>
 475
 476 : reverse-as ( seq exemplar -- newseq )
 477     [ (reverse) ] [ like ] bi* ;
 478
 479 : map-product ( ... seq quot: ( ... elt -- ... n ) -- ... n )
 480     [ 1 ] 2dip [ dip * ] curry [ swap ] prepose each ; inline
 481
 482 : insert-nth! ( elt n seq -- )
 483     [ length ] keep ensure swap pick (a..b]
 484     over '[ [ 1 + ] keep _ move-unsafe ] each
 485     set-nth-unsafe ;
 486
 487 : set-nths ( value indices seq -- )
 488     swapd '[ _ swap _ set-nth ] each ; inline
 489
 490 : set-nths-unsafe ( value indices seq -- )
 491     swapd '[ _ swap _ set-nth-unsafe ] each ; inline
 492
 493 <PRIVATE
 494
 495 : (map-find-index) ( seq quot find-quot -- result i elt )
 496     [ [ f ] 2dip [ [ nip ] 2dip call dup ] curry ] dip call
 497     [ [ [ drop f ] unless ] keep ] dip ; inline
 498
 499 PRIVATE>
 500
 501 : map-find-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 502     [ find-index ] (map-find-index) ; inline
 503
 504 : filter-length ( seq n -- seq' ) '[ length _ = ] filter ;
 505
 506 : all-shortest ( seqs -- seqs' ) dup shortest length filter-length ;
 507
 508 : all-longest ( seqs -- seqs' ) dup longest length filter-length ;
 509
 510 : remove-first ( obj seq -- seq' )
 511     [ index ] keep over [ remove-nth ] [ nip ] if ;
 512
 513 : remove-first! ( obj seq -- seq )
 514     [ index ] keep over [ remove-nth! ] [ nip ] if ;
 515
 516 : remove-last ( obj seq -- seq' )
 517     [ last-index ] keep over [ remove-nth ] [ nip ] if ;
 518
 519 : remove-last! ( obj seq -- seq )
 520     [ last-index ] keep over [ remove-nth! ] [ nip ] if ;
 521
 522 : ?first2 ( seq -- first/f second/f )
 523     dup length {
 524         { 0 [ drop f f ] }
 525         { 1 [ first-unsafe f ] }
 526         [ drop first2-unsafe ]
 527     } case ;
 528
 529 : ?first3 ( seq -- first/f second/f third/f )
 530     dup length {
 531         { 0 [ drop f f f ] }
 532         { 1 [ first-unsafe f f ] }
 533         { 2 [ first2-unsafe f ] }
 534         [ drop first3-unsafe ]
 535     } case ;
 536
 537 : ?first4 ( seq -- first/f second/f third/f fourth/f )
 538     dup length {
 539         { 0 [ drop f f f f ] }
 540         { 1 [ first-unsafe f f f ] }
 541         { 2 [ first2-unsafe f f ] }
 542         { 3 [ first3-unsafe f ] }
 543         [ drop first4-unsafe ]
 544     } case ;
 545
 546 : cut-when ( ... seq quot: ( ... elt -- ... ? ) -- ... before after )
 547     [ find drop ] keepd swap
 548     [ cut ] [ f over like ] if* ; inline
 549
 550 : nth* ( n seq -- elt )
 551     [ length 1 - swap - ] [ nth ] bi ; inline
 552
 553 : each-index-from ( ... seq quot: ( ... elt index -- ... ) i -- ... )
 554     -rot (each-index) (each-integer) ; inline
 555
 556 <PRIVATE
 557
 558 : select-by* ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... i elt )
 559     [
 560         [ keep swap ] curry [ dip ] curry
 561         [ [ first 0 ] dip call ] 2keep
 562         [ 2curry 3dip 5 npick pick ] curry
 563     ] [
 564         [ [ 3drop ] [ [ 3drop ] 3dip ] if ] compose
 565     ] bi* compose 1 each-index-from nip swap ; inline
 566
 567 PRIVATE>
 568
 569 : supremum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 570     [ after? ] select-by* ; inline
 571
 572 : infimum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 573     [ before? ] select-by* ; inline
 574
 575 : ?supremum ( seq/f -- elt/f )
 576     [ f ] [
 577         [ ] [ 2dup and [ max ] [ dupd ? ] if ] map-reduce
 578     ] if-empty ;
 579
 580 : ?infimum ( seq/f -- elt/f )
 581     [ f ] [
 582         [ ] [ 2dup and [ min ] [ dupd ? ] if ] map-reduce
 583     ] if-empty ;
 584
 585 : change-last ( seq quot -- )
 586     [ drop length 1 - ] [ change-nth ] 2bi ; inline
 587
 588 : change-last-unsafe ( seq quot -- )
 589     [ drop length 1 - ] [ change-nth-unsafe ] 2bi ; inline
 590
 591 : replicate-into ( ... seq quot: ( ... -- ... newelt ) -- ... )
 592     over [ length ] 2dip '[ _ dip _ set-nth-unsafe ] each-integer ; inline
 593
 594 : count* ( ... seq quot: ( ... elt -- ... ? ) -- ... % )
 595     over [ count ] [ length ] bi* / ; inline
 596
 597 : find-last-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 598     [ [ 1 - ] dip find-last-integer ] (find-index) ; inline
 599
 600 : map-find-last-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 601     [ find-last-index ] (map-find-index) ; inline
 602
 603 :: (start-all) ( seq subseq increment -- indices )
 604     0
 605     [ [ subseq seq ] dip subseq-start-from dup ]
 606     [ [ increment + ] keep ] produce nip ;
 607
 608 : start-all ( seq subseq -- indices )
 609     dup length (start-all) ; inline
 610
 611 : start-all* ( seq subseq -- indices )
 612     1 (start-all) ; inline
 613
 614 : count-subseq ( seq subseq -- n )
 615     start-all length ; inline
 616
 617 : count-subseq* ( seq subseq -- n )
 618     start-all* length ; inline
 619
 620 : assoc-zip-with ( quot: ( key value -- calc ) -- alist )
 621     '[ _ 2keep 2array swap ] assoc-map ; inline
 622
 623 : take-while ( ... seq quot: ( ... elt -- ... ? ) -- head-slice )
 624     [ '[ @ not ] find drop ] keepd swap
 625     [ dup length ] unless* head-slice ; inline
 626
 627 : drop-while ( ... seq quot: ( ... elt -- ... ? ) -- tail-slice )
 628     [ '[ @ not ] find drop ] keepd swap
 629     [ dup length ] unless* tail-slice ; inline
 630
 631 : count-head ( seq quot -- n )
 632     [ not ] compose [ find drop ] keepd length or ; inline
 633
 634 : count-tail ( seq quot -- n )
 635     [ not ] compose [ find-last drop ] keepd
 636     length swap [ - 1 - ] when* ; inline
 637
 638 :: interleaved-as ( seq glue exemplar -- newseq )
 639     seq length dup 1 - + 0 max exemplar new-sequence :> newseq
 640     seq [ 2 * newseq set-nth-unsafe ] each-index
 641     seq length 1 - [ 2 * 1 + glue swap newseq set-nth-unsafe ] each-integer
 642     newseq ;
 643
 644 : interleaved ( seq glue -- newseq )
 645     over interleaved-as ;
 646
 647 : extract! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 648     [ dup ] compose over [ length ] keep new-resizable
 649     [ [ push-if ] 2curry reject! ] keep swap like ; inline
 650
 651 : find-pred-loop ( ... i n seq quot: ( ... elt -- ... calc ? ) -- ... calc/f i/f elt/f )
 652     2pick < [
 653         [ nipd call ] 4keep
 654         7 nrot 7 nrot 7 nrot
 655         [ [ 3drop ] 2dip rot ]
 656         [ 2drop [ 1 + ] 3dip find-pred-loop ] if
 657     ] [
 658         4drop f f f
 659     ] if ; inline recursive
 660
 661 : find-pred ( ... seq quot: ( ... elt -- ... calc ) pred: ( ... calc -- ... ? ) -- ... calc/f i/f elt/f )
 662     [ 0 ] 3dip
 663     [ [ length check-length ] keep ] 2dip
 664     '[ nth-unsafe _ keep swap _ keep swap ] find-pred-loop swapd ; inline
 665
 666 ! https://en.wikipedia.org/wiki/Maximum_subarray_problem
 667 ! Kadane's algorithm O(n) largest sum in subarray
 668 : max-subarray-sum ( seq -- sum )
 669     [ -1/0. 0 ] dip
 670     [ [ + ] keep max [ max ] keep ] each drop ;
 671
 672 TUPLE: step-slice
 673     { from integer read-only initial: 0 }
 674     { to integer read-only initial: 0 }
 675     { seq read-only }
 676     { step integer read-only } ;
 677
 678 :: <step-slice> ( from to step seq -- step-slice )
 679     step zero? [ "can't be zero" throw ] when
 680     seq length :> len
 681     step 0 > [
 682         from [ 0 ] unless*
 683         to [ len ] unless*
 684     ] [
 685         from [ len ] unless*
 686         to [ 0 ] unless*
 687     ] if
 688     [ dup 0 < [ len + ] when 0 len clamp ] bi@
 689     ! FIXME: make this work with steps
 690     seq dup slice? [ collapse-slice ] when
 691     step step-slice boa ;
 692
 693 M: step-slice virtual-exemplar seq>> ; inline
 694
 695 M: step-slice virtual@
 696     [ step>> * ] [ from>> + ] [ seq>> ] tri ; inline
 697
 698 M: step-slice length
 699     [ to>> ] [ from>> - ] [ step>> ] tri
 700     dup 0 < [ [ neg 0 max ] dip neg ] when /mod
 701     zero? [ 1 + ] unless ; inline
 702
 703 INSTANCE: step-slice virtual-sequence