extra/sequences/extras/extras.factor

   1 USING: accessors arrays assocs fry grouping growable kernel
   2 locals make math math.order math.ranges sequences
   3 sequences.deep sequences.private sorting splitting ;
   4 FROM: sequences => change-nth ;
   5 IN: sequences.extras
   6
   7 : reduce1 ( seq quot -- result ) [ unclip ] dip reduce ; inline
   8
   9 :: reduce-r ( list identity quot: ( obj1 obj2 -- obj ) -- result )
  10     list empty?
  11     [ identity ]
  12     [ list rest identity quot reduce-r list first quot call ] if ;
  13     inline recursive
  14
  15 ! Quot must have static stack effect, unlike "reduce"
  16 :: reduce* ( seq id quot -- result ) seq
  17     [ id ]
  18     [ unclip id swap quot call( prev elt -- next ) quot reduce* ] if-empty ; inline recursive
  19
  20 :: combos ( list1 list2 -- result )
  21     list2 [ [ 2array ] curry list1 swap map ] map concat ;
  22
  23 : find-all ( seq quot -- elts )
  24     [ [ length iota ] keep ] dip
  25     [ dupd call( a -- ? ) [ 2array ] [ 2drop f ] if ] curry
  26     2map [ ] filter ; inline
  27
  28 : insert-sorted ( elt seq -- seq )
  29     2dup [ < ] with find drop over length or swap insert-nth ;
  30
  31 : reduce-from ( ... seq identity quot: ( ... prev elt -- ... next ) i -- ... result )
  32     [ swap ] 2dip each-from ; inline
  33
  34 : all-subseqs ( seq -- seqs )
  35     dup length [1,b] [ clump ] with map concat ;
  36
  37 :: each-subseq ( ... seq quot: ( ... x -- ... ) -- ... )
  38     seq length :> len
  39     len [0,b] [
  40         :> from
  41         from len (a,b] [
  42             :> to
  43             from to seq subseq quot call( x -- )
  44         ] each
  45     ] each ;
  46
  47 : map-like ( seq exemplar -- seq' )
  48     '[ _ like ] map ; inline
  49
  50 : filter-all-subseqs-range ( ... seq range quot: ( ... x -- ... ) -- seq )
  51     [
  52         '[ <clumps> _ filter ] with map concat
  53     ] 3keep 2drop map-like ; inline
  54
  55 : filter-all-subseqs ( ... seq quot: ( ... x -- ... ) -- seq )
  56     [ dup length [1,b] ] dip filter-all-subseqs-range ; inline
  57
  58 :: longest-subseq ( seq1 seq2 -- subseq )
  59     seq1 length :> len1
  60     seq2 length :> len2
  61     0 :> n!
  62     0 :> end!
  63     len1 1 + [ len2 1 + 0 <array> ] replicate :> table
  64     len1 [1,b] [| x |
  65         len2 [1,b] [| y |
  66             x 1 - seq1 nth-unsafe
  67             y 1 - seq2 nth-unsafe = [
  68                 y 1 - x 1 - table nth-unsafe nth-unsafe 1 + :> len
  69                 len y x table nth-unsafe set-nth-unsafe
  70                 len n > [ len n! x end! ] when
  71             ] [ 0 y x table nth-unsafe set-nth-unsafe ] if
  72         ] each
  73     ] each end n - end seq1 subseq ;
  74
  75 : pad-longest ( seq1 seq2 elt -- seq1 seq2 )
  76     [ 2dup max-length ] dip [ pad-tail ] 2curry bi@ ;
  77
  78 : change-nths ( ... indices seq quot: ( ... elt -- ... elt' ) -- ... )
  79     [ change-nth ] 2curry each ; inline
  80
  81 : push-if-index ( ..a elt i quot: ( ..a elt i -- ..b ? ) accum -- ..b )
  82     [ 2keep drop ] dip rot [ push ] [ 2drop ] if ; inline
  83
  84 : index-selector-for ( quot exemplar -- selector accum )
  85     [ length ] keep new-resizable [ [ push-if-index ] 2curry ] keep ; inline
  86
  87 : filter-index-as ( ... seq quot: ( ... elt i -- ... ? ) exemplar -- ... seq' )
  88     dup [ index-selector-for [ each-index ] dip ] curry dip like ; inline
  89
  90 : filter-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... seq' )
  91     over filter-index-as ; inline
  92
  93 : even-indices ( seq -- seq' )
  94     [ length 1 + 2/ ] keep [
  95         [ [ 2 * ] dip nth-unsafe ] curry
  96     ] keep map-integers ;
  97
  98 : odd-indices ( seq -- seq' )
  99     [ length 2/ ] keep [
 100         [ [ 2 * 1 + ] dip nth-unsafe ] curry
 101     ] keep map-integers ;
 102
 103 : compact ( seq quot elt -- seq' )
 104     [ split-when harvest ] dip join ; inline
 105
 106 : collapse ( seq quot elt -- seq' )
 107     [ split-when ] dip
 108     [ [ harvest ] dip join ]
 109     [ [ first empty? ] dip [ prepend ] curry when ]
 110     [ [ last empty? ] dip [ append ] curry when ]
 111     2tri ; inline
 112
 113 :: slice-when ( seq quot: ( elt -- ? ) -- seq' )
 114     seq length :> len
 115     0 [ len dupd < ] [
 116         dup seq quot find-from drop
 117         [ 2dup = [ 1 + ] when ] [ len ] if*
 118         [ seq <slice> ] keep len or swap
 119     ] produce nip ; inline
 120
 121 : rotate ( seq n -- seq' )
 122     cut prepend ;
 123
 124 :: rotate! ( seq n -- )
 125     n seq bounds-check length :> end
 126     0 n [ 2dup = ] [
 127         [ seq exchange-unsafe ] [ [ 1 + ] bi@ ] 2bi
 128         dup end = [ drop over ] when
 129         2over = [ -rot nip over ] when
 130     ] until 3drop ;
 131
 132 : all-rotations ( seq -- seq' )
 133     dup length iota [ rotate ] with map ;
 134
 135 : appender-for ( quot exemplar -- quot' vec )
 136     [ length ] keep new-resizable
 137     [ [ push-all ] curry compose ] keep ; inline
 138
 139 : appender ( quot -- quot' vec )
 140     V{ } appender-for ; inline
 141
 142 : map-concat-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 143     dup [ appender-for [ each ] dip ] curry dip like ; inline
 144
 145 : >resizable ( seq -- vec ) ! fixes map-concat "cannot apply call to run-time..."
 146     [ length ] keep [ new-resizable ] [ over push-all ] bi ;
 147
 148 : map-concat ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 149     over [ 2drop { } ] [
 150         first over call dup [
 151             >resizable [ [ push-all ] curry compose ] keep
 152             [ 1 ] 3dip [ (each) (each-integer) ] dip
 153         ] curry dip like
 154     ] if-empty ; inline
 155
 156 : map-filter-as ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) exemplar -- ... subseq )
 157     dup [ selector-for [ compose each ] dip ] curry dip like ; inline
 158
 159 : map-filter ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) -- ... subseq )
 160     pick map-filter-as ; inline
 161
 162 : map-sift ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 163     [ ] map-filter ; inline
 164
 165 : map-harvest ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 166     [ empty? not ] map-filter ; inline
 167
 168 <PRIVATE
 169
 170 : ((each-from)) ( i seq -- n quot )
 171     [ length over [-] swap ] keep '[ _ + _ nth-unsafe ] ; inline
 172
 173 : (each-from) ( i seq quot -- n quot' ) [ ((each-from)) ] dip compose ;
 174     inline
 175
 176 PRIVATE>
 177
 178 : map-from-as ( ... seq quot: ( ... elt -- ... newelt ) i exemplar -- ... newseq )
 179     [ -rot (each-from) ] dip map-integers ; inline
 180
 181 : map-from ( ... seq quot: ( ... elt -- ... newelt ) i -- ... newseq )
 182     pick map-from-as ; inline
 183
 184 <PRIVATE
 185
 186 : push-map-if ( ..a elt filter-quot: ( ..a elt -- ..b ? ) map-quot: ( ..a elt -- ..b newelt ) accum -- ..b )
 187     [ keep over ] 2dip [ when ] dip rot [ push ] [ 2drop ] if ; inline
 188
 189 : filter-mapper-for ( filter-quot map-quot exemplar -- quot' vec )
 190     [ length ] keep new-resizable [ [ push-map-if ] 3curry ] keep ; inline
 191
 192 : filter-mapper ( filter-quot map-quot -- quot' vec )
 193     V{ } filter-mapper-for ; inline
 194
 195 PRIVATE>
 196
 197 : filter-map-as ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 198     dup [ filter-mapper-for [ each ] dip ] curry dip like ; inline
 199
 200 : filter-map ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) -- ... newseq )
 201     pick filter-map-as ; inline
 202
 203 : 2map-sum ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... n ) -- ... n )
 204     [ 0 ] 3dip [ dip + ] curry [ rot ] prepose 2each ; inline
 205
 206 : 2count ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... n )
 207     [ 1 0 ? ] compose 2map-sum ; inline
 208
 209 : round-robin ( seq -- newseq )
 210     [ { } ] [
 211         [ longest length iota ] keep
 212         [ [ ?nth ] with map ] curry map concat sift
 213     ] if-empty ;
 214
 215 : sift-as ( seq exemplar -- newseq )
 216     [ ] swap filter-as ;
 217
 218 : sift! ( seq -- newseq )
 219     [ ] filter! ;
 220
 221 : harvest-as ( seq exemplar -- newseq )
 222     [ empty? not ] swap filter-as ;
 223
 224 : harvest! ( seq -- newseq )
 225     [ empty? not ] filter! ;
 226
 227 : contains? ( seq elts -- ? )
 228     [ member? ] curry any? ; inline
 229
 230 : head-as ( seq n exemplar -- seq' )
 231     [ head-slice ] [ like ] bi* ; inline
 232
 233 : head*-as ( seq n exemplar -- seq' )
 234     [ head-slice* ] [ like ] bi* ; inline
 235
 236 : tail-as ( seq n exemplar -- seq' )
 237     [ tail-slice ] [ like ] bi* ; inline
 238
 239 : tail*-as ( seq n exemplar -- seq' )
 240     [ tail-slice* ] [ like ] bi* ; inline
 241
 242 : trim-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... newseq )
 243     [ trim-slice ] [ like ] bi* ; inline
 244
 245 : ?trim ( seq quot: ( elt -- ? ) -- seq/newseq )
 246     over empty? [ drop ] [
 247         over [ first-unsafe ] [ last-unsafe ] bi pick bi@ or
 248         [ trim ] [ drop ] if
 249     ] if ; inline
 250
 251 : ?trim-head ( seq quot: ( elt -- ? ) -- seq/newseq )
 252     over empty? [ drop ] [
 253         over first-unsafe over call
 254         [ trim-head ] [ drop ] if
 255     ] if ; inline
 256
 257 : ?trim-tail ( seq quot: ( elt -- ? ) -- seq/newseq )
 258     over empty? [ drop ] [
 259         over last-unsafe over call
 260         [ trim-tail ] [ drop ] if
 261     ] if ; inline
 262
 263 : unsurround ( newseq seq2 seq3 -- seq1 )
 264    [ ?head drop ] [ ?tail drop ] bi* ;
 265
 266 : none? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 267     any? not ; inline
 268
 269 : one? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 270     [ find ] 2keep rot [
 271         [ 1 + ] 2dip find-from drop not
 272     ] [ 3drop f ] if ; inline
 273
 274 : map-index! ( ... seq quot: ( ... elt index -- ... newelt ) -- ... seq )
 275     over [ [ (each-index) ] dip collect ] keep ; inline
 276
 277 <PRIVATE
 278
 279 : (2each-index) ( seq1 seq2 quot -- n quot' )
 280     [ ((2each)) [ keep ] curry ] dip compose ; inline
 281
 282 PRIVATE>
 283
 284 : 2each-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... ) -- ... )
 285     (2each-index) each-integer ; inline
 286
 287 : 2map-into ( seq1 seq2 quot into -- )
 288     [ (2each) ] dip collect ; inline
 289
 290 : 2map! ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... seq1 )
 291     pick [ 2map-into ] keep ; inline
 292
 293 : 2map-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... newelt ) -- ... newseq )
 294     pick [ (2each-index) ] dip map-integers ; inline
 295
 296 TUPLE: evens seq length ;
 297
 298 : <evens> ( seq -- evens )
 299     dup length 1 + 2/ evens boa ; inline
 300
 301 M: evens length length>> ; inline
 302
 303 M: evens nth-unsafe [ 2 * ] [ seq>> nth-unsafe ] bi* ; inline
 304
 305 INSTANCE: evens immutable-sequence
 306
 307 TUPLE: odds seq length ;
 308
 309 : <odds> ( seq -- odds )
 310     dup length 2/ odds boa ; inline
 311
 312 M: odds length length>> ; inline
 313
 314 M: odds nth-unsafe [ 2 * 1 + ] [ seq>> nth-unsafe ] bi* ; inline
 315
 316 INSTANCE: odds immutable-sequence
 317
 318 : until-empty ( seq quot -- )
 319     [ dup empty? ] swap until drop ; inline
 320
 321 : arg-max ( seq -- n )
 322     dup length iota zip [ first-unsafe ] supremum-by second ;
 323
 324 : arg-min ( seq -- n )
 325     dup length iota zip [ first-unsafe ] infimum-by second ;
 326
 327 : arg-where ( ... seq quot: ( ... elt -- ... ? ) -- ... indices )
 328     [ dup length iota zip ] dip
 329     [ first-unsafe ] prepose filter values ; inline
 330
 331 : arg-sort ( seq -- indices )
 332     dup length iota zip sort-keys values ;
 333
 334 : first= ( seq elt -- ? ) [ first ] dip = ; inline
 335 : second= ( seq elt -- ? ) [ second ] dip = ; inline
 336 : third= ( seq elt -- ? ) [ third ] dip = ; inline
 337 : fourth= ( seq elt -- ? ) [ fourth ] dip = ; inline
 338 : last= ( seq elt -- ? ) [ last ] dip = ; inline
 339 : nth= ( n seq elt -- ? ) [ nth ] dip = ; inline
 340
 341 : first? ( seq quot -- ? ) [ first ] dip call ; inline
 342 : second? ( seq quot -- ? ) [ second ] dip call ; inline
 343 : third? ( seq quot -- ? ) [ third ] dip call ; inline
 344 : fourth? ( seq quot -- ? ) [ fourth ] dip call ; inline
 345 : last? ( seq quot -- ? ) [ last ] dip call ; inline
 346 : nth? ( n seq quot -- ? ) [ nth ] dip call ; inline
 347
 348 : loop>sequence ( quot exemplar -- seq )
 349    [ '[ [ @ [ [ , ] when* ] keep ] loop ] ] dip make ; inline
 350
 351 : loop>array ( quot -- seq )
 352    { } loop>sequence ; inline
 353
 354 <PRIVATE
 355
 356 : (reverse) ( seq -- newseq )
 357     dup [ length ] keep new-sequence [ 0 swap copy ] keep reverse! ;
 358
 359 PRIVATE>
 360
 361 : reverse-as ( seq exemplar -- newseq )
 362     [ (reverse) ] [ like ] bi* ;
 363
 364 : map-product ( ... seq quot: ( ... elt -- ... n ) -- ... n )
 365     [ 1 ] 2dip [ dip * ] curry [ swap ] prepose each ; inline
 366
 367 : insert-nth! ( elt n seq -- )
 368     [ length ] keep ensure swap pick (a,b]
 369     over '[ [ 1 + ] keep _ move-unsafe ] each
 370     set-nth-unsafe ;
 371
 372 : set-nths ( value indices seq -- )
 373     swapd '[ [ _ ] dip _ set-nth ] each ; inline
 374
 375 : set-nths-unsafe ( value indices seq -- )
 376     swapd '[ [ _ ] dip _ set-nth-unsafe ] each ; inline
 377
 378 : flatten1 ( obj -- seq )
 379     [
 380         [
 381             dup branch? [
 382                 [ dup branch? [ % ] [ , ] if ] each
 383             ] [ , ] if
 384         ]
 385     ] keep dup branch? [ drop f ] unless make ;
 386
 387 : (map-find-index) ( seq quot find-quot -- result elt index )
 388     [ [ f ] 2dip [ [ nip ] 2dip call dup ] curry ] dip call
 389     [ [ [ drop f ] unless ] keep ] dip ; inline
 390
 391 : map-find-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result elt index )
 392     [ find-index ] (map-find-index) ; inline