extra/sequences/extras/extras.factor

   1 USING: accessors arrays assocs fry grouping growable kernel
   2 locals make math math.order math.ranges sequences
   3 sequences.deep sequences.private sorting splitting vectors ;
   4 FROM: sequences => change-nth ;
   5 IN: sequences.extras
   6
   7 : reduce1 ( seq quot -- result ) [ unclip ] dip reduce ; inline
   8
   9 :: reduce-r ( seq identity quot: ( obj1 obj2 -- obj ) -- result )
  10     seq [ identity ] [
  11         unclip [ identity quot reduce-r ] [ quot call ] bi*
  12     ] if-empty ; inline recursive
  13
  14 ! Quot must have static stack effect, unlike "reduce"
  15 :: reduce* ( seq identity quot: ( prev elt -- next ) -- result )
  16     seq [ identity ] [
  17         unclip identity swap quot call( prev elt -- next )
  18         quot reduce*
  19     ] if-empty ; inline recursive
  20
  21 :: combos ( list1 list2 -- result )
  22     list2 [ [ 2array ] curry list1 swap map ] map concat ;
  23
  24 : find-all ( seq quot -- elts )
  25     [ [ length iota ] keep ] dip
  26     [ dupd call( a -- ? ) [ 2array ] [ 2drop f ] if ] curry
  27     2map [ ] filter ; inline
  28
  29 : insert-sorted ( elt seq -- seq )
  30     2dup [ < ] with find drop over length or swap insert-nth ;
  31
  32 : reduce-from ( ... seq identity quot: ( ... prev elt -- ... next ) i -- ... result )
  33     [ swap ] 2dip each-from ; inline
  34
  35 : all-subseqs ( seq -- seqs )
  36     dup length [1,b] [ clump ] with map concat ;
  37
  38 :: each-subseq ( ... seq quot: ( ... x -- ... ) -- ... )
  39     seq length :> len
  40     len [0,b] [
  41         :> from
  42         from len (a,b] [
  43             :> to
  44             from to seq subseq quot call( x -- )
  45         ] each
  46     ] each ;
  47
  48 : subseq-as ( from to seq exemplar -- subseq )
  49     [ check-slice subseq>copy (copy) ] dip like ;
  50
  51 : map-like ( seq exemplar -- seq' )
  52     '[ _ like ] map ; inline
  53
  54 : filter-all-subseqs-range ( ... seq range quot: ( ... x -- ... ) -- seq )
  55     [
  56         '[ <clumps> _ filter ] with map concat
  57     ] 3keep 2drop map-like ; inline
  58
  59 : filter-all-subseqs ( ... seq quot: ( ... x -- ... ) -- seq )
  60     [ dup length [1,b] ] dip filter-all-subseqs-range ; inline
  61
  62 :: longest-subseq ( seq1 seq2 -- subseq )
  63     seq1 length :> len1
  64     seq2 length :> len2
  65     0 :> n!
  66     0 :> end!
  67     len1 1 + [ len2 1 + 0 <array> ] replicate :> table
  68     len1 [1,b] [| x |
  69         len2 [1,b] [| y |
  70             x 1 - seq1 nth-unsafe
  71             y 1 - seq2 nth-unsafe = [
  72                 y 1 - x 1 - table nth-unsafe nth-unsafe 1 + :> len
  73                 len y x table nth-unsafe set-nth-unsafe
  74                 len n > [ len n! x end! ] when
  75             ] [ 0 y x table nth-unsafe set-nth-unsafe ] if
  76         ] each
  77     ] each end n - end seq1 subseq ;
  78
  79 : pad-longest ( seq1 seq2 elt -- seq1 seq2 )
  80     [ 2dup max-length ] dip [ pad-tail ] 2curry bi@ ;
  81
  82 : change-nths ( ... indices seq quot: ( ... elt -- ... elt' ) -- ... )
  83     [ change-nth ] 2curry each ; inline
  84
  85 : push-if-index ( ..a elt i quot: ( ..a elt i -- ..b ? ) accum -- ..b )
  86     [ 2keep drop ] dip rot [ push ] [ 2drop ] if ; inline
  87
  88 : index-selector-for ( quot exemplar -- selector accum )
  89     [ length ] keep new-resizable [ [ push-if-index ] 2curry ] keep ; inline
  90
  91 : filter-index-as ( ... seq quot: ( ... elt i -- ... ? ) exemplar -- ... seq' )
  92     dup [ index-selector-for [ each-index ] dip ] curry dip like ; inline
  93
  94 : filter-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... seq' )
  95     over filter-index-as ; inline
  96
  97 : even-indices ( seq -- seq' )
  98     [ length 1 + 2/ ] keep [
  99         [ [ 2 * ] dip nth-unsafe ] curry
 100     ] keep map-integers ;
 101
 102 : odd-indices ( seq -- seq' )
 103     [ length 2/ ] keep [
 104         [ [ 2 * 1 + ] dip nth-unsafe ] curry
 105     ] keep map-integers ;
 106
 107 : compact ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 108     [ split-when harvest ] dip join ; inline
 109
 110 : collapse ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 111     [ split-when ] dip
 112     [ [ harvest ] dip join ]
 113     [ [ first empty? ] dip [ prepend ] curry when ]
 114     [ [ last empty? ] dip [ append ] curry when ]
 115     2tri ; inline
 116
 117 :: slice-when ( seq quot: ( elt -- ? ) -- seq' )
 118     seq length :> len
 119     0 [ len dupd < ] [
 120         dup seq quot find-from drop
 121         [ 2dup = [ 1 + ] when ] [ len ] if*
 122         [ seq <slice> ] keep len or swap
 123     ] produce nip ; inline
 124
 125 : cut-slice* ( seq n -- before after )
 126     [ head-slice* ] [ tail-slice* ] 2bi ;
 127
 128 : rotate ( seq n -- seq' )
 129     cut prepend ;
 130
 131 :: rotate! ( seq n -- )
 132     n seq bounds-check length :> end
 133     0 n [ 2dup = ] [
 134         [ seq exchange-unsafe ] [ [ 1 + ] bi@ ] 2bi
 135         dup end = [ drop over ] when
 136         2over = [ -rot nip over ] when
 137     ] until 3drop ;
 138
 139 : all-rotations ( seq -- seq' )
 140     dup length iota [ rotate ] with map ;
 141
 142 : appender-for ( quot exemplar -- quot' vec )
 143     [ length ] keep new-resizable
 144     [ [ push-all ] curry compose ] keep ; inline
 145
 146 : appender ( quot -- quot' vec )
 147     V{ } appender-for ; inline
 148
 149 : map-concat-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 150     dup [ appender-for [ each ] dip ] curry dip like ; inline
 151
 152 : >resizable ( seq -- vec ) ! fixes map-concat "cannot apply call to run-time..."
 153     [ length ] keep [ new-resizable ] [ over push-all ] bi ;
 154
 155 : map-concat ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 156     over [ 2drop { } ] [
 157         first over call dup [
 158             >resizable [ [ push-all ] curry compose ] keep
 159             [ 1 ] 3dip [ (each) (each-integer) ] dip
 160         ] curry dip like
 161     ] if-empty ; inline
 162
 163 : map-filter-as ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) exemplar -- ... subseq )
 164     dup [ selector-for [ compose each ] dip ] curry dip like ; inline
 165
 166 : map-filter ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) -- ... subseq )
 167     pick map-filter-as ; inline
 168
 169 : map-sift ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 170     [ ] map-filter ; inline
 171
 172 : map-harvest ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 173     [ empty? not ] map-filter ; inline
 174
 175 <PRIVATE
 176
 177 : ((each-from)) ( i seq -- n quot )
 178     [ length over [-] swap ] keep '[ _ + _ nth-unsafe ] ; inline
 179
 180 : (each-from) ( i seq quot -- n quot' ) [ ((each-from)) ] dip compose ;
 181     inline
 182
 183 PRIVATE>
 184
 185 : map-from-as ( ... seq quot: ( ... elt -- ... newelt ) i exemplar -- ... newseq )
 186     [ -rot (each-from) ] dip map-integers ; inline
 187
 188 : map-from ( ... seq quot: ( ... elt -- ... newelt ) i -- ... newseq )
 189     pick map-from-as ; inline
 190
 191 <PRIVATE
 192
 193 : push-map-if ( ..a elt filter-quot: ( ..a elt -- ..b ? ) map-quot: ( ..a elt -- ..b newelt ) accum -- ..b )
 194     [ keep over ] 2dip [ when ] dip rot [ push ] [ 2drop ] if ; inline
 195
 196 : filter-mapper-for ( filter-quot map-quot exemplar -- quot' vec )
 197     [ length ] keep new-resizable [ [ push-map-if ] 3curry ] keep ; inline
 198
 199 : filter-mapper ( filter-quot map-quot -- quot' vec )
 200     V{ } filter-mapper-for ; inline
 201
 202 PRIVATE>
 203
 204 : filter-map-as ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 205     dup [ filter-mapper-for [ each ] dip ] curry dip like ; inline
 206
 207 : filter-map ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) -- ... newseq )
 208     pick filter-map-as ; inline
 209
 210 : 2map-sum ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... n ) -- ... n )
 211     [ 0 ] 3dip [ dip + ] curry [ rot ] prepose 2each ; inline
 212
 213 : 2count ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... n )
 214     [ 1 0 ? ] compose 2map-sum ; inline
 215
 216 : round-robin ( seq -- newseq )
 217     [ { } ] [
 218         [ longest length iota ] keep
 219         [ [ ?nth ] with map ] curry map concat sift
 220     ] if-empty ;
 221
 222 : sift-as ( seq exemplar -- newseq )
 223     [ ] swap filter-as ;
 224
 225 : sift! ( seq -- newseq )
 226     [ ] filter! ;
 227
 228 : harvest-as ( seq exemplar -- newseq )
 229     [ empty? not ] swap filter-as ;
 230
 231 : harvest! ( seq -- newseq )
 232     [ empty? not ] filter! ;
 233
 234 : contains? ( seq elts -- ? )
 235     [ member? ] curry any? ; inline
 236
 237 : head-as ( seq n exemplar -- seq' )
 238     [ head-slice ] [ like ] bi* ; inline
 239
 240 : head*-as ( seq n exemplar -- seq' )
 241     [ head-slice* ] [ like ] bi* ; inline
 242
 243 : tail-as ( seq n exemplar -- seq' )
 244     [ tail-slice ] [ like ] bi* ; inline
 245
 246 : tail*-as ( seq n exemplar -- seq' )
 247     [ tail-slice* ] [ like ] bi* ; inline
 248
 249 : trim-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... newseq )
 250     [ trim-slice ] [ like ] bi* ; inline
 251
 252 : ?trim ( seq quot: ( elt -- ? ) -- seq/newseq )
 253     over empty? [ drop ] [
 254         over [ first-unsafe ] [ last-unsafe ] bi pick bi@ or
 255         [ trim ] [ drop ] if
 256     ] if ; inline
 257
 258 : ?trim-head ( seq quot: ( elt -- ? ) -- seq/newseq )
 259     over empty? [ drop ] [
 260         over first-unsafe over call
 261         [ trim-head ] [ drop ] if
 262     ] if ; inline
 263
 264 : ?trim-tail ( seq quot: ( elt -- ? ) -- seq/newseq )
 265     over empty? [ drop ] [
 266         over last-unsafe over call
 267         [ trim-tail ] [ drop ] if
 268     ] if ; inline
 269
 270 : unsurround ( newseq seq2 seq3 -- seq1 )
 271    [ ?head drop ] [ ?tail drop ] bi* ;
 272
 273 : none? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 274     any? not ; inline
 275
 276 : one? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 277     [ find ] 2keep rot [
 278         [ 1 + ] 2dip find-from drop not
 279     ] [ 3drop f ] if ; inline
 280
 281 : map-index! ( ... seq quot: ( ... elt index -- ... newelt ) -- ... seq )
 282     over [ [ (each-index) ] dip collect ] keep ; inline
 283
 284 <PRIVATE
 285
 286 : (2each-index) ( seq1 seq2 quot -- n quot' )
 287     [ ((2each)) [ keep ] curry ] dip compose ; inline
 288
 289 PRIVATE>
 290
 291 : 2each-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... ) -- ... )
 292     (2each-index) each-integer ; inline
 293
 294 : 2map-into ( seq1 seq2 quot into -- )
 295     [ (2each) ] dip collect ; inline
 296
 297 : 2map! ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... seq1 )
 298     pick [ 2map-into ] keep ; inline
 299
 300 : 2map-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... newelt ) -- ... newseq )
 301     pick [ (2each-index) ] dip map-integers ; inline
 302
 303 TUPLE: evens seq length ;
 304
 305 : <evens> ( seq -- evens )
 306     dup length 1 + 2/ evens boa ; inline
 307
 308 M: evens length length>> ; inline
 309
 310 M: evens nth-unsafe [ 2 * ] [ seq>> nth-unsafe ] bi* ; inline
 311
 312 INSTANCE: evens immutable-sequence
 313
 314 TUPLE: odds seq length ;
 315
 316 : <odds> ( seq -- odds )
 317     dup length 2/ odds boa ; inline
 318
 319 M: odds length length>> ; inline
 320
 321 M: odds nth-unsafe [ 2 * 1 + ] [ seq>> nth-unsafe ] bi* ; inline
 322
 323 INSTANCE: odds immutable-sequence
 324
 325 : until-empty ( seq quot -- )
 326     [ dup empty? ] swap until drop ; inline
 327
 328 : arg-max ( seq -- n )
 329     <enum> [ second-unsafe ] supremum-by first ;
 330
 331 : arg-min ( seq -- n )
 332     <enum> [ second-unsafe ] infimum-by first ;
 333
 334 <PRIVATE
 335
 336 : push-index-if ( ..a elt i quot: ( ..a elt -- ..b ? ) accum -- ..b )
 337     [ dip ] dip rot [ push ] [ 2drop ] if ; inline
 338
 339 PRIVATE>
 340
 341 : arg-where ( ... seq quot: ( ... elt -- ... ? ) -- ... indices )
 342     over length <vector> [
 343         [ push-index-if ] 2curry each-index
 344     ] keep ; inline
 345
 346 : arg-sort ( seq -- indices )
 347     dup length iota zip sort-keys values ;
 348
 349 : first= ( seq elt -- ? ) [ first ] dip = ; inline
 350 : second= ( seq elt -- ? ) [ second ] dip = ; inline
 351 : third= ( seq elt -- ? ) [ third ] dip = ; inline
 352 : fourth= ( seq elt -- ? ) [ fourth ] dip = ; inline
 353 : last= ( seq elt -- ? ) [ last ] dip = ; inline
 354 : nth= ( n seq elt -- ? ) [ nth ] dip = ; inline
 355
 356 : first? ( seq quot -- ? ) [ first ] dip call ; inline
 357 : second? ( seq quot -- ? ) [ second ] dip call ; inline
 358 : third? ( seq quot -- ? ) [ third ] dip call ; inline
 359 : fourth? ( seq quot -- ? ) [ fourth ] dip call ; inline
 360 : last? ( seq quot -- ? ) [ last ] dip call ; inline
 361 : nth? ( n seq quot -- ? ) [ nth ] dip call ; inline
 362
 363 : loop>sequence ( quot exemplar -- seq )
 364    [ '[ [ @ [ [ , ] when* ] keep ] loop ] ] dip make ; inline
 365
 366 : loop>array ( quot -- seq )
 367    { } loop>sequence ; inline
 368
 369 <PRIVATE
 370
 371 : (reverse) ( seq -- newseq )
 372     dup [ length ] keep new-sequence
 373     [ 0 swap copy-unsafe ] keep reverse! ;
 374
 375 PRIVATE>
 376
 377 : reverse-as ( seq exemplar -- newseq )
 378     [ (reverse) ] [ like ] bi* ;
 379
 380 : map-product ( ... seq quot: ( ... elt -- ... n ) -- ... n )
 381     [ 1 ] 2dip [ dip * ] curry [ swap ] prepose each ; inline
 382
 383 : insert-nth! ( elt n seq -- )
 384     [ length ] keep ensure swap pick (a,b]
 385     over '[ [ 1 + ] keep _ move-unsafe ] each
 386     set-nth-unsafe ;
 387
 388 : set-nths ( value indices seq -- )
 389     swapd '[ [ _ ] dip _ set-nth ] each ; inline
 390
 391 : set-nths-unsafe ( value indices seq -- )
 392     swapd '[ [ _ ] dip _ set-nth-unsafe ] each ; inline
 393
 394 : flatten1 ( obj -- seq )
 395     [
 396         [
 397             dup branch? [
 398                 [ dup branch? [ % ] [ , ] if ] each
 399             ] [ , ] if
 400         ]
 401     ] keep dup branch? [ drop f ] unless make ;
 402
 403 <PRIVATE
 404
 405 : (map-find-index) ( seq quot find-quot -- result elt index )
 406     [ [ f ] 2dip [ [ nip ] 2dip call dup ] curry ] dip call
 407     [ [ [ drop f ] unless ] keep ] dip ; inline
 408
 409 PRIVATE>
 410
 411 : map-find-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result elt index )
 412     [ find-index ] (map-find-index) ; inline
 413
 414 : filter-length ( seq n -- seq' ) '[ length _ = ] filter ;
 415
 416 : all-shortest ( seqs -- seqs' ) dup shortest length filter-length ;
 417
 418 : all-longest ( seqs -- seqs' ) dup longest length filter-length ;
 419
 420 : remove-first ( obj seq -- seq' )
 421     [ index ] keep over [ remove-nth ] [ nip ] if ;
 422
 423 : remove-first! ( obj seq -- seq )
 424     [ index ] keep over [ remove-nth! ] [ nip ] if ;