extra/sequences/extras/extras.factor

   1 USING: accessors arrays assocs combinators fry generalizations
   2 grouping growable kernel locals make math math.order math.ranges
   3 sequences sequences.deep sequences.private sorting splitting
   4 vectors ;
   5 IN: sequences.extras
   6
   7 : find-all ( ... seq quot: ( ... elt -- ... ? ) -- ... elts )
   8     [ <enum> ] dip '[ nip @ ] assoc-filter ; inline
   9
  10 : reduce-from ( ... seq identity quot: ( ... prev elt -- ... next ) i -- ... result )
  11     [ swap ] 2dip each-from ; inline
  12
  13 :: subseq* ( from to seq -- subseq )
  14     seq length :> len
  15     from [ dup 0 < [ len + ] when ] [ 0 ] if*
  16     to [ dup 0 < [ len + ] when ] [ len ] if*
  17     [ 0 len clamp ] bi@ dupd max seq subseq ;
  18
  19 : safe-subseq ( from to seq -- subseq )
  20     [ length '[ 0 _ clamp ] bi@ ] keep subseq ;
  21
  22 : all-subseqs ( seq -- seqs )
  23     dup length [1,b] [ clump ] with map concat ;
  24
  25 :: each-subseq ( ... seq quot: ( ... subseq -- ... ) -- ... )
  26     seq length :> len
  27     len [0,b] [| from |
  28         from len (a,b] [| to |
  29             from to seq subseq quot call
  30         ] each
  31     ] each ; inline
  32
  33 : map-like ( seq exemplar -- seq' )
  34     '[ _ like ] map ; inline
  35
  36 : filter-all-subseqs-range ( ... seq range quot: ( ... subseq -- ... ) -- seq )
  37     [
  38         '[ <clumps> _ filter ] with map concat
  39     ] 3keep 2drop map-like ; inline
  40
  41 : filter-all-subseqs ( ... seq quot: ( ... subseq -- ... ) -- seq )
  42     [ dup length [1,b] ] dip filter-all-subseqs-range ; inline
  43
  44 :: longest-subseq ( seq1 seq2 -- subseq )
  45     seq1 length :> len1
  46     seq2 length :> len2
  47     0 :> n!
  48     0 :> end!
  49     len1 1 + [ len2 1 + 0 <array> ] replicate :> table
  50     len1 [1,b] [| x |
  51         len2 [1,b] [| y |
  52             x 1 - seq1 nth-unsafe
  53             y 1 - seq2 nth-unsafe = [
  54                 y 1 - x 1 - table nth-unsafe nth-unsafe 1 + :> len
  55                 len y x table nth-unsafe set-nth-unsafe
  56                 len n > [ len n! x end! ] when
  57             ] [ 0 y x table nth-unsafe set-nth-unsafe ] if
  58         ] each
  59     ] each end n - end seq1 subseq ;
  60
  61 : pad-longest ( seq1 seq2 elt -- seq1 seq2 )
  62     [ 2dup max-length ] dip [ pad-tail ] 2curry bi@ ;
  63
  64 :: pad-center ( seq n elt -- padded )
  65     n seq length [-] :> extra
  66     extra 2/ :> left
  67     extra left - :> right
  68     left elt <repetition> seq right elt <repetition>
  69     seq 3append-as ;
  70
  71 : change-nths ( ... indices seq quot: ( ... elt -- ... elt' ) -- ... )
  72     [ change-nth ] 2curry each ; inline
  73
  74 : push-if-index ( ..a elt i quot: ( ..a elt i -- ..b ? ) accum -- ..b )
  75     [ 2keep drop ] dip rot [ push ] [ 2drop ] if ; inline
  76
  77 : push-if* ( ..a elt quot: ( ..a elt -- ..b obj/f ) accum -- ..b )
  78     [ call ] dip [ push ] [ drop ] if* ; inline
  79
  80 <PRIVATE
  81
  82 : (index-selector-as) ( quot length exampler -- selector accum )
  83     new-resizable [ [ push-if-index ] 2curry ] keep ; inline
  84
  85 : (selector-as*) ( quot length exemplar -- selector accum )
  86     new-resizable [ [ push-if* ] 2curry ] keep ; inline
  87
  88 PRIVATE>
  89
  90 : index-selector-as ( quot exemplar -- selector accum )
  91     [ length ] keep (index-selector-as) ; inline
  92
  93 : index-selector ( quot -- selector accum )
  94     V{ } index-selector-as ; inline
  95
  96 : selector-as* ( quot exemplar -- selector accum )
  97     [ length ] keep (selector-as*) ; inline
  98
  99 : selector* ( quot -- selector accum ) V{ } selector-as* ; inline
 100
 101 : filter-index-as ( ... seq quot: ( ... elt i -- ... ? ) exemplar -- ... seq' )
 102     pick length over [ (index-selector-as) [ each-index ] dip ] 2curry dip like ; inline
 103
 104 : filter-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... seq' )
 105     over filter-index-as ; inline
 106
 107 : even-indices ( seq -- seq' )
 108     [ length 1 + 2/ ] keep [
 109         [ [ 2 * ] dip nth-unsafe ] curry
 110     ] keep map-integers ;
 111
 112 : odd-indices ( seq -- seq' )
 113     [ length 2/ ] keep [
 114         [ [ 2 * 1 + ] dip nth-unsafe ] curry
 115     ] keep map-integers ;
 116
 117 : compact ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 118     [ split-when harvest ] dip join ; inline
 119
 120 : collapse ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 121     [ split-when ] dip
 122     [ [ harvest ] dip join ]
 123     [ [ first empty? ] dip [ prepend ] curry when ]
 124     [ [ last empty? ] dip [ append ] curry when ]
 125     2tri ; inline
 126
 127 :: slice-when ( seq quot: ( elt -- ? ) -- seq' )
 128     seq length :> len
 129     0 [ len dupd < ] [
 130         dup seq quot find-from drop
 131         [ 2dup = [ 1 + ] when ] [ len ] if*
 132         [ seq <slice> ] keep len or swap
 133     ] produce nip ; inline
 134
 135 : cut-slice* ( seq n -- before after )
 136     [ head-slice* ] [ tail-slice* ] 2bi ;
 137
 138 : ?<slice> ( from/f to/f sequence -- slice )
 139     [ [ 0 ] unless* ] 2dip
 140     over [ nip [ length ] [ ] bi ] unless
 141     <slice> ; inline
 142
 143 : sequence>slice ( sequence -- slice )
 144     [ drop 0 ] [ length ] [ ] tri <slice> ; inline
 145
 146 : slice-order-by-from ( slice1 slice2 -- slice-lt slice-gt )
 147     2dup [ from>> ] bi@ > [ swap ] when ; inline
 148
 149 : ordered-slices-range ( slice-lt slice-gt -- to from )
 150     [ to>> ] [ from>> ] bi* ;
 151
 152 : unordered-slices-range ( slice1 slice2 -- to from )
 153     slice-order-by-from ordered-slices-range ;
 154
 155 : ordered-slices-overlap? ( slice-lt slice-gt -- ? )
 156     ordered-slices-range > ; inline
 157
 158 : unordered-slices-overlap? ( slice1 slice2 -- ? )
 159     unordered-slices-range > ; inline
 160
 161 : slices-overlap? ( slice1 slice2 -- ? )
 162     unordered-slices-overlap? ;
 163
 164 : ordered-slices-touch? ( slice-lt slice-gt -- ? )
 165     ordered-slices-range >= ; inline
 166
 167 : unordered-slices-touch? ( slice1 slice2 -- ? )
 168     unordered-slices-range >= ; inline
 169
 170 : slices-touch? ( slice1 slice2 -- ? )
 171     unordered-slices-touch? ;
 172
 173 ERROR: slices-don't-touch slice1 slice2 ;
 174
 175 : merge-slices ( slice1 slice2 -- slice/* )
 176     slice-order-by-from
 177     2dup ordered-slices-touch? [
 178         [ from>> ] [ [ to>> ] [ seq>> ] bi ] bi* <slice>
 179     ] [
 180         slices-don't-touch
 181     ] if ;
 182
 183 : rotate ( seq n -- seq' )
 184     over length mod dup 0 >= [ cut ] [ abs cut* ] if prepend ;
 185
 186 ERROR: underlying-mismatch slice1 slice2 ;
 187
 188 : ensure-same-underlying ( slice1 slice2 -- slice1 slice2 )
 189     2dup [ seq>> ] bi@ eq? [ underlying-mismatch ] unless ;
 190
 191 : span-slices ( slice1 slice2 -- slice )
 192     ensure-same-underlying
 193     [ [ from>> ] bi@ min ]
 194     [ [ to>> ] bi@ max ]
 195     [ drop seq>> ] 2tri <slice> ;
 196
 197 : ?span-slices ( slice1/f slice2/f -- slice )
 198     2dup and [ span-slices ] [ or ] if ;
 199
 200 :: rotate! ( seq n -- )
 201     seq length :> len
 202     n len mod dup 0 < [ len + ] when seq bounds-check drop 0 over
 203     [ 2dup = ] [
 204         [ seq exchange-unsafe ] [ [ 1 + ] bi@ ] 2bi
 205         dup len = [ drop over ] when
 206         2over = [ -rot nip over ] when
 207     ] until 3drop ;
 208
 209 : all-rotations ( seq -- seq' )
 210     dup length <iota> [ rotate ] with map ;
 211
 212 <PRIVATE
 213
 214 : (appender-for) ( quot length exemplar -- appender accum )
 215     new-resizable [ [ push-all ] curry compose ] keep ; inline
 216
 217 PRIVATE>
 218
 219 : appender-for ( quot exemplar -- appender accum )
 220     [ length ] keep (appender-for) ; inline
 221
 222 : appender ( quot -- appender accum )
 223     V{ } appender-for ; inline
 224
 225 : map-concat-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 226     [ appender-for [ each ] dip ] keep like ; inline
 227
 228 : >resizable ( seq -- accum ) ! fixes map-concat "cannot apply call to run-time..."
 229     [ length ] keep [ new-resizable ] [ append! ] bi ;
 230
 231 : map-concat ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 232     over empty? [ 2drop { } ] [
 233         [ [ first ] dip call ] 2keep rot [
 234             >resizable [ '[ @ _ push-all ] 1 each-from ] keep
 235         ] keep like
 236     ] if ; inline
 237
 238 : map-filter-as ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) exemplar -- ... subseq )
 239     [ pick ] dip swap length over
 240     [ (selector-as) [ compose each ] dip ] 2curry dip like ; inline
 241
 242 : map-filter ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) -- ... subseq )
 243     pick map-filter-as ; inline
 244
 245 : map-sift ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 246     [ ] map-filter ; inline
 247
 248 : map-harvest ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 249     [ empty? not ] map-filter ; inline
 250
 251 <PRIVATE
 252
 253 : (setup-each-from) ( i seq -- n quot )
 254     [ length over [-] swap ] keep '[ _ + _ nth-unsafe ] ; inline
 255
 256 : setup-each-from ( i seq quot -- n quot' )
 257     [ (setup-each-from) ] dip compose ; inline
 258
 259 PRIVATE>
 260
 261 : map-from-as ( ... seq quot: ( ... elt -- ... newelt ) i exemplar -- ... newseq )
 262     [ -rot setup-each-from ] dip map-integers ; inline
 263
 264 : map-from ( ... seq quot: ( ... elt -- ... newelt ) i -- ... newseq )
 265     pick map-from-as ; inline
 266
 267 <PRIVATE
 268
 269 : push-map-if ( ..a elt filter-quot: ( ..a elt -- ..b ? ) map-quot: ( ..a elt -- ..b newelt ) accum -- ..b )
 270     [ keep over ] 2dip [ when ] dip rot [ push ] [ 2drop ] if ; inline
 271
 272 : (filter-mapper-for) ( filter-quot map-quot length exempler -- filter-mapper accum )
 273     new-resizable [ [ push-map-if ] 3curry ] keep ; inline
 274
 275 : filter-mapper-for ( filter-quot map-quot exemplar -- filter-mapper accum )
 276     [ length ] keep (filter-mapper-for) ; inline
 277
 278 : filter-mapper ( filter-quot map-quot -- filter-mapper accum )
 279     V{ } filter-mapper-for ; inline
 280
 281 PRIVATE>
 282
 283 : filter-map-as ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 284     [ pick ] dip swap length over
 285     [ (filter-mapper-for) [ each ] dip ] 2curry dip like ; inline
 286
 287 : filter-map ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) -- ... newseq )
 288     pick filter-map-as ; inline
 289
 290 : 2map-sum ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... n ) -- ... n )
 291     [ 0 ] 3dip [ dip + ] curry [ rot ] prepose 2each ; inline
 292
 293 : 2count ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... n )
 294     [ 1 0 ? ] compose 2map-sum ; inline
 295
 296 : round-robin ( seq -- newseq )
 297     [ { } ] [
 298         [ longest length <iota> ] keep
 299         [ [ ?nth ] with map ] curry map concat sift
 300     ] if-empty ;
 301
 302 : sift-as ( seq exemplar -- newseq )
 303     [ ] swap filter-as ;
 304
 305 : sift! ( seq -- newseq )
 306     [ ] filter! ;
 307
 308 : harvest-as ( seq exemplar -- newseq )
 309     [ empty? not ] swap filter-as ;
 310
 311 : harvest! ( seq -- newseq )
 312     [ empty? ] reject! ;
 313
 314 : head-as ( seq n exemplar -- seq' )
 315     [ head-slice ] [ like ] bi* ; inline
 316
 317 : head*-as ( seq n exemplar -- seq' )
 318     [ head-slice* ] [ like ] bi* ; inline
 319
 320 : tail-as ( seq n exemplar -- seq' )
 321     [ tail-slice ] [ like ] bi* ; inline
 322
 323 : tail*-as ( seq n exemplar -- seq' )
 324     [ tail-slice* ] [ like ] bi* ; inline
 325
 326 : trim-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... newseq )
 327     [ trim-slice ] [ like ] bi* ; inline
 328
 329 : ?trim ( seq quot: ( elt -- ? ) -- seq/newseq )
 330     over empty? [ drop ] [
 331         over [ first-unsafe ] [ last-unsafe ] bi pick either?
 332         [ trim ] [ drop ] if
 333     ] if ; inline
 334
 335 : ?trim-head ( seq quot: ( elt -- ? ) -- seq/newseq )
 336     over empty? [ drop ] [
 337         over first-unsafe over call
 338         [ trim-head ] [ drop ] if
 339     ] if ; inline
 340
 341 : ?trim-tail ( seq quot: ( elt -- ? ) -- seq/newseq )
 342     over empty? [ drop ] [
 343         over last-unsafe over call
 344         [ trim-tail ] [ drop ] if
 345     ] if ; inline
 346
 347 : unsurround ( newseq seq2 seq3 -- seq1 )
 348    [ ?head drop ] [ ?tail drop ] bi* ;
 349
 350 : none? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 351     any? not ; inline
 352
 353 : one? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 354     [ find ] 2keep rot [
 355         [ 1 + ] 2dip find-from drop not
 356     ] [ 3drop f ] if ; inline
 357
 358 : map-index! ( ... seq quot: ( ... elt index -- ... newelt ) -- ... seq )
 359     over [ [ (each-index) ] dip collect ] keep ; inline
 360
 361 <PRIVATE
 362
 363 : (2each-index) ( seq1 seq2 quot -- n quot' )
 364     [ setup-2each [ keep ] curry ] dip compose ; inline
 365
 366 PRIVATE>
 367
 368 : 2each-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... ) -- ... )
 369     (2each-index) each-integer ; inline
 370
 371 : 2map-into ( seq1 seq2 quot into -- )
 372     [ (2each) ] dip collect ; inline
 373
 374 : 2map! ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... seq1 )
 375     pick [ 2map-into ] keep ; inline
 376
 377 : 2map-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... newelt ) -- ... newseq )
 378     pick [ (2each-index) ] dip map-integers ; inline
 379
 380 TUPLE: evens seq length ;
 381
 382 : <evens> ( seq -- evens )
 383     dup length 1 + 2/ evens boa ; inline
 384
 385 M: evens length length>> ; inline
 386
 387 M: evens nth-unsafe [ 2 * ] [ seq>> nth-unsafe ] bi* ; inline
 388
 389 INSTANCE: evens immutable-sequence
 390
 391 TUPLE: odds seq length ;
 392
 393 : <odds> ( seq -- odds )
 394     dup length 2/ odds boa ; inline
 395
 396 M: odds length length>> ; inline
 397
 398 M: odds nth-unsafe [ 2 * 1 + ] [ seq>> nth-unsafe ] bi* ; inline
 399
 400 INSTANCE: odds immutable-sequence
 401
 402 : until-empty ( seq quot -- )
 403     [ dup empty? ] swap until drop ; inline
 404
 405 : arg-max ( seq -- n )
 406     <enum> [ second-unsafe ] supremum-by first ;
 407
 408 : arg-min ( seq -- n )
 409     <enum> [ second-unsafe ] infimum-by first ;
 410
 411 <PRIVATE
 412
 413 : push-index-if ( ..a elt i quot: ( ..a elt -- ..b ? ) accum -- ..b )
 414     [ dip ] dip rot [ push ] [ 2drop ] if ; inline
 415
 416 PRIVATE>
 417
 418 : arg-where ( ... seq quot: ( ... elt -- ... ? ) -- ... indices )
 419     over length <vector> [
 420         [ push-index-if ] 2curry each-index
 421     ] keep ; inline
 422
 423 : arg-sort ( seq -- indices )
 424     zip-index sort-keys values ;
 425
 426 : first= ( seq elt -- ? ) [ first ] dip = ; inline
 427 : second= ( seq elt -- ? ) [ second ] dip = ; inline
 428 : third= ( seq elt -- ? ) [ third ] dip = ; inline
 429 : fourth= ( seq elt -- ? ) [ fourth ] dip = ; inline
 430 : last= ( seq elt -- ? ) [ last ] dip = ; inline
 431 : nth= ( n seq elt -- ? ) [ nth ] dip = ; inline
 432
 433 : first? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ first ] dip call ; inline
 434 : second? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ second ] dip call ; inline
 435 : third? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ third ] dip call ; inline
 436 : fourth? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ fourth ] dip call ; inline
 437 : last? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ last ] dip call ; inline
 438 : nth? ( ... n seq quot: ( ... elt -- ... ? ) -- ... ? ) [ nth ] dip call ; inline
 439
 440 : loop>sequence ( quot exemplar -- seq )
 441    [ '[ [ @ [ [ , ] when* ] keep ] loop ] ] dip make ; inline
 442
 443 : loop>array ( quot -- seq )
 444    { } loop>sequence ; inline
 445
 446 <PRIVATE
 447
 448 : (reverse) ( seq -- newseq )
 449     dup [ length ] keep new-sequence
 450     [ 0 swap copy-unsafe ] keep reverse! ;
 451
 452 PRIVATE>
 453
 454 : reverse-as ( seq exemplar -- newseq )
 455     [ (reverse) ] [ like ] bi* ;
 456
 457 : map-product ( ... seq quot: ( ... elt -- ... n ) -- ... n )
 458     [ 1 ] 2dip [ dip * ] curry [ swap ] prepose each ; inline
 459
 460 : insert-nth! ( elt n seq -- )
 461     [ length ] keep ensure swap pick (a,b]
 462     over '[ [ 1 + ] keep _ move-unsafe ] each
 463     set-nth-unsafe ;
 464
 465 : set-nths ( value indices seq -- )
 466     swapd '[ _ swap _ set-nth ] each ; inline
 467
 468 : set-nths-unsafe ( value indices seq -- )
 469     swapd '[ _ swap _ set-nth-unsafe ] each ; inline
 470
 471 : flatten1 ( obj -- seq )
 472     [
 473         [
 474             dup branch? [
 475                 [ dup branch? [ % ] [ , ] if ] each
 476             ] [ , ] if
 477         ]
 478     ] keep dup branch? [ drop f ] unless make ;
 479
 480 <PRIVATE
 481
 482 : (map-find-index) ( seq quot find-quot -- result i elt )
 483     [ [ f ] 2dip [ [ nip ] 2dip call dup ] curry ] dip call
 484     [ [ [ drop f ] unless ] keep ] dip ; inline
 485
 486 PRIVATE>
 487
 488 : map-find-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 489     [ find-index ] (map-find-index) ; inline
 490
 491 : filter-length ( seq n -- seq' ) '[ length _ = ] filter ;
 492
 493 : all-shortest ( seqs -- seqs' ) dup shortest length filter-length ;
 494
 495 : all-longest ( seqs -- seqs' ) dup longest length filter-length ;
 496
 497 : remove-first ( obj seq -- seq' )
 498     [ index ] keep over [ remove-nth ] [ nip ] if ;
 499
 500 : remove-first! ( obj seq -- seq )
 501     [ index ] keep over [ remove-nth! ] [ nip ] if ;
 502
 503 : remove-last ( obj seq -- seq' )
 504     [ last-index ] keep over [ remove-nth ] [ nip ] if ;
 505
 506 : remove-last! ( obj seq -- seq )
 507     [ last-index ] keep over [ remove-nth! ] [ nip ] if ;
 508
 509 : ?first2 ( seq -- first/f second/f )
 510     dup length {
 511         { 0 [ drop f f ] }
 512         { 1 [ first-unsafe f ] }
 513         [ drop first2-unsafe ]
 514     } case ;
 515
 516 : ?first3 ( seq -- first/f second/f third/f )
 517     dup length {
 518         { 0 [ drop f f f ] }
 519         { 1 [ first-unsafe f f ] }
 520         { 2 [ first2-unsafe f ] }
 521         [ drop first3-unsafe ]
 522     } case ;
 523
 524 : ?first4 ( seq -- first/f second/f third/f fourth/f )
 525     dup length {
 526         { 0 [ drop f f f f ] }
 527         { 1 [ first-unsafe f f f ] }
 528         { 2 [ first2-unsafe f f ] }
 529         { 3 [ first3-unsafe f ] }
 530         [ drop first4-unsafe ]
 531     } case ;
 532
 533 : cut-when ( ... seq quot: ( ... elt -- ... ? ) -- ... before after )
 534     [ find drop ] 2keep drop swap
 535     [ cut ] [ f over like ] if* ; inline
 536
 537 : nth* ( n seq -- elt )
 538     [ length 1 - swap - ] [ nth ] bi ; inline
 539
 540 : each-index-from ( ... seq quot: ( ... elt index -- ... ) i -- ... )
 541     -rot (each-index) (each-integer) ; inline
 542
 543 <PRIVATE
 544
 545 : select-by* ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... i elt )
 546     [
 547         [ keep swap ] curry [ dip ] curry
 548         [ [ first 0 ] dip call ] 2keep
 549         [ 2curry 3dip 5 npick pick ] curry
 550     ] [
 551         [ [ 3drop ] [ [ 3drop ] 3dip ] if ] compose
 552     ] bi* compose 1 each-index-from nip swap ; inline
 553
 554 PRIVATE>
 555
 556 : supremum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 557     [ after? ] select-by* ; inline
 558
 559 : infimum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 560     [ before? ] select-by* ; inline
 561
 562 : change-last ( seq quot -- )
 563     [ drop length 1 - ] [ change-nth ] 2bi ; inline
 564
 565 : change-last-unsafe ( seq quot -- )
 566     [ drop length 1 - ] [ change-nth-unsafe ] 2bi ; inline
 567
 568 : replicate-into ( ... seq quot: ( ... -- ... newelt ) -- ... )
 569     over [ length ] 2dip '[ _ dip _ set-nth-unsafe ] each-integer ; inline
 570
 571 : count* ( ... seq quot: ( ... elt -- ... ? ) -- ... % )
 572     over [ count ] [ length ] bi* / ; inline
 573
 574 : find-last-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 575     [ [ 1 - ] dip find-last-integer ] (find-index) ; inline
 576
 577 : map-find-last-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 578     [ find-last-index ] (map-find-index) ; inline
 579
 580 :: (start-all) ( subseq seq increment -- indices )
 581     0
 582     [ [ subseq seq ] dip subseq-start-from dup ]
 583     [ [ increment + ] keep ] produce nip ;
 584
 585 : start-all ( subseq seq -- indices )
 586     over length (start-all) ; inline
 587
 588 : start-all* ( subseq seq -- indices )
 589     1 (start-all) ; inline
 590
 591 : count-subseq ( subseq seq -- n )
 592     start-all length ; inline
 593
 594 : count-subseq* ( subseq seq -- n )
 595     start-all* length ; inline
 596
 597 : map-zip ( quot: ( x -- y ) -- alist )
 598     '[ _ keep swap ] map>alist ; inline
 599
 600 : map-keys ( assoc quot: ( key -- key' ) -- assoc )
 601     '[ _ dip ] assoc-map ; inline
 602
 603 : map-values ( assoc quot: ( value -- value' ) -- assoc )
 604     '[ swap _ dip swap ] assoc-map ; inline
 605
 606 : take-while ( ... seq quot: ( ... elt -- ... ? ) -- head-slice )
 607     [ '[ @ not ] find drop ] 2keep drop swap
 608     [ dup length ] unless* head-slice ; inline
 609
 610 : drop-while ( ... seq quot: ( ... elt -- ... ? ) -- tail-slice )
 611     [ '[ @ not ] find drop ] 2keep drop swap
 612     [ dup length ] unless* tail-slice ; inline