extra/sequences/extras/extras.factor

   1 USING: accessors arrays assocs combinators fry generalizations
   2 grouping growable kernel locals make math math.order math.ranges
   3 sequences sequences.deep sequences.private sorting splitting
   4 vectors ;
   5 IN: sequences.extras
   6
   7 : reduce1 ( seq quot -- result ) [ unclip ] dip reduce ; inline
   8
   9 :: reduce-r ( seq identity quot: ( obj1 obj2 -- obj ) -- result )
  10     seq [ identity ] [
  11         unclip [ identity quot reduce-r ] [ quot call ] bi*
  12     ] if-empty ; inline recursive
  13
  14 ! Quot must have static stack effect, unlike "reduce"
  15 :: reduce* ( seq identity quot: ( prev elt -- next ) -- result )
  16     seq [ identity ] [
  17         unclip identity swap quot call( prev elt -- next )
  18         quot reduce*
  19     ] if-empty ; inline recursive
  20
  21 :: combos ( list1 list2 -- result )
  22     list2 [ [ 2array ] curry list1 swap map ] map concat ;
  23
  24 : find-all ( seq quot: ( elt -- ? ) -- elts )
  25     [ [ length iota ] keep ] dip
  26     [ dupd call( a -- ? ) [ 2array ] [ 2drop f ] if ] curry
  27     2map sift ; inline
  28
  29 : reduce-from ( ... seq identity quot: ( ... prev elt -- ... next ) i -- ... result )
  30     [ swap ] 2dip each-from ; inline
  31
  32 :: subseq* ( from to seq -- subseq )
  33     seq length :> len
  34     from [ dup 0 < [ len + ] when ] [ 0 ] if*
  35     to [ dup 0 < [ len + ] when ] [ len ] if*
  36     [ 0 len clamp ] bi@ dupd max seq subseq ;
  37
  38 : safe-subseq ( from to seq -- subseq )
  39     [ length '[ 0 _ clamp ] bi@ ] keep subseq ;
  40
  41 : all-subseqs ( seq -- seqs )
  42     dup length [1,b] [ clump ] with map concat ;
  43
  44 :: each-subseq ( ... seq quot: ( ... x -- ... ) -- ... )
  45     seq length :> len
  46     len [0,b] [
  47         :> from
  48         from len (a,b] [
  49             :> to
  50             from to seq subseq quot call
  51         ] each
  52     ] each ; inline
  53
  54 : subseq-as ( from to seq exemplar -- subseq )
  55     [ check-slice subseq>copy (copy) ] dip like ;
  56
  57 : map-like ( seq exemplar -- seq' )
  58     '[ _ like ] map ; inline
  59
  60 : filter-all-subseqs-range ( ... seq range quot: ( ... x -- ... ) -- seq )
  61     [
  62         '[ <clumps> _ filter ] with map concat
  63     ] 3keep 2drop map-like ; inline
  64
  65 : filter-all-subseqs ( ... seq quot: ( ... x -- ... ) -- seq )
  66     [ dup length [1,b] ] dip filter-all-subseqs-range ; inline
  67
  68 :: longest-subseq ( seq1 seq2 -- subseq )
  69     seq1 length :> len1
  70     seq2 length :> len2
  71     0 :> n!
  72     0 :> end!
  73     len1 1 + [ len2 1 + 0 <array> ] replicate :> table
  74     len1 [1,b] [| x |
  75         len2 [1,b] [| y |
  76             x 1 - seq1 nth-unsafe
  77             y 1 - seq2 nth-unsafe = [
  78                 y 1 - x 1 - table nth-unsafe nth-unsafe 1 + :> len
  79                 len y x table nth-unsafe set-nth-unsafe
  80                 len n > [ len n! x end! ] when
  81             ] [ 0 y x table nth-unsafe set-nth-unsafe ] if
  82         ] each
  83     ] each end n - end seq1 subseq ;
  84
  85 : pad-longest ( seq1 seq2 elt -- seq1 seq2 )
  86     [ 2dup max-length ] dip [ pad-tail ] 2curry bi@ ;
  87
  88 : change-nths ( ... indices seq quot: ( ... elt -- ... elt' ) -- ... )
  89     [ change-nth ] 2curry each ; inline
  90
  91 : push-if-index ( ..a elt i quot: ( ..a elt i -- ..b ? ) accum -- ..b )
  92     [ 2keep drop ] dip rot [ push ] [ 2drop ] if ; inline
  93
  94 : push-if* ( ..a elt quot: ( ..a elt -- ..b obj/f ) accum -- ..b )
  95     [ call ] dip [ push ] [ drop ] if* ; inline
  96
  97 <PRIVATE
  98
  99 : (index-selector-for) ( quot length exampler -- selector accum )
 100     new-resizable [ [ push-if-index ] 2curry ] keep ; inline
 101
 102 : (selector-for*) ( quot length exemplar -- selector accum )
 103     new-resizable [ [ push-if* ] 2curry ] keep ; inline
 104
 105 PRIVATE>
 106
 107 : index-selector-for ( quot exemplar -- selector accum )
 108     [ length ] keep (index-selector-for) ; inline
 109
 110 : index-selector ( quot -- selector accum )
 111     V{ } index-selector-for ; inline
 112
 113 : selector-for* ( quot exemplar -- selector accum )
 114     [ length ] keep (selector-for*) ; inline
 115
 116 : selector* ( quot -- selector accum ) V{ } selector-for* ; inline
 117
 118 : filter-index-as ( ... seq quot: ( ... elt i -- ... ? ) exemplar -- ... seq' )
 119     pick length over [ (index-selector-for) [ each-index ] dip ] 2curry dip like ; inline
 120
 121 : filter-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... seq' )
 122     over filter-index-as ; inline
 123
 124 : even-indices ( seq -- seq' )
 125     [ length 1 + 2/ ] keep [
 126         [ [ 2 * ] dip nth-unsafe ] curry
 127     ] keep map-integers ;
 128
 129 : odd-indices ( seq -- seq' )
 130     [ length 2/ ] keep [
 131         [ [ 2 * 1 + ] dip nth-unsafe ] curry
 132     ] keep map-integers ;
 133
 134 : compact ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 135     [ split-when harvest ] dip join ; inline
 136
 137 : collapse ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 138     [ split-when ] dip
 139     [ [ harvest ] dip join ]
 140     [ [ first empty? ] dip [ prepend ] curry when ]
 141     [ [ last empty? ] dip [ append ] curry when ]
 142     2tri ; inline
 143
 144 :: slice-when ( seq quot: ( elt -- ? ) -- seq' )
 145     seq length :> len
 146     0 [ len dupd < ] [
 147         dup seq quot find-from drop
 148         [ 2dup = [ 1 + ] when ] [ len ] if*
 149         [ seq <slice> ] keep len or swap
 150     ] produce nip ; inline
 151
 152 : cut-slice* ( seq n -- before after )
 153     [ head-slice* ] [ tail-slice* ] 2bi ;
 154
 155 : ?<slice> ( from to/f sequence -- slice )
 156     over [ nip [ length ] [ ] bi ] unless <slice> ; inline
 157
 158 : sequence>slice ( sequence -- slice )
 159     [ drop 0 ] [ length ] [ ] tri <slice> ; inline
 160
 161 : slice-order-by-from ( slice1 slice2 -- slice-lt slice-gt )
 162     2dup [ from>> ] bi@ > [ swap ] when ; inline
 163
 164 : ordered-slices-range ( slice-lt slice-gt -- to from )
 165     [ to>> ] [ from>> ] bi* ;
 166
 167 : unordered-slices-range ( slice1 slice2 -- to from )
 168     slice-order-by-from ordered-slices-range ;
 169
 170 : ordered-slices-overlap? ( slice-lt slice-gt -- ? )
 171     ordered-slices-range > ; inline
 172
 173 : unordered-slices-overlap? ( slice1 slice2 -- ? )
 174     unordered-slices-range > ; inline
 175
 176 : slices-overlap? ( slice1 slice2 -- ? )
 177     unordered-slices-overlap? ;
 178
 179 : ordered-slices-touch? ( slice-lt slice-gt -- ? )
 180     ordered-slices-range >= ; inline
 181
 182 : unordered-slices-touch? ( slice1 slice2 -- ? )
 183     unordered-slices-range >= ; inline
 184
 185 : slices-touch? ( slice1 slice2 -- ? )
 186     unordered-slices-touch? ;
 187
 188 ERROR: slices-don't-touch slice1 slice2 ;
 189 : merge-slices ( slice1 slice2 -- slice/* )
 190     slice-order-by-from
 191     2dup ordered-slices-touch? [
 192         [ from>> ] [ [ to>> ] [ seq>> ] bi ] bi* <slice>
 193     ] [
 194         slices-don't-touch
 195     ] if ;
 196
 197 : length- ( n sequence -- m ) length swap - ; inline
 198
 199 : rotate-headwards ( seq n -- seq' )
 200     cut prepend ;
 201
 202 : rotate-tailwards ( seq n -- seq' )
 203     over length- cut prepend ;
 204
 205 :: rotate-headwards! ( seq n -- )
 206     n seq bounds-check length :> end
 207     0 n [ 2dup = ] [
 208         [ seq exchange-unsafe ] [ [ 1 + ] bi@ ] 2bi
 209         dup end = [ drop over ] when
 210         2over = [ -rot nip over ] when
 211     ] until 3drop ;
 212
 213 : all-rotations ( seq -- seq' )
 214     dup length iota [ rotate-headwards ] with map ;
 215
 216 <PRIVATE
 217
 218 : (appender-for) ( quot length exemplar -- appender accum )
 219     new-resizable [ [ push-all ] curry compose ] keep ; inline
 220
 221 PRIVATE>
 222
 223 : appender-for ( quot exemplar -- appender accum )
 224     [ length ] keep (appender-for) ; inline
 225
 226 : appender ( quot -- appender accum )
 227     V{ } appender-for ; inline
 228
 229 : map-concat-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 230     [ appender-for [ each ] dip ] keep like ; inline
 231
 232 : >resizable ( seq -- accum ) ! fixes map-concat "cannot apply call to run-time..."
 233     [ length ] keep [ new-resizable ] [ append! ] bi ;
 234
 235 : map-concat ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 236     over empty? [ 2drop { } ] [
 237         [ [ first ] dip call ] 2keep rot dup [
 238             >resizable [ [ push-all ] curry compose ] keep
 239             [ 1 ] 3dip [ setup-each (each-integer) ] dip
 240         ] curry dip like
 241     ] if ; inline
 242
 243 : map-filter-as ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) exemplar -- ... subseq )
 244     [ pick ] dip swap length over
 245     [ (selector-for) [ compose each ] dip ] 2curry dip like ; inline
 246
 247 : map-filter ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) -- ... subseq )
 248     pick map-filter-as ; inline
 249
 250 : map-sift ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 251     [ ] map-filter ; inline
 252
 253 : map-harvest ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 254     [ empty? not ] map-filter ; inline
 255
 256 <PRIVATE
 257
 258 : (setup-each-from) ( i seq -- n quot )
 259     [ length over [-] swap ] keep '[ _ + _ nth-unsafe ] ; inline
 260
 261 : setup-each-from ( i seq quot -- n quot' )
 262     [ (setup-each-from) ] dip compose ; inline
 263
 264 PRIVATE>
 265
 266 : map-from-as ( ... seq quot: ( ... elt -- ... newelt ) i exemplar -- ... newseq )
 267     [ -rot setup-each-from ] dip map-integers ; inline
 268
 269 : map-from ( ... seq quot: ( ... elt -- ... newelt ) i -- ... newseq )
 270     pick map-from-as ; inline
 271
 272 <PRIVATE
 273
 274 : push-map-if ( ..a elt filter-quot: ( ..a elt -- ..b ? ) map-quot: ( ..a elt -- ..b newelt ) accum -- ..b )
 275     [ keep over ] 2dip [ when ] dip rot [ push ] [ 2drop ] if ; inline
 276
 277 : (filter-mapper-for) ( filter-quot map-quot length exempler -- filter-mapper accum )
 278     new-resizable [ [ push-map-if ] 3curry ] keep ; inline
 279
 280 : filter-mapper-for ( filter-quot map-quot exemplar -- filter-mapper accum )
 281     [ length ] keep (filter-mapper-for) ; inline
 282
 283 : filter-mapper ( filter-quot map-quot -- filter-mapper accum )
 284     V{ } filter-mapper-for ; inline
 285
 286 PRIVATE>
 287
 288 : filter-map-as ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 289     [ pick ] dip swap length over
 290     [ (filter-mapper-for) [ each ] dip ] 2curry dip like ; inline
 291
 292 : filter-map ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) -- ... newseq )
 293     pick filter-map-as ; inline
 294
 295 : 2map-sum ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... n ) -- ... n )
 296     [ 0 ] 3dip [ dip + ] curry [ rot ] prepose 2each ; inline
 297
 298 : 2count ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... n )
 299     [ 1 0 ? ] compose 2map-sum ; inline
 300
 301 : round-robin ( seq -- newseq )
 302     [ { } ] [
 303         [ longest length iota ] keep
 304         [ [ ?nth ] with map ] curry map concat sift
 305     ] if-empty ;
 306
 307 : sift-as ( seq exemplar -- newseq )
 308     [ ] swap filter-as ;
 309
 310 : sift! ( seq -- newseq )
 311     [ ] filter! ;
 312
 313 : harvest-as ( seq exemplar -- newseq )
 314     [ empty? not ] swap filter-as ;
 315
 316 : harvest! ( seq -- newseq )
 317     [ empty? ] reject! ;
 318
 319 : head-as ( seq n exemplar -- seq' )
 320     [ head-slice ] [ like ] bi* ; inline
 321
 322 : head*-as ( seq n exemplar -- seq' )
 323     [ head-slice* ] [ like ] bi* ; inline
 324
 325 : tail-as ( seq n exemplar -- seq' )
 326     [ tail-slice ] [ like ] bi* ; inline
 327
 328 : tail*-as ( seq n exemplar -- seq' )
 329     [ tail-slice* ] [ like ] bi* ; inline
 330
 331 : trim-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... newseq )
 332     [ trim-slice ] [ like ] bi* ; inline
 333
 334 : ?trim ( seq quot: ( elt -- ? ) -- seq/newseq )
 335     over empty? [ drop ] [
 336         over [ first-unsafe ] [ last-unsafe ] bi pick either?
 337         [ trim ] [ drop ] if
 338     ] if ; inline
 339
 340 : ?trim-head ( seq quot: ( elt -- ? ) -- seq/newseq )
 341     over empty? [ drop ] [
 342         over first-unsafe over call
 343         [ trim-head ] [ drop ] if
 344     ] if ; inline
 345
 346 : ?trim-tail ( seq quot: ( elt -- ? ) -- seq/newseq )
 347     over empty? [ drop ] [
 348         over last-unsafe over call
 349         [ trim-tail ] [ drop ] if
 350     ] if ; inline
 351
 352 : unsurround ( newseq seq2 seq3 -- seq1 )
 353    [ ?head drop ] [ ?tail drop ] bi* ;
 354
 355 : none? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 356     any? not ; inline
 357
 358 : one? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 359     [ find ] 2keep rot [
 360         [ 1 + ] 2dip find-from drop not
 361     ] [ 3drop f ] if ; inline
 362
 363 : map-index! ( ... seq quot: ( ... elt index -- ... newelt ) -- ... seq )
 364     over [ [ (each-index) ] dip collect ] keep ; inline
 365
 366 <PRIVATE
 367
 368 : (2each-index) ( seq1 seq2 quot -- n quot' )
 369     [ setup-2each [ keep ] curry ] dip compose ; inline
 370
 371 PRIVATE>
 372
 373 : 2each-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... ) -- ... )
 374     (2each-index) each-integer ; inline
 375
 376 : 2map-into ( seq1 seq2 quot into -- )
 377     [ (2each) ] dip collect ; inline
 378
 379 : 2map! ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... seq1 )
 380     pick [ 2map-into ] keep ; inline
 381
 382 : 2map-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... newelt ) -- ... newseq )
 383     pick [ (2each-index) ] dip map-integers ; inline
 384
 385 TUPLE: evens seq length ;
 386
 387 : <evens> ( seq -- evens )
 388     dup length 1 + 2/ evens boa ; inline
 389
 390 M: evens length length>> ; inline
 391
 392 M: evens nth-unsafe [ 2 * ] [ seq>> nth-unsafe ] bi* ; inline
 393
 394 INSTANCE: evens immutable-sequence
 395
 396 TUPLE: odds seq length ;
 397
 398 : <odds> ( seq -- odds )
 399     dup length 2/ odds boa ; inline
 400
 401 M: odds length length>> ; inline
 402
 403 M: odds nth-unsafe [ 2 * 1 + ] [ seq>> nth-unsafe ] bi* ; inline
 404
 405 INSTANCE: odds immutable-sequence
 406
 407 : until-empty ( seq quot -- )
 408     [ dup empty? ] swap until drop ; inline
 409
 410 : arg-max ( seq -- n )
 411     <enum> [ second-unsafe ] supremum-by first ;
 412
 413 : arg-min ( seq -- n )
 414     <enum> [ second-unsafe ] infimum-by first ;
 415
 416 <PRIVATE
 417
 418 : push-index-if ( ..a elt i quot: ( ..a elt -- ..b ? ) accum -- ..b )
 419     [ dip ] dip rot [ push ] [ 2drop ] if ; inline
 420
 421 PRIVATE>
 422
 423 : arg-where ( ... seq quot: ( ... elt -- ... ? ) -- ... indices )
 424     over length <vector> [
 425         [ push-index-if ] 2curry each-index
 426     ] keep ; inline
 427
 428 : arg-sort ( seq -- indices )
 429     zip-index sort-keys values ;
 430
 431 : first= ( seq elt -- ? ) [ first ] dip = ; inline
 432 : second= ( seq elt -- ? ) [ second ] dip = ; inline
 433 : third= ( seq elt -- ? ) [ third ] dip = ; inline
 434 : fourth= ( seq elt -- ? ) [ fourth ] dip = ; inline
 435 : last= ( seq elt -- ? ) [ last ] dip = ; inline
 436 : nth= ( n seq elt -- ? ) [ nth ] dip = ; inline
 437
 438 : first? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ first ] dip call ; inline
 439 : second? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ second ] dip call ; inline
 440 : third? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ third ] dip call ; inline
 441 : fourth? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ fourth ] dip call ; inline
 442 : last? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ last ] dip call ; inline
 443 : nth? ( ... n seq quot: ( ... elt -- ... ? ) -- ... ? ) [ nth ] dip call ; inline
 444
 445 : loop>sequence ( quot exemplar -- seq )
 446    [ '[ [ @ [ [ , ] when* ] keep ] loop ] ] dip make ; inline
 447
 448 : loop>array ( quot -- seq )
 449    { } loop>sequence ; inline
 450
 451 <PRIVATE
 452
 453 : (reverse) ( seq -- newseq )
 454     dup [ length ] keep new-sequence
 455     [ 0 swap copy-unsafe ] keep reverse! ;
 456
 457 PRIVATE>
 458
 459 : reverse-as ( seq exemplar -- newseq )
 460     [ (reverse) ] [ like ] bi* ;
 461
 462 : map-product ( ... seq quot: ( ... elt -- ... n ) -- ... n )
 463     [ 1 ] 2dip [ dip * ] curry [ swap ] prepose each ; inline
 464
 465 : insert-nth! ( elt n seq -- )
 466     [ length ] keep ensure swap pick (a,b]
 467     over '[ [ 1 + ] keep _ move-unsafe ] each
 468     set-nth-unsafe ;
 469
 470 : set-nths ( value indices seq -- )
 471     swapd '[ _ swap _ set-nth ] each ; inline
 472
 473 : set-nths-unsafe ( value indices seq -- )
 474     swapd '[ _ swap _ set-nth-unsafe ] each ; inline
 475
 476 : flatten1 ( obj -- seq )
 477     [
 478         [
 479             dup branch? [
 480                 [ dup branch? [ % ] [ , ] if ] each
 481             ] [ , ] if
 482         ]
 483     ] keep dup branch? [ drop f ] unless make ;
 484
 485 <PRIVATE
 486
 487 : (map-find-index) ( seq quot find-quot -- result i elt )
 488     [ [ f ] 2dip [ [ nip ] 2dip call dup ] curry ] dip call
 489     [ [ [ drop f ] unless ] keep ] dip ; inline
 490
 491 PRIVATE>
 492
 493 : map-find-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 494     [ find-index ] (map-find-index) ; inline
 495
 496 : filter-length ( seq n -- seq' ) '[ length _ = ] filter ;
 497
 498 : all-shortest ( seqs -- seqs' ) dup shortest length filter-length ;
 499
 500 : all-longest ( seqs -- seqs' ) dup longest length filter-length ;
 501
 502 : remove-first ( obj seq -- seq' )
 503     [ index ] keep over [ remove-nth ] [ nip ] if ;
 504
 505 : remove-first! ( obj seq -- seq )
 506     [ index ] keep over [ remove-nth! ] [ nip ] if ;
 507
 508 : remove-last ( obj seq -- seq' )
 509     [ last-index ] keep over [ remove-nth ] [ nip ] if ;
 510
 511 : remove-last! ( obj seq -- seq )
 512     [ last-index ] keep over [ remove-nth! ] [ nip ] if ;
 513
 514 : ?first2 ( seq -- first/f second/f )
 515     dup length {
 516         { 0 [ drop f f ] }
 517         { 1 [ first-unsafe f ] }
 518         [ drop first2-unsafe ]
 519     } case ;
 520
 521 : ?first3 ( seq -- first/f second/f third/f )
 522     dup length {
 523         { 0 [ drop f f f ] }
 524         { 1 [ first-unsafe f f ] }
 525         { 2 [ first2-unsafe f ] }
 526         [ drop first3-unsafe ]
 527     } case ;
 528
 529 : ?first4 ( seq -- first/f second/f third/f fourth/f )
 530     dup length {
 531         { 0 [ drop f f f f ] }
 532         { 1 [ first-unsafe f f f ] }
 533         { 2 [ first2-unsafe f f ] }
 534         { 3 [ first3-unsafe f ] }
 535         [ drop first4-unsafe ]
 536     } case ;
 537
 538 : cut-when ( ... seq quot: ( ... elt -- ... ? ) -- ... before after )
 539     [ find drop ] 2keep drop swap
 540     [ cut ] [ f over like ] if* ; inline
 541
 542 : nth* ( n seq -- elt )
 543     [ length 1 - swap - ] [ nth ] bi ; inline
 544
 545 : each-index-from ( ... seq quot: ( ... elt index -- ... ) i -- ... )
 546     -rot (each-index) (each-integer) ; inline
 547
 548 <PRIVATE
 549
 550 : select-by* ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... i elt )
 551     [
 552         [ keep swap ] curry [ dip ] curry
 553         [ [ first 0 ] dip call ] 2keep
 554         [ 2curry 3dip 5 npick pick ] curry
 555     ] [
 556         [ [ 3drop ] [ [ 3drop ] 3dip ] if ] compose
 557     ] bi* compose 1 each-index-from nip swap ; inline
 558
 559 PRIVATE>
 560
 561 : supremum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 562     [ after? ] select-by* ; inline
 563
 564 : infimum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 565     [ before? ] select-by* ; inline
 566
 567 : change-last ( seq quot -- )
 568     [ drop length 1 - ] [ change-nth ] 2bi ; inline
 569
 570 : change-last-unsafe ( seq quot -- )
 571     [ drop length 1 - ] [ change-nth-unsafe ] 2bi ; inline
 572
 573 : replicate-into ( ... seq quot: ( ... -- ... newelt ) -- ... )
 574     over [ length ] 2dip '[ _ dip _ set-nth-unsafe ] each-integer ; inline
 575
 576 : count* ( ... seq quot: ( ... elt -- ... ? ) -- ... % )
 577     over [ count ] [ length ] bi* / ; inline
 578
 579 : find-last-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 580     [ [ 1 - ] dip find-last-integer ] (find-index) ; inline
 581
 582 : map-find-last-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 583     [ find-last-index ] (map-find-index) ; inline
 584
 585 :: (start-all) ( subseq seq increment -- indices )
 586     0
 587     [ [ subseq seq ] dip start* dup ]
 588     [ [ increment + ] keep ] produce nip ;
 589
 590 : start-all ( subseq seq -- indices )
 591     over length (start-all) ; inline
 592
 593 : start-all* ( subseq seq -- indices )
 594     1 (start-all) ; inline
 595
 596 : count-subseq ( subseq seq -- n )
 597     start-all length ; inline
 598
 599 : count-subseq* ( subseq seq -- n )
 600     start-all* length ; inline
 601
 602 : map-zip ( quot: ( x -- y ) -- alist )
 603     '[ _ keep swap ] map>alist ; inline