extra/sequences/extras/extras.factor

   1 USING: accessors arrays assocs combinators fry generalizations
   2 grouping growable kernel locals make math math.order ranges
   3 sequences sequences.deep sequences.private shuffle sorting
   4 splitting vectors ;
   5 IN: sequences.extras
   6
   7 : find-all ( ... seq quot: ( ... elt -- ... ? ) -- ... elts )
   8     [ <enumerated> ] dip '[ nip @ ] assoc-filter ; inline
   9
  10 : reduce-from ( ... seq identity quot: ( ... prev elt -- ... next ) i -- ... result )
  11     [ swap ] 2dip each-from ; inline
  12
  13 :: subseq* ( from to seq -- subseq )
  14     seq length :> len
  15     from [ dup 0 < [ len + ] when ] [ 0 ] if*
  16     to [ dup 0 < [ len + ] when ] [ len ] if*
  17     [ 0 len clamp ] bi@ dupd max seq subseq ;
  18
  19 : safe-subseq ( from to seq -- subseq )
  20     [ length '[ 0 _ clamp ] bi@ ] keep subseq ;
  21
  22 : all-subseqs ( seq -- seqs )
  23     dup length [1..b] [ clump ] with map concat ;
  24
  25 :: each-subseq ( ... seq quot: ( ... subseq -- ... ) -- ... )
  26     seq length :> len
  27     len [0..b] [| from |
  28         from len (a..b] [| to |
  29             from to seq subseq quot call
  30         ] each
  31     ] each ; inline
  32
  33 : map-like ( seq exemplar -- seq' )
  34     '[ _ like ] map ; inline
  35
  36 : filter-all-subseqs-range ( ... seq range quot: ( ... subseq -- ... ? ) -- seq )
  37     [
  38         '[ <clumps> _ filter ] with map concat
  39     ] keepdd map-like ; inline
  40
  41 : filter-all-subseqs ( ... seq quot: ( ... subseq -- ... ? ) -- seq )
  42     [ dup length [1..b] ] dip filter-all-subseqs-range ; inline
  43
  44 :: longest-subseq ( seq1 seq2 -- subseq )
  45     seq1 length :> len1
  46     seq2 length :> len2
  47     0 :> n!
  48     0 :> end!
  49     len1 1 + [ len2 1 + 0 <array> ] replicate :> table
  50     len1 [1..b] [| x |
  51         len2 [1..b] [| y |
  52             x 1 - seq1 nth-unsafe
  53             y 1 - seq2 nth-unsafe = [
  54                 y 1 - x 1 - table nth-unsafe nth-unsafe 1 + :> len
  55                 len y x table nth-unsafe set-nth-unsafe
  56                 len n > [ len n! x end! ] when
  57             ] [ 0 y x table nth-unsafe set-nth-unsafe ] if
  58         ] each
  59     ] each end n - end seq1 subseq ;
  60
  61 : pad-longest ( seq1 seq2 elt -- seq1 seq2 )
  62     [ 2dup max-length ] dip [ pad-tail ] 2curry bi@ ;
  63
  64 : pad-center ( seq n elt -- padded )
  65     swap pick length [-] [ drop ] [
  66         [ 2/ ] [ over - ] bi rot '[ _ <repetition> ] bi@
  67         pick surround-as
  68     ] if-zero ;
  69
  70 : change-nths ( ... indices seq quot: ( ... elt -- ... elt' ) -- ... )
  71     [ change-nth ] 2curry each ; inline
  72
  73 : push-if-index ( ..a elt i quot: ( ..a elt i -- ..b ? ) accum -- ..b )
  74     [ keepd ] dip rot [ push ] [ 2drop ] if ; inline
  75
  76 : push-if* ( ..a elt quot: ( ..a elt -- ..b obj/f ) accum -- ..b )
  77     [ call ] dip [ push ] [ drop ] if* ; inline
  78
  79 <PRIVATE
  80
  81 : (index-selector-as) ( quot length exampler -- selector accum )
  82     new-resizable [ [ push-if-index ] 2curry ] keep ; inline
  83
  84 : (selector-as*) ( quot length exemplar -- selector accum )
  85     new-resizable [ [ push-if* ] 2curry ] keep ; inline
  86
  87 PRIVATE>
  88
  89 : index-selector-as ( quot exemplar -- selector accum )
  90     [ length ] keep (index-selector-as) ; inline
  91
  92 : index-selector ( quot -- selector accum )
  93     V{ } index-selector-as ; inline
  94
  95 : selector-as* ( quot exemplar -- selector accum )
  96     [ length ] keep (selector-as*) ; inline
  97
  98 : selector* ( quot -- selector accum ) V{ } selector-as* ; inline
  99
 100 : filter-index-as ( ... seq quot: ( ... elt i -- ... ? ) exemplar -- ... seq' )
 101     pick length over [ (index-selector-as) [ each-index ] dip ] 2curry dip like ; inline
 102
 103 : filter-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... seq' )
 104     over filter-index-as ; inline
 105
 106 : even-indices ( seq -- seq' )
 107     [ length 1 + 2/ ] keep [
 108         [ [ 2 * ] dip nth-unsafe ] curry
 109     ] keep map-integers ;
 110
 111 : odd-indices ( seq -- seq' )
 112     [ length 2/ ] keep [
 113         [ [ 2 * 1 + ] dip nth-unsafe ] curry
 114     ] keep map-integers ;
 115
 116 : compact ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 117     [ split-when harvest ] dip join ; inline
 118
 119 : collapse ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 120     [ split-when ] dip
 121     [ [ harvest ] dip join ]
 122     [ [ first empty? ] dip [ prepend ] curry when ]
 123     [ [ last empty? ] dip [ append ] curry when ]
 124     2tri ; inline
 125
 126 :: slice-when ( seq quot: ( elt -- ? ) -- seq' )
 127     seq length :> len
 128     0 [ len dupd < ] [
 129         dup seq quot find-from drop
 130         [ 2dup = [ 1 + ] when ] [ len ] if*
 131         [ seq <slice> ] keep len or swap
 132     ] produce nip ; inline
 133
 134 : ?<slice> ( from/f to/f sequence -- slice )
 135     [ [ 0 ] unless* ] 2dip
 136     over [ nip [ length ] [ ] bi ] unless
 137     <slice> ; inline
 138
 139 : sequence>slice ( sequence -- slice )
 140     [ drop 0 ] [ length ] [ ] tri <slice> ; inline
 141
 142 : slice-order-by-from ( slice1 slice2 -- slice-lt slice-gt )
 143     2dup [ from>> ] bi@ > [ swap ] when ; inline
 144
 145 : ordered-slices-range ( slice-lt slice-gt -- to from )
 146     [ to>> ] [ from>> ] bi* ;
 147
 148 : unordered-slices-range ( slice1 slice2 -- to from )
 149     slice-order-by-from ordered-slices-range ;
 150
 151 : ordered-slices-overlap? ( slice-lt slice-gt -- ? )
 152     ordered-slices-range > ; inline
 153
 154 : unordered-slices-overlap? ( slice1 slice2 -- ? )
 155     unordered-slices-range > ; inline
 156
 157 : slices-overlap? ( slice1 slice2 -- ? )
 158     unordered-slices-overlap? ;
 159
 160 : ordered-slices-touch? ( slice-lt slice-gt -- ? )
 161     ordered-slices-range >= ; inline
 162
 163 : unordered-slices-touch? ( slice1 slice2 -- ? )
 164     unordered-slices-range >= ; inline
 165
 166 : slices-touch? ( slice1 slice2 -- ? )
 167     unordered-slices-touch? ;
 168
 169 ERROR: slices-don't-touch slice1 slice2 ;
 170
 171 : merge-slices ( slice1 slice2 -- slice/* )
 172     slice-order-by-from
 173     2dup ordered-slices-touch? [
 174         [ from>> ] [ [ to>> ] [ seq>> ] bi ] bi* <slice>
 175     ] [
 176         slices-don't-touch
 177     ] if ;
 178
 179 : rotate ( seq n -- seq' )
 180     over length mod dup 0 >= [ cut ] [ abs cut* ] if prepend ;
 181
 182 ERROR: underlying-mismatch slice1 slice2 ;
 183
 184 : ensure-same-underlying ( slice1 slice2 -- slice1 slice2 )
 185     2dup [ seq>> ] bi@ eq? [ underlying-mismatch ] unless ;
 186
 187 : span-slices ( slice1 slice2 -- slice )
 188     ensure-same-underlying
 189     [ [ from>> ] bi@ min ]
 190     [ [ to>> ] bi@ max ]
 191     [ drop seq>> ] 2tri <slice> ;
 192
 193 : ?span-slices ( slice1/f slice2/f -- slice )
 194     2dup and [ span-slices ] [ or ] if ;
 195
 196 :: rotate! ( seq n -- )
 197     seq length :> len
 198     n len mod dup 0 < [ len + ] when seq bounds-check drop 0 over
 199     [ 2dup = ] [
 200         [ seq exchange-unsafe ] [ [ 1 + ] bi@ ] 2bi
 201         dup len = [ drop over ] when
 202         2over = [ -rot nip over ] when
 203     ] until 3drop ;
 204
 205 : all-rotations ( seq -- seq' )
 206     dup length <iota> [ rotate ] with map ;
 207
 208 <PRIVATE
 209
 210 : (appender-for) ( quot length exemplar -- appender accum )
 211     new-resizable [ [ push-all ] curry compose ] keep ; inline
 212
 213 PRIVATE>
 214
 215 : appender-for ( quot exemplar -- appender accum )
 216     [ length ] keep (appender-for) ; inline
 217
 218 : appender ( quot -- appender accum )
 219     V{ } appender-for ; inline
 220
 221 : map-concat-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 222     [ appender-for [ each ] dip ] keep like ; inline
 223
 224 : >resizable ( seq -- accum ) ! fixes map-concat "cannot apply call to run-time..."
 225     [ length ] keep [ new-resizable ] [ append! ] bi ;
 226
 227 : map-concat ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 228     over empty? [ 2drop { } ] [
 229         [ [ first ] dip call ] 2keep rot [
 230             >resizable [ '[ @ _ push-all ] 1 each-from ] keep
 231         ] keep like
 232     ] if ; inline
 233
 234 : map-filter-as ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) exemplar -- ... subseq )
 235     reach length over
 236     [ (selector-as) [ compose each ] dip ] 2curry dip like ; inline
 237
 238 : map-filter ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) -- ... subseq )
 239     pick map-filter-as ; inline
 240
 241 : map-sift ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 242     [ ] map-filter ; inline
 243
 244 : map-harvest ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 245     [ empty? not ] map-filter ; inline
 246
 247 <PRIVATE
 248
 249 : (setup-each-from) ( i seq -- n quot )
 250     [ length over [-] swap ] keep '[ _ + _ nth-unsafe ] ; inline
 251
 252 : setup-each-from ( i seq quot -- n quot' )
 253     [ (setup-each-from) ] dip compose ; inline
 254
 255 PRIVATE>
 256
 257 : map-from-as ( ... seq quot: ( ... elt -- ... newelt ) i exemplar -- ... newseq )
 258     [ -rot setup-each-from ] dip map-integers ; inline
 259
 260 : map-from ( ... seq quot: ( ... elt -- ... newelt ) i -- ... newseq )
 261     pick map-from-as ; inline
 262
 263 <PRIVATE
 264
 265 : push-map-if ( ..a elt filter-quot: ( ..a elt -- ..b ? ) map-quot: ( ..a elt -- ..b newelt ) accum -- ..b )
 266     [ keep over ] 2dip [ when ] dip rot [ push ] [ 2drop ] if ; inline
 267
 268 : (filter-mapper-for) ( filter-quot map-quot length exempler -- filter-mapper accum )
 269     new-resizable [ [ push-map-if ] 3curry ] keep ; inline
 270
 271 : filter-mapper-for ( filter-quot map-quot exemplar -- filter-mapper accum )
 272     [ length ] keep (filter-mapper-for) ; inline
 273
 274 : filter-mapper ( filter-quot map-quot -- filter-mapper accum )
 275     V{ } filter-mapper-for ; inline
 276
 277 PRIVATE>
 278
 279 : filter-map-as ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 280     reach length over
 281     [ (filter-mapper-for) [ each ] dip ] 2curry dip like ; inline
 282
 283 : filter-map ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) -- ... newseq )
 284     pick filter-map-as ; inline
 285
 286 : 2map-sum ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... n ) -- ... n )
 287     [ 0 ] 3dip [ dip + ] curry [ rot ] prepose 2each ; inline
 288
 289 : 2count ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... n )
 290     [ 1 0 ? ] compose 2map-sum ; inline
 291
 292 : 3each-from
 293     ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... ) i -- ... )
 294     [ (3each) ] dip -rot (each-integer) ; inline
 295
 296 : 3map-reduce
 297     ( ..a seq1 seq2 seq3 map-quot: ( ..a elt1 elt2 elt3 -- ..b intermediate ) reduce-quot: ( ..b prev intermediate -- ..a next ) -- ..a result )
 298     [ [ [ [ first ] tri@ ] 3keep ] dip [ 3dip ] keep ] dip compose 1 3each-from ; inline
 299
 300 : round-robin ( seq -- newseq )
 301     [ { } ] [
 302         [ longest length <iota> ] keep
 303         [ [ ?nth ] with map ] curry map concat sift
 304     ] if-empty ;
 305
 306 : sift-as ( seq exemplar -- newseq )
 307     [ ] swap filter-as ;
 308
 309 : sift! ( seq -- newseq )
 310     [ ] filter! ;
 311
 312 : harvest-as ( seq exemplar -- newseq )
 313     [ empty? not ] swap filter-as ;
 314
 315 : harvest! ( seq -- newseq )
 316     [ empty? ] reject! ;
 317
 318 : head-as ( seq n exemplar -- seq' )
 319     [ head-slice ] [ like ] bi* ; inline
 320
 321 : head*-as ( seq n exemplar -- seq' )
 322     [ head-slice* ] [ like ] bi* ; inline
 323
 324 : tail-as ( seq n exemplar -- seq' )
 325     [ tail-slice ] [ like ] bi* ; inline
 326
 327 : tail*-as ( seq n exemplar -- seq' )
 328     [ tail-slice* ] [ like ] bi* ; inline
 329
 330 : trim-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... newseq )
 331     [ trim-slice ] [ like ] bi* ; inline
 332
 333 : ?trim ( seq quot: ( elt -- ? ) -- seq/newseq )
 334     over empty? [ drop ] [
 335         over [ first-unsafe ] [ last-unsafe ] bi pick either?
 336         [ trim ] [ drop ] if
 337     ] if ; inline
 338
 339 : ?trim-head ( seq quot: ( elt -- ? ) -- seq/newseq )
 340     over empty? [ drop ] [
 341         over first-unsafe over call
 342         [ trim-head ] [ drop ] if
 343     ] if ; inline
 344
 345 : ?trim-tail ( seq quot: ( elt -- ? ) -- seq/newseq )
 346     over empty? [ drop ] [
 347         over last-unsafe over call
 348         [ trim-tail ] [ drop ] if
 349     ] if ; inline
 350
 351 : unsurround ( newseq seq2 seq3 -- seq1 )
 352    [ ?head drop ] [ ?tail drop ] bi* ;
 353
 354 : >string-list ( seq -- seq' )
 355     [ "\"" 1surround ] map "," join ;
 356
 357 : one? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 358     [ find ] 2keep rot [
 359         [ 1 + ] 2dip find-from drop not
 360     ] [ 3drop f ] if ; inline
 361
 362 : map-index! ( ... seq quot: ( ... elt index -- ... newelt ) -- ... seq )
 363     over [ [ (each-index) ] dip collect ] keep ; inline
 364
 365 <PRIVATE
 366
 367 : (2each-index) ( seq1 seq2 quot -- n quot' )
 368     [ setup-2each [ keep ] curry ] dip compose ; inline
 369
 370 PRIVATE>
 371
 372 : 2each-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... ) -- ... )
 373     (2each-index) each-integer ; inline
 374
 375 : 2map-into ( seq1 seq2 quot into -- )
 376     [ (2each) ] dip collect ; inline
 377
 378 : 2map! ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... seq1 )
 379     pick [ 2map-into ] keep ; inline
 380
 381 : 2map-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... newelt ) -- ... newseq )
 382     pick [ (2each-index) ] dip map-integers ; inline
 383
 384 TUPLE: evens { seq read-only } ;
 385
 386 C: <evens> evens
 387
 388 M: evens length seq>> length 1 + 2/ ; inline
 389
 390 M: evens virtual@ [ 2 * ] [ seq>> ] bi* ; inline
 391
 392 M: evens virtual-exemplar seq>> ; inline
 393
 394 INSTANCE: evens virtual-sequence
 395
 396 TUPLE: odds { seq read-only } ;
 397
 398 C: <odds> odds
 399
 400 M: odds length seq>> length 2/ ; inline
 401
 402 M: odds virtual@ [ 2 * 1 + ] [ seq>> ] bi* ; inline
 403
 404 M: odds virtual-exemplar seq>> ; inline
 405
 406 INSTANCE: odds virtual-sequence
 407
 408 : until-empty ( seq quot -- )
 409     [ dup empty? ] swap until drop ; inline
 410
 411 : arg-max ( seq -- n )
 412     [ supremum ] keep index ;
 413
 414 : arg-min ( seq -- n )
 415     [ infimum ] keep index ;
 416
 417 <PRIVATE
 418
 419 : push-index-if ( ..a elt i quot: ( ..a elt -- ..b ? ) accum -- ..b )
 420     [ dip ] dip rot [ push ] [ 2drop ] if ; inline
 421
 422 PRIVATE>
 423
 424 : arg-where ( ... seq quot: ( ... elt -- ... ? ) -- ... indices )
 425     over length <vector> [
 426         [ push-index-if ] 2curry each-index
 427     ] keep ; inline
 428
 429 : arg-sort ( seq -- indices )
 430     zip-index sort-keys values ;
 431
 432 : first= ( seq elt -- ? ) [ first ] dip = ; inline
 433 : second= ( seq elt -- ? ) [ second ] dip = ; inline
 434 : third= ( seq elt -- ? ) [ third ] dip = ; inline
 435 : fourth= ( seq elt -- ? ) [ fourth ] dip = ; inline
 436 : last= ( seq elt -- ? ) [ last ] dip = ; inline
 437 : nth= ( n seq elt -- ? ) [ nth ] dip = ; inline
 438
 439 : first? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ first ] dip call ; inline
 440 : second? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ second ] dip call ; inline
 441 : third? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ third ] dip call ; inline
 442 : fourth? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ fourth ] dip call ; inline
 443 : last? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ last ] dip call ; inline
 444 : nth? ( ... n seq quot: ( ... elt -- ... ? ) -- ... ? ) [ nth ] dip call ; inline
 445
 446 : loop>sequence** ( ... quot: ( ... -- ... obj ? ) exemplar -- ... seq )
 447     [ ] swap produce-as nip ; inline
 448
 449 : loop>array** ( ... quot: ( ... -- ... obj ? ) -- ... array )
 450     { } loop>sequence** ; inline
 451
 452 : loop>sequence* ( ... quot: ( ... -- ... obj ? ) exemplar -- ... seq )
 453     [ t ] [ '[ [ _ dip ] [ f f f ] if* ] [ swap ] ] [ produce-as 2nip ] tri* ; inline
 454
 455 : loop>array* ( ... quot: ( ... -- ... obj ? ) -- ... array )
 456     { } loop>sequence* ; inline
 457
 458 : loop>sequence ( ... quot: ( ... -- ... obj/f ) exemplar -- ... seq )
 459     [ [ dup ] compose [ ] ] dip produce-as nip ; inline
 460
 461 : loop>array ( ... quot: ( ... -- ... obj/f ) -- ... array )
 462    { } loop>sequence ; inline
 463
 464 : zero-loop>sequence ( ... quot: ( ... n -- ... obj/f ) exemplar -- ... seq )
 465     [ 0 ] [ '[ _ keep 1 + swap ] ] [ loop>sequence ] tri* nip ; inline
 466
 467 : zero-loop>array ( quot: ( ..a n -- ..a obj ) -- seq )
 468     { } zero-loop>sequence ; inline
 469
 470 <PRIVATE
 471
 472 : (reverse) ( seq -- newseq )
 473     dup [ length ] keep new-sequence
 474     [ 0 swap copy-unsafe ] keep reverse! ;
 475
 476 PRIVATE>
 477
 478 : reverse-as ( seq exemplar -- newseq )
 479     [ (reverse) ] [ like ] bi* ;
 480
 481 : map-product ( ... seq quot: ( ... elt -- ... n ) -- ... n )
 482     [ 1 ] 2dip [ dip * ] curry [ swap ] prepose each ; inline
 483
 484 : insert-nth! ( elt n seq -- )
 485     [ length ] keep ensure swap pick (a..b]
 486     over '[ [ 1 + ] keep _ move-unsafe ] each
 487     set-nth-unsafe ;
 488
 489 : set-nths ( value indices seq -- )
 490     swapd '[ _ swap _ set-nth ] each ; inline
 491
 492 : set-nths-unsafe ( value indices seq -- )
 493     swapd '[ _ swap _ set-nth-unsafe ] each ; inline
 494
 495 <PRIVATE
 496
 497 : (map-find-index) ( seq quot find-quot -- result i elt )
 498     [ [ f ] 2dip [ [ nip ] 2dip call dup ] curry ] dip call
 499     [ [ [ drop f ] unless ] keep ] dip ; inline
 500
 501 PRIVATE>
 502
 503 : map-find-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 504     [ find-index ] (map-find-index) ; inline
 505
 506 : filter-length ( seq n -- seq' ) '[ length _ = ] filter ;
 507
 508 : all-shortest ( seqs -- seqs' ) dup shortest length filter-length ;
 509
 510 : all-longest ( seqs -- seqs' ) dup longest length filter-length ;
 511
 512 : remove-first ( obj seq -- seq' )
 513     [ index ] keep over [ remove-nth ] [ nip ] if ;
 514
 515 : remove-first! ( obj seq -- seq )
 516     [ index ] keep over [ remove-nth! ] [ nip ] if ;
 517
 518 : remove-last ( obj seq -- seq' )
 519     [ last-index ] keep over [ remove-nth ] [ nip ] if ;
 520
 521 : remove-last! ( obj seq -- seq )
 522     [ last-index ] keep over [ remove-nth! ] [ nip ] if ;
 523
 524 : ?first2 ( seq -- first/f second/f )
 525     dup length {
 526         { 0 [ drop f f ] }
 527         { 1 [ first-unsafe f ] }
 528         [ drop first2-unsafe ]
 529     } case ;
 530
 531 : ?first3 ( seq -- first/f second/f third/f )
 532     dup length {
 533         { 0 [ drop f f f ] }
 534         { 1 [ first-unsafe f f ] }
 535         { 2 [ first2-unsafe f ] }
 536         [ drop first3-unsafe ]
 537     } case ;
 538
 539 : ?first4 ( seq -- first/f second/f third/f fourth/f )
 540     dup length {
 541         { 0 [ drop f f f f ] }
 542         { 1 [ first-unsafe f f f ] }
 543         { 2 [ first2-unsafe f f ] }
 544         { 3 [ first3-unsafe f ] }
 545         [ drop first4-unsafe ]
 546     } case ;
 547
 548 : cut-when ( ... seq quot: ( ... elt -- ... ? ) -- ... before after )
 549     [ find drop ] keepd swap
 550     [ cut ] [ f over like ] if* ; inline
 551
 552 : nth* ( n seq -- elt )
 553     [ length 1 - swap - ] [ nth ] bi ; inline
 554
 555 : each-index-from ( ... seq quot: ( ... elt index -- ... ) i -- ... )
 556     -rot (each-index) (each-integer) ; inline
 557
 558 <PRIVATE
 559
 560 : select-by* ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... i elt )
 561     [
 562         [ keep swap ] curry [ dip ] curry
 563         [ [ first 0 ] dip call ] 2keep
 564         [ 2curry 3dip 5 npick pick ] curry
 565     ] [
 566         [ [ 3drop ] [ [ 3drop ] 3dip ] if ] compose
 567     ] bi* compose 1 each-index-from nip swap ; inline
 568
 569 PRIVATE>
 570
 571 : supremum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 572     [ after? ] select-by* ; inline
 573
 574 : infimum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 575     [ before? ] select-by* ; inline
 576
 577 : ?supremum ( seq/f -- elt/f )
 578     [ f ] [
 579         [ ] [ 2dup and [ max ] [ dupd ? ] if ] map-reduce
 580     ] if-empty ;
 581
 582 : ?infimum ( seq/f -- elt/f )
 583     [ f ] [
 584         [ ] [ 2dup and [ min ] [ dupd ? ] if ] map-reduce
 585     ] if-empty ;
 586
 587 : change-last ( seq quot -- )
 588     [ drop length 1 - ] [ change-nth ] 2bi ; inline
 589
 590 : change-last-unsafe ( seq quot -- )
 591     [ drop length 1 - ] [ change-nth-unsafe ] 2bi ; inline
 592
 593 : replicate-into ( ... seq quot: ( ... -- ... newelt ) -- ... )
 594     over [ length ] 2dip '[ _ dip _ set-nth-unsafe ] each-integer ; inline
 595
 596 : count* ( ... seq quot: ( ... elt -- ... ? ) -- ... % )
 597     over [ count ] [ length ] bi* / ; inline
 598
 599 : find-last-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 600     [ [ 1 - ] dip find-last-integer ] (find-index) ; inline
 601
 602 : map-find-last-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 603     [ find-last-index ] (map-find-index) ; inline
 604
 605 :: (start-all) ( seq subseq increment -- indices )
 606     0
 607     [ [ subseq seq ] dip subseq-start-from dup ]
 608     [ [ increment + ] keep ] produce nip ;
 609
 610 : start-all ( seq subseq -- indices )
 611     dup length (start-all) ; inline
 612
 613 : start-all* ( seq subseq -- indices )
 614     1 (start-all) ; inline
 615
 616 : count-subseq ( seq subseq -- n )
 617     start-all length ; inline
 618
 619 : count-subseq* ( seq subseq -- n )
 620     start-all* length ; inline
 621
 622 : assoc-zip-with ( quot: ( key value -- calc ) -- alist )
 623     '[ _ 2keep 2array swap ] assoc-map ; inline
 624
 625 : take-while ( ... seq quot: ( ... elt -- ... ? ) -- head-slice )
 626     [ '[ @ not ] find drop ] keepd swap
 627     [ dup length ] unless* head-slice ; inline
 628
 629 : drop-while ( ... seq quot: ( ... elt -- ... ? ) -- tail-slice )
 630     [ '[ @ not ] find drop ] keepd swap
 631     [ dup length ] unless* tail-slice ; inline
 632
 633 : count-head ( seq quot -- n )
 634     [ not ] compose [ find drop ] keepd length or ; inline
 635
 636 : count-tail ( seq quot -- n )
 637     [ not ] compose [ find-last drop ] keepd
 638     length swap [ - 1 - ] when* ; inline
 639
 640 :: interleaved-as ( seq glue exemplar -- newseq )
 641     seq length dup 1 - + 0 max exemplar new-sequence :> newseq
 642     seq [ 2 * newseq set-nth-unsafe ] each-index
 643     seq length 1 - [ 2 * 1 + glue swap newseq set-nth-unsafe ] each-integer
 644     newseq ;
 645
 646 : interleaved ( seq glue -- newseq )
 647     over interleaved-as ;
 648
 649 : extract! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 650     [ dup ] compose over [ length ] keep new-resizable
 651     [ [ push-if ] 2curry reject! ] keep swap like ; inline
 652
 653 : find-pred-loop ( ... i n seq quot: ( ... elt -- ... calc ? ) -- ... calc/f i/f elt/f )
 654     2pick < [
 655         [ nipd call ] 4keep
 656         7 nrot 7 nrot 7 nrot
 657         [ [ 3drop ] 2dip rot ]
 658         [ 2drop [ 1 + ] 3dip find-pred-loop ] if
 659     ] [
 660         4drop f f f
 661     ] if ; inline recursive
 662
 663 : find-pred ( ... seq quot: ( ... elt -- ... calc ) pred: ( ... calc -- ... ? ) -- ... calc/f i/f elt/f )
 664     [ 0 ] 3dip
 665     [ [ length check-length ] keep ] 2dip
 666     '[ nth-unsafe _ keep swap _ keep swap ] find-pred-loop swapd ; inline
 667
 668 ! https://en.wikipedia.org/wiki/Maximum_subarray_problem
 669 ! Kadane's algorithm O(n) largest sum in subarray
 670 : max-subarray-sum ( seq -- sum )
 671     [ -1/0. 0 ] dip
 672     [ [ + ] keep max [ max ] keep ] each drop ;