extra/sequences/extras/extras.factor

   1 USING: accessors arrays assocs combinators fry generalizations
   2 grouping growable kernel locals make math math.order math.ranges
   3 sequences sequences.deep sequences.private sorting splitting
   4 vectors ;
   5 IN: sequences.extras
   6
   7 : reduce1 ( seq quot -- result ) [ unclip ] dip reduce ; inline
   8
   9 :: reduce-r ( seq identity quot: ( obj1 obj2 -- obj ) -- result )
  10     seq [ identity ] [
  11         unclip [ identity quot reduce-r ] [ quot call ] bi*
  12     ] if-empty ; inline recursive
  13
  14 ! Quot must have static stack effect, unlike "reduce"
  15 :: reduce* ( seq identity quot: ( prev elt -- next ) -- result )
  16     seq [ identity ] [
  17         unclip identity swap quot call( prev elt -- next )
  18         quot reduce*
  19     ] if-empty ; inline recursive
  20
  21 :: combos ( list1 list2 -- result )
  22     list2 [ [ 2array ] curry list1 swap map ] map concat ;
  23
  24 : find-all ( seq quot: ( elt -- ? ) -- elts )
  25     [ [ length iota ] keep ] dip
  26     [ dupd call( a -- ? ) [ 2array ] [ 2drop f ] if ] curry
  27     2map sift ; inline
  28
  29 : reduce-from ( ... seq identity quot: ( ... prev elt -- ... next ) i -- ... result )
  30     [ swap ] 2dip each-from ; inline
  31
  32 :: subseq* ( from to seq -- subseq )
  33     seq length :> len
  34     from [ dup 0 < [ len + ] when ] [ 0 ] if*
  35     to [ dup 0 < [ len + ] when ] [ len ] if*
  36     [ 0 len clamp ] bi@ dupd max seq subseq ;
  37
  38 : safe-subseq ( from to seq -- subseq )
  39     [ length '[ 0 _ clamp ] bi@ ] keep subseq ;
  40
  41 : all-subseqs ( seq -- seqs )
  42     dup length [1,b] [ clump ] with map concat ;
  43
  44 :: each-subseq ( ... seq quot: ( ... x -- ... ) -- ... )
  45     seq length :> len
  46     len [0,b] [
  47         :> from
  48         from len (a,b] [
  49             :> to
  50             from to seq subseq quot call
  51         ] each
  52     ] each ; inline
  53
  54 : map-like ( seq exemplar -- seq' )
  55     '[ _ like ] map ; inline
  56
  57 : filter-all-subseqs-range ( ... seq range quot: ( ... x -- ... ) -- seq )
  58     [
  59         '[ <clumps> _ filter ] with map concat
  60     ] 3keep 2drop map-like ; inline
  61
  62 : filter-all-subseqs ( ... seq quot: ( ... x -- ... ) -- seq )
  63     [ dup length [1,b] ] dip filter-all-subseqs-range ; inline
  64
  65 :: longest-subseq ( seq1 seq2 -- subseq )
  66     seq1 length :> len1
  67     seq2 length :> len2
  68     0 :> n!
  69     0 :> end!
  70     len1 1 + [ len2 1 + 0 <array> ] replicate :> table
  71     len1 [1,b] [| x |
  72         len2 [1,b] [| y |
  73             x 1 - seq1 nth-unsafe
  74             y 1 - seq2 nth-unsafe = [
  75                 y 1 - x 1 - table nth-unsafe nth-unsafe 1 + :> len
  76                 len y x table nth-unsafe set-nth-unsafe
  77                 len n > [ len n! x end! ] when
  78             ] [ 0 y x table nth-unsafe set-nth-unsafe ] if
  79         ] each
  80     ] each end n - end seq1 subseq ;
  81
  82 : pad-longest ( seq1 seq2 elt -- seq1 seq2 )
  83     [ 2dup max-length ] dip [ pad-tail ] 2curry bi@ ;
  84
  85 :: pad-center ( seq n elt -- padded )
  86     n seq length [-] :> extra
  87     extra 2/ :> left
  88     extra left - :> right
  89     left elt <repetition> seq right elt <repetition>
  90     seq 3append-as ;
  91
  92 : change-nths ( ... indices seq quot: ( ... elt -- ... elt' ) -- ... )
  93     [ change-nth ] 2curry each ; inline
  94
  95 : push-if-index ( ..a elt i quot: ( ..a elt i -- ..b ? ) accum -- ..b )
  96     [ 2keep drop ] dip rot [ push ] [ 2drop ] if ; inline
  97
  98 : push-if* ( ..a elt quot: ( ..a elt -- ..b obj/f ) accum -- ..b )
  99     [ call ] dip [ push ] [ drop ] if* ; inline
 100
 101 <PRIVATE
 102
 103 : (index-selector-as) ( quot length exampler -- selector accum )
 104     new-resizable [ [ push-if-index ] 2curry ] keep ; inline
 105
 106 : (selector-as*) ( quot length exemplar -- selector accum )
 107     new-resizable [ [ push-if* ] 2curry ] keep ; inline
 108
 109 PRIVATE>
 110
 111 : index-selector-as ( quot exemplar -- selector accum )
 112     [ length ] keep (index-selector-as) ; inline
 113
 114 : index-selector ( quot -- selector accum )
 115     V{ } index-selector-as ; inline
 116
 117 : selector-as* ( quot exemplar -- selector accum )
 118     [ length ] keep (selector-as*) ; inline
 119
 120 : selector* ( quot -- selector accum ) V{ } selector-as* ; inline
 121
 122 : filter-index-as ( ... seq quot: ( ... elt i -- ... ? ) exemplar -- ... seq' )
 123     pick length over [ (index-selector-as) [ each-index ] dip ] 2curry dip like ; inline
 124
 125 : filter-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... seq' )
 126     over filter-index-as ; inline
 127
 128 : even-indices ( seq -- seq' )
 129     [ length 1 + 2/ ] keep [
 130         [ [ 2 * ] dip nth-unsafe ] curry
 131     ] keep map-integers ;
 132
 133 : odd-indices ( seq -- seq' )
 134     [ length 2/ ] keep [
 135         [ [ 2 * 1 + ] dip nth-unsafe ] curry
 136     ] keep map-integers ;
 137
 138 : compact ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 139     [ split-when harvest ] dip join ; inline
 140
 141 : collapse ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 142     [ split-when ] dip
 143     [ [ harvest ] dip join ]
 144     [ [ first empty? ] dip [ prepend ] curry when ]
 145     [ [ last empty? ] dip [ append ] curry when ]
 146     2tri ; inline
 147
 148 :: slice-when ( seq quot: ( elt -- ? ) -- seq' )
 149     seq length :> len
 150     0 [ len dupd < ] [
 151         dup seq quot find-from drop
 152         [ 2dup = [ 1 + ] when ] [ len ] if*
 153         [ seq <slice> ] keep len or swap
 154     ] produce nip ; inline
 155
 156 : cut-slice* ( seq n -- before after )
 157     [ head-slice* ] [ tail-slice* ] 2bi ;
 158
 159 : ?<slice> ( from/f to/f sequence -- slice )
 160     [ [ 0 ] unless* ] 2dip
 161     over [ nip [ length ] [ ] bi ] unless
 162     <slice> ; inline
 163
 164 : sequence>slice ( sequence -- slice )
 165     [ drop 0 ] [ length ] [ ] tri <slice> ; inline
 166
 167 : slice-order-by-from ( slice1 slice2 -- slice-lt slice-gt )
 168     2dup [ from>> ] bi@ > [ swap ] when ; inline
 169
 170 : ordered-slices-range ( slice-lt slice-gt -- to from )
 171     [ to>> ] [ from>> ] bi* ;
 172
 173 : unordered-slices-range ( slice1 slice2 -- to from )
 174     slice-order-by-from ordered-slices-range ;
 175
 176 : ordered-slices-overlap? ( slice-lt slice-gt -- ? )
 177     ordered-slices-range > ; inline
 178
 179 : unordered-slices-overlap? ( slice1 slice2 -- ? )
 180     unordered-slices-range > ; inline
 181
 182 : slices-overlap? ( slice1 slice2 -- ? )
 183     unordered-slices-overlap? ;
 184
 185 : ordered-slices-touch? ( slice-lt slice-gt -- ? )
 186     ordered-slices-range >= ; inline
 187
 188 : unordered-slices-touch? ( slice1 slice2 -- ? )
 189     unordered-slices-range >= ; inline
 190
 191 : slices-touch? ( slice1 slice2 -- ? )
 192     unordered-slices-touch? ;
 193
 194 ERROR: slices-don't-touch slice1 slice2 ;
 195
 196 : merge-slices ( slice1 slice2 -- slice/* )
 197     slice-order-by-from
 198     2dup ordered-slices-touch? [
 199         [ from>> ] [ [ to>> ] [ seq>> ] bi ] bi* <slice>
 200     ] [
 201         slices-don't-touch
 202     ] if ;
 203
 204 : rotate ( seq n -- seq' )
 205     over length mod dup 0 >= [ cut ] [ abs cut* ] if prepend ;
 206
 207 ERROR: underlying-mismatch slice1 slice2 ;
 208 : ensure-same-underlying ( slice1 slice2 -- slice1 slice2 )
 209     2dup [ seq>> ] bi@ eq? [ underlying-mismatch ] unless ;
 210
 211 : span-slices ( slice1 slice2 -- slice )
 212     ensure-same-underlying
 213     [ [ from>> ] bi@ min ]
 214     [ [ to>> ] bi@ max ]
 215     [ drop seq>> ] 2tri <slice> ;
 216
 217 : ?span-slices ( slice1/f slice2/f -- slice )
 218     2dup and [ span-slices ] [ or ] if ;
 219
 220 :: rotate! ( seq n -- )
 221     seq length :> len
 222     n len mod dup 0 < [ len + ] when seq bounds-check drop 0 over
 223     [ 2dup = ] [
 224         [ seq exchange-unsafe ] [ [ 1 + ] bi@ ] 2bi
 225         dup len = [ drop over ] when
 226         2over = [ -rot nip over ] when
 227     ] until 3drop ;
 228
 229 : all-rotations ( seq -- seq' )
 230     dup length iota [ rotate ] with map ;
 231
 232 <PRIVATE
 233
 234 : (appender-for) ( quot length exemplar -- appender accum )
 235     new-resizable [ [ push-all ] curry compose ] keep ; inline
 236
 237 PRIVATE>
 238
 239 : appender-for ( quot exemplar -- appender accum )
 240     [ length ] keep (appender-for) ; inline
 241
 242 : appender ( quot -- appender accum )
 243     V{ } appender-for ; inline
 244
 245 : map-concat-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 246     [ appender-for [ each ] dip ] keep like ; inline
 247
 248 : >resizable ( seq -- accum ) ! fixes map-concat "cannot apply call to run-time..."
 249     [ length ] keep [ new-resizable ] [ append! ] bi ;
 250
 251 : map-concat ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 252     over empty? [ 2drop { } ] [
 253         [ [ first ] dip call ] 2keep rot dup [
 254             >resizable [ [ push-all ] curry compose ] keep
 255             [ 1 ] 3dip [ setup-each (each-integer) ] dip
 256         ] curry dip like
 257     ] if ; inline
 258
 259 : map-filter-as ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) exemplar -- ... subseq )
 260     [ pick ] dip swap length over
 261     [ (selector-as) [ compose each ] dip ] 2curry dip like ; inline
 262
 263 : map-filter ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) -- ... subseq )
 264     pick map-filter-as ; inline
 265
 266 : map-sift ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 267     [ ] map-filter ; inline
 268
 269 : map-harvest ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 270     [ empty? not ] map-filter ; inline
 271
 272 <PRIVATE
 273
 274 : (setup-each-from) ( i seq -- n quot )
 275     [ length over [-] swap ] keep '[ _ + _ nth-unsafe ] ; inline
 276
 277 : setup-each-from ( i seq quot -- n quot' )
 278     [ (setup-each-from) ] dip compose ; inline
 279
 280 PRIVATE>
 281
 282 : map-from-as ( ... seq quot: ( ... elt -- ... newelt ) i exemplar -- ... newseq )
 283     [ -rot setup-each-from ] dip map-integers ; inline
 284
 285 : map-from ( ... seq quot: ( ... elt -- ... newelt ) i -- ... newseq )
 286     pick map-from-as ; inline
 287
 288 <PRIVATE
 289
 290 : push-map-if ( ..a elt filter-quot: ( ..a elt -- ..b ? ) map-quot: ( ..a elt -- ..b newelt ) accum -- ..b )
 291     [ keep over ] 2dip [ when ] dip rot [ push ] [ 2drop ] if ; inline
 292
 293 : (filter-mapper-for) ( filter-quot map-quot length exempler -- filter-mapper accum )
 294     new-resizable [ [ push-map-if ] 3curry ] keep ; inline
 295
 296 : filter-mapper-for ( filter-quot map-quot exemplar -- filter-mapper accum )
 297     [ length ] keep (filter-mapper-for) ; inline
 298
 299 : filter-mapper ( filter-quot map-quot -- filter-mapper accum )
 300     V{ } filter-mapper-for ; inline
 301
 302 PRIVATE>
 303
 304 : filter-map-as ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 305     [ pick ] dip swap length over
 306     [ (filter-mapper-for) [ each ] dip ] 2curry dip like ; inline
 307
 308 : filter-map ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) -- ... newseq )
 309     pick filter-map-as ; inline
 310
 311 : 2map-sum ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... n ) -- ... n )
 312     [ 0 ] 3dip [ dip + ] curry [ rot ] prepose 2each ; inline
 313
 314 : 2count ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... n )
 315     [ 1 0 ? ] compose 2map-sum ; inline
 316
 317 : round-robin ( seq -- newseq )
 318     [ { } ] [
 319         [ longest length iota ] keep
 320         [ [ ?nth ] with map ] curry map concat sift
 321     ] if-empty ;
 322
 323 : sift-as ( seq exemplar -- newseq )
 324     [ ] swap filter-as ;
 325
 326 : sift! ( seq -- newseq )
 327     [ ] filter! ;
 328
 329 : harvest-as ( seq exemplar -- newseq )
 330     [ empty? not ] swap filter-as ;
 331
 332 : harvest! ( seq -- newseq )
 333     [ empty? ] reject! ;
 334
 335 : head-as ( seq n exemplar -- seq' )
 336     [ head-slice ] [ like ] bi* ; inline
 337
 338 : head*-as ( seq n exemplar -- seq' )
 339     [ head-slice* ] [ like ] bi* ; inline
 340
 341 : tail-as ( seq n exemplar -- seq' )
 342     [ tail-slice ] [ like ] bi* ; inline
 343
 344 : tail*-as ( seq n exemplar -- seq' )
 345     [ tail-slice* ] [ like ] bi* ; inline
 346
 347 : trim-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... newseq )
 348     [ trim-slice ] [ like ] bi* ; inline
 349
 350 : ?trim ( seq quot: ( elt -- ? ) -- seq/newseq )
 351     over empty? [ drop ] [
 352         over [ first-unsafe ] [ last-unsafe ] bi pick either?
 353         [ trim ] [ drop ] if
 354     ] if ; inline
 355
 356 : ?trim-head ( seq quot: ( elt -- ? ) -- seq/newseq )
 357     over empty? [ drop ] [
 358         over first-unsafe over call
 359         [ trim-head ] [ drop ] if
 360     ] if ; inline
 361
 362 : ?trim-tail ( seq quot: ( elt -- ? ) -- seq/newseq )
 363     over empty? [ drop ] [
 364         over last-unsafe over call
 365         [ trim-tail ] [ drop ] if
 366     ] if ; inline
 367
 368 : unsurround ( newseq seq2 seq3 -- seq1 )
 369    [ ?head drop ] [ ?tail drop ] bi* ;
 370
 371 : none? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 372     any? not ; inline
 373
 374 : one? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 375     [ find ] 2keep rot [
 376         [ 1 + ] 2dip find-from drop not
 377     ] [ 3drop f ] if ; inline
 378
 379 : map-index! ( ... seq quot: ( ... elt index -- ... newelt ) -- ... seq )
 380     over [ [ (each-index) ] dip collect ] keep ; inline
 381
 382 <PRIVATE
 383
 384 : (2each-index) ( seq1 seq2 quot -- n quot' )
 385     [ setup-2each [ keep ] curry ] dip compose ; inline
 386
 387 PRIVATE>
 388
 389 : 2each-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... ) -- ... )
 390     (2each-index) each-integer ; inline
 391
 392 : 2map-into ( seq1 seq2 quot into -- )
 393     [ (2each) ] dip collect ; inline
 394
 395 : 2map! ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... seq1 )
 396     pick [ 2map-into ] keep ; inline
 397
 398 : 2map-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... newelt ) -- ... newseq )
 399     pick [ (2each-index) ] dip map-integers ; inline
 400
 401 TUPLE: evens seq length ;
 402
 403 : <evens> ( seq -- evens )
 404     dup length 1 + 2/ evens boa ; inline
 405
 406 M: evens length length>> ; inline
 407
 408 M: evens nth-unsafe [ 2 * ] [ seq>> nth-unsafe ] bi* ; inline
 409
 410 INSTANCE: evens immutable-sequence
 411
 412 TUPLE: odds seq length ;
 413
 414 : <odds> ( seq -- odds )
 415     dup length 2/ odds boa ; inline
 416
 417 M: odds length length>> ; inline
 418
 419 M: odds nth-unsafe [ 2 * 1 + ] [ seq>> nth-unsafe ] bi* ; inline
 420
 421 INSTANCE: odds immutable-sequence
 422
 423 : until-empty ( seq quot -- )
 424     [ dup empty? ] swap until drop ; inline
 425
 426 : arg-max ( seq -- n )
 427     <enum> [ second-unsafe ] supremum-by first ;
 428
 429 : arg-min ( seq -- n )
 430     <enum> [ second-unsafe ] infimum-by first ;
 431
 432 <PRIVATE
 433
 434 : push-index-if ( ..a elt i quot: ( ..a elt -- ..b ? ) accum -- ..b )
 435     [ dip ] dip rot [ push ] [ 2drop ] if ; inline
 436
 437 PRIVATE>
 438
 439 : arg-where ( ... seq quot: ( ... elt -- ... ? ) -- ... indices )
 440     over length <vector> [
 441         [ push-index-if ] 2curry each-index
 442     ] keep ; inline
 443
 444 : arg-sort ( seq -- indices )
 445     zip-index sort-keys values ;
 446
 447 : first= ( seq elt -- ? ) [ first ] dip = ; inline
 448 : second= ( seq elt -- ? ) [ second ] dip = ; inline
 449 : third= ( seq elt -- ? ) [ third ] dip = ; inline
 450 : fourth= ( seq elt -- ? ) [ fourth ] dip = ; inline
 451 : last= ( seq elt -- ? ) [ last ] dip = ; inline
 452 : nth= ( n seq elt -- ? ) [ nth ] dip = ; inline
 453
 454 : first? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ first ] dip call ; inline
 455 : second? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ second ] dip call ; inline
 456 : third? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ third ] dip call ; inline
 457 : fourth? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ fourth ] dip call ; inline
 458 : last? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ last ] dip call ; inline
 459 : nth? ( ... n seq quot: ( ... elt -- ... ? ) -- ... ? ) [ nth ] dip call ; inline
 460
 461 : loop>sequence ( quot exemplar -- seq )
 462    [ '[ [ @ [ [ , ] when* ] keep ] loop ] ] dip make ; inline
 463
 464 : loop>array ( quot -- seq )
 465    { } loop>sequence ; inline
 466
 467 <PRIVATE
 468
 469 : (reverse) ( seq -- newseq )
 470     dup [ length ] keep new-sequence
 471     [ 0 swap copy-unsafe ] keep reverse! ;
 472
 473 PRIVATE>
 474
 475 : reverse-as ( seq exemplar -- newseq )
 476     [ (reverse) ] [ like ] bi* ;
 477
 478 : map-product ( ... seq quot: ( ... elt -- ... n ) -- ... n )
 479     [ 1 ] 2dip [ dip * ] curry [ swap ] prepose each ; inline
 480
 481 : insert-nth! ( elt n seq -- )
 482     [ length ] keep ensure swap pick (a,b]
 483     over '[ [ 1 + ] keep _ move-unsafe ] each
 484     set-nth-unsafe ;
 485
 486 : set-nths ( value indices seq -- )
 487     swapd '[ _ swap _ set-nth ] each ; inline
 488
 489 : set-nths-unsafe ( value indices seq -- )
 490     swapd '[ _ swap _ set-nth-unsafe ] each ; inline
 491
 492 : flatten1 ( obj -- seq )
 493     [
 494         [
 495             dup branch? [
 496                 [ dup branch? [ % ] [ , ] if ] each
 497             ] [ , ] if
 498         ]
 499     ] keep dup branch? [ drop f ] unless make ;
 500
 501 <PRIVATE
 502
 503 : (map-find-index) ( seq quot find-quot -- result i elt )
 504     [ [ f ] 2dip [ [ nip ] 2dip call dup ] curry ] dip call
 505     [ [ [ drop f ] unless ] keep ] dip ; inline
 506
 507 PRIVATE>
 508
 509 : map-find-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 510     [ find-index ] (map-find-index) ; inline
 511
 512 : filter-length ( seq n -- seq' ) '[ length _ = ] filter ;
 513
 514 : all-shortest ( seqs -- seqs' ) dup shortest length filter-length ;
 515
 516 : all-longest ( seqs -- seqs' ) dup longest length filter-length ;
 517
 518 : remove-first ( obj seq -- seq' )
 519     [ index ] keep over [ remove-nth ] [ nip ] if ;
 520
 521 : remove-first! ( obj seq -- seq )
 522     [ index ] keep over [ remove-nth! ] [ nip ] if ;
 523
 524 : remove-last ( obj seq -- seq' )
 525     [ last-index ] keep over [ remove-nth ] [ nip ] if ;
 526
 527 : remove-last! ( obj seq -- seq )
 528     [ last-index ] keep over [ remove-nth! ] [ nip ] if ;
 529
 530 : ?first2 ( seq -- first/f second/f )
 531     dup length {
 532         { 0 [ drop f f ] }
 533         { 1 [ first-unsafe f ] }
 534         [ drop first2-unsafe ]
 535     } case ;
 536
 537 : ?first3 ( seq -- first/f second/f third/f )
 538     dup length {
 539         { 0 [ drop f f f ] }
 540         { 1 [ first-unsafe f f ] }
 541         { 2 [ first2-unsafe f ] }
 542         [ drop first3-unsafe ]
 543     } case ;
 544
 545 : ?first4 ( seq -- first/f second/f third/f fourth/f )
 546     dup length {
 547         { 0 [ drop f f f f ] }
 548         { 1 [ first-unsafe f f f ] }
 549         { 2 [ first2-unsafe f f ] }
 550         { 3 [ first3-unsafe f ] }
 551         [ drop first4-unsafe ]
 552     } case ;
 553
 554 : cut-when ( ... seq quot: ( ... elt -- ... ? ) -- ... before after )
 555     [ find drop ] 2keep drop swap
 556     [ cut ] [ f over like ] if* ; inline
 557
 558 : nth* ( n seq -- elt )
 559     [ length 1 - swap - ] [ nth ] bi ; inline
 560
 561 : each-index-from ( ... seq quot: ( ... elt index -- ... ) i -- ... )
 562     -rot (each-index) (each-integer) ; inline
 563
 564 <PRIVATE
 565
 566 : select-by* ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... i elt )
 567     [
 568         [ keep swap ] curry [ dip ] curry
 569         [ [ first 0 ] dip call ] 2keep
 570         [ 2curry 3dip 5 npick pick ] curry
 571     ] [
 572         [ [ 3drop ] [ [ 3drop ] 3dip ] if ] compose
 573     ] bi* compose 1 each-index-from nip swap ; inline
 574
 575 PRIVATE>
 576
 577 : supremum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 578     [ after? ] select-by* ; inline
 579
 580 : infimum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 581     [ before? ] select-by* ; inline
 582
 583 : change-last ( seq quot -- )
 584     [ drop length 1 - ] [ change-nth ] 2bi ; inline
 585
 586 : change-last-unsafe ( seq quot -- )
 587     [ drop length 1 - ] [ change-nth-unsafe ] 2bi ; inline
 588
 589 : replicate-into ( ... seq quot: ( ... -- ... newelt ) -- ... )
 590     over [ length ] 2dip '[ _ dip _ set-nth-unsafe ] each-integer ; inline
 591
 592 : count* ( ... seq quot: ( ... elt -- ... ? ) -- ... % )
 593     over [ count ] [ length ] bi* / ; inline
 594
 595 : find-last-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 596     [ [ 1 - ] dip find-last-integer ] (find-index) ; inline
 597
 598 : map-find-last-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 599     [ find-last-index ] (map-find-index) ; inline
 600
 601 :: (start-all) ( subseq seq increment -- indices )
 602     0
 603     [ [ subseq seq ] dip start* dup ]
 604     [ [ increment + ] keep ] produce nip ;
 605
 606 : start-all ( subseq seq -- indices )
 607     over length (start-all) ; inline
 608
 609 : start-all* ( subseq seq -- indices )
 610     1 (start-all) ; inline
 611
 612 : count-subseq ( subseq seq -- n )
 613     start-all length ; inline
 614
 615 : count-subseq* ( subseq seq -- n )
 616     start-all* length ; inline
 617
 618 : map-zip ( quot: ( x -- y ) -- alist )
 619     '[ _ keep swap ] map>alist ; inline
 620
 621 : map-keys ( assoc quot: ( key -- key' ) -- assoc )
 622     '[ _ dip ] assoc-map ; inline
 623
 624 : map-values ( assoc quot: ( value -- value' ) -- assoc )
 625     '[ swap _ dip swap ] assoc-map ; inline