extra/sequences/extras/extras.factor

   1 USING: accessors arrays assocs fry grouping kernel locals make
   2 math math.order math.ranges sequences sequences.private
   3 splitting ;
   4 FROM: sequences => change-nth ;
   5 IN: sequences.extras
   6
   7 : reduce1 ( seq quot -- result ) [ unclip ] dip reduce ; inline
   8
   9 :: reduce-r ( list identity quot: ( obj1 obj2 -- obj ) -- result )
  10     list empty?
  11     [ identity ]
  12     [ list rest identity quot reduce-r list first quot call ] if ;
  13     inline recursive
  14
  15 ! Quot must have static stack effect, unlike "reduce"
  16 :: reduce* ( seq id quot -- result ) seq
  17     [ id ]
  18     [ unclip id swap quot call( prev elt -- next ) quot reduce* ] if-empty ; inline recursive
  19
  20 :: combos ( list1 list2 -- result )
  21     list2 [ [ 2array ] curry list1 swap map ] map concat ;
  22
  23 : find-all ( seq quot -- elts )
  24     [ [ length iota ] keep ] dip
  25     [ dupd call( a -- ? ) [ 2array ] [ 2drop f ] if ] curry
  26     2map [ ] filter ; inline
  27
  28 : insert-sorted ( elt seq -- seq )
  29     2dup [ < ] with find drop over length or swap insert-nth ;
  30
  31 : each-from ( ... seq quot: ( ... x -- ... ) i -- ... )
  32     -rot (each) (each-integer) ; inline
  33
  34 : reduce-from ( ... seq identity quot: ( ... prev elt -- ... next ) i -- ... result )
  35     [ swap ] 2dip each-from ; inline
  36
  37 : supremum-by ( seq quot: ( ... elt -- ... x ) -- elt )
  38     [ [ first dup ] dip call ] 2keep [
  39         dupd call pick dupd after?
  40         [ [ 2drop ] 2dip ] [ 2drop ] if
  41     ] curry 1 each-from drop ; inline
  42
  43 : infimum-by ( seq quot: ( ... elt -- ... x ) -- elt )
  44     [ [ first dup ] dip call ] 2keep [
  45         dupd call pick dupd before?
  46         [ [ 2drop ] 2dip ] [ 2drop ] if
  47     ] curry 1 each-from drop ; inline
  48
  49 : all-subseqs ( seq -- seqs )
  50     dup length [1,b] [ <clumps> ] with map concat ;
  51
  52 :: each-subseq ( ... seq quot: ( ... x -- ... ) -- ... )
  53     seq length :> len
  54     len [0,b] [
  55         :> from
  56         from len (a,b] [
  57             :> to
  58             from to seq subseq quot call( x -- )
  59         ] each
  60     ] each ;
  61
  62 :: longest-subseq ( seq1 seq2 -- subseq )
  63     seq1 length :> len1
  64     seq2 length :> len2
  65     0 :> n!
  66     0 :> end!
  67     len1 1 + [ len2 1 + 0 <array> ] replicate :> table
  68     len1 [1,b] [| x |
  69         len2 [1,b] [| y |
  70             x 1 - seq1 nth-unsafe
  71             y 1 - seq2 nth-unsafe = [
  72                 y 1 - x 1 - table nth-unsafe nth-unsafe 1 + :> len
  73                 len y x table nth-unsafe set-nth-unsafe
  74                 len n > [ len n! x end! ] when
  75             ] [ 0 y x table nth-unsafe set-nth-unsafe ] if
  76         ] each
  77     ] each end n - end seq1 subseq ;
  78
  79 : pad-longest ( seq1 seq2 elt -- seq1 seq2 )
  80     [ 2dup max-length ] dip [ pad-tail ] 2curry bi@ ;
  81
  82 : change-nths ( ... indices seq quot: ( ... elt -- ... elt' ) -- ... )
  83     [ change-nth ] 2curry each ; inline
  84
  85 : push-if-index ( ..a elt i quot: ( ..a elt i -- ..b ? ) accum -- ..b )
  86     [ 2keep drop ] dip rot [ push ] [ 2drop ] if ; inline
  87
  88 : index-selector-for ( quot exemplar -- selector accum )
  89     [ length ] keep new-resizable [ [ push-if-index ] 2curry ] keep ; inline
  90
  91 : filter-index-as ( ... seq quot: ( ... elt i -- ... ? ) exemplar -- ... seq' )
  92     dup [ index-selector-for [ each-index ] dip ] curry dip like ; inline
  93
  94 : filter-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... seq' )
  95     over filter-index-as ; inline
  96
  97 : even-indices ( seq -- seq' ) [ nip even? ] filter-index ;
  98
  99 : odd-indices ( seq -- seq' ) [ nip odd? ] filter-index ;
 100
 101 : compact ( seq quot elt -- seq' )
 102     [ split-when harvest ] dip join ; inline
 103
 104 : collapse ( seq quot elt -- seq' )
 105     [ split-when ] dip
 106     [ [ harvest ] dip join ]
 107     [ [ first empty? ] dip [ prepend ] curry when ]
 108     [ [ last empty? ] dip [ append ] curry when ]
 109     2tri ; inline
 110
 111 :: slice-when ( seq quot: ( elt -- ? ) -- seq' )
 112     seq length :> len
 113     0 [ len dupd < ] [
 114         dup seq quot find-from drop
 115         [ 2dup = [ 1 + ] when ] [ len ] if*
 116         [ seq <slice> ] keep len or swap
 117     ] produce nip ; inline
 118
 119 : rotate ( seq n -- seq' )
 120     cut prepend ;
 121
 122 :: rotate! ( seq n -- )
 123     n seq bounds-check length :> end
 124     0 n [ 2dup = ] [
 125         [ seq exchange-unsafe ] [ [ 1 + ] bi@ ] 2bi
 126         dup end = [ drop over ] when
 127         2over = [ -rot nip over ] when
 128     ] until 3drop ;
 129
 130 : all-rotations ( seq -- seq' )
 131     dup length iota [ rotate ] with map ;
 132
 133 : appender-for ( quot exemplar -- quot' vec )
 134     [ length ] keep new-resizable
 135     [ [ push-all ] curry compose ] keep ; inline
 136
 137 : appender ( quot -- quot' vec )
 138     V{ } appender-for ; inline
 139
 140 : map-concat-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 141     dup [ appender-for [ each ] dip ] curry dip like ; inline
 142
 143 : >resizable ( seq -- vec ) ! fixes map-concat "cannot apply call to run-time..."
 144     [ length ] keep [ new-resizable ] [ over push-all ] bi ;
 145
 146 : map-concat ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 147     over [ 2drop { } ] [
 148         first over call dup [
 149             >resizable [ [ push-all ] curry compose ] keep
 150             [ 1 ] 3dip [ (each) (each-integer) ] dip
 151         ] curry dip like
 152     ] if-empty ; inline
 153
 154 : map-filter-as ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) exemplar -- ... subseq )
 155     dup [ selector-for [ compose each ] dip ] curry dip like ; inline
 156
 157 : map-filter ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) -- ... subseq )
 158     pick map-filter-as ; inline
 159
 160 : map-sift ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 161     [ ] map-filter ; inline
 162
 163 : map-harvest ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 164     [ empty? not ] map-filter ; inline
 165
 166 <PRIVATE
 167
 168 : ((each-from)) ( i seq -- n quot )
 169     [ length over - 0 max swap ] keep '[ _ + _ nth-unsafe ] ; inline
 170
 171 : (each-from) ( i seq quot -- n quot' ) [ ((each-from)) ] dip compose ;
 172     inline
 173
 174 PRIVATE>
 175
 176 : map-from-as ( ... seq quot: ( ... elt -- ... newelt ) i exemplar -- ... newseq )
 177     [ -rot (each-from) ] dip map-integers ; inline
 178
 179 : map-from ( ... seq quot: ( ... elt -- ... newelt ) i -- ... newseq )
 180     pick map-from-as ; inline
 181
 182 <PRIVATE
 183
 184 : push-map-if ( ..a elt filter-quot: ( ..a elt -- ..b ? ) map-quot: ( ..a elt -- ..b newelt ) accum -- ..b )
 185     [ keep over ] 2dip [ when ] dip rot [ push ] [ 2drop ] if ; inline
 186
 187 : filter-mapper-for ( filter-quot map-quot exemplar -- quot' vec )
 188     [ length ] keep new-resizable [ [ push-map-if ] 3curry ] keep ; inline
 189
 190 : filter-mapper ( filter-quot map-quot -- quot' vec )
 191     V{ } filter-mapper-for ; inline
 192
 193 PRIVATE>
 194
 195 : filter-map-as ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 196     dup [ filter-mapper-for [ each ] dip ] curry dip like ; inline
 197
 198 : filter-map ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) -- ... newseq )
 199     pick filter-map-as ; inline
 200
 201 : 2map-sum ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... n ) -- ... n )
 202     [ 0 ] 3dip [ dip + ] curry [ rot ] prepose 2each ; inline
 203
 204 : 2count ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... n )
 205     [ 1 0 ? ] compose 2map-sum ; inline
 206
 207 : round-robin ( seq -- newseq )
 208     [ { } ] [
 209         [ [ length ] [ max ] map-reduce iota ] keep
 210         [ [ ?nth ] with map ] curry map concat sift
 211     ] if-empty ;
 212
 213 : sift-as ( seq exemplar -- newseq )
 214     [ ] swap filter-as ;
 215
 216 : harvest-as ( seq exemplar -- newseq )
 217     [ empty? not ] swap filter-as ;
 218
 219 : contains? ( seq elts -- ? )
 220     [ member? ] curry any? ; inline
 221
 222 : trim-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... newseq )
 223     [ trim-slice ] [ like ] bi* ; inline
 224
 225 : ?trim ( ... seq quot: ( ... elt -- ... ? ) -- ... seq/newseq )
 226     over empty? [ drop ] [
 227         over [ first-unsafe ] [ last-unsafe ] bi pick bi@ or
 228         [ trim ] [ drop ] if
 229     ] if ; inline
 230
 231 : unsurround ( newseq seq2 seq3 -- seq1 )
 232    [ ?head drop ] [ ?tail drop ] bi* ;
 233
 234 : none? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 235     any? not ; inline
 236
 237 : one? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 238     [ find ] 2keep rot [
 239         [ 1 + ] 2dip find-from drop not
 240     ] [ 3drop f ] if ; inline
 241
 242 : map-index! ( ... seq quot: ( ... elt index -- ... newelt ) -- ... seq )
 243     over [ [ (each-index) ] dip collect ] keep ; inline
 244
 245 <PRIVATE
 246
 247 : (2each-index) ( seq1 seq2 quot -- n quot' )
 248     [ ((2each)) [ keep ] curry ] dip compose ; inline
 249
 250 PRIVATE>
 251
 252 : 2each-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... ) -- ... )
 253     (2each-index) each-integer ; inline
 254
 255 : 2map-into ( seq1 seq2 quot into -- )
 256     [ (2each) ] dip collect ; inline
 257
 258 : 2map! ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... seq1 )
 259     pick [ 2map-into ] keep ; inline
 260
 261 : 2map-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... newelt ) -- ... newseq )
 262     pick [ (2each-index) ] dip map-integers ; inline
 263
 264 TUPLE: evens seq length ;
 265
 266 : <evens> ( seq -- evens )
 267     dup length 1 + 2/ evens boa ; inline
 268
 269 M: evens length length>> ; inline
 270
 271 M: evens nth-unsafe [ 2 * ] [ seq>> nth-unsafe ] bi* ; inline
 272
 273 INSTANCE: evens immutable-sequence
 274
 275 TUPLE: odds seq length ;
 276
 277 : <odds> ( seq -- odds )
 278     dup length 2/ odds boa ; inline
 279
 280 M: odds length length>> ; inline
 281
 282 M: odds nth-unsafe [ 2 * 1 + ] [ seq>> nth-unsafe ] bi* ; inline
 283
 284 INSTANCE: odds immutable-sequence
 285
 286 : until-empty ( seq quot -- )
 287     [ dup empty? ] swap until drop ; inline
 288
 289 : arg-max ( seq -- n )
 290     dup length iota zip [ first-unsafe ] supremum-by second ;
 291
 292 : arg-min ( seq -- n )
 293     dup length iota zip [ first-unsafe ] infimum-by second ;
 294
 295 : arg-where ( ... seq quot: ( ... elt -- ... ? ) -- ... indices )
 296     [ dup length iota zip ] dip
 297     [ first-unsafe ] prepose filter values ; inline
 298
 299 : first= ( seq elt -- ? ) [ first ] dip = ; inline
 300 : second= ( seq elt -- ? ) [ second ] dip = ; inline
 301 : third= ( seq elt -- ? ) [ third ] dip = ; inline
 302 : fourth= ( seq elt -- ? ) [ fourth ] dip = ; inline
 303 : last= ( seq elt -- ? ) [ last ] dip = ; inline
 304 : nth= ( n seq elt -- ? ) [ nth ] dip = ; inline
 305
 306 : first? ( seq quot -- ? ) [ first ] dip call ; inline
 307 : second? ( seq quot -- ? ) [ second ] dip call ; inline
 308 : third? ( seq quot -- ? ) [ third ] dip call ; inline
 309 : fourth? ( seq quot -- ? ) [ fourth ] dip call ; inline
 310 : last? ( seq quot -- ? ) [ last ] dip call ; inline
 311 : nth? ( n seq quot -- ? ) [ nth ] dip call ; inline
 312
 313 : loop>sequence ( quot exemplar -- seq )
 314    [ '[ [ @ [ [ , ] when* ] keep ] loop ] ] dip make ; inline
 315
 316 : loop>array ( quot -- seq )
 317    { } loop>sequence ; inline